CMake/HPHPSetup.cmake

   1 include(Options)
   2
   3 set_property(GLOBAL PROPERTY DEBUG_CONFIGURATIONS Debug DebugOpt RelWithDebInfo)
   4
   5 set(HHVM_WHOLE_ARCHIVE_LIBRARIES
   6     hphp_runtime_static
   7     hphp_runtime_ext
   8    )
   9
  10 if (LINUX)
  11   set(HHVM_WRAP_SYMS -Wl,--wrap=pthread_create -Wl,--wrap=pthread_exit -Wl,--wrap=pthread_join)
  12 else ()
  13   set(HHVM_WRAP_SYMS)
  14 endif ()
  15
  16 set(HHVM_LINK_LIBRARIES
  17   ${HHVM_WRAP_SYMS}
  18   hphp_analysis
  19   hphp_system
  20   hphp_parser
  21   hphp_zend
  22   hphp_util
  23   hphp_hhbbc
  24   jit_sort
  25   ppc64-asm
  26   vixl neo)
  27
  28 if(ENABLE_FASTCGI)
  29   LIST(APPEND HHVM_LINK_LIBRARIES hphp_thrift)
  30   LIST(APPEND HHVM_LINK_LIBRARIES hphp_proxygen)
  31   include(CheckCXXSourceCompiles)
  32   CHECK_CXX_SOURCE_COMPILES("#include <pthread.h>
  33   int main() {
  34     return pthread_mutex_timedlock();
  35   }" PTHREAD_TIMEDLOCK)
  36   if (NOT PTHREAD_TIMEDLOCK)
  37     add_definitions(-DTHRIFT_MUTEX_EMULATE_PTHREAD_TIMEDLOCK)
  38   endif()
  39 endif()
  40
  41 if(HHVM_DYNAMIC_EXTENSION_DIR)
  42   add_definitions(-DHHVM_DYNAMIC_EXTENSION_DIR="${HHVM_DYNAMIC_EXTENSION_DIR}")
  43 else()
  44   if(UNIX)
  45     add_definitions(-DHHVM_DYNAMIC_EXTENSION_DIR="${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR}/hhvm/extensions")
  46   endif()
  47 endif()
  48
  49 # Look for the chrpath tool so we can warn if it's not there
  50 SET(FOUND_CHRPATH OFF)
  51 IF(UNIX AND NOT APPLE)
  52     find_program(CHRPATH chrpath)
  53     IF (NOT CHRPATH STREQUAL "CHRPATH-NOTFOUND")
  54         SET(FOUND_CHRPATH ON)
  55     endif()
  56 ENDIF(UNIX AND NOT APPLE)
  57
  58 LIST(APPEND CMAKE_PREFIX_PATH "$ENV{CMAKE_PREFIX_PATH}")
  59
  60 if(APPLE)
  61   if(EXISTS "/opt/local/var/macports/")
  62     LIST (APPEND CMAKE_PREFIX_PATH "/opt/local")
  63     LIST (APPEND CMAKE_LIBRARY_PATH "/opt/local/lib/x86_64")
  64   endif()
  65 endif()
  66
  67 include(HPHPCompiler)
  68 include(HPHPFunctions)
  69 include(HPHPFindLibs)
  70
  71 # Ubuntu 15.10 and 14.04 have been failing to include a dependency on jemalloc
  72 # as a these linked flags force the dependency to be recorded
  73 if (JEMALLOC_ENABLED AND LINUX)
  74   LIST(APPEND HHVM_LINK_LIBRARIES -Wl,--no-as-needed ${JEMALLOC_LIB} -Wl,--as-needed)
  75 endif()
  76
  77 if (HHVM_VERSION_OVERRIDE)
  78   parse_version("HHVM_VERSION_" ${HHVM_VERSION_OVERRIDE})
  79   add_definitions("-DHHVM_VERSION_OVERRIDE")
  80   add_definitions("-DHHVM_VERSION_MAJOR=${HHVM_VERSION_MAJOR}")
  81   add_definitions("-DHHVM_VERSION_MINOR=${HHVM_VERSION_MINOR}")
  82   add_definitions("-DHHVM_VERSION_PATCH=${HHVM_VERSION_PATCH}")
  83   add_definitions("-DHHVM_VERSION_SUFFIX=\"${HHVM_VERSION_SUFFIX}\"")
  84 endif()
  85
  86 add_definitions(-D_REENTRANT=1 -D_PTHREADS=1 -D__STDC_FORMAT_MACROS)
  87
  88 if (LINUX)
  89   add_definitions(-D_GNU_SOURCE)
  90 endif()
  91
  92 if(MSVC)
  93   add_definitions(-DGLOG_NO_ABBREVIATED_SEVERITIES)
  94   add_definitions(-DWIN32_LEAN_AND_MEAN)
  95 endif()
  96
  97 if(CMAKE_CONFIGURATION_TYPES)
  98   if(NOT MSVC)
  99     message(FATAL_ERROR "Adding the appropriate defines for multi-config targets using anything other than MSVC is not yet supported!")
 100   endif()
 101   foreach(flag_var
 102       CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 103       CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 104     set(${flag_var} "${${flag_var}} /D NDEBUG")
 105   endforeach()
 106 elseif(${CMAKE_BUILD_TYPE} MATCHES "Debug")
 107   message("Generating DEBUG build")
 108 else()
 109   add_definitions(-DNDEBUG)
 110   message("Generating Release build")
 111 endif()
 112
 113 if(ALWAYS_ASSERT)
 114   add_definitions(-DALWAYS_ASSERT=1)
 115 endif()
 116
 117 if(APPLE OR FREEBSD OR MSVC)
 118   add_definitions(-DSKIP_USER_CHANGE=1)
 119 endif()
 120
 121 if(ENABLE_TRACE)
 122     add_definitions(-DUSE_TRACE=1)
 123 endif()
 124
 125 if(APPLE)
 126   # We have to be a little more permissive in some cases.
 127   add_definitions(-fpermissive)
 128
 129   # Skip deprecation warnings in OpenSSL.
 130   add_definitions(-DMAC_OS_X_VERSION_MIN_REQUIRED=MAC_OS_X_VERSION_10_6)
 131
 132   # Enable weak linking
 133   add_definitions(-DMACOSX_DEPLOYMENT_TARGET=10.6)
 134 endif()
 135
 136 if(ENABLE_FASTCGI)
 137   add_definitions(-DENABLE_FASTCGI=1)
 138 endif ()
 139
 140 if(DISABLE_HARDWARE_COUNTERS OR NOT LINUX)
 141   add_definitions(-DNO_HARDWARE_COUNTERS=1)
 142 endif ()
 143
 144 # enable the OSS options if we have any
 145 add_definitions(-DHPHP_OSS=1)
 146
 147 # later versions of binutils don't play well without automake
 148 add_definitions(-DPACKAGE=hhvm -DPACKAGE_VERSION=Release)
 149
 150 add_definitions(-DDEFAULT_CONFIG_DIR="${DEFAULT_CONFIG_DIR}")
 151
 152 add_definitions(-DHAVE_INTTYPES_H)
 153
 154 include_directories(${TP_DIR})
 155 if (THIRD_PARTY_INCLUDE_PATHS)
 156   include_directories(${THIRD_PARTY_INCLUDE_PATHS})
 157   add_definitions(${THIRD_PARTY_DEFINITIONS})
 158   include_directories(${HPHP_HOME}/hphp)
 159   include_directories(${HPHP_HOME})
 160 endif()