CMake/HPHPFindLibs.cmake

   1 #
   2 #   +----------------------------------------------------------------------+
   3 #   | HipHop for PHP                                                       |
   4 #   +----------------------------------------------------------------------+
   5 #   | Copyright (c) 2010 Facebook, Inc. (http://www.facebook.com)          |
   6 #   | Copyright (c) 1997-2010 The PHP Group                                |
   7 #   +----------------------------------------------------------------------+
   8 #   | This source file is subject to version 3.01 of the PHP license,      |
   9 #   | that is bundled with this package in the file LICENSE, and is        |
  10 #   | available through the world-wide-web at the following url:           |
  11 #   | http://www.php.net/license/3_01.txt                                  |
  12 #   | If you did not receive a copy of the PHP license and are unable to   |
  13 #   | obtain it through the world-wide-web, please send a note to          |
  14 #   | license@php.net so we can mail you a copy immediately.               |
  15 #   +----------------------------------------------------------------------+
  16 #
  17
  18 include(CheckFunctionExists)
  19
  20 # libdl
  21 find_package(LibDL)
  22 if (LIBDL_INCLUDE_DIRS)
  23   add_definitions("-DHAVE_LIBDL")
  24   include_directories(${LIBDL_INCLUDE_DIRS})
  25   if (LIBDL_NEEDS_UNDERSCORE)
  26     add_definitions("-DLIBDL_NEEDS_UNDERSCORE")
  27   endif()
  28 endif()
  29
  30 # google-glog
  31 find_package(Glog REQUIRED)
  32 if (LIBGLOG_STATIC)
  33   add_definitions("-DGOOGLE_GLOG_DLL_DECL=")
  34 endif()
  35 include_directories(${LIBGLOG_INCLUDE_DIR})
  36
  37 # inotify checks
  38 find_package(Libinotify)
  39 if (LIBINOTIFY_INCLUDE_DIR)
  40   include_directories(${LIBINOTIFY_INCLUDE_DIR})
  41 endif()
  42
  43 # mysql checks - if we're using async mysql, we use webscalesqlclient from
  44 # third-party/ instead
  45 if (ENABLE_ASYNC_MYSQL)
  46   include_directories(
  47     ${TP_DIR}/re2/src/
  48     ${TP_DIR}/squangle/src/
  49     ${TP_DIR}/webscalesqlclient/src/include/
  50   )
  51   set(MYSQL_CLIENT_LIB_DIR ${TP_DIR}/webscalesqlclient/src/)
  52   set(MYSQL_CLIENT_LIBS
  53     ${MYSQL_CLIENT_LIB_DIR}/libmysql/libfbmysqlclient_r.a
  54   )
  55 else()
  56   find_package(MySQL REQUIRED)
  57   link_directories(${MYSQL_LIB_DIR})
  58   include_directories(${MYSQL_INCLUDE_DIR})
  59 endif()
  60 MYSQL_SOCKET_SEARCH()
  61 if (MYSQL_UNIX_SOCK_ADDR)
  62   add_definitions(-DPHP_MYSQL_UNIX_SOCK_ADDR="${MYSQL_UNIX_SOCK_ADDR}")
  63 else ()
  64   message(FATAL_ERROR "Could not find MySQL socket path - if you install a MySQL server, this should be automatically detected. Alternatively, specify -DMYSQL_UNIX_SOCK_ADDR=/path/to/mysql.socket ; if you don't care about unix socket support for MySQL, specify -DMYSQL_UNIX_SOCK_ADDR=/dev/null")
  65 endif ()
  66
  67 # pcre checks
  68 find_package(PCRE)
  69 include_directories(${PCRE_INCLUDE_DIR})
  70
  71 # libevent checks
  72 find_package(LibEvent REQUIRED)
  73 include_directories(${LIBEVENT_INCLUDE_DIR})
  74
  75 set(CMAKE_REQUIRED_LIBRARIES "${LIBEVENT_LIB}")
  76 CHECK_FUNCTION_EXISTS("evhttp_bind_socket_with_fd" HAVE_CUSTOM_LIBEVENT)
  77 if(HAVE_CUSTOM_LIBEVENT)
  78         message("Using custom LIBEVENT")
  79         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DHAVE_CUSTOM_LIBEVENT")
  80 endif()
  81 set(CMAKE_REQUIRED_LIBRARIES)
  82
  83 # libXed
  84 find_package(LibXed)
  85 if (LibXed_INCLUDE_DIR AND LibXed_LIBRARY)
  86   include_directories(${LibXed_INCLUDE_DIR})
  87   add_definitions("-DHAVE_LIBXED")
  88 endif()
  89
  90 # CURL checks
  91 find_package(CURL REQUIRED)
  92 include_directories(${CURL_INCLUDE_DIR})
  93 if (CURL_STATIC)
  94   add_definitions("-DCURL_STATICLIB")
  95 endif()
  96
  97 set(CMAKE_REQUIRED_LIBRARIES "${CURL_LIBRARIES}")
  98 CHECK_FUNCTION_EXISTS("curl_multi_select" HAVE_CURL_MULTI_SELECT)
  99 CHECK_FUNCTION_EXISTS("curl_multi_wait" HAVE_CURL_MULTI_WAIT)
 100 if (HAVE_CURL_MULTI_SELECT)
 101   add_definitions("-DHAVE_CURL_MULTI_SELECT")
 102 endif()
 103 if (HAVE_CURL_MULTI_WAIT)
 104   add_definitions("-DHAVE_CURL_MULTI_WAIT")
 105 endif()
 106 set(CMAKE_REQUIRED_LIBRARIES)
 107
 108 # LibXML2 checks
 109 find_package(LibXml2 REQUIRED)
 110 include_directories(${LIBXML2_INCLUDE_DIR})
 111 add_definitions(${LIBXML2_DEFINITIONS})
 112
 113 # libsqlite3
 114 find_package(LibSQLite)
 115 if (LIBSQLITE_INCLUDE_DIR)
 116   include_directories(${LIBSQLITE_INCLUDE_DIR})
 117 endif ()
 118
 119 # libdouble-conversion
 120 find_package(DoubleConversion)
 121 if (DOUBLE_CONVERSION_INCLUDE_DIR)
 122   include_directories(${DOUBLE_CONVERSION_INCLUDE_DIR})
 123 endif ()
 124
 125 # liblz4
 126 find_package(LZ4)
 127 if (LZ4_FOUND)
 128   include_directories(${LZ4_INCLUDE_DIR})
 129 endif()
 130
 131 # fastlz
 132 find_package(FastLZ)
 133 if (FASTLZ_INCLUDE_DIR)
 134   include_directories(${FASTLZ_INCLUDE_DIR})
 135 endif()
 136
 137 # libzip
 138 find_package(LibZip)
 139 if (LIBZIP_INCLUDE_DIR_ZIP AND LIBZIP_INCLUDE_DIR_ZIPCONF)
 140   if (LIBZIP_VERSION VERSION_LESS "0.11")
 141     unset(LIBZIP_FOUND CACHE)
 142     unset(LIBZIP_LIBRARY CACHE)
 143     unset(LIBZIP_INCLUDE_DIR_ZIP CACHE)
 144     unset(LIBZIP_INCLUDE_DIR_ZIPCONF CACHE)
 145     message(STATUS "libzip is too old, found ${LIBZIP_VERSION} and we need 0.11+, using third-party bundled libzip")
 146   else ()
 147     include_directories(${LIBZIP_INCLUDE_DIR_ZIP} ${LIBZIP_INCLUDE_DIR_ZIPCONF})
 148     message(STATUS "Found libzip: ${LIBZIP_LIBRARY} ${LIBZIP_VERSION}")
 149   endif ()
 150 else ()
 151   message(STATUS "Using third-party bundled libzip")
 152 endif()
 153
 154 # ICU
 155 find_package(ICU REQUIRED)
 156 if (ICU_FOUND)
 157   if (ICU_VERSION VERSION_LESS "4.2")
 158     unset(ICU_FOUND CACHE)
 159     unset(ICU_INCLUDE_DIRS CACHE)
 160     unset(ICU_LIBRARIES CACHE)
 161     message(FATAL_ERROR "ICU is too old, found ${ICU_VERSION} and we need 4.2")
 162   endif ()
 163   include_directories(${ICU_INCLUDE_DIRS})
 164   if (ICU_STATIC)
 165     add_definitions("-DU_EXPORT=")
 166     add_definitions("-DU_IMPORT=")
 167   endif()
 168 endif (ICU_FOUND)
 169
 170 # jemalloc/tmalloc and profiler
 171 if (USE_GOOGLE_HEAP_PROFILER OR USE_GOOGLE_CPU_PROFILER)
 172   FIND_LIBRARY(GOOGLE_PROFILER_LIB profiler)
 173   FIND_PATH(GOOGLE_PROFILER_INCLUDE_DIR NAMES google/profiler.h)
 174   if (GOOGLE_PROFILER_INCLUDE_DIR)
 175     include_directories(${GOOGLE_PROFILER_INCLUDE_DIR})
 176   endif()
 177   if (GOOGLE_PROFILER_LIB)
 178     message(STATUS "Found Google profiler: ${GOOGLE_PROFILER_LIB}")
 179     if (USE_GOOGLE_CPU_PROFILER)
 180       set(GOOGLE_CPU_PROFILER_ENABLED 1)
 181     endif()
 182   else()
 183     message(STATUS "Can't find Google profiler")
 184   endif()
 185 endif()
 186
 187 if (USE_GOOGLE_HEAP_PROFILER AND GOOGLE_PROFILER_LIB)
 188   FIND_LIBRARY(GOOGLE_TCMALLOC_FULL_LIB tcmalloc)
 189   if (GOOGLE_TCMALLOC_FULL_LIB)
 190     message(STATUS "Found full tcmalloc: ${GOOGLE_TCMALLOC_FULL_LIB}")
 191     set(GOOGLE_HEAP_PROFILER_ENABLED 1)
 192     set(GOOGLE_TCMALLOC_ENABLED 1)
 193   else()
 194     message(STATUS "Can't find full tcmalloc - heap profiling is disabled")
 195   endif()
 196 endif()
 197
 198 if (USE_JEMALLOC AND NOT GOOGLE_TCMALLOC_ENABLED)
 199   FIND_LIBRARY(JEMALLOC_LIB NAMES jemalloc)
 200   FIND_PATH(JEMALLOC_INCLUDE_DIR NAMES jemalloc/jemalloc.h)
 201
 202   if (JEMALLOC_INCLUDE_DIR AND JEMALLOC_LIB)
 203     include_directories(${JEMALLOC_INCLUDE_DIR})
 204
 205     set (CMAKE_REQUIRED_INCLUDES ${JEMALLOC_INCLUDE_DIR})
 206     INCLUDE(CheckCXXSourceCompiles)
 207     CHECK_CXX_SOURCE_COMPILES("
 208 #include <jemalloc/jemalloc.h>
 209
 210 #define JEMALLOC_VERSION_NUMERIC ((JEMALLOC_VERSION_MAJOR << 24) | (JEMALLOC_VERSION_MINOR << 16) | (JEMALLOC_VERSION_BUGFIX << 8) | JEMALLOC_VERSION_NDEV)
 211
 212 #if JEMALLOC_VERSION_NUMERIC < 0x03050100
 213 # error jemalloc version >= 3.5.1 required
 214 #endif
 215
 216 int main(void) { return 0; }" JEMALLOC_VERSION_MINIMUM)
 217     set (CMAKE_REQUIRED_INCLUDES)
 218
 219     if (JEMALLOC_VERSION_MINIMUM)
 220       message(STATUS "Found jemalloc: ${JEMALLOC_LIB}")
 221       set(JEMALLOC_ENABLED 1)
 222     else()
 223       message(STATUS "Found jemalloc, but it was too old")
 224     endif()
 225   endif()
 226 endif()
 227
 228 if (USE_TCMALLOC AND NOT JEMALLOC_ENABLED AND NOT GOOGLE_TCMALLOC_ENABLED)
 229   FIND_LIBRARY(GOOGLE_TCMALLOC_MIN_LIB tcmalloc_minimal)
 230   if (GOOGLE_TCMALLOC_MIN_LIB)
 231     message(STATUS "Found minimal tcmalloc: ${GOOGLE_TCMALLOC_MIN_LIB}")
 232     set(GOOGLE_TCMALLOC_ENABLED 1)
 233   else()
 234     message(STATUS "Can't find minimal tcmalloc")
 235   endif()
 236 endif()
 237
 238 if (JEMALLOC_ENABLED)
 239   add_definitions(-DUSE_JEMALLOC=1)
 240 else()
 241   add_definitions(-DNO_JEMALLOC=1)
 242 endif()
 243 if (GOOGLE_TCMALLOC_ENABLED)
 244   add_definitions(-DGOOGLE_TCMALLOC=1)
 245 else()
 246   add_definitions(-DNO_TCMALLOC=1)
 247 endif()
 248 if (GOOGLE_HEAP_PROFILER_ENABLED)
 249   add_definitions(-DGOOGLE_HEAP_PROFILER=1)
 250 endif()
 251 if (GOOGLE_CPU_PROFILER_ENABLED)
 252   add_definitions(-DGOOGLE_CPU_PROFILER=1)
 253 endif()
 254
 255 # HHProf
 256 if (JEMALLOC_ENABLED AND ENABLE_HHPROF)
 257   add_definitions(-DENABLE_HHPROF=1)
 258 endif()
 259
 260 # tbb libs
 261 find_package(TBB REQUIRED)
 262 if (${TBB_INTERFACE_VERSION} LESS 5005)
 263   unset(TBB_FOUND CACHE)
 264   unset(TBB_INCLUDE_DIRS CACHE)
 265   unset(TBB_LIBRARIES CACHE)
 266   message(FATAL_ERROR "TBB is too old, please install at least 3.0(5005), preferably 4.0(6000) or higher")
 267 endif()
 268 include_directories(${TBB_INCLUDE_DIRS})
 269 link_directories(${TBB_LIBRARY_DIRS})
 270
 271 # OpenSSL libs
 272 find_package(OpenSSL REQUIRED)
 273 include_directories(${OPENSSL_INCLUDE_DIR})
 274
 275 # LibreSSL explicitly refuses to support RAND_egd()
 276 SET(CMAKE_REQUIRED_INCLUDES ${OPENSSL_INCLUDE_DIR})
 277 SET(CMAKE_REQUIRED_LIBRARIES ${OPENSSL_LIBRARIES})
 278 INCLUDE(CheckCXXSourceCompiles)
 279 CHECK_CXX_SOURCE_COMPILES("#include <openssl/rand.h>
 280 int main() {
 281   return RAND_egd(\"/dev/null\");
 282 }" OPENSSL_HAVE_RAND_EGD)
 283 if (NOT OPENSSL_HAVE_RAND_EGD)
 284   add_definitions("-DOPENSSL_NO_RAND_EGD")
 285 endif()
 286 SET(CMAKE_REQUIRED_INCLUDES)
 287 SET(CMAKE_REQUIRED_LIBRARIES)
 288
 289
 290 # ZLIB
 291 find_package(ZLIB REQUIRED)
 292 include_directories(${ZLIB_INCLUDE_DIR})
 293
 294 # oniguruma
 295 find_package(ONIGURUMA REQUIRED)
 296 include_directories(${ONIGURUMA_INCLUDE_DIRS})
 297 if (ONIGURUMA_STATIC)
 298   add_definitions("-DONIG_EXTERN=extern")
 299 endif()
 300
 301 # libpthreads
 302 find_package(PThread REQUIRED)
 303 include_directories(${LIBPTHREAD_INCLUDE_DIRS})
 304 if (LIBPTHREAD_STATIC)
 305   add_definitions("-DPTW32_STATIC_LIB")
 306 endif()
 307
 308 # Either Readline or Editline (for hphpd)
 309 find_package(Readline)
 310 find_package(Editline)
 311 if (EDITLINE_INCLUDE_DIRS)
 312   add_definitions("-DUSE_EDITLINE")
 313   include_directories(${EDITLINE_INCLUDE_DIRS})
 314 elseif (READLINE_INCLUDE_DIR)
 315   if (READLINE_STATIC)
 316     add_definitions("-DREADLINE_STATIC")
 317   endif()
 318   include_directories(${READLINE_INCLUDE_DIR})
 319 else()
 320   message(FATAL_ERROR "Could not find Readline or Editline")
 321 endif()
 322
 323 if (NOT WINDOWS)
 324   find_package(LibDwarf REQUIRED)
 325   include_directories(${LIBDWARF_INCLUDE_DIRS})
 326   if (LIBDWARF_CONST_NAME)
 327     add_definitions("-DLIBDWARF_CONST_NAME")
 328   endif()
 329   if (LIBDWARF_USE_INIT_C)
 330     add_definitions("-DLIBDWARF_USE_INIT_C")
 331   endif()
 332
 333   find_package(LibElf REQUIRED)
 334   include_directories(${LIBELF_INCLUDE_DIRS})
 335   if (ELF_GETSHDRSTRNDX)
 336     add_definitions("-DHAVE_ELF_GETSHDRSTRNDX")
 337   endif()
 338 endif()
 339
 340 FIND_LIBRARY(CRYPT_LIB NAMES xcrypt crypt crypto)
 341 if (LINUX OR FREEBSD)
 342   FIND_LIBRARY (RT_LIB rt)
 343 endif()
 344
 345 if (LINUX)
 346   FIND_LIBRARY (CAP_LIB cap)
 347
 348   if (NOT CAP_LIB)
 349     message(FATAL_ERROR "You need to install libcap")
 350   endif()
 351 endif()
 352
 353 if (LINUX OR APPLE)
 354   FIND_LIBRARY (DL_LIB dl)
 355   FIND_LIBRARY (RESOLV_LIB resolv)
 356 endif()
 357
 358 if (FREEBSD)
 359   FIND_LIBRARY (EXECINFO_LIB execinfo)
 360   if (NOT EXECINFO_LIB)
 361     message(FATAL_ERROR "You need to install libexecinfo")
 362   endif()
 363 endif()
 364
 365 if (APPLE)
 366   find_library(KERBEROS_LIB NAMES gssapi_krb5)
 367
 368   # This is required by Homebrew's libc. See
 369   # https://github.com/facebook/hhvm/pull/5728#issuecomment-124290712
 370   # for more info.
 371   find_package(Libpam)
 372   if (PAM_INCLUDE_PATH)
 373     include_directories(${PAM_INCLUDE_PATH})
 374   endif()
 375 endif()
 376
 377 #find_package(BISON REQUIRED)
 378 #find_package(FLEX REQUIRED)
 379
 380 #if (${FLEX_VERSION} VERSION_LESS 2.5.33)
 381 #  message(FATAL_ERROR "Flex is too old, found ${FLEX_VERSION} and we need 2.5.33")
 382 #endif()
 383
 384 include_directories(${HPHP_HOME}/hphp)
 385
 386 macro(hphp_link target)
 387   # oniguruma must remain first for OS X to work -- see below for a somewhat
 388   # dogscience explanation. If you deeply understand this, feel free to fix
 389   # properly; in particular, two-level namespaces on OS X should allow us to
 390   # say *which* copy of the disputed functions we want, but I don' t know
 391   # how to get that to work.
 392   #
 393   # oniguruma has some of its own implementations of POSIX regex functions,
 394   # like regcomp() an regexec(). We use onig everywhere, for both its own
 395   # sepcial functions and for the POSIX replacements. This means that the
 396   # linker needs to pick the implementions of the POSIX regex functions from
 397   # onig, not libc.
 398   #
 399   # On Linux, that works out fine, since the linker sees onig on the link
 400   # line before (implicitly) libc. However, on OS X, despide the manpage for
 401   # ld claiming otherwise about indirect dylib dependencies, as soon as we
 402   # include one of the libs here that pull in libSystem.B, the linker will
 403   # pick the implementations of those functions from libc, not from onig.
 404   # And since we've included the onig headers, which have very slightly
 405   # different definintions for some of the key data structures, things go
 406   # quite awry -- this manifests as infinite loops or crashes when calling
 407   # the PHP split() function.
 408   #
 409   # So make sure to link onig first, so its implementations are picked.
 410   target_link_libraries(${target} ${ONIGURUMA_LIBRARIES})
 411
 412   if (LIBDL_LIBRARIES)
 413     target_link_libraries(${target} ${LIBDL_LIBRARIES})
 414   endif ()
 415
 416   if (GOOGLE_HEAP_PROFILER_ENABLED OR GOOGLE_CPU_PROFILER_ENABLED)
 417     target_link_libraries(${target} ${GOOGLE_PROFILER_LIB})
 418   endif()
 419
 420   if (JEMALLOC_ENABLED)
 421     target_link_libraries(${target} ${JEMALLOC_LIB})
 422   endif()
 423
 424   if (GOOGLE_HEAP_PROFILER_ENABLED)
 425     target_link_libraries(${target} ${GOOGLE_TCMALLOC_FULL_LIB})
 426   elseif (GOOGLE_TCMALLOC_ENABLED)
 427     target_link_libraries(${target} ${GOOGLE_TCMALLOC_MIN_LIB})
 428   endif()
 429
 430   target_link_libraries(${target} boost)
 431   target_link_libraries(${target} ${MYSQL_CLIENT_LIBS})
 432   if (ENABLE_ASYNC_MYSQL)
 433     target_link_libraries(${target} squangle)
 434   endif()
 435   target_link_libraries(${target} ${PCRE_LIBRARY})
 436   target_link_libraries(${target} ${ICU_DATA_LIBRARIES} ${ICU_I18N_LIBRARIES} ${ICU_LIBRARIES})
 437   target_link_libraries(${target} ${LIBEVENT_LIB})
 438   target_link_libraries(${target} ${CURL_LIBRARIES})
 439   target_link_libraries(${target} ${LIBGLOG_LIBRARY})
 440   if (LIBJSONC_LIBRARY)
 441     target_link_libraries(${target} ${LIBJSONC_LIBRARY})
 442   endif()
 443
 444   if (LibXed_LIBRARY)
 445     target_link_libraries(${target} ${LibXed_LIBRARY})
 446   endif()
 447
 448   if (LIBINOTIFY_LIBRARY)
 449     target_link_libraries(${target} ${LIBINOTIFY_LIBRARY})
 450   endif()
 451
 452   if (LINUX)
 453     target_link_libraries(${target} ${CAP_LIB})
 454   endif()
 455
 456   if (LINUX OR APPLE)
 457     target_link_libraries(${target} ${RESOLV_LIB})
 458     target_link_libraries(${target} ${DL_LIB})
 459   endif()
 460
 461   if (FREEBSD)
 462     target_link_libraries(${target} ${EXECINFO_LIB})
 463   endif()
 464
 465   if (APPLE)
 466     target_link_libraries(${target} ${LIBINTL_LIBRARIES})
 467     target_link_libraries(${target} ${KERBEROS_LIB})
 468
 469     if (PAM_LIBRARY)
 470       target_link_libraries(${target} ${PAM_LIBRARY})
 471     endif()
 472   endif()
 473
 474   if (LIBPTHREAD_LIBRARIES)
 475     target_link_libraries(${target} ${LIBPTHREAD_LIBRARIES})
 476   endif()
 477
 478   target_link_libraries(${target} ${TBB_LIBRARIES})
 479   target_link_libraries(${target} ${OPENSSL_LIBRARIES})
 480   target_link_libraries(${target} ${ZLIB_LIBRARIES})
 481
 482   target_link_libraries(${target} ${LIBXML2_LIBRARIES})
 483
 484   target_link_libraries(${target} ${LBER_LIBRARIES})
 485
 486   if (CRYPT_LIB)
 487     target_link_libraries(${target} ${CRYPT_LIB})
 488   endif()
 489
 490   if (LINUX OR FREEBSD)
 491     target_link_libraries(${target} ${RT_LIB})
 492   endif()
 493
 494   if (LIBSQLITE3_FOUND AND LIBSQLITE3_LIBRARY)
 495     target_link_libraries(${target} ${LIBSQLITE3_LIBRARY})
 496   else()
 497     target_link_libraries(${target} sqlite3)
 498   endif()
 499
 500   if (DOUBLE_CONVERSION_FOUND)
 501     target_link_libraries(${target} ${DOUBLE_CONVERSION_LIBRARY})
 502   else()
 503     target_link_libraries(${target} double-conversion)
 504   endif()
 505
 506   if (LZ4_FOUND)
 507     target_link_libraries(${target} ${LZ4_LIBRARY})
 508   else()
 509     target_link_libraries(${target} lz4)
 510   endif()
 511
 512   if (LIBZIP_LIBRARY)
 513     target_link_libraries(${target} ${LIBZIP_LIBRARY})
 514   else()
 515     target_link_libraries(${target} zip_static)
 516   endif()
 517
 518   if (PCRE_LIBRARY)
 519     target_link_libraries(${target} ${PCRE_LIBRARY})
 520   else()
 521     target_link_libraries(${target} pcre)
 522   endif()
 523
 524   if (LIBFASTLZ_LIBRARY)
 525     target_link_libraries(${target} ${LIBFASTLZ_LIBRARY})
 526   else()
 527     target_link_libraries(${target} fastlz)
 528   endif()
 529
 530   target_link_libraries(${target} timelib)
 531   target_link_libraries(${target} folly)
 532   target_link_libraries(${target} wangle)
 533   target_link_libraries(${target} brotli_enc)
 534   target_link_libraries(${target} brotli_dec)
 535
 536   if (ENABLE_MCROUTER)
 537     target_link_libraries(${target} mcrouter)
 538   endif()
 539
 540   if (NOT MSVC)
 541     target_link_libraries(${target} afdt)
 542   endif()
 543   target_link_libraries(${target} mbfl)
 544
 545   if (EDITLINE_LIBRARIES)
 546     target_link_libraries(${target} ${EDITLINE_LIBRARIES})
 547   elseif (READLINE_LIBRARY)
 548     target_link_libraries(${target} ${READLINE_LIBRARY})
 549   endif()
 550
 551   if (NOT WINDOWS)
 552     target_link_libraries(${target} ${LIBDWARF_LIBRARIES})
 553     target_link_libraries(${target} ${LIBELF_LIBRARIES})
 554   endif()
 555
 556   if (LINUX)
 557     target_link_libraries(${target} -Wl,--wrap=pthread_create -Wl,--wrap=pthread_exit -Wl,--wrap=pthread_join)
 558   endif()
 559
 560   if (MSVC)
 561     target_link_libraries(${target} dbghelp.lib dnsapi.lib)
 562   endif()
 563 endmacro()