CMake/HPHPFunctions.cmake

   1 if (${CMAKE_MAJOR_VERSION} GREATER 2)
   2   cmake_policy(SET CMP0026 OLD)
   3 endif()
   4
   5 include(GNUInstallDirs)
   6
   7 function(auto_sources RETURN_VALUE PATTERN SOURCE_SUBDIRS)
   8
   9   if ("${SOURCE_SUBDIRS}" STREQUAL "RECURSE")
  10     SET(PATH ".")
  11     if (${ARGC} EQUAL 4)
  12       list(GET ARGV 3 PATH)
  13     endif ()
  14   endif()
  15
  16   if ("${SOURCE_SUBDIRS}" STREQUAL "RECURSE")
  17     unset(${RETURN_VALUE})
  18     file(GLOB SUBDIR_FILES "${PATH}/${PATTERN}")
  19     list(APPEND ${RETURN_VALUE} ${SUBDIR_FILES})
  20
  21     file(GLOB subdirs RELATIVE ${PATH} ${PATH}/*)
  22
  23     foreach(DIR ${subdirs})
  24       if (IS_DIRECTORY ${PATH}/${DIR})
  25         if (NOT "${DIR}" STREQUAL "CMakeFiles")
  26           file(GLOB_RECURSE SUBDIR_FILES "${PATH}/${DIR}/${PATTERN}")
  27           list(APPEND ${RETURN_VALUE} ${SUBDIR_FILES})
  28         endif()
  29       endif()
  30     endforeach()
  31   else ()
  32     file(GLOB ${RETURN_VALUE} "${PATTERN}")
  33
  34     foreach (PATH ${SOURCE_SUBDIRS})
  35       file(GLOB SUBDIR_FILES "${PATH}/${PATTERN}")
  36       list(APPEND ${RETURN_VALUE} ${SUBDIR_FILES})
  37     endforeach(PATH ${SOURCE_SUBDIRS})
  38   endif ()
  39
  40   if (${FILTER_OUT})
  41     list(REMOVE_ITEM ${RETURN_VALUE} ${FILTER_OUT})
  42   endif()
  43
  44   set(${RETURN_VALUE} ${${RETURN_VALUE}} PARENT_SCOPE)
  45 endfunction(auto_sources)
  46
  47 macro(HHVM_SELECT_SOURCES DIR)
  48   auto_sources(files "*.cpp" "RECURSE" "${DIR}")
  49   foreach(f ${files})
  50     if (NOT (${f} MATCHES "(ext_hhvm|/(old-)?tests?/)"))
  51       list(APPEND CXX_SOURCES ${f})
  52     endif()
  53   endforeach()
  54   auto_sources(files "*.c" "RECURSE" "${DIR}")
  55   foreach(f ${files})
  56     if (NOT (${f} MATCHES "(ext_hhvm|/(old-)?tests?/)"))
  57       list(APPEND C_SOURCES ${f})
  58     endif()
  59   endforeach()
  60   if (MSVC)
  61     auto_sources(files "*.asm" "RECURSE" "${DIR}")
  62     foreach(f ${files})
  63       if (NOT (${f} MATCHES "(ext_hhvm|/(old-)?tests?/)"))
  64         list(APPEND ASM_SOURCES ${f})
  65       endif()
  66     endforeach()
  67   else()
  68     auto_sources(files "*.S" "RECURSE" "${DIR}")
  69     foreach(f ${files})
  70       if (NOT (${f} MATCHES "(ext_hhvm|/(old-)?tests?/)"))
  71         list(APPEND ASM_SOURCES ${f})
  72       endif()
  73     endforeach()
  74   endif()
  75   auto_sources(files "*.h" "RECURSE" "${DIR}")
  76   foreach(f ${files})
  77     if (NOT (${f} MATCHES "(/(old-)?tests?/)"))
  78       list(APPEND HEADER_SOURCES ${f})
  79     endif()
  80   endforeach()
  81 endmacro(HHVM_SELECT_SOURCES)
  82
  83 function(CONTAINS_STRING FILE SEARCH RETURN_VALUE)
  84   file(STRINGS ${FILE} FILE_CONTENTS REGEX ".*${SEARCH}.*")
  85   if (FILE_CONTENTS)
  86     set(${RETURN_VALUE} True PARENT_SCOPE)
  87   endif()
  88 endfunction(CONTAINS_STRING)
  89
  90 macro(MYSQL_SOCKET_SEARCH)
  91   execute_process(COMMAND mysql_config --socket OUTPUT_VARIABLE MYSQL_SOCK OUTPUT_STRIP_TRAILING_WHITESPACE ERROR_QUIET)
  92   if (NOT MYSQL_SOCK)
  93     foreach (i
  94       /var/run/mysqld/mysqld.sock
  95       /var/tmp/mysql.sock
  96       /var/run/mysql/mysql.sock
  97       /var/lib/mysql/mysql.sock
  98       /var/mysql/mysql.sock
  99       /usr/local/mysql/var/mysql.sock
 100       /Private/tmp/mysql.sock
 101       /private/tmp/mysql.sock
 102       /tmp/mysql.sock
 103       )
 104       if (EXISTS ${i})
 105         set(MYSQL_SOCK ${i})
 106         break()
 107       endif()
 108     endforeach()
 109   endif()
 110   if (MYSQL_SOCK)
 111     set(MYSQL_UNIX_SOCK_ADDR ${MYSQL_SOCK} CACHE STRING "Path to MySQL Socket")
 112   endif()
 113 endmacro()
 114
 115 function(append_systemlib TARGET SOURCE SECTNAME)
 116   if(MSVC)
 117     list(APPEND ${TARGET}_SLIBS_NAMES "${SECTNAME}")
 118     set(${TARGET}_SLIBS_NAMES ${${TARGET}_SLIBS_NAMES} PARENT_SCOPE)
 119     list(APPEND ${TARGET}_SLIBS_SOURCES "${SOURCE}")
 120     set(${TARGET}_SLIBS_SOURCES ${${TARGET}_SLIBS_SOURCES} PARENT_SCOPE)
 121   else()
 122     if (APPLE)
 123       set(${TARGET}_SLIBS ${${TARGET}_SLIBS} -Wl,-sectcreate,__text,${SECTNAME},${SOURCE} PARENT_SCOPE)
 124     else()
 125       set(${TARGET}_SLIBS ${${TARGET}_SLIBS} "--add-section" "${SECTNAME}=${SOURCE}" PARENT_SCOPE)
 126     endif()
 127     # Add the systemlib file to the "LINK_DEPENDS" for the systemlib, this will cause it
 128     # to be relinked and the systemlib re-embedded
 129     set_property(TARGET ${TARGET} APPEND PROPERTY LINK_DEPENDS ${SOURCE})
 130   endif()
 131 endfunction(append_systemlib)
 132
 133 function(embed_sections TARGET DEST)
 134   add_custom_command(TARGET ${TARGET} PRE_BUILD
 135     # OUTPUT "${CMAKE_CURRENT_SOURCE_DIR}/generated-compiler-id.txt"
 136     #        "${CMAKE_CURRENT_SOURCE_DIR}/generated-repo-schema-id.txt"
 137     #        "${CMAKE_CURRENT_SOURCE_DIR}/generated-build-id.txt"
 138     COMMAND
 139       "INSTALL_DIR=${CMAKE_BINARY_DIR}/hphp/util"
 140       "SOURCE_ROOT=${CMAKE_SOURCE_DIR}"
 141       "${HPHP_HOME}/hphp/hhvm/generate-buildinfo.sh"
 142     WORKING_DIRECTORY "${HPHP_HOME}/hphp/util"
 143     COMMENT "Generating Repo Schema ID and Compiler ID"
 144     VERBATIM)
 145
 146   if (APPLE)
 147     set(COMPILER_ID -Wl,-sectcreate,__text,"compiler_id","${CMAKE_BINARY_DIR}/hphp/util/generated-compiler-id.txt")
 148     set(REPO_SCHEMA -Wl,-sectcreate,__text,"repo_schema_id","${CMAKE_BINARY_DIR}/hphp/util/generated-repo-schema-id.txt")
 149     set(BUILD_ID -Wl,-sectcreate,__text,"build_id","${CMAKE_BINARY_DIR}/hphp/util/generated-build-id.txt")
 150     target_link_libraries(${TARGET} ${${TARGET}_SLIBS} ${COMPILER_ID} ${REPO_SCHEMA} ${BUILD_ID})
 151   elseif(MSVC)
 152     set(RESOURCE_FILE "#pragma code_page(1252)\n")
 153     set(RESOURCE_FILE "${RESOURCE_FILE}LANGUAGE 0, 0\n")
 154     set(RESOURCE_FILE "${RESOURCE_FILE}\n")
 155     set(RESOURCE_FILE "${RESOURCE_FILE}#include \"${CMAKE_BINARY_DIR}/hphp/runtime/version.h\"\n")
 156     file(READ "${CMAKE_BINARY_DIR}/hphp/hhvm/hhvm.rc" VERSION_INFO)
 157     set(RESOURCE_FILE "${RESOURCE_FILE}compiler_id RCDATA \"${CMAKE_BINARY_DIR}/hphp/util/generated-compiler-id.txt\"\n")
 158     set(RESOURCE_FILE "${RESOURCE_FILE}repo_schema_id RCDATA \"${CMAKE_BINARY_DIR}/hphp/util/generated-repo-schema-id.txt\"\n")
 159     set(RESOURCE_FILE "${RESOURCE_FILE}build_id RCDATA \"${CMAKE_BINARY_DIR}/hphp/util/generated-build-id.txt\"\n")
 160     set(RESOURCE_FILE "${RESOURCE_FILE}${VERSION_INFO}\n")
 161     set(i 0)
 162     foreach (nm ${${TARGET}_SLIBS_NAMES})
 163       list(GET ${TARGET}_SLIBS_SOURCES ${i} source)
 164       set(RESOURCE_FILE "${RESOURCE_FILE}${nm} RCDATA \"${source}\"\n")
 165       math(EXPR i "${i} + 1")
 166     endforeach()
 167     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/embed.rc "${RESOURCE_FILE}")
 168   else()
 169     add_custom_command(TARGET ${TARGET} POST_BUILD
 170       COMMAND "objcopy"
 171       ARGS "--add-section" "compiler_id=${CMAKE_BINARY_DIR}/hphp/util/generated-compiler-id.txt"
 172            "--add-section" "repo_schema_id=${CMAKE_BINARY_DIR}/hphp/util/generated-repo-schema-id.txt"
 173            "--add-section" "build_id=${CMAKE_BINARY_DIR}/hphp/util/generated-build-id.txt"
 174            ${${TARGET}_SLIBS}
 175            ${DEST}
 176       DEPENDS "${CMAKE_BINARY_DIR}/hphp/util/generated-compiler-id.txt"
 177               "${CMAKE_BINARY_DIR}/hphp/util/generated-repo-schema-id.txt"
 178               "${CMAKE_BINARY_DIR}/hphp/util/generated-build-id.txt"
 179       COMMENT "Embedding php in ${TARGET}")
 180   endif()
 181 endfunction(embed_sections)
 182
 183 macro(embed_systemlib_byname TARGET SLIB)
 184   get_filename_component(SLIB_BN ${SLIB} "NAME_WE")
 185   string(LENGTH ${SLIB_BN} SLIB_BN_LEN)
 186   math(EXPR SLIB_BN_REL_LEN "${SLIB_BN_LEN} - 4")
 187   string(SUBSTRING ${SLIB_BN} 4 ${SLIB_BN_REL_LEN} SLIB_EXTNAME)
 188   string(MD5 SLIB_HASH_NAME ${SLIB_EXTNAME})
 189   # Some platforms limit section names to 16 characters :(
 190   string(SUBSTRING ${SLIB_HASH_NAME} 0 12 SLIB_HASH_NAME_SHORT)
 191   if (MSVC)
 192     # The dot would be causing the RC lexer to begin a number in the
 193     # middle of our resource name, so use an underscore instead.
 194     append_systemlib(${TARGET} ${SLIB} "ext_${SLIB_HASH_NAME_SHORT}")
 195   else()
 196     append_systemlib(${TARGET} ${SLIB} "ext.${SLIB_HASH_NAME_SHORT}")
 197   endif()
 198 endmacro()
 199
 200 function(embed_all_systemlibs TARGET ROOT DEST)
 201   add_dependencies(${TARGET} systemlib)
 202   append_systemlib(${TARGET} ${ROOT}/system/systemlib.php systemlib)
 203   foreach(SLIB ${EXTENSION_SYSTEMLIB_SOURCES} ${EZC_SYSTEMLIB_SOURCES})
 204     embed_systemlib_byname(${TARGET} ${SLIB})
 205   endforeach()
 206   embed_sections(${TARGET} ${DEST})
 207 endfunction(embed_all_systemlibs)
 208
 209 # Custom install function that doesn't relink, instead it uses chrpath to change it, if
 210 # it's available, otherwise, it leaves the chrpath alone
 211 function(HHVM_INSTALL TARGET DEST)
 212   get_target_property(LOC ${TARGET} LOCATION)
 213   get_target_property(TY ${TARGET} TYPE)
 214   if (FOUND_CHRPATH)
 215     get_target_property(RPATH ${TARGET} INSTALL_RPATH)
 216     if (NOT RPATH STREQUAL "RPATH-NOTFOUND")
 217       if (RPATH STREQUAL "")
 218         install(CODE "execute_process(COMMAND \"${CHRPATH}\" \"-d\" \"${LOC}\" ERROR_QUIET)")
 219       else()
 220         install(CODE "execute_process(COMMAND \"${CHRPATH}\" \"-r\" \"${RPATH}\" \"${LOC}\" ERROR_QUIET)")
 221       endif()
 222     endif()
 223   endif()
 224   string(TOUPPER ${DEST} DEST_UPPER)
 225   install(CODE "FILE(INSTALL DESTINATION \"\${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_${DEST_UPPER}DIR}\" TYPE ${TY} FILES \"${LOC}\")")
 226 endfunction(HHVM_INSTALL)
 227
 228 function(HHVM_PUBLIC_HEADERS TARGET)
 229   install(
 230     CODE "INCLUDE(\"${HPHP_HOME}/CMake/HPHPFunctions.cmake\")
 231       HHVM_INSTALL_HEADERS(${TARGET} ${HPHP_HOME}
 232       \"\${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_INCLUDEDIR}\" ${ARGN})"
 233     COMPONENT dev)
 234 endfunction()
 235
 236 function(HHVM_INSTALL_HEADERS TARGET SRCROOT DEST)
 237   message(STATUS "Installing header files for ${TARGET}")
 238   foreach(src_rel ${ARGN})
 239     # Determine the relative directory name so that we can mirror the
 240     # directory structure in the output
 241     file(RELATIVE_PATH dest_rel ${SRCROOT} ${src_rel})
 242     if (IS_ABSOLUTE ${dest_rel})
 243       message(WARNING "${TARGET}: Header file ${dest_rel} is not inside ${SRCROOT}")
 244     else()
 245       string(FIND ${dest_rel} / slash_pos REVERSE)
 246       if(slash_pos EQUAL -1)
 247         set(dest_rel)
 248       else()
 249         string(SUBSTRING ${dest_rel} 0 ${slash_pos} dest_rel)
 250       endif()
 251       file(COPY ${src_rel}
 252         DESTINATION "$ENV{DESTDIR}${DEST}/${dest_rel}"
 253         NO_SOURCE_PERMISSIONS)
 254     endif()
 255   endforeach()
 256 endfunction()
 257
 258 macro(HHVM_EXT_OPTION EXTNAME PACKAGENAME)
 259   if (NOT DEFINED EXT_${EXTNAME})
 260     # Implicit check
 261     find_package(${PACKAGENAME})
 262   elseif (EXT_${EXTNAME} STREQUAL "ON")
 263     # Explicit check
 264     find_package(${PACKAGENAME} REQUIRED)
 265   endif()
 266 endmacro()
 267
 268 # Remove all files matching a set of patterns, and,
 269 # optionally, not matching a second set of patterns,
 270 # from a set of lists.
 271 #
 272 # Example:
 273 # This will remove all files in the CPP_SOURCES list
 274 # matching "/test/" or "Test.cpp$", but not matching
 275 # "BobTest.cpp$".
 276 # HHVM_REMOVE_MATCHES_FROM_LISTS(CPP_SOURCES MATCHES "/test/" "Test.cpp$" IGNORE_MATCHES "BobTest.cpp$")
 277 #
 278 # Parameters:
 279 #
 280 # [...]:
 281 # The names of the lists to remove matches from.
 282 #
 283 # [MATCHES ...]:
 284 # The matches to remove from the lists.
 285 #
 286 # [IGNORE_MATCHES ...]:
 287 # The matches not to remove, even if they match
 288 # the main set of matches to remove.
 289 function(HHVM_REMOVE_MATCHES_FROM_LISTS)
 290   set(LISTS_TO_SEARCH)
 291   set(MATCHES_TO_REMOVE)
 292   set(MATCHES_TO_IGNORE)
 293   set(argumentState 0)
 294   foreach (arg ${ARGN})
 295     if ("x${arg}" STREQUAL "xMATCHES")
 296       set(argumentState 1)
 297     elseif ("x${arg}" STREQUAL "xIGNORE_MATCHES")
 298       set(argumentState 2)
 299     elseif (argumentState EQUAL 0)
 300       list(APPEND LISTS_TO_SEARCH ${arg})
 301     elseif (argumentState EQUAL 1)
 302       list(APPEND MATCHES_TO_REMOVE ${arg})
 303     elseif (argumentState EQUAL 2)
 304       list(APPEND MATCHES_TO_IGNORE ${arg})
 305     else()
 306       message(FATAL_ERROR "Unknown argument state!")
 307     endif()
 308   endforeach()
 309
 310   foreach (theList ${LISTS_TO_SEARCH})
 311     foreach (entry ${${theList}})
 312       foreach (match ${MATCHES_TO_REMOVE})
 313         if (${entry} MATCHES ${match})
 314           set(SHOULD_IGNORE OFF)
 315           foreach (ign ${MATCHES_TO_IGNORE})
 316             if (${entry} MATCHES ${ign})
 317               set(SHOULD_IGNORE ON)
 318               break()
 319             endif()
 320           endforeach()
 321
 322           if (NOT SHOULD_IGNORE)
 323             list(REMOVE_ITEM ${theList} ${entry})
 324           endif()
 325         endif()
 326       endforeach()
 327     endforeach()
 328     set(${theList} ${${theList}} PARENT_SCOPE)
 329   endforeach()
 330 endfunction()
 331
 332 # Automatically create source_group directives for the sources passed in.
 333 function(auto_source_group rootName rootDir)
 334   file(TO_CMAKE_PATH "${rootDir}" rootDir)
 335   string(LENGTH "${rootDir}" rootDirLength)
 336   set(sourceGroups)
 337   foreach (fil ${ARGN})
 338     file(TO_CMAKE_PATH "${fil}" filePath)
 339     string(FIND "${filePath}" "/" rIdx REVERSE)
 340     if (rIdx EQUAL -1)
 341       message(FATAL_ERROR "Unable to locate the final forward slash in '${filePath}'!")
 342     endif()
 343     string(SUBSTRING "${filePath}" 0 ${rIdx} filePath)
 344
 345     string(LENGTH "${filePath}" filePathLength)
 346     string(FIND "${filePath}" "${rootDir}" rIdx)
 347     if (rIdx EQUAL 0)
 348       math(EXPR filePathLength "${filePathLength} - ${rootDirLength}")
 349       string(SUBSTRING "${filePath}" ${rootDirLength} ${filePathLength} fileGroup)
 350
 351       string(REPLACE "/" "\\" fileGroup "${fileGroup}")
 352       set(fileGroup "\\${rootName}${fileGroup}")
 353
 354       list(FIND sourceGroups "${fileGroup}" rIdx)
 355       if (rIdx EQUAL -1)
 356         list(APPEND sourceGroups "${fileGroup}")
 357         source_group("${fileGroup}" REGULAR_EXPRESSION "${filePath}/[^/.]+(.(tab|yy))?.(c|cc|cpp|h|hpp|ll|php|tcc|y)$")
 358       endif()
 359     endif()
 360   endforeach()
 361 endfunction()
 362
 363 function(parse_version PREFIX VERSION)
 364   if (NOT ${VERSION} MATCHES "^[0-9]+\\.[0-9]+(\\.[0-9]+)?(-.+)?$")
 365     message(FATAL_ERROR "VERSION must conform to X.Y(.Z)?(-.+)?")
 366   endif()
 367
 368   string(FIND ${VERSION} "-" SUFFIX_POS)
 369   set(SUFFIX "")
 370   if (SUFFIX_POS)
 371     string(SUBSTRING ${VERSION} ${SUFFIX_POS} -1 SUFFIX)
 372     string(SUBSTRING ${VERSION} 0 ${SUFFIX_POS} NUMERIC_VERSION)
 373   else()
 374     set(NUMERIC_VERSION ${VERSION})
 375   endif()
 376
 377   string(REPLACE "." ";" VERSION_LIST "${NUMERIC_VERSION}")
 378   list(GET VERSION_LIST 0 MAJOR)
 379   list(GET VERSION_LIST 1 MINOR)
 380   list(LENGTH VERSION_LIST VERSION_LIST_LENGTH)
 381   if (VERSION_LIST_LENGTH GREATER 2)
 382     list(GET VERSION_LIST 2 PATCH)
 383   else()
 384     set(PATCH 0)
 385   endif()
 386
 387   set(${PREFIX}MAJOR ${MAJOR} PARENT_SCOPE)
 388   set(${PREFIX}MINOR ${MINOR} PARENT_SCOPE)
 389   set(${PREFIX}PATCH ${PATCH} PARENT_SCOPE)
 390   set(${PREFIX}SUFFIX ${SUFFIX} PARENT_SCOPE)
 391 endfunction()
 392
 393 # MSVC doesn't support a --whole-archive flag, but newer versions
 394 # of CMake do support object libraries, which give the same result.
 395 # As we can't easily upgrade the normal builds to CMake 3.0, we
 396 # will just require CMake 3.0+ for MSVC builds only.
 397 function(add_object_library libraryName)
 398   if (MSVC)
 399     add_library(${libraryName} OBJECT ${ARGN})
 400   else()
 401     add_library(${libraryName} STATIC ${ARGN})
 402   endif()
 403 endfunction()
 404
 405 # Get what might be the objects of the object libraries, if needed.
 406 function(get_object_libraries_objects targetVariable)
 407   set(OBJECTS)
 408   if (MSVC)
 409     foreach (fil ${ARGN})
 410       list(APPEND OBJECTS $<TARGET_OBJECTS:${fil}>)
 411     endforeach()
 412   endif()
 413
 414   set(${targetVariable} ${OBJECTS} PARENT_SCOPE)
 415 endfunction()
 416
 417 # Add the additional link targets for a set of object libraries,
 418 # if needed.
 419 function(link_object_libraries target)
 420   if (MSVC)
 421     return()
 422   endif()
 423
 424   set(WHOLE_ARCHIVE_LIBS)
 425   foreach (fil ${ARGN})
 426     list(APPEND WHOLE_ARCHIVE_LIBS ${fil})
 427   endforeach()
 428
 429   set(ANCHOR_SYMS)
 430   if (APPLE)
 431     set(ANCHOR_SYMS
 432       -Wl,-pagezero_size,0x00001000
 433       # Set the .text.keep section to be executable.
 434       -Wl,-segprot,.text,rx,rx)
 435     foreach(lib ${WHOLE_ARCHIVE_LIBS})
 436       # It's important to use -Xlinker and not -Wl here: ${lib} needs to be its
 437       # own option on the command line, since target_link_libraries will expand it
 438       # from its logical name here into the full .a path. (Eww.)
 439       list(APPEND ANCHOR_SYMS -Xlinker -force_load -Xlinker ${lib})
 440     endforeach()
 441   else()
 442     set(ANCHOR_SYMS -Wl,--whole-archive ${WHOLE_ARCHIVE_LIBS} -Wl,--no-whole-archive)
 443   endif()
 444
 445   target_link_libraries(${target} ${ANCHOR_SYMS})
 446 endfunction()
 447
 448 # This should be called for object libraries, rather than calling
 449 # hphp_link directly.
 450 function(object_library_hphp_link target)
 451   # MSVC can't have it. (see below)
 452   if (NOT MSVC)
 453     hphp_link(${target})
 454   endif()
 455 endfunction()
 456
 457 # If a library needs to be linked in to make GNU ld happy,
 458 # it should be done by calling this.
 459 function(object_library_ld_link_libraries target)
 460   if (${ARGC})
 461     # CMake doesn't allow calls to target_link_libraries if the target
 462     # is an OBJECT library, so MSVC can't have this.
 463     if (NOT MSVC)
 464       target_link_libraries(${target} ${ARGN})
 465     endif()
 466   endif()
 467 endfunction()
 468
 469 set(
 470   HHVM_THIRD_PARTY_SOURCE_CACHE_PREFIX
 471   ""
 472   CACHE
 473   STRING
 474   "URL prefix containing cache of third-party dependencies"
 475 )
 476 set(
 477   HHVM_THIRD_PARTY_SOURCE_CACHE_SUFFIX
 478   ""
 479   CACHE
 480   STRING
 481   "URL suffix for third-party dependency cache"
 482 )
 483 set(
 484   HHVM_THIRD_PARTY_SOURCE_ONLY_USE_CACHE
 485   OFF
 486   CACHE
 487   BOOL
 488   "Do not download sources that are not in cache; may cause build to fail."
 489 )
 490 set(
 491   HHVM_THIRD_PARTY_SOURCE_URL_LIST_OUTPUT
 492   ""
 493   CACHE
 494   STRING
 495   "Path to a text file to put a list of sources that should be in the cache"
 496 )
 497
 498 # Usage:
 499 #  SET_HHVM_THIRD_PARTY_SOURCE_ARGS(
 500 #    MY_VAR_NAME
 501 #    SOURCE_URL https://example.com/
 502 #    SOURCE_HASH SHA256=deadbeef
 503 #  )
 504 #  ... or ...
 505 #  SET_HHVM_THIRD_PARTY_SOURCE_ARGS(
 506 #    MY_VAR_NAME
 507 #    Linux_URL https://example.com/linux.tar.bz2
 508 #    Linux_HASH SHA256=deadbeef
 509 #    Darwin_URL https://example.com/macos.tar.bz2
 510 #    Darwin_HASH SHA256=deadbeef
 511 #  )
 512 #
 513 macro(SET_HHVM_THIRD_PARTY_SOURCE_ARGS VAR_NAME)
 514   cmake_parse_arguments(
 515     # Prefix (FOO becomes _arg_FOO - trailing _ implied)
 516     _arg
 517     # No-arg parameter (none):
 518     ""
 519     # Single-argument parameters
 520     "SOURCE_URL;SOURCE_HASH;Linux_URL;Linux_HASH;Darwin_URL;Darwin_HASH;FILENAME_PREFIX"
 521     # Multi-argument parameters (none)
 522     ""
 523     ${ARGN}
 524   )
 525
 526   # Try source, but fall back to platform-specific
 527   if (NOT "${_arg_SOURCE_URL}" STREQUAL "")
 528     set(_URL "${_arg_SOURCE_URL}")
 529     set("${VAR_NAME}" URL_HASH "${_arg_SOURCE_HASH}")
 530     if (NOT "${HHVM_THIRD_PARTY_SOURCE_URL_LIST_OUTPUT}" STREQUAL "")
 531       FILE(
 532         APPEND
 533         "${HHVM_THIRD_PARTY_SOURCE_URL_LIST_OUTPUT}"
 534         "${_arg_SOURCE_URL}\n"
 535       )
 536     endif()
 537   else()
 538     set(_URL "${_arg_${CMAKE_HOST_SYSTEM_NAME}_URL}")
 539     set("${VAR_NAME}" URL_HASH "${_arg_${CMAKE_HOST_SYSTEM_NAME}_HASH}")
 540     if (NOT "${HHVM_THIRD_PARTY_SOURCE_URL_LIST_OUTPUT}" STREQUAL "")
 541       FILE(
 542         APPEND
 543         "${HHVM_THIRD_PARTY_SOURCE_URL_LIST_OUTPUT}"
 544         "${_arg_Linux_URL}\n"
 545         "${_arg_Darwin_URL}\n"
 546       )
 547     endif()
 548   endif()
 549
 550
 551   get_filename_component("_URL_NAME" "${_URL}" NAME)
 552   if ("${HHVM_THIRD_PARTY_SOURCE_CACHE_PREFIX}" STREQUAL "")
 553     list(APPEND ${VAR_NAME} URL "${_URL}")
 554     if (${HHVM_THIRD_PARTY_SOURCE_ONLY_USE_CACHE})
 555       message(
 556         FATAL_ERROR
 557         "HHVM_THIRD_PARTY_ONLY_USE_CACHE is set, but cache is not configured"
 558       )
 559     endif()
 560   else()
 561     list(
 562       APPEND "${VAR_NAME}"
 563       URL
 564       "${HHVM_THIRD_PARTY_SOURCE_CACHE_PREFIX}${_arg_FILENAME_PREFIX}${_URL_NAME}${HHVM_THIRD_PARTY_SOURCE_CACHE_SUFFIX}"
 565     )
 566     if (NOT ${HHVM_THIRD_PARTY_SOURCE_ONLY_USE_CACHE})
 567       list(APPEND "${VAR_NAME}" "${_URL}")
 568     endif()
 569   endif()
 570   list(APPEND "${VAR_NAME}" DOWNLOAD_NAME "${_arg_FILENAME_PREFIX}${_URL_NAME}")
 571   message(STATUS "Download name: ${_arg_FILENAME_PREFIX}${_URL_NAME}")
 572 endmacro()