kernel/arch/sparc64/src/context.S

   1 #
   2 # Copyright (C) 2005 Jakub Jermar
   3 # All rights reserved.
   4 #
   5 # Redistribution and use in source and binary forms, with or without
   6 # modification, are permitted provided that the following conditions
   7 # are met:
   8 #
   9 # - Redistributions of source code must retain the above copyright
  10 #   notice, this list of conditions and the following disclaimer.
  11 # - Redistributions in binary form must reproduce the above copyright
  12 #   notice, this list of conditions and the following disclaimer in the
  13 #   documentation and/or other materials provided with the distribution.
  14 # - The name of the author may not be used to endorse or promote products
  15 #   derived from this software without specific prior written permission.
  16 #
  17 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  18 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  21 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  22 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  23 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  24 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  25 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  26 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27 #
  28
  29 #include <arch/context_offset.h>
  30
  31 /**
  32  * Both context_save_arch() and context_restore_arch() are
  33  * leaf-optimized procedures. This kind of optimization
  34  * is very important and prevents any implicit window
  35  * spill/fill/clean traps in these very core kernel
  36  * functions.
  37  */
  38
  39 .text
  40
  41 .global context_save_arch
  42 .global context_restore_arch
  43
  44 .macro CONTEXT_STORE r
  45         stx %sp, [\r + OFFSET_SP]
  46         stx %o7, [\r + OFFSET_PC]
  47         stx %i0, [\r + OFFSET_I0]
  48         stx %i1, [\r + OFFSET_I1]
  49         stx %i2, [\r + OFFSET_I2]
  50         stx %i3, [\r + OFFSET_I3]
  51         stx %i4, [\r + OFFSET_I4]
  52         stx %i5, [\r + OFFSET_I5]
  53         stx %fp, [\r + OFFSET_FP]
  54         stx %i7, [\r + OFFSET_I7]
  55         stx %l0, [\r + OFFSET_L0]
  56         stx %l1, [\r + OFFSET_L1]
  57         stx %l2, [\r + OFFSET_L2]
  58         stx %l3, [\r + OFFSET_L3]
  59         stx %l4, [\r + OFFSET_L4]
  60         stx %l5, [\r + OFFSET_L5]
  61         stx %l6, [\r + OFFSET_L6]
  62         stx %l7, [\r + OFFSET_L7]
  63         rdpr %cleanwin, %g1
  64         stx %g1, [\r + OFFSET_CLEANWIN]
  65 .endm
  66
  67 .macro CONTEXT_LOAD r
  68         ldx [\r + OFFSET_SP], %sp
  69         ldx [\r + OFFSET_PC], %o7
  70         ldx [\r + OFFSET_I0], %i0
  71         ldx [\r + OFFSET_I1], %i1
  72         ldx [\r + OFFSET_I2], %i2
  73         ldx [\r + OFFSET_I3], %i3
  74         ldx [\r + OFFSET_I4], %i4
  75         ldx [\r + OFFSET_I5], %i5
  76         ldx [\r + OFFSET_FP], %fp
  77         ldx [\r + OFFSET_I7], %i7
  78         ldx [\r + OFFSET_L0], %l0
  79         ldx [\r + OFFSET_L1], %l1
  80         ldx [\r + OFFSET_L2], %l2
  81         ldx [\r + OFFSET_L3], %l3
  82         ldx [\r + OFFSET_L4], %l4
  83         ldx [\r + OFFSET_L5], %l5
  84         ldx [\r + OFFSET_L6], %l6
  85         ldx [\r + OFFSET_L7], %l7
  86         ldx [\r + OFFSET_CLEANWIN], %g1
  87         wrpr %g1, %g0, %cleanwin
  88 .endm
  89
  90 context_save_arch:
  91         CONTEXT_STORE %o0
  92         retl
  93         mov 1, %o0              ! context_save_arch returns 1
  94
  95 context_restore_arch:
  96         #
  97         # Flush all active windows.
  98         # This is essential, because CONTEXT_LOAD overwrites
  99         # %sp of CWP - 1 with the value written to %fp of CWP.
 100         # Flushing all active windows mitigates this problem
 101         # as CWP - 1 becomes the overlap window.
 102         #
 103         flushw
 104
 105         CONTEXT_LOAD %o0
 106         retl
 107         xor %o0, %o0, %o0       ! context_restore_arch returns 0