kernel/arch/sparc64/src/start.S

   1 #
   2 # Copyright (C) 2005 Jakub Jermar
   3 # All rights reserved.
   4 #
   5 # Redistribution and use in source and binary forms, with or without
   6 # modification, are permitted provided that the following conditions
   7 # are met:
   8 #
   9 # - Redistributions of source code must retain the above copyright
  10 #   notice, this list of conditions and the following disclaimer.
  11 # - Redistributions in binary form must reproduce the above copyright
  12 #   notice, this list of conditions and the following disclaimer in the
  13 #   documentation and/or other materials provided with the distribution.
  14 # - The name of the author may not be used to endorse or promote products
  15 #   derived from this software without specific prior written permission.
  16 #
  17 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  18 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  21 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  22 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  23 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  24 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  25 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  26 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27 #
  28
  29 #include <arch/regdef.h>
  30 #include <arch/boot/boot.h>
  31
  32 #include <arch/mm/mmu.h>
  33 #include <arch/mm/tlb.h>
  34 #include <arch/mm/tte.h>
  35
  36 .register %g2, #scratch
  37 .register %g3, #scratch
  38
  39 .section K_TEXT_START, "ax"
  40
  41 /*
  42  * Here is where the kernel is passed control
  43  * from the boot loader.
  44  *
  45  * The registers are expected to be in this state:
  46  * - %o0 bootinfo structure address
  47  * - %o1 bootinfo structure size
  48  *
  49  * Moreover, we depend on boot having established the
  50  * following environment:
  51  * - TLBs are on
  52  * - identity mapping for the kernel image
  53  * - identity mapping for memory stack
  54  */
  55
  56 .global kernel_image_start
  57 kernel_image_start:
  58
  59         /*
  60          * Setup basic runtime environment.
  61          */
  62
  63         flushw                          ! flush all but the active register window
  64         wrpr %g0, 0, %tl                ! TL = 0, primary context register is used
  65
  66         ! Disable interrupts and disable 32-bit address masking.
  67         rdpr %pstate, %g1
  68         and %g1, ~(PSTATE_AM_BIT|PSTATE_IE_BIT), %g1
  69         wrpr %g1, 0, %pstate
  70
  71         wrpr %g0, 0, %pil               ! intialize %pil
  72
  73         /*
  74          * Copy the bootinfo structure passed from the boot loader
  75          * to the kernel bootinfo structure.
  76          */
  77         mov %o1, %o2
  78         mov %o0, %o1
  79         set bootinfo, %o0
  80         call memcpy
  81         nop
  82
  83         /*
  84          * Switch to kernel trap table.
  85          */
  86         set trap_table, %g1
  87         wrpr %g1, 0, %tba
  88
  89         /*
  90          * Take over the DMMU by installing global locked
  91          * TTE entry identically mapping the first 4M
  92          * of memory.
  93          *
  94          * In case of DMMU, no FLUSH instructions need to be
  95          * issued. Because of that, the old DTLB contents can
  96          * be demapped pretty straightforwardly and without
  97          * causing any traps.
  98          */
  99
 100         wr %g0, ASI_DMMU, %asi
 101
 102 #define SET_TLB_DEMAP_CMD(r1, context_id) \
 103         set (TLB_DEMAP_CONTEXT<<TLB_DEMAP_TYPE_SHIFT) | (context_id<<TLB_DEMAP_CONTEXT_SHIFT), %r1
 104
 105         ! demap context 0
 106         SET_TLB_DEMAP_CMD(g1, TLB_DEMAP_NUCLEUS)
 107         stxa %g0, [%g1] ASI_DMMU_DEMAP
 108         membar #Sync
 109
 110 #define SET_TLB_TAG(r1, context) \
 111         set VMA | (context<<TLB_TAG_ACCESS_CONTEXT_SHIFT), %r1
 112
 113         ! write DTLB tag
 114         SET_TLB_TAG(g1, MEM_CONTEXT_KERNEL)
 115         stxa %g1, [VA_DMMU_TAG_ACCESS] %asi
 116         membar #Sync
 117
 118 #define SET_TLB_DATA(r1, r2, imm) \
 119         set TTE_L | TTE_CP | TTE_P | TTE_W | LMA | imm, %r1; \
 120         set PAGESIZE_4M, %r2; \
 121         sllx %r2, TTE_SIZE_SHIFT, %r2; \
 122         or %r1, %r2, %r1; \
 123         set 1, %r2; \
 124         sllx %r2, TTE_V_SHIFT, %r2; \
 125         or %r1, %r2, %r1;
 126
 127         ! write DTLB data and install the kernel mapping
 128         SET_TLB_DATA(g1, g2, TTE_G)
 129         stxa %g1, [%g0] ASI_DTLB_DATA_IN_REG
 130         membar #Sync
 131
 132         /*
 133          * Now is time to take over the IMMU.
 134          * Unfortunatelly, it cannot be done as easily as the DMMU,
 135          * because the IMMU is mapping the code it executes.
 136          *
 137          * [ Note that brave experiments with disabling the IMMU
 138          * and using the DMMU approach failed after a dozen
 139          * of desparate days with only little success. ]
 140          *
 141          * The approach used here is inspired from OpenBSD.
 142          * First, the kernel creates IMMU mapping for itself
 143          * in context 1 (MEM_CONTEXT_TEMP) and switches to
 144          * it. Context 0 (MEM_CONTEXT_KERNEL) can be demapped
 145          * afterwards and replaced with the kernel permanent
 146          * mapping. Finally, the kernel switches back to
 147          * context 0 and demaps context 1.
 148          *
 149          * Moreover, the IMMU requires use of the FLUSH instructions.
 150          * But that is OK because we always use operands with
 151          * addresses already mapped by the taken over DTLB.
 152          */
 153
 154         set kernel_image_start, %g5
 155
 156         ! write ITLB tag of context 1
 157         SET_TLB_TAG(g1, MEM_CONTEXT_TEMP)
 158         set VA_DMMU_TAG_ACCESS, %g2
 159         stxa %g1, [%g2] ASI_IMMU
 160         flush %g5
 161
 162         ! write ITLB data and install the temporary mapping in context 1
 163         SET_TLB_DATA(g1, g2, 0)                 ! use non-global mapping
 164         stxa %g1, [%g0] ASI_ITLB_DATA_IN_REG
 165         flush %g5
 166
 167         ! switch to context 1
 168         set MEM_CONTEXT_TEMP, %g1
 169         stxa %g1, [VA_PRIMARY_CONTEXT_REG] %asi ! ASI_DMMU is correct here !!!
 170         flush %g5
 171
 172         ! demap context 0
 173         SET_TLB_DEMAP_CMD(g1, TLB_DEMAP_NUCLEUS)
 174         stxa %g0, [%g1] ASI_IMMU_DEMAP
 175         flush %g5
 176
 177         ! write ITLB tag of context 0
 178         SET_TLB_TAG(g1, MEM_CONTEXT_KERNEL)
 179         set VA_DMMU_TAG_ACCESS, %g2
 180         stxa %g1, [%g2] ASI_IMMU
 181         flush %g5
 182
 183         ! write ITLB data and install the permanent kernel mapping in context 0
 184         SET_TLB_DATA(g1, g2, 0)                 ! use non-global mapping
 185         stxa %g1, [%g0] ASI_ITLB_DATA_IN_REG
 186         flush %g5
 187
 188         ! switch to context 0
 189         stxa %g0, [VA_PRIMARY_CONTEXT_REG] %asi ! ASI_DMMU is correct here !!!
 190         flush %g5
 191
 192         ! ensure nucleus mapping
 193         wrpr %g0, 1, %tl
 194
 195         ! set context 1 in the primary context register
 196         set MEM_CONTEXT_TEMP, %g1
 197         stxa %g1, [VA_PRIMARY_CONTEXT_REG] %asi ! ASI_DMMU is correct here !!!
 198         flush %g5
 199
 200         ! demap context 1
 201         SET_TLB_DEMAP_CMD(g1, TLB_DEMAP_PRIMARY)
 202         stxa %g0, [%g1] ASI_IMMU_DEMAP
 203         flush %g5
 204
 205         ! set context 0 in the primary context register
 206         stxa %g0, [VA_PRIMARY_CONTEXT_REG] %asi ! ASI_DMMU is correct here !!!
 207         flush %g5
 208
 209         ! set TL back to 0
 210         wrpr %g0, 0, %tl
 211
 212         call arch_pre_main
 213         nop
 214
 215         call main_bsp
 216         nop
 217
 218         /* Not reached. */
 219
 220 2:
 221         b 2b
 222         nop