configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 AC_PREFIX_DEFAULT(/usr/heimdal)
  25
  26 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  27 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  28
  29 AC_CANONICAL_HOST
  30 CANONICAL_HOST=$host
  31 AC_SUBST(CANONICAL_HOST)
  32
  33 rk_SYS_LARGEFILE
  34
  35 rk_AIX
  36 rk_IRIX
  37 rk_SUNOS
  38
  39 dnl
  40 dnl this is needed to run the configure tests against glibc
  41 dnl
  42 AC_DEFINE([_GNU_SOURCE], 1,
  43         [Define to enable extensions on glibc-based systems such as Linux.])
  44
  45 AC_OBJEXT
  46 AC_EXEEXT
  47
  48 dnl
  49 dnl this is needed when der-protos.h or der-private.h has to be generated
  50 dnl
  51 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  52    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  53     AC_KRB_PROG_PERL
  54     AC_KRB_PERL_MOD(Getopt::Std)
  55     AC_KRB_PERL_MOD(File::Compare)
  56     AC_KRB_PERL_MOD(JSON)
  57 fi
  58
  59 dnl AC_KRB_PROG_YACC
  60 AC_PROG_YACC
  61 AM_PROG_LEX
  62 AS_IF([$LEX --nounput -V > /dev/null 2>&1 && test $? -eq 0],
  63       [AC_SUBST([FLEXNOUNPUTARGS], ["--nounput"])],
  64       [AC_SUBST([FLEXNOUNPUTARGS], [""])])
  65 dnl AC_PROG_RANLIB
  66 AC_PROG_AWK
  67 AC_KRB_PROG_LN_S
  68
  69 AC_MIPS_ABI
  70 CC="$CC $abi"
  71 libdir="$libdir$abilibdirext"
  72
  73 AC_C___ATTRIBUTE__
  74
  75 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  76 rk_VERSIONSCRIPT
  77
  78 dnl Code coverage
  79 AC_ARG_ENABLE([gcov],
  80         AC_HELP_STRING([--enable-gcov], [enable gcov code coverage tool]))
  81 AM_CONDITIONAL([ENABLE_GCOV], [test "x$enable_gcov" = xyes])
  82
  83
  84 dnl
  85 dnl Helper bits for cross compiling
  86 dnl
  87
  88
  89
  90 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  91
  92 AC_ARG_WITH(cross-tools,
  93         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  94         [if test "$withval" = "yes"; then
  95                 AC_MSG_ERROR([Need path to cross tools])
  96         fi
  97         with_cross_tools="${with_cross_tools}/"
  98         ])
  99
 100 if test "${cross_compiling}" != yes ; then
 101
 102    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
 103    SLC="\$(top_builddir)/lib/sl/slc"
 104
 105    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
 106    SLC_DEP="\$(SLC)"
 107 else
 108    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 109    SLC="${with_cross_tools}slc"
 110
 111    ASN1_COMPILE_DEP=
 112    SLC_DEP=
 113
 114    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 115
 116 fi
 117
 118 AC_SUBST([ASN1_COMPILE])
 119 AC_SUBST([ASN1_COMPILE_DEP])
 120 AC_SUBST([SLC])
 121 AC_SUBST([SLC_DEP])
 122
 123 dnl ---
 124
 125 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 126
 127 rk_TEST_PACKAGE(openldap,
 128 [#include <lber.h>
 129 #include <ldap.h>],
 130 [-lldap -llber],,,OPENLDAP)
 131
 132 AC_ARG_ENABLE(hdb-openldap-module,
 133         AS_HELP_STRING([--enable-hdb-openldap-module],
 134                 [if you want support to build openldap hdb as shared object]))
 135 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 136     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 137 fi
 138 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 139
 140 dnl
 141 dnl Optional modules, pk-init, digest, kx509
 142 dnl
 143
 144 AC_ARG_ENABLE(pk-init,
 145         AS_HELP_STRING([--disable-pk-init],
 146                 [if you want disable to PK-INIT support]))
 147 if test "$enable_pk_init" != no ;then
 148         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 149 fi
 150 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 151
 152 AC_ARG_ENABLE(digest,
 153         AS_HELP_STRING([--disable-digest],
 154                 [if you want disable to DIGEST support]))
 155 if test "$enable_digest" != no ;then
 156         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 157 fi
 158
 159 AC_ARG_ENABLE(kx509,
 160         AS_HELP_STRING([--disable-kx509],
 161                 [if you want disable to kx509 support]))
 162 if test "$enable_kx509" != no ;then
 163         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 164 fi
 165
 166 dnl Need to test if pkg-config exists
 167 PKG_PROG_PKG_CONFIG
 168
 169 dnl libcap-ng
 170 AC_ARG_WITH([capng],
 171   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 172   [],
 173   [with_capng=check])
 174 if test "$with_capng" != "no"; then
 175   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 176                     [with_capng=yes],[with_capng=no])
 177 fi
 178 if test "$with_capng" = "yes"; then
 179   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 180 fi
 181 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 182 AC_SUBST([CAPNG_CFLAGS])
 183 AC_SUBST([CAPNG_LIBS])
 184
 185 dnl libmicrohttpd
 186 AC_ARG_WITH([microhttpd],
 187   AC_HELP_STRING([--with-microhttpd], [use microhttpd to serve KDC REST API @<:@default=check@:>@]),
 188   [],
 189   [with_microhttpd=check])
 190 if test "$with_microhttpd" != "no"; then
 191   PKG_CHECK_MODULES([MICROHTTPD], [libmicrohttpd >= 0.9.37],
 192                     [with_microhttpd=yes],[with_microhttpd=no])
 193 fi
 194 if test "$with_microhttpd" = "yes"; then
 195   AC_DEFINE_UNQUOTED([HAVE_MICROHTTPD], 1, [whether libmicrohttpd is available for KDC REST API])
 196 fi
 197 AM_CONDITIONAL([HAVE_MICROHTTPD], [test "$with_microhttpd" != "no"])
 198 AC_SUBST([MICROHTTPD_CFLAGS])
 199 AC_SUBST([MICROHTTPD_LIBS])
 200
 201 dnl libcjwt
 202 AC_ARG_WITH([cjwt],
 203   AC_HELP_STRING([--with-cjwt], [(Experimental) use cjwt to validate JWT tokens @<:@default=check@:>@]),
 204   [],
 205   [with_cjwt=check])
 206 if test "$with_cjwt" != "no"; then
 207   PKG_CHECK_MODULES([CJWT], [libcjwt >= 1.0.0],
 208                     [with_cjwt=yes],[with_cjwt=no])
 209 fi
 210 if test "$with_cjwt" = "yes"; then
 211   AC_DEFINE_UNQUOTED([HAVE_CJWT], 1, [whether libcjwt is available for KDC REST API])
 212 fi
 213 AM_CONDITIONAL([HAVE_CJWT], [test "$with_cjwt" != "no"])
 214 AC_SUBST([CJWT_CFLAGS])
 215 AC_SUBST([CJWT_LIBS])
 216
 217 dnl libcjson
 218 AC_ARG_WITH([cjson],
 219   AC_HELP_STRING([--with-cjson], [(Experimental) use cJSON to extract private claims from JWT tokens @<:@default=check@:>@]),
 220   [],
 221   [with_cjson=check])
 222 if test "$with_cjson" != "no"; then
 223   PKG_CHECK_MODULES([CJSON], [libcjson >= 1.0.0],
 224                     [with_cjson=yes],[with_cjson=no])
 225 fi
 226 if test "$with_cjson" = "yes"; then
 227   AC_DEFINE_UNQUOTED([HAVE_CJSON], 1, [whether libcjson is available for KDC REST API])
 228 fi
 229 AM_CONDITIONAL([HAVE_CJSON], [test "$with_cjson" != "no"])
 230 AC_SUBST([CJSON_CFLAGS])
 231 AC_SUBST([CJSON_LIBS])
 232
 233 dnl Check for sqlite
 234 rk_TEST_PACKAGE(sqlite3,
 235 [#include <sqlite3.h>
 236 #ifndef SQLITE_OPEN_CREATE
 237 #error "old version"
 238 #endif],
 239 [-lsqlite3],,,SQLITE3)
 240
 241 if test "X$with_sqlite3" != Xyes ; then
 242    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 243    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 244 fi
 245 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 246
 247 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 248
 249 AC_ARG_ENABLE(sqlite-cache,
 250         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 251 if test "$enable_sqlite_cache" != no; then
 252     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 253 fi
 254 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 255
 256
 257 dnl check for libintl
 258 rk_TEST_PACKAGE(libintl,
 259 [#include <libintl.h>],
 260 [-lintl],,,LIBINTL)
 261
 262 dnl path where the hdb directory is stored
 263 AC_ARG_WITH([hdbdir],
 264         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 265         [],
 266         [with_hdbdir=/var/heimdal])
 267 DIR_hdbdir="$with_hdbdir"
 268 AC_SUBST([DIR_hdbdir])
 269
 270
 271 AM_CONDITIONAL(KRB5, true)
 272 AM_CONDITIONAL(do_roken_rename, true)
 273
 274 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 275
 276
 277 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 278 AC_SUBST(LIB_kdb)dnl
 279
 280 KRB_CRYPTO
 281
 282 KRB_PTHREADS
 283
 284 AC_ARG_ENABLE(dce,
 285         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 286 if test "$enable_dce" = yes; then
 287     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 288 fi
 289 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 290
 291 ## XXX quite horrible:
 292 if test -f /etc/ibmcxx.cfg; then
 293         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 294         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 295         dpagaix_ldflags=
 296 else
 297         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 298         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 299         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 300 fi
 301 AC_SUBST(dpagaix_cflags)
 302 AC_SUBST(dpagaix_ldadd)
 303 AC_SUBST(dpagaix_ldflags)
 304
 305 AC_ARG_ENABLE([afs-support],
 306         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 307 if test "$enable_afs_support" = no; then
 308         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 309         NO_AFS="1"
 310 fi
 311 AC_SUBST(NO_AFS)dnl
 312 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 313
 314 rk_DB
 315
 316 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 317
 318 rk_ROKEN(lib/roken)
 319 LIBADD_roken="$LIB_roken"
 320 AC_SUBST(LIBADD_roken)dnl
 321 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 322
 323 rk_OTP
 324
 325 rk_LIBDISPATCH
 326
 327 AC_CHECK_OSFC2
 328
 329 AC_ARG_ENABLE(mmap,
 330         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 331 if test "$enable_mmap" = "no"; then
 332         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 333 fi
 334
 335 AC_ARG_ENABLE(afs-string-to-key,
 336         AS_HELP_STRING([--disable-afs-string-to-key],
 337         [disable use of weak AFS string-to-key functions]),
 338         [], [enable_afs_string_to_key=yes])
 339
 340 if test "$enable_afs_string_to_key" = "yes"; then
 341         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 342         ENABLE_AFS_STRING_TO_KEY=1
 343 fi
 344 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 345
 346
 347 rk_CHECK_MAN
 348
 349 rk_TEST_PACKAGE(readline,
 350 [#include <stdio.h>
 351 #if defined(HAVE_READLINE_READLINE_H)
 352 #include <readline/readline.h>
 353 #elif defined(HAVE_READLINE_H)
 354 #include <readline.h>
 355 #endif
 356 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 357
 358 rk_TEST_PACKAGE(libedit,
 359 [#include <stdio.h>
 360 #if defined(HAVE_READLINE_READLINE_H)
 361 #include <readline/readline.h>
 362 #elif defined(HAVE_READLINE_H)
 363 #include <readline.h>
 364 #elif defined(HAVE_EDITLINE_READLINE_H)
 365 #include <editline/readline.h>
 366 #endif
 367 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 368
 369 AC_CONFIG_SUBDIRS([lib/libedit])
 370
 371 KRB_C_BIGENDIAN
 372 AC_C_INLINE
 373
 374 dnl AM_C_PROTOTYPES
 375
 376 dnl Checks for typedefs, structures, and compiler characteristics.
 377 AC_C_CONST
 378 AC_TYPE_OFF_T
 379 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 380 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 381 AC_HAVE_TYPE([long long])
 382 AC_HEADER_TIME
 383 AC_STRUCT_TM
 384
 385 dnl Checks for header files.
 386 AC_HEADER_STDC
 387
 388 AC_CHECK_HEADERS([\
 389         CommonCrypto/CommonDigest.h             \
 390         CommonCrypto/CommonCryptor.h            \
 391         arpa/telnet.h                           \
 392         bind/bitypes.h                          \
 393         bsdsetjmp.h                             \
 394         curses.h                                \
 395         dlfcn.h                                 \
 396         execinfo.h                              \
 397         fnmatch.h                               \
 398         inttypes.h                              \
 399         io.h                                    \
 400         keyutils.h                              \
 401         libutil.h                               \
 402         limits.h                                \
 403         maillock.h                              \
 404         netgroup.h                              \
 405         netinet/in6_machtypes.h                 \
 406         netinet/tcp.h                           \
 407         pthread.h                               \
 408         pty.h                                   \
 409         sac.h                                   \
 410         sgtty.h                                 \
 411         siad.h                                  \
 412         signal.h                                \
 413         strings.h                               \
 414         stropts.h                               \
 415         sys/bitypes.h                           \
 416         sys/category.h                          \
 417         sys/file.h                              \
 418         sys/filio.h                             \
 419         sys/ioccom.h                            \
 420         sys/mman.h                              \
 421         sys/param.h                             \
 422         sys/pty.h                               \
 423         sys/ptyio.h                             \
 424         sys/select.h                            \
 425         sys/socket.h                            \
 426         sys/str_tty.h                           \
 427         sys/stream.h                            \
 428         sys/stropts.h                           \
 429         sys/syscall.h                           \
 430         sys/termio.h                            \
 431         sys/timeb.h                             \
 432         sys/times.h                             \
 433         sys/types.h                             \
 434         sys/un.h                                \
 435         locale.h                                \
 436         termcap.h                               \
 437         termio.h                                \
 438         termios.h                               \
 439         time.h                                  \
 440         tmpdir.h                                \
 441         udb.h                                   \
 442         util.h                                  \
 443 ])
 444
 445 dnl On Solaris 8 there's a compilation warning for term.h because
 446 dnl it doesn't define `bool'.
 447 AC_CHECK_HEADERS(term.h, , , -)
 448
 449 dnl aix have asl.h (A/IX screen library) that we don't want
 450 AC_CHECK_HEADERS(asl.h, , , [
 451 #include <asl.h>
 452 #ifndef ASL_STRING_EMERG
 453 #error ASL_STRING_EMERG missing
 454 #endif])
 455
 456 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 457 #if HAVE_SYS_SOCKET_H
 458 #include <sys/socket.h>
 459 #endif])
 460
 461 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 462 #if HAVE_SYS_TTY_H
 463 #include <sys/tty.h>
 464 #endif])
 465
 466 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 467 #if HAVE_TERMIOS_H
 468 #include <termios.h>
 469 #endif
 470 #if HAVE_SYS_STREAM_H
 471 #include <sys/stream.h>
 472 #endif])
 473
 474 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 475 #if HAVE_SYS_TYPES_H
 476 #include <sys/types.h>
 477 #endif
 478 #if HAVE_SYS_PARAM_H
 479 #include <sys/param.h>
 480 #endif])
 481
 482 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 483 #include <security/pam_appl.h>
 484 ])
 485
 486 dnl export symbols
 487 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 488 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 489 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 490
 491 dnl Checks for libraries.
 492
 493 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 494 #ifdef HAVE_UTIL_H
 495 #include <util.h>
 496 #endif
 497 ],[0,0,0])
 498 AC_FIND_FUNC_NO_LIBS(logout, util,[
 499 #ifdef HAVE_UTIL_H
 500 #include <util.h>
 501 #endif
 502 ],[0])
 503 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 504 #ifdef HAVE_UTIL_H
 505 #include <util.h>
 506 #endif
 507 ],[0,0,0,0,0])
 508
 509 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses tinfo,[
 510 #ifdef HAVE_TERMCAP_H
 511 #include <termcap.h>
 512 #endif
 513 #ifdef HAVE_CURSES_H
 514 #include <curses.h>
 515 #endif
 516 ],[0,0])
 517
 518 dnl Checks for library functions.
 519
 520 AC_CHECK_FUNCS([                                \
 521         _getpty                                 \
 522         _scrsize                                \
 523         arc4random                              \
 524         backtrace                               \
 525         fcntl                                   \
 526         fork                                    \
 527         fseeko                                  \
 528         ftello                                  \
 529         getpeereid                              \
 530         getpeerucred                            \
 531         getresgid                               \
 532         getresuid                               \
 533         grantpt                                 \
 534         kill                                    \
 535         mktime                                  \
 536         ptsname                                 \
 537         rand                                    \
 538         revoke                                  \
 539         select                                  \
 540         setitimer                               \
 541         setpcred                                \
 542         setpgid                                 \
 543         setproctitle                            \
 544         setregid                                \
 545         setresgid                               \
 546         setresuid                               \
 547         setreuid                                \
 548         setsid                                  \
 549         setutent                                \
 550         sigaction                               \
 551         strstr                                  \
 552         ttyname                                 \
 553         ttyslot                                 \
 554         umask                                   \
 555         unlockpt                                \
 556         vhangup                                 \
 557         waitpid                                 \
 558         yp_get_default_domain                   \
 559 ])
 560
 561 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 562 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 563         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 564         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 565 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 566         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 567 fi
 568 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 569
 570 AC_FUNC_MMAP
 571
 572 KRB_CAPABILITIES
 573 rk_DLADDR
 574
 575 AC_CHECK_GETPWNAM_R_POSIX
 576 AC_CHECK_GETPWUID_R_POSIX
 577
 578 dnl detect doors on solaris
 579 if test "$enable_pthread_support" != no; then
 580    saved_LIBS="$LIBS"
 581    LIBS="$LIBS $PTHREADS_LIBS"
 582    AC_FIND_FUNC_NO_LIBS(door_create, door)
 583    LIBS="$saved_LIBS"
 584 fi
 585
 586 AC_ARG_ENABLE(kcm,
 587         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 588 ,[enable_kcm=yes])
 589
 590 if test "$enable_kcm" = yes ; then
 591    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 592         enable_kcm=no
 593    fi
 594 fi
 595 if test "$enable_kcm" = yes; then
 596        AC_DEFINE(HAVE_KCM, 1,
 597                [Define if you want to use the Kerberos Credentials Manager.])
 598 fi
 599 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 600
 601 dnl detect keyring on Linux
 602 if test "$ac_cv_header_keyutils_h" = yes; then
 603     AC_CHECK_SIZEOF([key_serial_t],,[
 604         #ifdef HAVE_INTTYPES_H
 605         #include <inttypes.h>
 606         #endif
 607         #ifdef HAVE_SYS_TYPES_H
 608         #include <sys/types.h>
 609         #endif
 610         #include <keyutils.h>
 611     ])
 612 fi
 613
 614 AC_FIND_FUNC_NO_LIBS(add_key, keyutils)
 615 if test -n "$LIB_add_key"; then
 616     saved_LIBS="$LIBS"
 617     LIBS="$LIBS $LIB_add_key"
 618     AC_CHECK_FUNCS(keyctl_get_persistent)
 619     LIBS="$saved_LIBS"
 620 fi
 621
 622 AC_CHECK_SIZEOF([time_t])
 623
 624 dnl Cray stuff
 625 AC_CHECK_FUNCS(getudbnam setlim)
 626
 627 dnl AC_KRB_FUNC_GETCWD_BROKEN
 628
 629 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 630         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 631         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 632 #ifdef HAVE_INTTYPES_H
 633 #include <inttypes.h>
 634 #endif
 635 #ifdef HAVE_SYS_TYPES_H
 636 #include <sys/types.h>
 637 #endif
 638 #ifdef HAVE_SYS_BITYPES_H
 639 #include <sys/bitypes.h>
 640 #endif
 641 #ifdef HAVE_BIND_BITYPES_H
 642 #include <bind/bitypes.h>
 643 #endif
 644 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 645 #include <netinet/in6_machtypes.h>
 646 #endif
 647 ])
 648
 649 rk_FRAMEWORK_SECURITY
 650 rk_FRAMEWORK_COREFOUNDATION
 651
 652 KRB_READLINE
 653
 654 rk_TELNET
 655
 656 dnl Some operating systems already have com_err and compile_et
 657 CHECK_COMPILE_ET
 658
 659 rk_AUTH_MODULES([sia afskauthlib])
 660
 661 rk_DESTDIRS
 662
 663 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 664
 665
 666 AH_BOTTOM([#ifdef __APPLE__
 667 #include <AvailabilityMacros.h>
 668 #endif])
 669
 670 AH_BOTTOM([#ifdef ROKEN_RENAME
 671 #include "roken_rename.h"
 672 #endif])
 673
 674 AC_ARG_ENABLE(heimdal-documentation,
 675         AS_HELP_STRING([--disable-heimdal-documentation],
 676                 [if you want disable to heimdal documentation]))
 677 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 678
 679 AC_CONFIG_FILES(Makefile                \
 680         etc/Makefile                    \
 681         include/Makefile                \
 682         include/gssapi/Makefile         \
 683         include/hcrypto/Makefile        \
 684         include/kadm5/Makefile          \
 685         lib/Makefile                    \
 686         lib/base/Makefile                       \
 687         lib/asn1/Makefile               \
 688         lib/com_err/Makefile            \
 689         lib/hcrypto/Makefile            \
 690         lib/hx509/Makefile              \
 691         lib/gssapi/Makefile             \
 692         lib/ntlm/Makefile               \
 693         lib/hdb/Makefile                \
 694         lib/ipc/Makefile                \
 695         lib/kadm5/Makefile              \
 696         lib/kafs/Makefile               \
 697         lib/kdfs/Makefile               \
 698         lib/krb5/Makefile               \
 699         lib/otp/Makefile                \
 700         lib/roken/Makefile              \
 701         lib/sl/Makefile                 \
 702         lib/sqlite/Makefile             \
 703         lib/vers/Makefile               \
 704         lib/wind/Makefile               \
 705         po/Makefile                     \
 706         kuser/Makefile                  \
 707         kpasswd/Makefile                \
 708         kadmin/Makefile                 \
 709         admin/Makefile                  \
 710         kcm/Makefile                    \
 711         kdc/Makefile                    \
 712         appl/Makefile                   \
 713         appl/afsutil/Makefile           \
 714         appl/dbutils/Makefile           \
 715         appl/gssmask/Makefile           \
 716         appl/otp/Makefile               \
 717         appl/test/Makefile              \
 718         appl/kf/Makefile                \
 719         appl/dceutils/Makefile          \
 720         tests/Makefile                  \
 721         tests/bin/Makefile              \
 722         tests/can/Makefile              \
 723         tests/db/Makefile               \
 724         tests/kdc/Makefile              \
 725         tests/ldap/Makefile             \
 726         tests/gss/Makefile              \
 727         tests/java/Makefile             \
 728         tests/plugin/Makefile           \
 729         packages/Makefile               \
 730         packages/mac/Makefile           \
 731         doc/Makefile                    \
 732         tools/Makefile                  \
 733 )
 734
 735 AC_OUTPUT
 736
 737 dnl
 738 dnl This is the release version name-number[beta]
 739 dnl
 740
 741 if test -d "$srcdir/.git"; then
 742     cat > include/newversion.h.in <<EOF
 743 #ifndef VERSION_HIDDEN
 744 #define VERSION_HIDDEN
 745 #endif
 746 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ @BRANCH@ @TAG@ ($host) @COMMIT@ @DATE@ \$";
 747 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 748 EOF
 749 else
 750     cat > include/newversion.h.in <<EOF
 751 #ifndef VERSION_HIDDEN
 752 #define VERSION_HIDDEN
 753 #endif
 754 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 755 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 756 EOF
 757 fi
 758
 759 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 760         echo "include/version.h is unchanged"
 761         rm -f include/newversion.h.in
 762 else
 763         echo "creating include/version.h"
 764         if test -n "$SOURCE_DATE_EPOCH"; then
 765             Date=`
 766                   # BSD, OS X
 767                   date -u -r "$SOURCE_DATE_EPOCH" "+%Y-%m-%dT%H:%M:%SZ" 2>/dev/null ||
 768                   # Linux
 769                   date -u -d "@${SOURCE_DATE_EPOCH}" 2>/dev/null ||
 770                   # Illumos -- sorry, no -r/-d here
 771                   date -u ||
 772                   date`
 773         else
 774             Date=`date -u "+%Y-%m-%dT%H:%M:%SZ"`
 775         fi
 776         if test -n "$SOURCE_HOST"; then
 777             Host=$SOURCE_HOST
 778         else
 779             Host=`uname -n`
 780         fi
 781         if test -n "$SOURCE_USER"; then
 782             User=$SOURCE_USER
 783         else
 784             User=${USER:-${LOGNAME:-`id -nu`}}
 785         fi
 786         if test -d "$srcdir/.git"; then
 787             GitCommit=`cd $srcdir && git rev-parse HEAD`
 788             GitBranch=`cd $srcdir && git rev-parse --abbrev-ref HEAD`
 789             if test "x$GitBranch" = master; then
 790                 GitDesc=`cd $srcdir && git describe --all --dirty`
 791             else
 792                 GitDesc=`cd $srcdir && \
 793                          git describe --tags --match 'heimdal-*' --dirty`
 794             fi
 795         else
 796             GitCommit='<commit-unknown>'
 797             GitBranch='<branch-unknown>'
 798             GitDesc='<tag-unknown>'
 799         fi
 800         mv -f include/newversion.h.in include/version.h.in
 801         sed -e "s/@HOST@/$Host/" \
 802             -e "s;@USER@;$User;" \
 803             -e "s;@DATE@;$Date;" \
 804             -e "s;@BRANCH@;$GitBranch;" \
 805             -e "s;@TAG@;$GitDesc;" \
 806             -e "s;@COMMIT@;$GitCommit;" \
 807             include/version.h.in > include/version.h
 808 fi