CMake/HPHPCompiler.cmake

   1 set(FREEBSD FALSE)
   2 if("${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD")
   3   set(FREEBSD TRUE)
   4 endif()
   5 set(LINUX FALSE)
   6 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
   7   set(LINUX TRUE)
   8 endif()
   9 set(DARWIN FALSE)
  10 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
  11   set(DARWIN TRUE)
  12 endif()
  13 set(WINDOWS FALSE)
  14 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  15   set(WINDOWS TRUE)
  16 endif()
  17
  18 # Do this until cmake has a define for ARMv8
  19 INCLUDE(CheckCXXSourceCompiles)
  20 CHECK_CXX_SOURCE_COMPILES("
  21 #ifndef __x86_64__
  22 #error Not x64
  23 #endif
  24 int main() { return 0; }" IS_X64)
  25
  26 CHECK_CXX_SOURCE_COMPILES("
  27 #ifndef __AARCH64EL__
  28 #error Not ARMv8
  29 #endif
  30 int main() { return 0; }" IS_AARCH64)
  31
  32 CHECK_CXX_SOURCE_COMPILES("
  33 #ifndef __powerpc64__
  34 #error Not PPC64
  35 #endif
  36 int main() { return 0; }" IS_PPC64)
  37
  38 # using Clang or GCC
  39 if (${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang" OR ${CMAKE_CXX_COMPILER_ID} STREQUAL "GNU")
  40   # Warnings to disable by name, -Wno-${name}
  41   set(DISABLED_NAMED_WARNINGS)
  42   list(APPEND DISABLED_NAMED_WARNINGS
  43     "error=array-bounds"
  44     "error=switch"
  45     "attributes"
  46     "deprecated"
  47     "invalid-offsetof"
  48     "sign-compare"
  49     "strict-aliasing"
  50     "unused-function"
  51     "unused-local-typedefs"
  52     "unused-result"
  53     "write-strings"
  54   )
  55
  56   # Warnings to disable by name when building C code.
  57   set(DISABLED_C_NAMED_WARNINGS)
  58   list(APPEND DISABLED_C_NAMED_WARNINGS
  59     "missing-field-initializers"
  60     "sign-compare"
  61   )
  62
  63   # General options to pass to both C & C++ compilers
  64   set(GENERAL_OPTIONS)
  65
  66   # General options to pass to the C++ compiler
  67   set(GENERAL_CXX_OPTIONS)
  68   list(APPEND GENERAL_CXX_OPTIONS
  69     "std=gnu++1y"
  70     "fno-omit-frame-pointer"
  71     "fno-operator-names"
  72     "Wall"
  73     "Woverloaded-virtual"
  74     "Werror=format-security"
  75   )
  76
  77   # Options to pass for debug mode to the C++ compiler
  78   set(DEBUG_CXX_OPTIONS)
  79
  80   # Options to pass for release mode to the C++ compiler
  81   set(RELEASE_CXX_OPTIONS)
  82
  83   # Suboption of -g in debug mode
  84   set(GDB_SUBOPTION)
  85
  86   # Enable GCC/LLVM stack-smashing protection
  87   if(ENABLE_SSP)
  88     list(APPEND GENERAL_OPTIONS
  89       # This needs two dashes in the name, so put one here.
  90       "-param=ssp-buffer-size=4"
  91       "pie"
  92       "fPIC"
  93     )
  94   endif()
  95
  96   if (${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang") # using Clang
  97     if (IS_X64)
  98       list(APPEND GENERAL_OPTIONS
  99         # For unclear reasons, our detection for what crc32 intrinsics you have
 100         # will cause clang to ICE. Specifying a baseline here works around the
 101         # issue. (SSE4.2 has been available on processors for quite some time now.)
 102         "msse4.2"
 103       )
 104       # Also need to pass the right option to ASM files to avoid inconsistencies
 105       # in CRC hash function handling
 106       set(CMAKE_ASM_FLAGS  "${CMAKE_ASM_FLAGS} -msse4.2")
 107     endif()
 108
 109     list(APPEND GENERAL_CXX_OPTIONS
 110       "Qunused-arguments"
 111     )
 112     list(APPEND DISABLED_C_NAMED_WARNINGS
 113       "unused-command-line-argument"
 114     )
 115     list(APPEND DISABLED_NAMED_WARNINGS
 116       "return-type-c-linkage"
 117       "unknown-warning-option"
 118       "unused-command-line-argument"
 119     )
 120
 121     # Enabled GCC/LLVM stack-smashing protection
 122     if(ENABLE_SSP)
 123       if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 3.6 OR
 124          CMAKE_CXX_COMPILER_VERSION VERSION_EQUAL 3.6)
 125         list(APPEND GENERAL_OPTIONS "fstack-protector-strong")
 126       else()
 127         list(APPEND GENERAL_OPTIONS "fstack-protector")
 128       endif()
 129     endif()
 130
 131     if(CLANG_FORCE_LIBSTDCXX)
 132       list(APPEND GENERAL_CXX_OPTIONS "stdlib=libstdc++")
 133     else()
 134       list(APPEND GENERAL_CXX_OPTIONS "stdlib=libc++")
 135     endif()
 136   else() # using GCC
 137     list(APPEND DISABLED_NAMED_WARNINGS
 138       "deprecated-declarations"
 139       "maybe-uninitialized"
 140     )
 141     list(APPEND DISABLED_C_NAMED_WARNINGS
 142       "maybe-uninitialized"
 143       "old-style-declaration"
 144     )
 145     list(APPEND GENERAL_OPTIONS
 146       "ffunction-sections"
 147     )
 148     list(APPEND GENERAL_CXX_OPTIONS
 149       "fdata-sections"
 150       "fno-gcse"
 151       "fno-canonical-system-headers"
 152       "Wvla"
 153     )
 154     list(APPEND RELEASE_CXX_OPTIONS
 155       "-param max-inline-insns-auto=100"
 156       "-param early-inlining-insns=200"
 157       "-param max-early-inliner-iterations=50"
 158       "-param=inline-unit-growth=200"
 159       "-param=large-unit-insns=10000"
 160     )
 161
 162     # Fix problem with GCC 4.9, https://kb.isc.org/article/AA-01167
 163     if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 4.9 OR
 164        CMAKE_CXX_COMPILER_VERSION VERSION_EQUAL 4.9)
 165       list(APPEND GENERAL_OPTIONS "fno-delete-null-pointer-checks")
 166     else()
 167        message(FATAL_ERROR "${PROJECT_NAME} requires g++ 4.9 or greater.")
 168     endif()
 169
 170     # Warn about a GCC 4.9 bug leading to an incorrect refcounting issue
 171     # https://github.com/facebook/hhvm/issues/8011
 172     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5.0)
 173        message(WARNING "HHVM is known to trigger optimization bugs in GCC 4.9. Upgrading to GCC 5 is recommended. See https://github.com/facebook/hhvm/issues/8011 for more details.")
 174     endif()
 175
 176     if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 6.0 OR
 177        CMAKE_CXX_COMPILER_VERSION VERSION_EQUAL 6.0)
 178      message(WARNING "HHVM is primarily tested on GCC 4.9 and 5. Using other versions may produce unexpected results, or may not even build at all.")
 179     endif()
 180
 181     if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 5.1 OR
 182        CMAKE_CXX_COMPILER_VERSION VERSION_EQUAL 5.1)
 183       list(APPEND DISABLED_NAMED_WARNINGS "bool-compare")
 184       list(APPEND GENERAL_OPTIONS "DFOLLY_HAVE_MALLOC_H")
 185     endif()
 186
 187     if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 6.0 OR
 188        CMAKE_CXX_COMPILER_VERSION VERSION_EQUAL 6.0)
 189       list(APPEND GENERAL_CXX_OPTIONS "Wno-misleading-indentation")
 190     endif()
 191
 192     # Enabled GCC/LLVM stack-smashing protection
 193     if(ENABLE_SSP)
 194       if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 4.8 OR
 195          CMAKE_CXX_COMPILER_VERSION VERSION_EQUAL 4.8)
 196         if(LINUX)
 197           # https://isisblogs.poly.edu/2011/06/01/relro-relocation-read-only/
 198           list(APPEND GENERAL_OPTIONS "Wl,-z,relro,-z,now")
 199         endif()
 200         if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 4.9 OR
 201            CMAKE_CXX_COMPILER_VERSION VERSION_EQUAL 4.9)
 202           list(APPEND GENERAL_OPTIONS "fstack-protector-strong")
 203         endif()
 204       else()
 205         list(APPEND GENERAL_OPTIONS "fstack-protector")
 206       endif()
 207     endif()
 208
 209     # X64
 210     if(IS_X64)
 211       list(APPEND GENERAL_CXX_OPTIONS "mcrc32")
 212         if(ENABLE_SSE4_2)
 213           list(APPEND GENERAL_CXX_OPTIONS
 214           # SSE4.2 has been available on processors for quite some time now. This
 215           # allows enabling CRC hash function code
 216           "msse4.2"
 217           )
 218           # Also pass the right option to ASM files to avoid inconsistencies
 219           # in CRC hash function handling
 220           set(CMAKE_ASM_FLAGS  "${CMAKE_ASM_FLAGS} -msse4.2")
 221         endif()
 222     endif()
 223
 224     # ARM64
 225     if(IS_AARCH64)
 226       # Force char type to be signed, which is not the case on aarch64.
 227       list(APPEND GENERAL_OPTIONS "fsigned-char")
 228
 229       # If a CPU was specified, build a -mcpu option for the compiler.
 230       set(AARCH64_TARGET_CPU "" CACHE STRING "CPU to tell gcc to optimize for (-mcpu)")
 231       if(AARCH64_TARGET_CPU)
 232         list(APPEND GENERAL_OPTIONS "mcpu=${AARCH64_TARGET_CPU}")
 233         set(CMAKE_ASM_FLAGS  "${CMAKE_ASM_FLAGS} -mcpu=${AARCH64_TARGET_CPU}")
 234
 235         # Make sure GCC is not using the fix for errata 843419. This change
 236         # interferes with the gold linker. Note that GCC applies this fix
 237         # even if you specify an mcpu other than cortex-a53, which is why
 238         # it's explicitly being disabled here for any cpu other than
 239         # cortex-a53. If you're running a newer pass of the cortex-a53, then
 240         # you can likely disable this fix with the following flag too. YMMV
 241         if(NOT ${AARCH64_TARGET_CPU} STREQUAL "cortex-a53")
 242           list(APPEND GENERAL_OPTIONS "mno-fix-cortex-a53-843419")
 243         endif()
 244       endif()
 245     endif()
 246
 247     # PPC64
 248     if(NOT IS_PPC64)
 249       list(APPEND RELEASE_CXX_OPTIONS "momit-leaf-frame-pointer")
 250     endif()
 251
 252     if(STATIC_CXX_LIB)
 253       set(CMAKE_EXE_LINKER_FLAGS "-static-libgcc -static-libstdc++")
 254     endif()
 255
 256     if (ENABLE_SPLIT_DWARF)
 257       set(GDB_SUBOPTION "split-dwarf")
 258     endif()
 259   endif()
 260
 261   # No optimizations for debug builds.
 262   # -Og enables some optimizations, but makes debugging harder by optimizing
 263   # away some functions and locals. -O0 is more debuggable.
 264   # -O0-ggdb was reputed to cause gdb to crash (github #4450)
 265   set(CMAKE_C_FLAGS_DEBUG            "-O0 -g${GDB_SUBOPTION}")
 266   set(CMAKE_CXX_FLAGS_DEBUG          "-O0 -g${GDB_SUBOPTION}")
 267   set(CMAKE_C_FLAGS_DEBUGOPT         "-O2 -g${GDB_SUBOPTION}")
 268   set(CMAKE_CXX_FLAGS_DEBUGOPT       "-O2 -g${GDB_SUBOPTION}")
 269   set(CMAKE_C_FLAGS_MINSIZEREL       "-Os -DNDEBUG")
 270   set(CMAKE_CXX_FLAGS_MINSIZEREL     "-Os -DNDEBUG")
 271   set(CMAKE_C_FLAGS_RELEASE          "-O3 -DNDEBUG")
 272   set(CMAKE_CXX_FLAGS_RELEASE        "-O3 -DNDEBUG")
 273   set(CMAKE_C_FLAGS_RELWITHDEBINFO   "-O2 -g${GDB_SUBOPTION} -DNDEBUG")
 274   set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "-O2 -g${GDB_SUBOPTION} -DNDEBUG")
 275   set(CMAKE_C_FLAGS                  "${CMAKE_C_FLAGS} -W -Werror=implicit-function-declaration")
 276
 277   mark_as_advanced(CMAKE_C_FLAGS_DEBUGOPT CMAKE_CXX_FLAGS_DEBUGOPT)
 278
 279   foreach(opt ${DISABLED_NAMED_WARNINGS})
 280     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-${opt}")
 281   endforeach()
 282
 283   foreach(opt ${DISABLED_C_NAMED_WARNINGS})
 284     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-${opt}")
 285   endforeach()
 286
 287   foreach(opt ${GENERAL_OPTIONS})
 288     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -${opt}")
 289     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -${opt}")
 290   endforeach()
 291
 292   foreach(opt ${GENERAL_CXX_OPTIONS})
 293     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -${opt}")
 294   endforeach()
 295
 296   foreach(opt ${DEBUG_CXX_OPTIONS})
 297     set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -${opt}")
 298   endforeach()
 299
 300   foreach(opt ${RELEASE_CXX_OPTIONS})
 301     set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -${opt}")
 302   endforeach()
 303
 304   # The ASM part of this makes it more effort than it's worth
 305   # to add these to the general flags system.
 306   if(ENABLE_AVX2)
 307     set(CMAKE_C_FLAGS    "${CMAKE_C_FLAGS} -mavx2 -march=core-avx2")
 308     set(CMAKE_CXX_FLAGS  "${CMAKE_CXX_FLAGS} -mavx2 -march=core-avx2")
 309     set(CMAKE_ASM_FLAGS  "${CMAKE_ASM_FLAGS} -mavx2 -march=core-avx2")
 310   endif()
 311 # using Intel C++
 312 elseif (${CMAKE_CXX_COMPILER_ID} STREQUAL "Intel")
 313   set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -no-ipo -fp-model precise -wd584 -wd1418 -wd1918 -wd383 -wd869 -wd981 -wd424 -wd1419 -wd444 -wd271 -wd2259 -wd1572 -wd1599 -wd82 -wd177 -wd593 -w")
 314   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -no-ipo -fp-model precise -wd584 -wd1418 -wd1918 -wd383 -wd869 -wd981 -wd424 -wd1419 -wd444 -wd271 -wd2259 -wd1572 -wd1599 -wd82 -wd177 -wd593 -fno-omit-frame-pointer -Wall -Woverloaded-virtual -Wno-deprecated -w1 -Wno-strict-aliasing -Wno-write-strings -Wno-invalid-offsetof -fno-operator-names")
 315 # using Visual Studio C++
 316 elseif (${CMAKE_CXX_COMPILER_ID} STREQUAL "MSVC")
 317   message(WARNING "MSVC support is VERY experimental. It will likely not compile, and is intended for the utterly insane.")
 318
 319   ############################################################
 320   # First we setup and account for the option sets.
 321   ############################################################
 322
 323   set(MSVC_GENERAL_OPTIONS)
 324   set(MSVC_DISABLED_WARNINGS)
 325   set(MSVC_WARNINGS_AS_ERRORS)
 326   set(MSVC_ADDITIONAL_DEFINES)
 327   set(MSVC_EXE_LINKER_OPTIONS)
 328   set(MSVC_DEBUG_OPTIONS)
 329   set(MSVC_RELEASE_OPTIONS)
 330   set(MSVC_RELEASE_LINKER_OPTIONS)
 331   set(MSVC_DEBUG_EXE_LINKER_OPTIONS)
 332   set(MSVC_RELEASE_EXE_LINKER_OPTIONS)
 333
 334   # Some addional configuration options.
 335   set(MSVC_ENABLE_ALL_WARNINGS ON CACHE BOOL "If enabled, pass /Wall to the compiler.")
 336   set(MSVC_ENABLE_DEBUG_INLINING ON CACHE BOOL "If enabled, enable inlining in the debug configuration. This allows /Zc:inline to be far more effective, resulting in hphp_runtime_static being ~450mb smaller.")
 337   set(MSVC_ENABLE_LTCG OFF CACHE BOOL "If enabled, use Link Time Code Generation for Release builds.")
 338   set(MSVC_ENABLE_PARALLEL_BUILD ON CACHE BOOL "If enabled, build multiple source files in parallel.")
 339   set(MSVC_ENABLE_PCH ON CACHE BOOL "If enabled, use precompiled headers to speed up the build.")
 340   set(MSVC_ENABLE_STATIC_ANALYSIS OFF CACHE BOOL "If enabled, do more complex static analysis and generate warnings appropriately.")
 341   set(MSVC_FAVORED_ARCHITECTURE "blend" CACHE STRING "One of 'blend', 'AMD64', 'INTEL64', or 'ATOM'. This tells the compiler to generate code optimized to run best on the specified architecture.")
 342
 343   # The general options passed:
 344   list(APPEND MSVC_GENERAL_OPTIONS
 345     "bigobj" # Support objects with > 65k sections. Needed for folly due to templates.
 346     "fp:precise" # Precise floating point model used in every other build, use it here as well.
 347     "EHa" # Enable both SEH and C++ Exceptions.
 348     "Oy-" # Disable elimination of stack frames.
 349     "Zc:inline" # Have the compiler eliminate unreferenced COMDAT functions and data before emitting the object file. This produces significantly less input to the linker, resulting in MUCH faster linking.
 350     "Zo" # Enable enhanced optimized debugging. Produces slightly larger pdb files, but the resulting optimized code is much much easier to debug.
 351   )
 352
 353   # Enable all warnings if requested.
 354   if (MSVC_ENABLE_ALL_WARNINGS)
 355     list(APPEND MSVC_GENERAL_OPTIONS "Wall")
 356   endif()
 357
 358   # Enable static analysis if requested.
 359   if (MSVC_ENABLE_STATIC_ANALYSIS)
 360     list(APPEND MSVC_GENERAL_OPTIONS "analyze")
 361   endif()
 362
 363   # Enable multi-processor compilation if requested.
 364   if (MSVC_ENABLE_PARALLEL_BUILD)
 365     list(APPEND MSVC_GENERAL_OPTIONS "MP")
 366   endif()
 367
 368   # Enable AVX2 codegen if available and requested.
 369   if (ENABLE_AVX2)
 370     list(APPEND MSVC_GENERAL_OPTIONS "arch:AVX2")
 371   endif()
 372
 373   # Validate, and then add the favored architecture.
 374   if (NOT MSVC_FAVORED_ARCHITECTURE STREQUAL "blend" AND NOT MSVC_FAVORED_ARCHITECTURE STREQUAL "AMD64" AND NOT MSVC_FAVORED_ARCHITECTURE STREQUAL "INTEL64" AND NOT MSVC_FAVORED_ARCHITECTURE STREQUAL "ATOM")
 375     message(FATAL_ERROR "MSVC_FAVORED_ARCHITECTURE must be set to one of exactly, 'blend', 'AMD64', 'INTEL64', or 'ATOM'! Got '${MSVC_FAVORED_ARCHITECTURE}' instead!")
 376   endif()
 377   list(APPEND MSVC_GENERAL_OPTIONS "favor:${MSVC_FAVORED_ARCHITECTURE}")
 378
 379   # The warnings that are disabled:
 380   list(APPEND MSVC_DISABLED_WARNINGS
 381     "4068" # Unknown pragma.
 382     "4091" # 'typedef' ignored on left of '' when no variable is declared.
 383     "4101" # Unused variables
 384     "4103" # Alignment changed after including header. This is needed because boost includes an ABI header that does some #pragma pack push/pop stuff, and we've passed our own packing
 385     "4146" # Unary minus applied to unsigned type, result still unsigned.
 386     "4250" # Function was inherited via dominance.
 387     "4800" # Values being forced to bool, this happens many places, and is a "performance warning".
 388   )
 389
 390   if (MSVC_ENABLE_ALL_WARNINGS)
 391     # These warnings are disabled because we've
 392     # enabled all warnings. If all warnings are
 393     # not enabled, then these don't need to be
 394     # disabled.
 395     list(APPEND MSVC_DISABLED_WARNINGS
 396       "4061" # Enum value not handled by a case in a switch on an enum. This isn't very helpful because it is produced even if a default statement is present.
 397       "4100" # Unreferenced formal parameter.
 398       "4127" # Conditional expression is constant.
 399       "4131" # Old style declarator used. This is triggered by ext_bc's backend code.
 400       "4189" # Local variable is initialized but not referenced.
 401       "4191" # Unsafe type cast.
 402       "4200" # Non-standard extension, zero sized array.
 403       "4201" # Non-standard extension used: nameless struct/union.
 404       "4232" # Non-standard extension used: 'pCurrent': address of dllimport.
 405       "4245" # Implicit change from signed/unsigned when initializing.
 406       "4255" # Implicitly converting fucntion prototype from `()` to `(void)`.
 407       "4265" # Class has virtual functions, but destructor is not virtual.
 408       "4287" # Unsigned/negative constant mismatch.
 409       "4296" # '<' Expression is always false.
 410       "4315" # 'this' pointer for member may not be aligned to 8 bytes as expected by the constructor.
 411       "4324" # Structure was padded due to alignment specifier.
 412       "4355" # 'this' used in base member initializer list.
 413       "4365" # Signed/unsigned mismatch.
 414       "4371" # Layout of class may have changed due to fixes in packing.
 415       "4388" # Signed/unsigned mismatch on relative comparison operator.
 416       "4389" # Signed/unsigned mismatch on equality comparison operator.
 417       "4435" # Object layout under /vd2 will change due to virtual base.
 418       "4456" # Declaration of local hides previous definition of local by the same name.
 419       "4457" # Declaration of local hides function parameter.
 420       "4458" # Declaration of parameter hides class member.
 421       "4459" # Declaration of parameter hides global declaration.
 422       "4464" # Relative include path contains "..". This is triggered by the TBB headers.
 423       "4505" # Unreferenced local function has been removed. This is mostly the result of things not being needed under MSVC.
 424       "4514" # Unreferenced inline function has been removed. (caused by /Zc:inline)
 425       "4548" # Expression before comma has no effect. I wouldn't disable this normally, but malloc.h triggers this warning.
 426       "4555" # Expression has no effect; expected expression with side-effect. This is triggered by boost/variant.hpp.
 427       "4574" # ifdef'd macro was defined to 0.
 428       "4582" # Constructor is not implicitly called.
 429       "4583" # Destructor is not implicitly called.
 430       "4608" # Member has already been initialized by another union member initializer.
 431       "4619" # Invalid warning number used in #pragma warning.
 432       "4623" # Default constructor was implicitly defined as deleted.
 433       "4625" # Copy constructor was implicitly defined as deleted.
 434       "4626" # Assignment operator was implicitly defined as deleted.
 435       "4647" # __is_pod() has a different value in pervious versions of MSVC.
 436       "4668" # Macro was not defined, replacing with 0.
 437       "4701" # Potentially uninitialized local variable used.
 438       "4702" # Unreachable code.
 439       "4706" # Assignment within conditional expression.
 440       "4709" # Comma operator within array index expression. This currently just produces false-positives.
 441       "4710" # Function was not inlined.
 442       "4711" # Function was selected for automated inlining. This produces tens of thousands of warnings in release mode if you leave it enabled, which will completely break Visual Studio, so don't enable it.
 443       "4714" # Function marked as __forceinline not inlined.
 444       "4774" # Format string expected in argument is not a string literal.
 445       "4820" # Padding added after data member.
 446       "4917" # A GUID can only be associated with a class. This is triggered by some standard windows headers.
 447       "4946" # reinterpret_cast used between related types.
 448       "5026" # Move constructor was implicitly defined as deleted.
 449       "5027" # Move assignment operator was implicitly defined as deleted.
 450       "5031" # #pragma warning(pop): likely mismatch, popping warning state pushed in different file. This is needed because of how boost does things.
 451     )
 452   endif()
 453
 454   if (MSVC_ENABLE_STATIC_ANALYSIS)
 455     # Warnings disabled for /analyze
 456     list(APPEND MSVC_DISABLED_WARNINGS
 457       "6001" # Using uninitialized memory. This is disabled because it is wrong 99% of the time.
 458       "6011" # Dereferencing potentially NULL pointer.
 459       "6031" # Return value ignored.
 460       "6235" # (<non-zero constant> || <expression>) is always a non-zero constant.
 461       "6237" # (<zero> && <expression>) is always zero. <expression> is never evaluated and may have side effects.
 462       "6239" # (<non-zero constant> && <expression>) always evaluates to the result of <expression>.
 463       "6240" # (<expression> && <non-zero constant>) always evaluates to the result of <expression>.
 464       "6246" # Local declaration hides declaration of same name in outer scope.
 465       "6248" # Setting a SECURITY_DESCRIPTOR's DACL to NULL will result in an unprotected object. This is done by one of the boost headers.
 466       "6255" # _alloca indicates failure by raising a stack overflow exception.
 467       "6262" # Function uses more than x bytes of stack space.
 468       "6271" # Extra parameter passed to format function. The analysis pass doesn't recognize %j or %z, even though the runtime does.
 469       "6285" # (<non-zero constant> || <non-zero constant>) is always true.
 470       "6297" # 32-bit value is shifted then cast to 64-bits. The places this occurs never use more than 32 bits.
 471       "6308" # Realloc might return null pointer: assigning null pointer to '<name>', which is passed as an argument to 'realloc', will cause the original memory to leak.
 472       "6326" # Potential comparison of a constant with another constant.
 473       "6330" # Unsigned/signed mismatch when passed as a parameter.
 474       "6340" # Mismatch on sign when passed as format string value.
 475       "6387" # '<value>' could be '0': This does not adhere to the specification for a function.
 476       "28182" # Dereferencing NULL pointer. '<value>' contains the same NULL value as '<expression>'.
 477       "28251" # Inconsistent annotation for function. This is because we only annotate the declaration and not the definition.
 478       "28278" # Function appears with no prototype in scope.
 479     )
 480   endif()
 481
 482   # Warnings disabled to keep it quiet for now,
 483   # most of these should be reviewed and re-enabled:
 484   list(APPEND MSVC_DISABLED_WARNINGS
 485     "4005" # Macro redefinition
 486     "4018" # Signed/unsigned mismatch.
 487     "4242" # Possible loss of data when returning a value.
 488     "4244" # Implicit truncation of data.
 489     "4267" # Implicit truncation of data. This really shouldn't be disabled.
 490     "4291" # No matching destructor found.
 491     "4302" # Pointer casting size difference
 492     "4311" # Pointer casting size difference
 493     "4312" # Pointer casting size difference
 494     "4477" # Parameter to a formatting function isn't the same type as was passed in the format string.
 495     "4624" # Destructor was implicitly undefined.
 496     "4804" # Unsafe use of type 'bool' in operation. (comparing if bool is <=> scalar)
 497     "4805" # Unsafe mix of scalar type and type 'bool' in operation. (comparing if bool is == scalar)
 498   )
 499
 500   # Warnings to treat as errors:
 501   list(APPEND MSVC_WARNINGS_AS_ERRORS
 502     "4099" # Mixed use of struct and class on same type names. This was absolutely everywhere, and can cause errors at link-time if not fixed.
 503     "4129" # Unknown escape sequence. This is usually caused by incorrect escaping.
 504     "4566" # Character cannot be represented in current charset. This is remidied by prefixing string with "u8".
 505   )
 506
 507   # And the extra defines:
 508   list(APPEND MSVC_ADDITIONAL_DEFINES
 509     "NOMINMAX" # This is needed because, for some absurd reason, one of the windows headers tries to define "min" and "max" as macros, which messes up most uses of std::numeric_limits.
 510     "_CRT_NONSTDC_NO_WARNINGS" # Don't deprecate posix names of functions.
 511     "_CRT_SECURE_NO_WARNINGS" # Don't deprecate the non _s versions of various standard library functions, because safety is for chumps.
 512     "_SCL_SECURE_NO_WARNINGS" # Don't deprecate the non _s versions of various standard library functions, because safety is for chumps.
 513     "_WINSOCK_DEPRECATED_NO_WARNINGS" # Don't deprecate pieces of winsock
 514     "YY_NO_UNISTD_H" # Because MSVC doesn't have unistd.h, which is requested by the YACC generated code.
 515   )
 516
 517   # The options passed to the linker for EXE targets:
 518   list(APPEND MSVC_EXE_LINKER_OPTIONS
 519     "BASE:0x10000" # Base the program at just over 64k in memory, to play nice with the JIT.
 520     "DYNAMICBASE:NO" # Don't randomize the base address.
 521     "FIXED" # The program can only be loaded at its preferred base address.
 522     "STACK:8388608,8388608" # Set the stack reserve,commit to 8mb. Reserve should probably be higher.
 523     "time" # Output some timing information about the link.
 524   )
 525
 526   # The options to pass to the compiler for debug builds:
 527   list(APPEND MSVC_DEBUG_OPTIONS
 528     "Gy-" # Disable function level linking.
 529     "GF-" # Disable string pooling.
 530   )
 531
 532   # Add /Ob2 if allowing inlining in debug mode:
 533   if (MSVC_ENABLE_DEBUG_INLINING)
 534     list(APPEND MSVC_DEBUG_OPTIONS "Ob2")
 535   endif()
 536
 537   # The options to pass to the compiler for release builds:
 538   list(APPEND MSVC_RELEASE_OPTIONS
 539     "GF" # Enable string pooling. (this is enabled by default by the optimization level, but we enable it here for clarity)
 540     "Gw" # Optimize global data. (-fdata-sections)
 541     "Gy" # Enable function level linking. (-ffunction-sections)
 542     "Qpar" # Enable parallel code generation. HHVM itself doesn't currently use this, but it's dependencies, TBB for instance, might, so enable it.
 543     "Oi" # Enable intrinsic functions.
 544     "Ot" # Favor fast code.
 545   )
 546
 547   # Add /GL to the compiler, and /LTCG to the linker
 548   # if link time code generation is enabled.
 549   if (MSVC_ENABLE_LTCG)
 550     list(APPEND MSVC_RELEASE_OPTIONS "GL")
 551     list(APPEND MSVC_RELEASE_LINKER_OPTIONS "LTCG")
 552   endif()
 553
 554   # The options to pass to the linker for debug builds for EXE targets:
 555   list(APPEND MSVC_DEBUG_EXE_LINKER_OPTIONS
 556     "OPT:NOREF" # No unreferenced data elimination. (well, mostly)
 557     "OPT:NOICF" # No Identical COMDAT folding.
 558   )
 559
 560   # The options to pass to the linker for release builds for EXE targets:
 561   list(APPEND MSVC_RELEASE_EXE_LINKER_OPTIONS
 562     "OPT:REF" # Remove unreferenced functions and data.
 563     "OPT:ICF" # Identical COMDAT folding.
 564   )
 565
 566   ############################################################
 567   # Now we need to adjust a couple of the default option sets.
 568   ############################################################
 569
 570   # We need the static runtime.
 571   foreach(flag_var
 572       CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 573       CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 574       CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
 575       CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 576     if (${flag_var} MATCHES "/MD")
 577       string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 578     endif()
 579   endforeach()
 580
 581   # In order for /Zc:inline, which speeds up the build significantly, to work
 582   # we need to remove the /Ob0 parameter that CMake adds by default, because that
 583   # would normally disable all inlining.
 584   foreach(flag_var CMAKE_C_FLAGS_DEBUG CMAKE_CXX_FLAGS_DEBUG)
 585     if (${flag_var} MATCHES "/Ob0")
 586       string(REGEX REPLACE "/Ob0" "" ${flag_var} "${${flag_var}}")
 587     endif()
 588   endforeach()
 589
 590   # Ignore a warning about an object file not defining any symbols,
 591   # these are known, and we don't care.
 592   set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /ignore:4221")
 593
 594   ############################################################
 595   # And finally, we can set all the flags we've built up.
 596   ############################################################
 597
 598   foreach(opt ${MSVC_GENERAL_OPTIONS})
 599     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /${opt}")
 600     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /${opt}")
 601   endforeach()
 602
 603   foreach(opt ${MSVC_DISABLED_WARNINGS})
 604     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /wd${opt}")
 605     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd${opt}")
 606   endforeach()
 607
 608   foreach(opt ${MSVC_WARNINGS_AS_ERRORS})
 609     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /we${opt}")
 610     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /we${opt}")
 611   endforeach()
 612
 613   foreach(opt ${MSVC_ADDITIONAL_DEFINES})
 614     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /D ${opt}")
 615     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /D ${opt}")
 616   endforeach()
 617
 618   foreach(opt ${MSVC_EXE_LINKER_OPTIONS})
 619     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /${opt}")
 620   endforeach()
 621
 622   foreach(opt ${MSVC_RELEASE_LINKER_OPTIONS})
 623     foreach(flag_var
 624         CMAKE_EXE_LINKER_FLAGS_RELEASE CMAKE_EXE_LINKER_FLAGS_MINSIZEREL CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO
 625         CMAKE_SHARED_LINKER_FLAGS_RELEASE CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO
 626         CMAKE_STATIC_LINKER_FLAGS_RELEASE CMAKE_STATIC_LINKER_FLAGS_MINSIZEREL CMAKE_STATIC_LINKER_FLAGS_RELWITHDEBINFO)
 627       set(${flag_var} "${${flag_var}} /${opt}")
 628     endforeach()
 629   endforeach()
 630
 631   foreach(opt ${MSVC_DEBUG_OPTIONS})
 632     set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} /${opt}")
 633     set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /${opt}")
 634   endforeach()
 635
 636   foreach(opt ${MSVC_RELEASE_OPTIONS})
 637     foreach(flag_var
 638         CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 639         CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 640       set(${flag_var} "${${flag_var}} /${opt}")
 641     endforeach()
 642   endforeach()
 643
 644   foreach(opt ${MSVC_DEBUG_EXE_LINKER_OPTIONS})
 645     set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} /${opt}")
 646   endforeach()
 647
 648   foreach(opt ${MSVC_RELEASE_EXE_LINKER_OPTIONS})
 649     set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /${opt}")
 650     set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "${CMAKE_EXE_LINKER_FLAGS_MINSIZEREL} /${opt}")
 651     set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /${opt}")
 652   endforeach()
 653 else()
 654   message("Warning: unknown/unsupported compiler, things may go wrong")
 655 endif()
 656
 657 include(ThinArchives)