cf/with-all.m4

   1 dnl
   2 dnl $Id$
   3 dnl
   4
   5 dnl AC_WITH_ALL(name)
   6
   7 AC_DEFUN([AC_WITH_ALL], [
   8 AC_ARG_WITH($1,
   9         AS_HELP_STRING([--with-$1=dir],
  10                 [use $1 in dir]))
  11
  12 AC_ARG_WITH($1-lib,
  13         AS_HELP_STRING([--with-$1-lib=dir],
  14                 [use $1 libraries in dir]),
  15 [if test "$withval" = "yes" -o "$withval" = "no"; then
  16   AC_MSG_ERROR([No argument for --with-$1-lib])
  17 elif test "X$with_$1" = "X"; then
  18   with_$1=yes
  19 fi])
  20
  21 AC_ARG_WITH($1-include,
  22         AS_HELP_STRING([--with-$1-include=dir],
  23                 [use $1 headers in dir]),
  24 [if test "$withval" = "yes" -o "$withval" = "no"; then
  25   AC_MSG_ERROR([No argument for --with-$1-include])
  26 elif test "X$with_$1" = "X"; then
  27   with_$1=yes
  28 fi])
  29
  30 case "$with_$1" in
  31 yes)    ;;
  32 no)     ;;
  33 "")     ;;
  34 *)      if test "$with_$1_include" = ""; then
  35                 with_$1_include="$with_$1/include"
  36         fi
  37         if test "$with_$1_lib" = ""; then
  38                 with_$1_lib="$with_$1/lib$abilibdirext"
  39         fi
  40         ;;
  41 esac
  42 ])