kernel/arch/ia32/src/context.s

   1 #
   2 # Copyright (c) 2001-2004 Jakub Jermar
   3 # All rights reserved.
   4 #
   5 # Redistribution and use in source and binary forms, with or without
   6 # modification, are permitted provided that the following conditions
   7 # are met:
   8 #
   9 # - Redistributions of source code must retain the above copyright
  10 #   notice, this list of conditions and the following disclaimer.
  11 # - Redistributions in binary form must reproduce the above copyright
  12 #   notice, this list of conditions and the following disclaimer in the
  13 #   documentation and/or other materials provided with the distribution.
  14 # - The name of the author may not be used to endorse or promote products
  15 #   derived from this software without specific prior written permission.
  16 #
  17 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  18 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  21 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  22 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  23 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  24 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  25 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  26 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27 #
  28
  29 .text
  30
  31 .global context_save_arch
  32 .global context_restore_arch
  33
  34
  35 ## Save current CPU context
  36 #
  37 # Save CPU context to the context_t variable
  38 # pointed by the 1st argument. Returns 1 in EAX.
  39 #
  40 context_save_arch:
  41         movl 0(%esp),%eax       # the caller's return %eip
  42         movl 4(%esp),%edx       # address of the kernel_context variable to save context to
  43
  44         movl %esp,0(%edx)       # %esp -> ctx->sp
  45         movl %eax,4(%edx)       # %eip -> ctx->pc
  46         movl %ebx,8(%edx)       # %ebx -> ctx->ebx
  47         movl %esi,12(%edx)      # %esi -> ctx->esi
  48         movl %edi,16(%edx)      # %edi -> ctx->edi
  49         movl %ebp,20(%edx)      # %ebp -> ctx->ebp
  50
  51         xorl %eax,%eax          # context_save returns 1
  52         incl %eax
  53         ret
  54
  55
  56 ## Restore saved CPU context
  57 #
  58 # Restore CPU context from context_t variable
  59 # pointed by the 1st argument. Returns 0 in EAX.
  60 #
  61 context_restore_arch:
  62         movl 4(%esp),%eax       # address of the kernel_context variable to restore context from
  63         movl 0(%eax),%esp       # ctx->sp -> %esp
  64         movl 4(%eax),%edx       # ctx->pc -> %edx
  65         movl 8(%eax),%ebx       # ctx->ebx -> %ebx
  66         movl 12(%eax),%esi      # ctx->esi -> %esi
  67         movl 16(%eax),%edi      # ctx->edi -> %edi
  68         movl 20(%eax),%ebp      # ctx->ebp -> %ebp
  69
  70         movl %edx,0(%esp)       # ctx->pc -> saver's return %eip
  71         xorl %eax,%eax          # context_restore returns 0
  72         ret