usr/src/lib/libm/amd64/src/expm1l.s

   1 /*
   2  * CDDL HEADER START
   3  *
   4  * The contents of this file are subject to the terms of the
   5  * Common Development and Distribution License (the "License").
   6  * You may not use this file except in compliance with the License.
   7  *
   8  * You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9  * or http://www.opensolaris.org/os/licensing.
  10  * See the License for the specific language governing permissions
  11  * and limitations under the License.
  12  *
  13  * When distributing Covered Code, include this CDDL HEADER in each
  14  * file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15  * If applicable, add the following below this CDDL HEADER, with the
  16  * fields enclosed by brackets "[]" replaced with your own identifying
  17  * information: Portions Copyright [yyyy] [name of copyright owner]
  18  *
  19  * CDDL HEADER END
  20  */
  21 /*
  22  * Copyright 2011 Nexenta Systems, Inc.  All rights reserved.
  23  */
  24 /*
  25  * Copyright 2005 Sun Microsystems, Inc.  All rights reserved.
  26  * Use is subject to license terms.
  27  */
  28
  29         .file "expm1l.s"
  30
  31 #include "libm.h"
  32 LIBM_ANSI_PRAGMA_WEAK(expm1l,function)
  33
  34         .data
  35         .align  16
  36 ln2_hi: .4byte  0xd1d00000, 0xb17217f7, 0x3ffe, 0x0
  37 ln2_lo: .4byte  0x4c67fc0d, 0x8654361c, 0xbfce, 0x0
  38
  39         ENTRY(expm1l)
  40         movl    16(%rsp),%ecx           / cx <--sign&bexp(x)
  41         movl    %ecx,%eax               / ax <--sign&bexp(x)
  42         andl    $0x7fff,%ecx            / ecx <-- zero_xtnd(bexp(x))
  43         cmpl    $0x3ffe,%ecx            / Is |x| < ln(2)?
  44         jb      .shortcut               / If so, take a shortcut.
  45         je      .check_tail             / |x| may be only slightly < ln(2)
  46 .general_case:                          / Here, |x| > ln(2) or x is NaN
  47         cmpl    $0x7fff,%ecx            / bexp(|x|) = bexp(INF)?
  48         je      .not_finite             / if so, x is not finite
  49         andl    $0xffff,%eax            / eax <-- sign&bexp(x)
  50         cmpl    $0xc006,%eax            / x <= -128?
  51         jae     1f                      / if so, simply return -1
  52         cmpl    $0x400d,%ecx            / |x| < 16384 = 2^14?
  53         jb      .finite_non_special     / if so, proceed with argument reduction
  54         fldt    8(%rsp)                 / x >= 16384; x
  55         fld1                            / 1, x
  56         fscale                          / +Inf, x
  57         fstp    %st(1)                  / +Inf
  58         ret
  59
  60 .finite_non_special:                    / -128 < x < -ln(2) || ln(2) < x < 2^14
  61         fldt    8(%rsp)                 / x
  62         fld     %st(0)                  / x, x
  63         fldl2e                          / log2(e), x, x
  64         fmulp                           / z := x*log2(e), x
  65         frndint                         / [z], x
  66         fst     %st(2)                  / [z], x, [z]
  67         PIC_SETUP(1)
  68         fldt    PIC_L(ln2_hi)           / ln2_hi, [z], x, [z]
  69         fmulp                           / [z]*ln2_hi, x, [z]
  70         fsubrp  %st,%st(1)              / x-[z]*ln2_hi, [z]
  71         fldt    PIC_L(ln2_lo)           / ln2_lo, x-[z]*ln2_hi, [z]
  72         PIC_WRAPUP
  73         fmul    %st(2),%st              / [z]*ln2_lo, x-[z]*ln2_hi, [z]
  74         fsubrp  %st,%st(1)              / r := x-[z]*ln(2), [z]
  75         fldl2e                          / log2(e), r, [z]
  76         fmulp                           / f := r*log2(e), [z]
  77         f2xm1                           / 2^f-1,[z]
  78         fld1                            / 1, 2^f-1, [z]
  79         faddp   %st,%st(1)              / 2^f, [z]
  80         fscale                          / e^x, [z]
  81         fstp    %st(1)                  / e^x
  82         fld1                            / 1, e^x
  83         fsubrp  %st,%st(1)              / e^x-1
  84         ret
  85
  86 .check_tail:
  87         movl    12(%rsp),%ecx           / ecx <-- hi_32(sgnfcnd(x))
  88         cmpl    $0xb17217f7,%ecx        / Is |x| < ln(2)?
  89         ja      .finite_non_special
  90         jb      .shortcut
  91         movl    8(%rsp),%edx            / edx <-- lo_32(x)
  92         cmpl    $0xd1cf79ab,%edx        / Is |x| slightly < ln(2)?
  93         ja      .finite_non_special     / branch if |x| slightly > ln(2)
  94 .shortcut:
  95         / Here, |x| < ln(2), so |z| = |x/ln(2)| < 1,
  96         / whence z is in f2xm1's domain.
  97         fldt    8(%rsp)                 / x
  98         fldl2e                          / log2(e), x
  99         fmulp                           / z := x*log2(e)
 100         f2xm1                           / 2^(x*log2(e))-1 = e^x-1
 101         ret
 102
 103 .not_finite:
 104         movl    12(%rsp),%ecx           / ecx <-- hi_32(sgnfcnd(x))
 105         cmpl    $0x80000000,%ecx        / hi_32(|x|) = hi_32(INF)?
 106         jne     .NaN_or_pinf            / if not, x is NaN
 107         movl    8(%rsp),%edx            / edx <-- lo_32(x)
 108         cmpl    $0,%edx                 / lo_32(x) = 0?
 109         jne     .NaN_or_pinf            / if not, x is NaN
 110         movl    16(%rsp),%eax           / ax <-- sign&bexp((x))
 111         andl    $0x8000,%eax            / here, x is infinite, but +/-?
 112         jz      .NaN_or_pinf            / branch if x = +INF
 113 1:
 114         fld1                            / Here, x = -inf, so return -1
 115         fchs
 116         ret
 117
 118 .NaN_or_pinf:
 119         / Here, x = NaN or +inf, so load x and return immediately.
 120         fldt    8(%rsp)
 121         ret
 122         .align  16
 123         SET_SIZE(expm1l)