CMake/HPHPFindLibs.cmake

   1 #
   2 #   +----------------------------------------------------------------------+
   3 #   | HipHop for PHP                                                       |
   4 #   +----------------------------------------------------------------------+
   5 #   | Copyright (c) 2010 Facebook, Inc. (http://www.facebook.com)          |
   6 #   | Copyright (c) 1997-2010 The PHP Group                                |
   7 #   +----------------------------------------------------------------------+
   8 #   | This source file is subject to version 3.01 of the PHP license,      |
   9 #   | that is bundled with this package in the file LICENSE, and is        |
  10 #   | available through the world-wide-web at the following url:           |
  11 #   | http://www.php.net/license/3_01.txt                                  |
  12 #   | If you did not receive a copy of the PHP license and are unable to   |
  13 #   | obtain it through the world-wide-web, please send a note to          |
  14 #   | license@php.net so we can mail you a copy immediately.               |
  15 #   +----------------------------------------------------------------------+
  16 #
  17
  18 include(CheckFunctionExists)
  19
  20 add_definitions("-DHAVE_QUICKLZ")
  21
  22 # libdl
  23 find_package(LibDL)
  24 if (LIBDL_INCLUDE_DIRS)
  25         add_definitions("-DHAVE_LIBDL")
  26         include_directories(${LIBDL_INCLUDE_DIRS})
  27         if (LIBDL_NEEDS_UNDERSCORE)
  28                 add_definitions("-DLIBDL_NEEDS_UNDERSCORE")
  29         endif()
  30 endif()
  31
  32 # boost checks
  33 find_package(Boost 1.49.0 COMPONENTS system program_options filesystem REQUIRED)
  34 include_directories(${Boost_INCLUDE_DIRS})
  35 link_directories(${Boost_LIBRARY_DIRS})
  36 add_definitions("-DHAVE_BOOST1_49")
  37
  38
  39 # features.h
  40 FIND_PATH(FEATURES_HEADER features.h)
  41 if (FEATURES_HEADER)
  42         add_definitions("-DHAVE_FEATURES_H=1")
  43 endif()
  44
  45 # google-glog
  46 find_package(Glog REQUIRED)
  47 include_directories(${LIBGLOG_INCLUDE_DIR})
  48
  49 # inotify checks
  50 find_package(Libinotify)
  51 if (LIBINOTIFY_INCLUDE_DIR)
  52         include_directories(${LIBINOTIFY_INCLUDE_DIR})
  53 endif()
  54
  55 # iconv checks
  56 find_package(Libiconv REQUIRED)
  57 include_directories(${LIBICONV_INCLUDE_DIR})
  58 if (LIBICONV_CONST)
  59   message(STATUS "Using const for input to iconv() call")
  60   add_definitions("-DICONV_CONST=const")
  61 endif()
  62
  63 # mysql checks
  64 find_package(MySQL REQUIRED)
  65 include_directories(${MYSQL_INCLUDE_DIR})
  66 link_directories(${MYSQL_LIB_DIR})
  67 MYSQL_SOCKET_SEARCH()
  68 if (MYSQL_UNIX_SOCK_ADDR)
  69   add_definitions(-DPHP_MYSQL_UNIX_SOCK_ADDR="${MYSQL_UNIX_SOCK_ADDR}")
  70 endif()
  71
  72 # libmemcached checks
  73 find_package(Libmemcached REQUIRED)
  74 if (LIBMEMCACHED_VERSION VERSION_LESS "0.39")
  75   unset(LIBMEMCACHED_INCLUDE_DIR CACHE)
  76   unset(LIBMEMCACHED_LIBRARY CACHE)
  77   unset(LIBMEMCACHED_VERSION CACHE)
  78   message(FATAL_ERROR "libmemcache is too old, found ${LIBMEMCACHED_VERSION} and we need 0.39")
  79 endif ()
  80 include_directories(${LIBMEMCACHED_INCLUDE_DIR})
  81
  82 # pcre checks
  83 find_package(PCRE REQUIRED)
  84 include_directories(${PCRE_INCLUDE_DIRS})
  85
  86 # libevent checks
  87 find_package(LibEvent REQUIRED)
  88 include_directories(${LIBEVENT_INCLUDE_DIR})
  89
  90 set(CMAKE_REQUIRED_LIBRARIES "${LIBEVENT_LIB}")
  91 CHECK_FUNCTION_EXISTS("evhttp_bind_socket_with_fd" HAVE_CUSTOM_LIBEVENT)
  92 if(HAVE_CUSTOM_LIBEVENT)
  93         message("Using custom LIBEVENT")
  94         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DHAVE_CUSTOM_LIBEVENT")
  95 endif()
  96 set(CMAKE_REQUIRED_LIBRARIES)
  97
  98 find_package(LibUODBC)
  99 if (LIBUODBC_INCLUDE_DIRS)
 100         include_directories(${LIBUODBC_INCLUDE_DIRS})
 101         add_definitions("-DHAVE_UODBC")
 102 endif ()
 103
 104 # libXed
 105 find_package(LibXed)
 106 if (LibXed_INCLUDE_DIR AND LibXed_LIBRARY)
 107         include_directories(${LibXed_INCLUDE_DIR})
 108         add_definitions("-DHAVE_LIBXED")
 109 endif()
 110
 111 # CURL checks
 112 find_package(CURL REQUIRED)
 113 include_directories(${CURL_INCLUDE_DIR})
 114
 115 set(CMAKE_REQUIRED_LIBRARIES "${CURL_LIBRARIES}")
 116 CHECK_FUNCTION_EXISTS("curl_multi_select" HAVE_CURL_MULTI_SELECT)
 117 CHECK_FUNCTION_EXISTS("curl_multi_wait" HAVE_CURL_MULTI_WAIT)
 118 if (HAVE_CURL_MULTI_SELECT)
 119         add_definitions("-DHAVE_CURL_MULTI_SELECT")
 120 endif()
 121 if (HAVE_CURL_MULTI_WAIT)
 122         add_definitions("-DHAVE_CURL_MULTI_WAIT")
 123 endif()
 124 set(CMAKE_REQUIRED_LIBRARIES)
 125
 126 # LibXML2 checks
 127 find_package(LibXml2 REQUIRED)
 128 include_directories(${LIBXML2_INCLUDE_DIR})
 129 add_definitions(${LIBXML2_DEFINITIONS})
 130
 131 find_package(LibXslt REQUIRED)
 132 include_directories(${LIBXSLT_INCLUDE_DIR})
 133 add_definitions(${LIBXSLT_DEFINITIONS})
 134
 135 find_package(EXPAT REQUIRED)
 136 include_directories(${EXPAT_INCLUDE_DIRS})
 137
 138 # ICU
 139 find_package(ICU REQUIRED)
 140 if (ICU_FOUND)
 141         if (ICU_VERSION VERSION_LESS "4.2")
 142                 unset(ICU_FOUND CACHE)
 143                 unset(ICU_INCLUDE_DIRS CACHE)
 144                 unset(ICU_LIBRARIES CACHE)
 145                 message(FATAL_ERROR "ICU is too old, found ${ICU_VERSION} and we need 4.2")
 146         endif ()
 147         include_directories(${ICU_INCLUDE_DIRS})
 148 endif (ICU_FOUND)
 149
 150 # jemalloc/tmalloc and profiler
 151 if (USE_GOOGLE_HEAP_PROFILER OR USE_GOOGLE_CPU_PROFILER)
 152         FIND_LIBRARY(GOOGLE_PROFILER_LIB profiler)
 153         if (GOOGLE_PROFILER_LIB)
 154                 message(STATUS "Found Google profiler: ${GOOGLE_PROFILER_LIB}")
 155                 if (USE_GOOGLE_CPU_PROFILER)
 156                         set(GOOGLE_CPU_PROFILER_ENABLED 1)
 157                 endif()
 158         else()
 159                 message(STATUS "Can't find Google profiler")
 160         endif()
 161 endif()
 162
 163 if (USE_GOOGLE_HEAP_PROFILER AND GOOGLE_PROFILER_LIB)
 164         FIND_LIBRARY(GOOGLE_TCMALLOC_FULL_LIB tcmalloc)
 165         if (GOOGLE_TCMALLOC_FULL_LIB)
 166                 message(STATUS "Found full tcmalloc: ${GOOGLE_TCMALLOC_FULL_LIB}")
 167                 set(GOOGLE_HEAP_PROFILER_ENABLED 1)
 168                 set(GOOGLE_TCMALLOC_ENABLED 1)
 169         else()
 170                 message(STATUS "Can't find full tcmalloc - heap profiling is disabled")
 171         endif()
 172 endif()
 173
 174 if (USE_JEMALLOC AND NOT GOOGLE_TCMALLOC_ENABLED)
 175         FIND_LIBRARY(JEMALLOC_LIB NAMES jemalloc)
 176         FIND_PATH(JEMALLOC_INCLUDE_DIR NAMES jemalloc/jemalloc.h)
 177
 178         if (JEMALLOC_INCLUDE_DIR AND JEMALLOC_LIB)
 179                 include_directories(${JEMALLOC_INCLUDE_DIR})
 180
 181                 set (CMAKE_REQUIRED_INCLUDES ${JEMALLOC_INCLUDE_DIR})
 182                 INCLUDE(CheckCXXSourceCompiles)
 183                 CHECK_CXX_SOURCE_COMPILES("
 184 #include <jemalloc/jemalloc.h>
 185 int main(void) {
 186 #if !defined(JEMALLOC_VERSION_MAJOR) || (JEMALLOC_VERSION_MAJOR < 3)
 187 # error \"jemalloc version >= 3.0.0 required\"
 188 #endif
 189         return 0;
 190 }" JEMALLOC_VERSION_3)
 191                 set (CMAKE_REQUIRED_INCLUDES)
 192
 193                 if (JEMALLOC_VERSION_3)
 194                         message(STATUS "Found jemalloc: ${JEMALLOC_LIB}")
 195                         set(JEMALLOC_ENABLED 1)
 196                 else()
 197                         message(STATUS "Found jemalloc, but it was too old")
 198                 endif()
 199         endif()
 200 endif()
 201
 202 if (USE_TCMALLOC AND NOT JEMALLOC_ENABLED AND NOT GOOGLE_TCMALLOC_ENABLED)
 203         FIND_LIBRARY(GOOGLE_TCMALLOC_MIN_LIB tcmalloc_minimal)
 204         if (GOOGLE_TCMALLOC_MIN_LIB)
 205                 message(STATUS "Found minimal tcmalloc: ${GOOGLE_TCMALLOC_MIN_LIB}")
 206                 set(GOOGLE_TCMALLOC_ENABLED 1)
 207         else()
 208                 message(STATUS "Can't find minimal tcmalloc")
 209         endif()
 210 endif()
 211
 212 if (JEMALLOC_ENABLED)
 213         add_definitions(-DUSE_JEMALLOC=1)
 214 else()
 215         add_definitions(-DNO_JEMALLOC=1)
 216 endif()
 217 if (GOOGLE_TCMALLOC_ENABLED)
 218         add_definitions(-DGOOGLE_TCMALLOC=1)
 219 else()
 220         add_definitions(-DNO_TCMALLOC=1)
 221 endif()
 222 if (GOOGLE_HEAP_PROFILER_ENABLED)
 223         add_definitions(-DGOOGLE_HEAP_PROFILER=1)
 224 endif()
 225 if (GOOGLE_CPU_PROFILER_ENABLED)
 226         add_definitions(-DGOOGLE_CPU_PROFILER=1)
 227 endif()
 228
 229 # tbb libs
 230 find_package(TBB REQUIRED)
 231 if (${TBB_INTERFACE_VERSION} LESS 5005)
 232         unset(TBB_FOUND CACHE)
 233         unset(TBB_INCLUDE_DIRS CACHE)
 234         unset(TBB_LIBRARIES CACHE)
 235         message(FATAL_ERROR "TBB is too old, please install at least 3.0(5005), preferably 4.0(6000) or higher")
 236 endif()
 237 include_directories(${TBB_INCLUDE_DIRS})
 238 link_directories(${TBB_LIBRARY_DIRS})
 239
 240 # mcrypt libs
 241 find_package(Mcrypt REQUIRED)
 242 include_directories(${Mcrypt_INCLUDE_DIR})
 243
 244 # OpenSSL libs
 245 find_package(OpenSSL REQUIRED)
 246 include_directories(${OPENSSL_INCLUDE_DIR})
 247
 248 # ZLIB
 249 find_package(ZLIB REQUIRED)
 250 include_directories(${ZLIB_INCLUDE_DIR})
 251
 252 find_package(BZip2 REQUIRED)
 253 include_directories(${BZIP2_INCLUDE_DIR})
 254 add_definitions(${BZIP2_DEFINITIONS})
 255
 256 # oniguruma
 257 find_package(ONIGURUMA REQUIRED)
 258 include_directories(${ONIGURUMA_INCLUDE_DIRS})
 259
 260 # LDAP
 261 find_package(Ldap REQUIRED)
 262 include_directories(${LDAP_INCLUDE_DIR})
 263
 264 # libpthreads
 265 find_package(PThread REQUIRED)
 266 include_directories(${LIBPTHREAD_INCLUDE_DIRS})
 267
 268 # Either Readline or Editline (for hphpd)
 269 find_package(Readline)
 270 find_package(Editline)
 271 if (READLINE_INCLUDE_DIR)
 272         include_directories(${READLINE_INCLUDE_DIR})
 273 elseif (EDITLINE_INCLUDE_DIRS)
 274         add_definitions("-DUSE_EDITLINE")
 275         include_directories(${EDITLINE_INCLUDE_DIRS})
 276 else()
 277         message(FATAL_ERROR "Could not find Readline or Editline")
 278 endif()
 279
 280 find_package(CClient REQUIRED)
 281 include_directories(${CCLIENT_INCLUDE_PATH})
 282
 283 find_package(LibDwarf REQUIRED)
 284 include_directories(${LIBDWARF_INCLUDE_DIRS})
 285 if (LIBDWARF_HAVE_ENCODE_LEB128)
 286         add_definitions("-DHAVE_LIBDWARF_20130729")
 287 endif()
 288
 289 find_package(LibElf REQUIRED)
 290 include_directories(${LIBELF_INCLUDE_DIRS})
 291 if (ELF_GETSHDRSTRNDX)
 292         add_definitions("-DHAVE_ELF_GETSHDRSTRNDX")
 293 endif()
 294
 295 CONTAINS_STRING("${CCLIENT_INCLUDE_PATH}/utf8.h" U8T_DECOMPOSE RECENT_CCLIENT)
 296 if (NOT RECENT_CCLIENT)
 297         unset(RECENT_CCLIENT CACHE)
 298         message(FATAL_ERROR "Your version of c-client is too old, you need 2007")
 299 endif()
 300
 301
 302 if (EXISTS "${CCLIENT_INCLUDE_PATH}/linkage.c")
 303         CONTAINS_STRING("${CCLIENT_INCLUDE_PATH}/linkage.c" auth_gss CCLIENT_HAS_GSS)
 304 elseif (EXISTS "${CCLIENT_INCLUDE_PATH}/linkage.h")
 305     CONTAINS_STRING("${CCLIENT_INCLUDE_PATH}/linkage.h" auth_gss CCLIENT_HAS_GSS)
 306 endif()
 307
 308 find_package(Libpam)
 309 if (PAM_INCLUDE_PATH)
 310         include_directories(${PAM_INCLUDE_PATH})
 311 endif()
 312
 313 if (NOT CCLIENT_HAS_GSS)
 314         add_definitions(-DSKIP_IMAP_GSS=1)
 315 endif()
 316
 317 if (EXISTS "${CCLIENT_INCLUDE_PATH}/linkage.c")
 318         CONTAINS_STRING("${CCLIENT_INCLUDE_PATH}/linkage.c" ssl_onceonlyinit CCLIENT_HAS_SSL)
 319 elseif (EXISTS "${CCLIENT_INCLUDE_PATH}/linkage.h")
 320         CONTAINS_STRING("${CCLIENT_INCLUDE_PATH}/linkage.h" ssl_onceonlyinit CCLIENT_HAS_SSL)
 321 endif()
 322
 323 if (NOT CCLIENT_HAS_SSL)
 324         add_definitions(-DSKIP_IMAP_SSL=1)
 325 endif()
 326
 327 FIND_LIBRARY(CRYPT_LIB NAMES xcrypt crypt crypto)
 328 if (LINUX OR FREEBSD)
 329         FIND_LIBRARY (RT_LIB rt)
 330 endif()
 331
 332 if (LINUX)
 333         FIND_LIBRARY (CAP_LIB cap)
 334
 335         if (NOT CAP_LIB)
 336                 message(FATAL_ERROR "You need to install libcap")
 337         endif()
 338 endif()
 339
 340 if (LINUX OR APPLE)
 341         FIND_LIBRARY (DL_LIB dl)
 342         FIND_LIBRARY (RESOLV_LIB resolv)
 343 endif()
 344
 345 FIND_LIBRARY (BFD_LIB bfd)
 346 FIND_LIBRARY (LIBIBERTY_LIB iberty)
 347
 348 if (NOT BFD_LIB)
 349         message(FATAL_ERROR "You need to install binutils")
 350 endif()
 351
 352 if (NOT LIBIBERTY_LIB)
 353         message(FATAL_ERROR "You need to install libiberty (usually bundled with binutils)")
 354 endif()
 355
 356 if (FREEBSD)
 357         FIND_LIBRARY (EXECINFO_LIB execinfo)
 358         if (NOT EXECINFO_LIB)
 359                 message(FATAL_ERROR "You need to install libexecinfo")
 360         endif()
 361 endif()
 362
 363 if (APPLE)
 364         find_library(LIBINTL_LIBRARIES NAMES intl libintl)
 365         if (LIBINTL_INCLUDE_DIR)
 366                 include_directories(${LIBINTL_INCLUDE_DIR})
 367         endif()
 368         find_library(KERBEROS_LIB NAMES gssapi_krb5)
 369 endif()
 370
 371 #find_package(BISON REQUIRED)
 372 #find_package(FLEX REQUIRED)
 373
 374 #if (${FLEX_VERSION} VERSION_LESS 2.5.33)
 375 #       message(FATAL_ERROR "Flex is too old, found ${FLEX_VERSION} and we need 2.5.33")
 376 #endif()
 377
 378 include_directories(${HPHP_HOME}/hphp)
 379
 380 macro(hphp_link target)
 381         if (LIBDL_LIBRARIES)
 382                 target_link_libraries(${target} ${LIBDL_LIBRARIES})
 383         endif ()
 384
 385         if (GOOGLE_HEAP_PROFILER_ENABLED OR GOOGLE_CPU_PROFILER_ENABLED)
 386                 target_link_libraries(${target} ${GOOGLE_PROFILER_LIB})
 387         endif()
 388
 389         if (JEMALLOC_ENABLED)
 390                 target_link_libraries(${target} ${JEMALLOC_LIB})
 391         endif()
 392
 393         if (GOOGLE_HEAP_PROFILER_ENABLED)
 394                 target_link_libraries(${target} ${GOOGLE_TCMALLOC_FULL_LIB})
 395         elseif (GOOGLE_TCMALLOC_ENABLED)
 396                 target_link_libraries(${target} ${GOOGLE_TCMALLOC_MIN_LIB})
 397         endif()
 398
 399         target_link_libraries(${target} ${Boost_LIBRARIES})
 400         target_link_libraries(${target} ${MYSQL_CLIENT_LIBS})
 401         target_link_libraries(${target} ${PCRE_LIBRARY})
 402         target_link_libraries(${target} ${ICU_DATA_LIBRARIES} ${ICU_I18N_LIBRARIES} ${ICU_LIBRARIES})
 403         target_link_libraries(${target} ${LIBEVENT_LIB})
 404         target_link_libraries(${target} ${CURL_LIBRARIES})
 405         target_link_libraries(${target} ${LIBGLOG_LIBRARY})
 406
 407 if (LibXed_LIBRARY)
 408         target_link_libraries(${target} ${LibXed_LIBRARY})
 409 endif()
 410
 411 if (LIBINOTIFY_LIBRARY)
 412         target_link_libraries(${target} ${LIBINOTIFY_LIBRARY})
 413 endif()
 414
 415 if (LIBICONV_LIBRARY)
 416         target_link_libraries(${target} ${LIBICONV_LIBRARY})
 417 endif()
 418
 419
 420 if (LINUX)
 421         target_link_libraries(${target} ${CAP_LIB})
 422 endif()
 423
 424 if (LINUX OR APPLE)
 425         target_link_libraries(${target} ${RESOLV_LIB})
 426         target_link_libraries(${target} ${DL_LIB})
 427 endif()
 428
 429 if (FREEBSD)
 430         target_link_libraries(${target} ${EXECINFO_LIB})
 431 endif()
 432
 433 if (APPLE)
 434         target_link_libraries(${target} ${LIBINTL_LIBRARIES})
 435         target_link_libraries(${target} ${KERBEROS_LIB})
 436 endif()
 437
 438         target_link_libraries(${target} ${BFD_LIB})
 439         target_link_libraries(${target} ${LIBIBERTY_LIB})
 440 if (${LIBPTHREAD_LIBRARIES})
 441         target_link_libraries(${target} ${LIBPTHREAD_LIBRARIES})
 442 endif()
 443         target_link_libraries(${target} ${TBB_LIBRARIES})
 444         target_link_libraries(${target} ${OPENSSL_LIBRARIES})
 445         target_link_libraries(${target} ${ZLIB_LIBRARIES})
 446         target_link_libraries(${target} ${BZIP2_LIBRARIES})
 447
 448         target_link_libraries(${target} ${LIBXML2_LIBRARIES})
 449         target_link_libraries(${target} ${LIBXSLT_LIBRARIES})
 450         target_link_libraries(${target} ${LIBXSLT_EXSLT_LIBRARIES})
 451         target_link_libraries(${target} ${EXPAT_LIBRARY})
 452         target_link_libraries(${target} ${ONIGURUMA_LIBRARIES})
 453         target_link_libraries(${target} ${Mcrypt_LIB})
 454 if (LIBUODBC_LIBRARIES)
 455         target_link_libraries(${target} ${LIBUODBC_LIBRARIES})
 456 endif()
 457         target_link_libraries(${target} ${LDAP_LIBRARIES})
 458         target_link_libraries(${target} ${LBER_LIBRARIES})
 459
 460         target_link_libraries(${target} ${LIBMEMCACHED_LIBRARY})
 461
 462         target_link_libraries(${target} ${CRYPT_LIB})
 463         if (LINUX OR FREEBSD)
 464                 target_link_libraries(${target} ${RT_LIB})
 465         endif()
 466
 467         target_link_libraries(${target} timelib)
 468         target_link_libraries(${target} sqlite3)
 469         target_link_libraries(${target} lz4)
 470         target_link_libraries(${target} double-conversion)
 471         target_link_libraries(${target} folly)
 472         target_link_libraries(${target} zip_static)
 473
 474         target_link_libraries(${target} afdt)
 475         target_link_libraries(${target} mbfl)
 476
 477         if (READLINE_LIBRARY)
 478                 target_link_libraries(${target} ${READLINE_LIBRARY})
 479         elseif (EDITLINE_LIBRARIES)
 480                 target_link_libraries(${target} ${EDITLINE_LIBRARIES})
 481         endif()
 482
 483         target_link_libraries(${target} ${CCLIENT_LIBRARY})
 484
 485         if (PAM_LIBRARY)
 486                 target_link_libraries(${target} ${PAM_LIBRARY})
 487         endif()
 488
 489         target_link_libraries(${target} ${LIBDWARF_LIBRARIES})
 490         target_link_libraries(${target} ${LIBELF_LIBRARIES})
 491 endmacro()