cf/wflags.m4

   1 dnl $Id$
   2 dnl
   3 dnl set WFLAGS
   4
   5 AC_DEFUN([rk_WFLAGS],[
   6
   7 AC_ARG_ENABLE(developer,
   8         AS_HELP_STRING([--enable-developer], [enable developer warnings]))
   9 if test "X$enable_developer" = Xyes; then
  10     dwflags="-Werror"
  11 fi
  12 AM_CONDITIONAL(DEVELOPER_MODE, test "X$enable_developer" = Xyes)
  13
  14 WFLAGS_NOUNUSED=""
  15 WFLAGS_NOIMPLICITINT=""
  16 if test -z "$WFLAGS" -a "$GCC" = "yes"; then
  17   # -Wno-implicit-int for broken X11 headers
  18   # leave these out for now:
  19   #   -Wcast-align doesn't work well on alpha osf/1
  20   #   -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast
  21   #   -Wmissing-declarations -Wnested-externs
  22   #   -Wstrict-overflow=5
  23   WFLAGS="ifelse($#, 0,-Wall, $1) $dwflags"
  24   WFLAGS_NOIMPLICITINT="-Wno-implicit-int"
  25
  26   #
  27   # WFLAGS_LITE can be appended to WFLAGS to turn off a host of warnings
  28   # that fail for various bits of older code in appl/.  Let's not use it
  29   # for the main libraries, though.
  30   WFLAGS_LITE="-Wno-extra -Wno-missing-field-initializers -Wno-strict-aliasing -Wno-shadow"
  31   # -Wno-unused-result (not supported on gcc-4.2)
  32
  33 fi
  34 AC_SUBST(WFLAGS)dnl
  35 AC_SUBST(WFLAGS_LITE)dnl
  36 AC_SUBST(WFLAGS_NOIMPLICITINT)dnl
  37 ])