CMake/HPHPFunctions.cmake

   1 if (${CMAKE_MAJOR_VERSION} GREATER 2)
   2   cmake_policy(SET CMP0026 OLD)
   3 endif()
   4
   5 include(GNUInstallDirs)
   6
   7 function(auto_sources RETURN_VALUE PATTERN SOURCE_SUBDIRS)
   8
   9   if ("${SOURCE_SUBDIRS}" STREQUAL "RECURSE")
  10     SET(PATH ".")
  11     if (${ARGC} EQUAL 4)
  12       list(GET ARGV 3 PATH)
  13     endif ()
  14   endif()
  15
  16   if ("${SOURCE_SUBDIRS}" STREQUAL "RECURSE")
  17     unset(${RETURN_VALUE})
  18     file(GLOB SUBDIR_FILES "${PATH}/${PATTERN}")
  19     list(APPEND ${RETURN_VALUE} ${SUBDIR_FILES})
  20
  21     file(GLOB subdirs RELATIVE ${PATH} ${PATH}/*)
  22
  23     foreach(DIR ${subdirs})
  24       if (IS_DIRECTORY ${PATH}/${DIR})
  25         if (NOT "${DIR}" STREQUAL "CMakeFiles")
  26           file(GLOB_RECURSE SUBDIR_FILES "${PATH}/${DIR}/${PATTERN}")
  27           list(APPEND ${RETURN_VALUE} ${SUBDIR_FILES})
  28         endif()
  29       endif()
  30     endforeach()
  31   else ()
  32     file(GLOB ${RETURN_VALUE} "${PATTERN}")
  33
  34     foreach (PATH ${SOURCE_SUBDIRS})
  35       file(GLOB SUBDIR_FILES "${PATH}/${PATTERN}")
  36       list(APPEND ${RETURN_VALUE} ${SUBDIR_FILES})
  37     endforeach(PATH ${SOURCE_SUBDIRS})
  38   endif ()
  39
  40   if (${FILTER_OUT})
  41     list(REMOVE_ITEM ${RETURN_VALUE} ${FILTER_OUT})
  42   endif()
  43
  44   set(${RETURN_VALUE} ${${RETURN_VALUE}} PARENT_SCOPE)
  45 endfunction(auto_sources)
  46
  47 macro(HHVM_SELECT_SOURCES DIR)
  48   auto_sources(files "*.cpp" "RECURSE" "${DIR}")
  49   foreach(f ${files})
  50     if (NOT (${f} MATCHES "(ext_hhvm|/(old-)?tests?/)"))
  51       list(APPEND CXX_SOURCES ${f})
  52     endif()
  53   endforeach()
  54   auto_sources(files "*.c" "RECURSE" "${DIR}")
  55   foreach(f ${files})
  56     if (NOT (${f} MATCHES "(ext_hhvm|/(old-)?tests?/)"))
  57       list(APPEND C_SOURCES ${f})
  58     endif()
  59   endforeach()
  60   if (MSVC)
  61     auto_sources(files "*.asm" "RECURSE" "${DIR}")
  62     foreach(f ${files})
  63       if (NOT (${f} MATCHES "(ext_hhvm|/(old-)?tests?/)"))
  64         list(APPEND ASM_SOURCES ${f})
  65       endif()
  66     endforeach()
  67   else()
  68     auto_sources(files "*.S" "RECURSE" "${DIR}")
  69     foreach(f ${files})
  70       if (NOT (${f} MATCHES "(ext_hhvm|/(old-)?tests?/)"))
  71         list(APPEND ASM_SOURCES ${f})
  72       endif()
  73     endforeach()
  74   endif()
  75   auto_sources(files "*.h" "RECURSE" "${DIR}")
  76   foreach(f ${files})
  77     if (NOT (${f} MATCHES "(/(old-)?tests?/)"))
  78       list(APPEND HEADER_SOURCES ${f})
  79     endif()
  80   endforeach()
  81 endmacro(HHVM_SELECT_SOURCES)
  82
  83 function(CONTAINS_STRING FILE SEARCH RETURN_VALUE)
  84   file(STRINGS ${FILE} FILE_CONTENTS REGEX ".*${SEARCH}.*")
  85   if (FILE_CONTENTS)
  86     set(${RETURN_VALUE} True PARENT_SCOPE)
  87   endif()
  88 endfunction(CONTAINS_STRING)
  89
  90 macro(MYSQL_SOCKET_SEARCH)
  91   execute_process(COMMAND mysql_config --socket OUTPUT_VARIABLE MYSQL_SOCK OUTPUT_STRIP_TRAILING_WHITESPACE ERROR_QUIET)
  92   if (NOT MYSQL_SOCK)
  93     foreach (i
  94       /var/run/mysqld/mysqld.sock
  95       /var/tmp/mysql.sock
  96       /var/run/mysql/mysql.sock
  97       /var/lib/mysql/mysql.sock
  98       /var/mysql/mysql.sock
  99       /usr/local/mysql/var/mysql.sock
 100       /Private/tmp/mysql.sock
 101       /private/tmp/mysql.sock
 102       /tmp/mysql.sock
 103       )
 104       if (EXISTS ${i})
 105         set(MYSQL_SOCK ${i})
 106         break()
 107       endif()
 108     endforeach()
 109   endif()
 110   if (MYSQL_SOCK)
 111     set(MYSQL_UNIX_SOCK_ADDR ${MYSQL_SOCK} CACHE STRING "Path to MySQL Socket")
 112   endif()
 113 endmacro()
 114
 115 function(append_systemlib TARGET SOURCE SECTNAME)
 116   if(MSVC)
 117     list(APPEND ${TARGET}_SLIBS_NAMES "${SECTNAME}")
 118     set(${TARGET}_SLIBS_NAMES ${${TARGET}_SLIBS_NAMES} PARENT_SCOPE)
 119     list(APPEND ${TARGET}_SLIBS_SOURCES "${SOURCE}")
 120     set(${TARGET}_SLIBS_SOURCES ${${TARGET}_SLIBS_SOURCES} PARENT_SCOPE)
 121   else()
 122     if (APPLE)
 123       set(${TARGET}_SLIBS ${${TARGET}_SLIBS} -Wl,-sectcreate,__text,${SECTNAME},${SOURCE} PARENT_SCOPE)
 124     else()
 125       set(${TARGET}_SLIBS ${${TARGET}_SLIBS} "--add-section" "${SECTNAME}=${SOURCE}" PARENT_SCOPE)
 126     endif()
 127     # Add the systemlib file to the "LINK_DEPENDS" for the systemlib, this will cause it
 128     # to be relinked and the systemlib re-embedded
 129     set_property(TARGET ${TARGET} APPEND PROPERTY LINK_DEPENDS ${SOURCE})
 130   endif()
 131 endfunction(append_systemlib)
 132
 133 function(embed_sections TARGET DEST)
 134   add_custom_command(TARGET ${TARGET} PRE_BUILD
 135     # OUTPUT "${CMAKE_CURRENT_SOURCE_DIR}/generated-compiler-id.txt"
 136     #        "${CMAKE_CURRENT_SOURCE_DIR}/generated-repo-schema-id.txt"
 137     #        "${CMAKE_CURRENT_SOURCE_DIR}/generated-build-id.txt"
 138     COMMAND "${HPHP_HOME}/hphp/hhvm/generate-buildinfo.sh"
 139     WORKING_DIRECTORY "${HPHP_HOME}/hphp/util"
 140     COMMENT "Generating Repo Schema ID and Compiler ID"
 141     VERBATIM)
 142
 143   if (APPLE)
 144     set(COMPILER_ID -Wl,-sectcreate,__text,"compiler_id","${HPHP_HOME}/hphp/util/generated-compiler-id.txt")
 145     set(REPO_SCHEMA -Wl,-sectcreate,__text,"repo_schema_id","${HPHP_HOME}/hphp/util/generated-repo-schema-id.txt")
 146     set(BUILD_ID -Wl,-sectcreate,__text,"build_id","${HPHP_HOME}/hphp/util/generated-build-id.txt")
 147     target_link_libraries(${TARGET} ${${TARGET}_SLIBS} ${COMPILER_ID} ${REPO_SCHEMA} ${BUILD_ID})
 148   elseif(MSVC)
 149     set(RESOURCE_FILE "#pragma code_page(1252)\n")
 150     set(RESOURCE_FILE "${RESOURCE_FILE}LANGUAGE 0, 0\n")
 151     set(RESOURCE_FILE "${RESOURCE_FILE}\n")
 152     set(RESOURCE_FILE "${RESOURCE_FILE}#include \"${HPHP_HOME}/hphp/runtime/version.h\"\n")
 153     file(READ "${HPHP_HOME}/hphp/hhvm/hhvm.rc" VERSION_INFO)
 154     set(RESOURCE_FILE "${RESOURCE_FILE}compiler_id RCDATA \"${HPHP_HOME}/hphp/util/generated-compiler-id.txt\"\n")
 155     set(RESOURCE_FILE "${RESOURCE_FILE}repo_schema_id RCDATA \"${HPHP_HOME}/hphp/util/generated-repo-schema-id.txt\"\n")
 156     set(RESOURCE_FILE "${RESOURCE_FILE}build_id RCDATA \"${HPHP_HOME}/hphp/util/generated-build-id.txt\"\n")
 157     set(RESOURCE_FILE "${RESOURCE_FILE}${VERSION_INFO}\n")
 158     set(i 0)
 159     foreach (nm ${${TARGET}_SLIBS_NAMES})
 160       list(GET ${TARGET}_SLIBS_SOURCES ${i} source)
 161       set(RESOURCE_FILE "${RESOURCE_FILE}${nm} RCDATA \"${source}\"\n")
 162       math(EXPR i "${i} + 1")
 163     endforeach()
 164     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/embed.rc "${RESOURCE_FILE}")
 165   else()
 166     add_custom_command(TARGET ${TARGET} POST_BUILD
 167       COMMAND "objcopy"
 168       ARGS "--add-section" "compiler_id=${HPHP_HOME}/hphp/util/generated-compiler-id.txt"
 169            "--add-section" "repo_schema_id=${HPHP_HOME}/hphp/util/generated-repo-schema-id.txt"
 170            "--add-section" "build_id=${HPHP_HOME}/hphp/util/generated-build-id.txt"
 171            ${${TARGET}_SLIBS}
 172            ${DEST}
 173       DEPENDS "${HPHP_HOME}/hphp/util/generated-compiler-id.txt"
 174               "${HPHP_HOME}/hphp/util/generated-repo-schema-id.txt"
 175               "${HPHP_HOME}/hphp/util/generated-build-id.txt"
 176       COMMENT "Embedding php in ${TARGET}")
 177   endif()
 178 endfunction(embed_sections)
 179
 180 macro(embed_systemlib_byname TARGET SLIB)
 181   get_filename_component(SLIB_BN ${SLIB} "NAME_WE")
 182   string(LENGTH ${SLIB_BN} SLIB_BN_LEN)
 183   math(EXPR SLIB_BN_REL_LEN "${SLIB_BN_LEN} - 4")
 184   string(SUBSTRING ${SLIB_BN} 4 ${SLIB_BN_REL_LEN} SLIB_EXTNAME)
 185   string(MD5 SLIB_HASH_NAME ${SLIB_EXTNAME})
 186   # Some platforms limit section names to 16 characters :(
 187   string(SUBSTRING ${SLIB_HASH_NAME} 0 12 SLIB_HASH_NAME_SHORT)
 188   if (MSVC)
 189     # The dot would be causing the RC lexer to begin a number in the
 190     # middle of our resource name, so use an underscore instead.
 191     append_systemlib(${TARGET} ${SLIB} "ext_${SLIB_HASH_NAME_SHORT}")
 192   else()
 193     append_systemlib(${TARGET} ${SLIB} "ext.${SLIB_HASH_NAME_SHORT}")
 194   endif()
 195 endmacro()
 196
 197 function(embed_all_systemlibs TARGET ROOT DEST)
 198   append_systemlib(${TARGET} ${ROOT}/system/systemlib.php systemlib)
 199   foreach(SLIB ${EXTENSION_SYSTEMLIB_SOURCES} ${EZC_SYSTEMLIB_SOURCES})
 200     embed_systemlib_byname(${TARGET} ${SLIB})
 201   endforeach()
 202   embed_sections(${TARGET} ${DEST})
 203 endfunction(embed_all_systemlibs)
 204
 205 # Custom install function that doesn't relink, instead it uses chrpath to change it, if
 206 # it's available, otherwise, it leaves the chrpath alone
 207 function(HHVM_INSTALL TARGET DEST)
 208   get_target_property(LOC ${TARGET} LOCATION)
 209   get_target_property(TY ${TARGET} TYPE)
 210   if (FOUND_CHRPATH)
 211     get_target_property(RPATH ${TARGET} INSTALL_RPATH)
 212     if (NOT RPATH STREQUAL "RPATH-NOTFOUND")
 213       if (RPATH STREQUAL "")
 214         install(CODE "execute_process(COMMAND \"${CHRPATH}\" \"-d\" \"${LOC}\" ERROR_QUIET)")
 215       else()
 216         install(CODE "execute_process(COMMAND \"${CHRPATH}\" \"-r\" \"${RPATH}\" \"${LOC}\" ERROR_QUIET)")
 217       endif()
 218     endif()
 219   endif()
 220   string(TOUPPER ${DEST} DEST_UPPER)
 221   install(CODE "FILE(INSTALL DESTINATION \"\${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_${DEST_UPPER}DIR}\" TYPE ${TY} FILES \"${LOC}\")")
 222 endfunction(HHVM_INSTALL)
 223
 224 function(HHVM_PUBLIC_HEADERS TARGET)
 225   install(
 226     CODE "INCLUDE(\"${HPHP_HOME}/CMake/HPHPFunctions.cmake\")
 227       HHVM_INSTALL_HEADERS(${TARGET} ${HPHP_HOME}
 228       \"\${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_INCLUDEDIR}\" ${ARGN})"
 229     COMPONENT dev)
 230 endfunction()
 231
 232 function(HHVM_INSTALL_HEADERS TARGET SRCROOT DEST)
 233   message(STATUS "Installing header files for ${TARGET}")
 234   foreach(src_rel ${ARGN})
 235     # Determine the relative directory name so that we can mirror the
 236     # directory structure in the output
 237     file(RELATIVE_PATH dest_rel ${SRCROOT} ${src_rel})
 238     if (IS_ABSOLUTE ${dest_rel})
 239       message(WARNING "${TARGET}: Header file ${dest_rel} is not inside ${SRCROOT}")
 240     else()
 241       string(FIND ${dest_rel} / slash_pos REVERSE)
 242       if(slash_pos EQUAL -1)
 243         set(dest_rel)
 244       else()
 245         string(SUBSTRING ${dest_rel} 0 ${slash_pos} dest_rel)
 246       endif()
 247       file(COPY ${src_rel}
 248         DESTINATION "$ENV{DESTDIR}${DEST}/${dest_rel}"
 249         NO_SOURCE_PERMISSIONS)
 250     endif()
 251   endforeach()
 252 endfunction()
 253
 254 macro(HHVM_EXT_OPTION EXTNAME PACKAGENAME)
 255   if (NOT DEFINED EXT_${EXTNAME})
 256     # Implicit check
 257     find_package(${PACKAGENAME})
 258   elseif (EXT_${EXTNAME} STREQUAL "ON")
 259     # Explicit check
 260     find_package(${PACKAGENAME} REQUIRED)
 261   endif()
 262 endmacro()
 263
 264 # Remove all files matching a set of patterns, and,
 265 # optionally, not matching a second set of patterns,
 266 # from a set of lists.
 267 #
 268 # Example:
 269 # This will remove all files in the CPP_SOURCES list
 270 # matching "/test/" or "Test.cpp$", but not matching
 271 # "BobTest.cpp$".
 272 # HHVM_REMOVE_MATCHES_FROM_LISTS(CPP_SOURCES MATCHES "/test/" "Test.cpp$" IGNORE_MATCHES "BobTest.cpp$")
 273 #
 274 # Parameters:
 275 #
 276 # [...]:
 277 # The names of the lists to remove matches from.
 278 #
 279 # [MATCHES ...]:
 280 # The matches to remove from the lists.
 281 #
 282 # [IGNORE_MATCHES ...]:
 283 # The matches not to remove, even if they match
 284 # the main set of matches to remove.
 285 function(HHVM_REMOVE_MATCHES_FROM_LISTS)
 286   set(LISTS_TO_SEARCH)
 287   set(MATCHES_TO_REMOVE)
 288   set(MATCHES_TO_IGNORE)
 289   set(argumentState 0)
 290   foreach (arg ${ARGN})
 291     if ("x${arg}" STREQUAL "xMATCHES")
 292       set(argumentState 1)
 293     elseif ("x${arg}" STREQUAL "xIGNORE_MATCHES")
 294       set(argumentState 2)
 295     elseif (argumentState EQUAL 0)
 296       list(APPEND LISTS_TO_SEARCH ${arg})
 297     elseif (argumentState EQUAL 1)
 298       list(APPEND MATCHES_TO_REMOVE ${arg})
 299     elseif (argumentState EQUAL 2)
 300       list(APPEND MATCHES_TO_IGNORE ${arg})
 301     else()
 302       message(FATAL_ERROR "Unknown argument state!")
 303     endif()
 304   endforeach()
 305
 306   foreach (theList ${LISTS_TO_SEARCH})
 307     foreach (entry ${${theList}})
 308       foreach (match ${MATCHES_TO_REMOVE})
 309         if (${entry} MATCHES ${match})
 310           set(SHOULD_IGNORE OFF)
 311           foreach (ign ${MATCHES_TO_IGNORE})
 312             if (${entry} MATCHES ${ign})
 313               set(SHOULD_IGNORE ON)
 314               break()
 315             endif()
 316           endforeach()
 317
 318           if (NOT SHOULD_IGNORE)
 319             list(REMOVE_ITEM ${theList} ${entry})
 320           endif()
 321         endif()
 322       endforeach()
 323     endforeach()
 324     set(${theList} ${${theList}} PARENT_SCOPE)
 325   endforeach()
 326 endfunction()
 327
 328 # Automatically create source_group directives for the sources passed in.
 329 function(auto_source_group rootName rootDir)
 330   file(TO_CMAKE_PATH "${rootDir}" rootDir)
 331   string(LENGTH "${rootDir}" rootDirLength)
 332   set(sourceGroups)
 333   foreach (fil ${ARGN})
 334     file(TO_CMAKE_PATH "${fil}" filePath)
 335     string(FIND "${filePath}" "/" rIdx REVERSE)
 336     if (rIdx EQUAL -1)
 337       message(FATAL_ERROR "Unable to locate the final forward slash in '${filePath}'!")
 338     endif()
 339     string(SUBSTRING "${filePath}" 0 ${rIdx} filePath)
 340
 341     string(LENGTH "${filePath}" filePathLength)
 342     string(FIND "${filePath}" "${rootDir}" rIdx)
 343     if (rIdx EQUAL 0)
 344       math(EXPR filePathLength "${filePathLength} - ${rootDirLength}")
 345       string(SUBSTRING "${filePath}" ${rootDirLength} ${filePathLength} fileGroup)
 346
 347       string(REPLACE "/" "\\" fileGroup "${fileGroup}")
 348       set(fileGroup "\\${rootName}${fileGroup}")
 349
 350       list(FIND sourceGroups "${fileGroup}" rIdx)
 351       if (rIdx EQUAL -1)
 352         list(APPEND sourceGroups "${fileGroup}")
 353         source_group("${fileGroup}" REGULAR_EXPRESSION "${filePath}/[^/.]+(.(tab|yy))?.(c|cc|cpp|h|hpp|ll|php|tcc|y)$")
 354       endif()
 355     endif()
 356   endforeach()
 357 endfunction()
 358
 359 macro(add_precompiled_header PrecompiledHead PrecompiledSrc SourcesVar)
 360   if (MSVC AND MSVC_ENABLE_PCH)
 361     get_filename_component(PrecompiledHeader "${PrecompiledHead}" ABSOLUTE)
 362     get_filename_component(PrecompiledSource "${PrecompiledSrc}" ABSOLUTE)
 363     get_filename_component(PrecompiledBasename "${PrecompiledHeader}" NAME_WE)
 364     get_filename_component(PrecompiledHeaderFilename "${PrecompiledHeader}" NAME)
 365     set(PrecompiledBinary "${CMAKE_CURRENT_BINARY_DIR}/${PrecompiledBasename}.pch")
 366     set(Sources ${${SourcesVar}})
 367
 368     set_source_files_properties(${PrecompiledSource} PROPERTIES
 369       COMPILE_FLAGS "/Yc\"${PrecompiledHeaderFilename}\" /Fp\"${PrecompiledBinary}\""
 370       OBJECT_OUTPUTS "${PrecompiledBinary}")
 371     set_source_files_properties(${Sources} PROPERTIES
 372       COMPILE_FLAGS "/Yu\"${PrecompiledHeader}\" /FI\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
 373       OBJECT_DEPENDS "${PrecompiledBinary}")
 374
 375     list(APPEND ${SourcesVar} ${PrecompiledSource} ${PrecompiledHeader})
 376   endif()
 377 endmacro()
 378
 379 function(parse_version PREFIX VERSION)
 380   if (NOT ${VERSION} MATCHES "^[0-9]+\\.[0-9]+(\\.[0-9]+)?(-.+)?$")
 381     message(FATAL_ERROR "VERSION must conform to X.Y(.Z)?(-.+)?")
 382   endif()
 383
 384   string(FIND ${VERSION} "-" SUFFIX_POS)
 385   set(SUFFIX "")
 386   if (SUFFIX_POS)
 387     string(SUBSTRING ${VERSION} ${SUFFIX_POS} -1 SUFFIX)
 388     string(SUBSTRING ${VERSION} 0 ${SUFFIX_POS} NUMERIC_VERSION)
 389   else()
 390     set(NUMERIC_VERSION ${VERSION})
 391   endif()
 392
 393   string(REPLACE "." ";" VERSION_LIST "${NUMERIC_VERSION}")
 394   list(GET VERSION_LIST 0 MAJOR)
 395   list(GET VERSION_LIST 1 MINOR)
 396   list(LENGTH VERSION_LIST VERSION_LIST_LENGTH)
 397   if (VERSION_LIST_LENGTH GREATER 2)
 398     list(GET VERSION_LIST 2 PATCH)
 399   else()
 400     set(PATCH 0)
 401   endif()
 402
 403   set(${PREFIX}MAJOR ${MAJOR} PARENT_SCOPE)
 404   set(${PREFIX}MINOR ${MINOR} PARENT_SCOPE)
 405   set(${PREFIX}PATCH ${PATCH} PARENT_SCOPE)
 406   set(${PREFIX}SUFFIX ${SUFFIX} PARENT_SCOPE)
 407 endfunction()
 408
 409 # MSVC doesn't support a --whole-archive flag, but newer versions
 410 # of CMake do support object libraries, which give the same result.
 411 # As we can't easily upgrade the normal builds to CMake 3.0, we
 412 # will just require CMake 3.0+ for MSVC builds only.
 413 function(add_object_library libraryName)
 414   if (MSVC)
 415     add_library(${libraryName} OBJECT ${ARGN})
 416   else()
 417     add_library(${libraryName} STATIC ${ARGN})
 418   endif()
 419 endfunction()
 420
 421 # Get what might be the objects of the object libraries, if needed.
 422 function(get_object_libraries_objects targetVariable)
 423   set(OBJECTS)
 424   if (MSVC)
 425     foreach (fil ${ARGN})
 426       list(APPEND OBJECTS $<TARGET_OBJECTS:${fil}>)
 427     endforeach()
 428   endif()
 429
 430   set(${targetVariable} ${OBJECTS} PARENT_SCOPE)
 431 endfunction()
 432
 433 # Add the additional link targets for a set of object libraries,
 434 # if needed.
 435 function(link_object_libraries target)
 436   if (MSVC)
 437     return()
 438   endif()
 439
 440   set(WHOLE_ARCHIVE_LIBS)
 441   foreach (fil ${ARGN})
 442     list(APPEND WHOLE_ARCHIVE_LIBS ${fil})
 443   endforeach()
 444
 445   set(ANCHOR_SYMS)
 446   if (APPLE)
 447     set(ANCHOR_SYMS
 448       -Wl,-pagezero_size,0x00001000
 449       # Set the .text.keep section to be executable.
 450       -Wl,-segprot,.text,rx,rx)
 451     foreach(lib ${WHOLE_ARCHIVE_LIBS})
 452       # It's important to use -Xlinker and not -Wl here: ${lib} needs to be its
 453       # own option on the command line, since target_link_libraries will expand it
 454       # from its logical name here into the full .a path. (Eww.)
 455       list(APPEND ANCHOR_SYMS -Xlinker -force_load -Xlinker ${lib})
 456     endforeach()
 457   else()
 458     set(ANCHOR_SYMS -Wl,--whole-archive ${WHOLE_ARCHIVE_LIBS} -Wl,--no-whole-archive)
 459   endif()
 460
 461   target_link_libraries(${target} ${ANCHOR_SYMS})
 462 endfunction()
 463
 464 # This should be called for object libraries, rather than calling
 465 # hphp_link directly.
 466 function(object_library_hphp_link target)
 467   # Gold doesn't need this, and MSVC can't have it. (see below)
 468   if (NOT ENABLE_LD_GOLD AND NOT MSVC)
 469     hphp_link(${target})
 470   endif()
 471 endfunction()
 472
 473 # If a library needs to be linked in to make GNU ld happy,
 474 # it should be done by calling this.
 475 function(object_library_ld_link_libraries target)
 476   if (${ARGC})
 477     # CMake doesn't allow calls to target_link_libraries if the target
 478     # is an OBJECT library, so MSVC can't have this.
 479     if (NOT MSVC)
 480       target_link_libraries(${target} ${ARGN})
 481     endif()
 482   endif()
 483 endfunction()