configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_INIT(lib/krb5/send_to_kdc.c)
   4 AM_CONFIG_HEADER(include/config.h)
   5
   6 AM_INIT_AUTOMAKE(heimdal,0.0k)
   7
   8 AC_PREFIX_DEFAULT(/usr/heimdal)
   9
  10 AC_CANONICAL_HOST
  11 CANONICAL_HOST=$host
  12 AC_SUBST(CANONICAL_HOST)
  13
  14 case "$host" in
  15 *-*-sunos4*)
  16         AC_DEFINE(SunOS, 4)
  17         ;;
  18 esac
  19
  20 dnl Checks for programs.
  21 AC_PROG_CC
  22
  23 dnl AC_KRB_PROG_YACC
  24 AC_PROG_YACC
  25 AC_PROG_LEX
  26 AC_PROG_RANLIB
  27 AC_PROG_AWK
  28 AC_KRB_PROG_LN_S
  29
  30 if test "$GCC" = "yes"; then
  31   WFLAGS="-Wall -Wno-unused -Wmissing-prototypes"
  32 fi
  33 AC_SUBST(WFLAGS)
  34 CFLAGS="-g"
  35
  36 berkeley_db=db
  37 AC_ARG_WITH(berkeley-db,
  38 [  --without-berkeley-db   if you don't want berkeley db],[
  39 if test "$withval" = no; then
  40         berkeley_db=""
  41 fi
  42 ])
  43
  44 AC_TEST_PACKAGE(krb4,krb.h,libkrb.a,-lkrb)
  45
  46 if test "$with_krb4"; then
  47         AC_DEFINE(KRB4, 1)
  48         LIB_krb4="$KRB4LIB -ldes"
  49         INCLUDE_krb4="$KRB4INCLUDE"
  50         EXTRA_LIB45=lib45.a
  51         AC_SUBST(EXTRA_LIB45)
  52 fi
  53 AM_CONDITIONAL(KRB4, test "$with_krb4")
  54 AC_SUBST(LIB_krb4)
  55 AC_SUBST(INCLUDE_krb4)
  56
  57 AC_ARG_ENABLE(kaserver,
  58 [  --enable-kaserver      if you want the KDC to try to emulate a kaserver],
  59 [
  60 if test "$enableval" != no; then
  61         AC_DEFINE(KASERVER, 1)
  62         if test "x$with_krb4" = "x"; then
  63                 AC_MSG_ERROR(kaserver requires krb4)
  64                 exit 1
  65         fi
  66 fi
  67 ])
  68
  69 otp=yes
  70 AC_ARG_ENABLE(otp,
  71 [  --disable-otp          if you don't want OTP support],
  72 [
  73 if test "$enableval" = "no"; then
  74         otp=no
  75 fi
  76 ])
  77 if test "$otp" = "yes"; then
  78         AC_DEFINE(OTP)
  79         LIB_otp='-L$(top_builddir)/lib/otp -lotp'
  80         OTP_dir=otp
  81 fi
  82 AC_SUBST(LIB_otp)
  83 AC_SUBST(OTP_dir)
  84
  85 AC_PATH_PROG(NROFF, nroff)
  86 AC_PATH_PROG(GROFF, groff)
  87 AC_CACHE_CHECK(how to format man pages,ac_cv_sys_man_format,
  88 [cat > conftest.1 << END
  89 .Dd January 1, 1970
  90 .Dt CONFTEST 1
  91 .Sh NAME
  92 .Nm conftest
  93 .Nd
  94 foobar
  95 END
  96
  97 if test "$NROFF" ; then
  98         for i in "-mdoc" "-mandoc"; do
  99                 if "$NROFF" $i conftest.1 2> /dev/null | \
 100                         grep Jan > /dev/null 2>&1 ; then
 101                         ac_cv_sys_man_format="$NROFF $i"
 102                         break
 103                 fi
 104         done
 105 fi
 106 if test "$ac_cv_sys_man_format" = "" -a "$GROFF" ; then
 107         for i in "-mdoc" "-mandoc"; do
 108                 if "$GROFF" -Tascii $i conftest.1 2> /dev/null | \
 109                         grep Jan > /dev/null 2>&1 ; then
 110                         ac_cv_sys_man_format="$GROFF -Tascii $i"
 111                         break
 112                 fi
 113         done
 114 fi
 115 if test "$ac_cv_sys_man_format"; then
 116         ac_cv_sys_man_format="$ac_cv_sys_man_format \$< > \$@"
 117 fi
 118 ])
 119 if test "$ac_cv_sys_man_format"; then
 120         CATMAN="$ac_cv_sys_man_format"
 121         AC_SUBST(CATMAN)
 122 fi
 123 AM_CONDITIONAL(CATMAN, test "$CATMAN")
 124 AC_CACHE_CHECK(extension of pre-formatted manual pages,ac_cv_sys_catman_ext,
 125 if grep _suffix /etc/man.conf > /dev/null 2>&1; then
 126         ac_cv_sys_catman_ext=0
 127 else
 128         ac_cv_sys_catman_ext=number
 129 fi
 130 )
 131 if test "$ac_cv_sys_catman_ext" = number; then
 132         CATMANEXT='$$section'
 133 else
 134         CATMANEXT=0
 135 fi
 136 AC_SUBST(CATMANEXT)
 137
 138 AC_TEST_PACKAGE(readline,readline.h,libreadline.a,-lreadline)
 139
 140 AC_C_BIGENDIAN
 141 AC_C_INLINE
 142
 143 AC_PATH_XTRA
 144
 145 dnl AM_C_PROTOTYPES
 146
 147 dnl Checks for typedefs, structures, and compiler characteristics.
 148 AC_C_CONST
 149 AC_TYPE_OFF_T
 150 AC_TYPE_SIZE_T
 151 AC_TYPE_MODE_T
 152 AC_HEADER_TIME
 153 AC_STRUCT_TM
 154 AC_DECL_YYTEXT
 155
 156 dnl Checks for header files.
 157 AC_HEADER_STDC
 158
 159 AC_CHECK_HEADERS(arpa/inet.h arpa/telnet.h bsdsetjmp.h crypt.h)
 160 AC_CHECK_HEADERS(curses.h db.h dbm.h dirent.h err.h errno.h)
 161 AC_CHECK_HEADERS(fcntl.h grp.h inttypes.h limits.h ndbm.h net/if.h netdb.h)
 162 AC_CHECK_HEADERS(netinet/in.h netinet/in6.h netinet/in6_var.h)
 163 AC_CHECK_HEADERS(netinet/in6_machtypes.h netinet/in_systm.h)
 164 AC_CHECK_HEADERS(netinet/ip.h netinet/tcp.h netinfo/ni.h netinet6/in6.h paths.h pty.h pwd.h)
 165 AC_CHECK_HEADERS(rpcsvc/dbm.h sac.h sgtty.h shadow.h signal.h stropts.h)
 166 AC_CHECK_HEADERS(sys/bitypes.h sys/file.h sys/filio.h sys/ioctl.h)
 167 AC_CHECK_HEADERS(sys/param.h sys/proc.h sys/pty.h sys/ptyio.h)
 168 AC_CHECK_HEADERS(sys/ptyvar.h sys/resource.h sys/select.h)
 169 AC_CHECK_HEADERS(sys/socket.h sys/sockio.h sys/stat.h sys/stream.h)
 170 AC_CHECK_HEADERS(sys/stropts.h sys/sysctl.h sys/time.h sys/timeb.h)
 171 AC_CHECK_HEADERS(sys/times.h sys/tty.h sys/types.h sys/uio.h)
 172 AC_CHECK_HEADERS(sys/utsname.h sys/wait.h syslog.h termio.h)
 173 AC_CHECK_HEADERS(termios.h tmpdir.h unistd.h util.h utmp.h utmpx.h)
 174
 175 if test "$ac_cv_header_err_h" = no; then
 176         EXTRA_HDRS="$EXTRA_HDRS err.h"
 177         AC_SUBST(EXTRA_HDRS)
 178 fi
 179
 180 dnl Checks for libraries.
 181
 182 AC_FIND_FUNC(socket, socket)
 183 AC_FIND_FUNC(gethostbyname, nsl)
 184 AC_FIND_FUNC(dbopen, $berkeley_db)
 185 AC_FIND_FUNC(dbm_firstkey, $berkeley_db gdbm ndbm)
 186 AC_FIND_FUNC(syslog, syslog)
 187
 188 AC_FIND_FUNC(logwtmp, util)
 189 AC_FIND_FUNC_NO_LIBS(tgetent, termcap)
 190 AC_FIND_FUNC(gethostbyname2, inet6 ip6)
 191 AC_FIND_FUNC(inet_ntop, inet6 ip6)
 192 AC_CHECK_FUNCS(inet_pton)
 193
 194 dnl Checks for library functions.
 195
 196 AC_BROKEN_SNPRINTF
 197 AC_BROKEN_VSNPRINTF
 198
 199 AC_CHECK_FUNCS(_getpty asnprintf asprintf fcntl gethostname)
 200 AC_CHECK_FUNCS(getmsg grantpt logwtmp mktime ptsname rand random)
 201 AC_CHECK_FUNCS(revoke select setitimer setlogin setpcred setpgid)
 202 AC_CHECK_FUNCS(setsid setsockopt sigaction strstr timegm ttyname umask)
 203 AC_CHECK_FUNCS(unlockpt vasnprintf vasprintf vhangup)
 204
 205 AC_TYPE_SIGNAL
 206 if test "$ac_cv_type_signal" = "void" ; then
 207         AC_DEFINE(VOID_RETSIGTYPE, 1)
 208 fi
 209 AC_SUBST(VOID_RETSIGTYPE)
 210
 211 AC_FIND_IF_NOT_BROKEN(hstrerror, resolv,
 212 [#ifdef HAVE_NETDB_H
 213 #include <netdb.h>
 214 #endif],
 215 17)
 216
 217 AC_BROKEN(chown daemon err errx fchown flock getcwd)
 218 AC_BROKEN(getdtablesize getusershell inet_aton initgroups)
 219 AC_BROKEN(lstat memmove mkstemp putenv rcmd setegid setenv)
 220 AC_BROKEN(seteuid strcasecmp strdup strerror strftime)
 221 AC_BROKEN(strlwr strnlen strsep strtok_r strupr unsetenv)
 222 AC_BROKEN(verr verrx vsyslog vwarn vwarnx warn warnx)
 223
 224 AC_CACHE_CHECK(if realloc if broken, ac_cv_func_realloc_broken, [
 225 ac_cv_func_realloc_broken=no
 226 AC_TRY_RUN([
 227 #include <stddef.h>
 228 #include <stdlib.h>
 229
 230 int main()
 231 {
 232         return realloc(NULL, 17) == NULL;
 233 }
 234 ],:, ac_cv_func_realloc_broken=yes, :)
 235 ])
 236 if test "$ac_cv_func_realloc_broken" = yes ; then
 237         AC_DEFINE(BROKEN_REALLOC)
 238 fi
 239
 240 dnl AC_KRB_FUNC_GETCWD_BROKEN
 241
 242 dnl
 243 dnl Checks for prototypes and declarations
 244 dnl
 245
 246 AC_PROTO_COMPAT([
 247 #ifdef HAVE_SYS_TYPES_H
 248 #include <sys/types.h>
 249 #endif
 250 #ifdef HAVE_SYS_SOCKET_H
 251 #include <sys/socket.h>
 252 #endif
 253 #ifdef HAVE_NETINET_IN_H
 254 #include <netinet/in.h>
 255 #endif
 256 #ifdef HAVE_ARPA_INET_H
 257 #include <arpa/inet.h>
 258 #endif
 259 #ifdef HAVE_NETDB_H
 260 #include <netdb.h>
 261 #endif
 262 ],
 263 gethostbyname, struct hostent *gethostbyname(const char *))
 264
 265 AC_PROTO_COMPAT([
 266 #ifdef HAVE_SYS_TYPES_H
 267 #include <sys/types.h>
 268 #endif
 269 #ifdef HAVE_SYS_SOCKET_H
 270 #include <sys/socket.h>
 271 #endif
 272 #ifdef HAVE_NETINET_IN_H
 273 #include <netinet/in.h>
 274 #endif
 275 #ifdef HAVE_ARPA_INET_H
 276 #include <arpa/inet.h>
 277 #endif
 278 #ifdef HAVE_NETDB_H
 279 #include <netdb.h>
 280 #endif
 281 ],
 282 gethostbyaddr, struct hostent *gethostbyaddr(const void *, size_t, int))
 283
 284 AC_PROTO_COMPAT([
 285 #ifdef HAVE_SYS_TYPES_H
 286 #include <sys/types.h>
 287 #endif
 288 #ifdef HAVE_SYS_SOCKET_H
 289 #include <sys/socket.h>
 290 #endif
 291 #ifdef HAVE_NETINET_IN_H
 292 #include <netinet/in.h>
 293 #endif
 294 #ifdef HAVE_ARPA_INET_H
 295 #include <arpa/inet.h>
 296 #endif
 297 #ifdef HAVE_NETDB_H
 298 #include <netdb.h>
 299 #endif
 300 ],
 301 getservbyname, struct servent *getservbyname(const char *, const char *))
 302
 303 AC_PROTO_COMPAT([
 304 #ifdef HAVE_SYSLOG_H
 305 #include <syslog.h>
 306 #endif
 307 ],
 308 openlog, void openlog(const char *, int, int))
 309
 310 AC_NEED_PROTO([
 311 #ifdef HAVE_CRYPT_H
 312 #include <crypt.h>
 313 #endif
 314 #ifdef HAVE_UNISTD_H
 315 #include <unistd.h>
 316 #endif
 317 ],
 318 crypt)
 319
 320 AC_NEED_PROTO([
 321 #include <string.h>
 322 ],
 323 strtok_r)
 324
 325 AC_CHECK_VAR([#ifdef HAVE_SYS_TYPES_H
 326 #include <sys/types.h>
 327 #endif
 328 #ifdef HAVE_NETDB_H
 329 #include <netdb.h>
 330 #endif],
 331 h_errno)
 332
 333 AC_CHECK_VAR([#ifdef HAVE_NETDB_H
 334 #include <netdb.h>
 335 #endif],
 336 h_errlist)
 337
 338 AC_CHECK_VAR([#ifdef HAVE_NETDB_H
 339 #include <netdb.h>
 340 #endif],
 341 h_nerr)
 342
 343 AC_CHECK_VAR([#ifdef HAVE_ERR_H
 344 #include <err.h>
 345 #endif],[__progname])
 346
 347 AC_CHECK_DECLARATION([#include <stdlib.h>], optarg)
 348 AC_CHECK_DECLARATION([#include <stdlib.h>], optind)
 349 AC_CHECK_DECLARATION([#include <stdlib.h>], opterr)
 350 AC_CHECK_DECLARATION([#include <stdlib.h>], optopt)
 351
 352 dnl
 353 dnl Check for fields in struct utmp
 354 dnl
 355 AC_EGREP_HEADER(ut_user, utmp.h, AC_DEFINE(HAVE_UT_USER))
 356 AC_EGREP_HEADER(ut_host, utmp.h, AC_DEFINE(HAVE_UT_HOST))
 357 AC_EGREP_HEADER(ut_addr, utmp.h, AC_DEFINE(HAVE_UT_ADDR))
 358 AC_EGREP_HEADER(ut_type, utmp.h, AC_DEFINE(HAVE_UT_TYPE))
 359 AC_EGREP_HEADER(ut_pid, utmp.h, AC_DEFINE(HAVE_UT_PID))
 360 AC_EGREP_HEADER(ut_id, utmp.h, AC_DEFINE(HAVE_UT_ID))
 361 AC_EGREP_HEADER(ut_syslen, utmpx.h, AC_DEFINE(HAVE_UT_SYSLEN))
 362
 363 AC_KRB_IPV6
 364
 365 dnl
 366 dnl Check for struct winsize
 367 dnl
 368
 369 AC_KRB_STRUCT_WINSIZE
 370
 371 dnl
 372 dnl Check for sa_len in struct sockaddr
 373 dnl
 374
 375 AC_KRB_STRUCT_SOCKADDR_SA_LEN
 376
 377 dnl
 378 dnl Check for some common types
 379 dnl
 380
 381 AC_TYPE_PID_T
 382 AC_TYPE_UID_T
 383 AC_TYPE_OFF_T
 384 AC_TYPE_SIZE_T
 385 AC_CHECK_TYPE(ssize_t, int)
 386 AC_TYPE_SIG_ATOMIC_T
 387
 388 dnl AC_SUBST(LIBOBJS)
 389
 390 AC_GROK_TYPES(int8_t int16_t int32_t int64_t)
 391 AC_GROK_TYPES(u_int8_t u_int16_t u_int32_t u_int64_t)
 392
 393 dnl
 394 dnl Tests for editline
 395 dnl
 396
 397 AC_FIND_FUNC_NO_LIBS(el_init, edit)
 398 AC_FIND_FUNC_NO_LIBS(readline, readline)
 399
 400 if test "$with_readline"; then
 401         AC_DEFINE(HAVE_READLINE, 1)
 402         editline_OBJS=
 403         LIB_readline="$READLINELIB "'$(LIB_tgetent)'
 404         INCLUDE_readline="$READLINEINCLUDE"
 405 elif test "$ac_cv_func_el_init" = yes; then
 406         AC_DEFINE(HAVE_READLINE, 1)
 407
 408         editline_OBJS=edit_compat.o
 409         LIB_readline='-L$(top_builddir)/lib/editline -leditline '"$LIB_el_init"' $(LIB_tgetent)'
 410
 411         INCLUDE_readline='-I$(top_builddir)/lib/editline -I$(top_srcdir)/lib/editline'
 412 elif test "$ac_cv_func_readline" = yes; then
 413         AC_DEFINE(HAVE_READLINE, 1)
 414         editline_OBJS=
 415         LIB_readline='-lreadline $(LIB_tgetent)'
 416         INCLUDE_readline=
 417 else
 418         AC_DEFINE(HAVE_READLINE, 1)
 419         editline_OBJS="editline.o complete.o sysunix.o"
 420         LIB_readline='-L$(top_builddir)/lib/editline -leditline $(LIB_tgetent)'
 421         INCLUDE_readline='-I$(top_builddir)/lib/editline -I$(top_srcdir)/lib/editline'
 422 fi
 423 AC_SUBST(LIB_tgetent)
 424 AC_SUBST(LIB_readline)
 425 AC_SUBST(INCLUDE_readline)
 426 AC_SUBST(editline_OBJS)
 427
 428 dnl telnet muck --------------------------------------------------
 429
 430 AC_DEFINE(AUTHENTICATION)dnl
 431 AC_DEFINE(KRB5)dnl
 432 AC_DEFINE(ENCRYPTION)dnl
 433 AC_DEFINE(DES_ENCRYPTION)dnl
 434 AC_DEFINE(DIAGNOSTICS)dnl
 435 AC_DEFINE(OLD_ENVIRON)dnl
 436
 437 # Simple test for streamspty, based on the existance of getmsg(), alas
 438 # this breaks on SunOS4 which have streams but BSD-like ptys
 439 #
 440 # And also something wierd has happend with dec-osf1, fallback to bsd-ptys
 441
 442 AC_MSG_CHECKING(for streamspty)
 443 case "`uname -sr`" in
 444 SunOS\ 4*|OSF1*|IRIX\ 4*|HP-UX\ ?.10.*)
 445         krb_cv_sys_streamspty=no
 446         ;;
 447 AIX*)
 448         os_rel=`uname -v`.`uname -r`
 449         if expr "$os_rel" : "3*" >/dev/null 2>&1; then
 450                 krb_cv_sys_streamspty=no
 451         else
 452                 krb_cv_sys_streamspty="$ac_cv_func_getmsg"
 453         fi
 454         ;;
 455 *)
 456         krb_cv_sys_streamspty="$ac_cv_func_getmsg"
 457         ;;
 458 esac
 459 if test "$krb_cv_sys_streamspty" = yes; then
 460         AC_DEFINE(STREAMSPTY)
 461 fi
 462 dnl AC_SUBST(STREAMSPTY)
 463 AC_MSG_RESULT($krb_cv_sys_streamspty)
 464
 465 AC_OUTPUT(Makefile                      \
 466         include/Makefile                \
 467         lib/Makefile                    \
 468         lib/roken/Makefile              \
 469         lib/editline/Makefile           \
 470         lib/sl/Makefile                 \
 471         lib/error/Makefile              \
 472         lib/error/compile_et            \
 473         lib/asn1/Makefile               \
 474         lib/des/Makefile                \
 475         lib/krb5/Makefile               \
 476         lib/hdb/Makefile                \
 477         lib/gssapi/Makefile             \
 478         lib/45/Makefile                 \
 479         lib/otp/Makefile                \
 480         lib/kafs/Makefile               \
 481         kuser/Makefile                  \
 482         kpasswd/Makefile                \
 483         admin/Makefile                  \
 484         kdc/Makefile                    \
 485         appl/Makefile                   \
 486         appl/test/Makefile              \
 487         appl/rsh/Makefile               \
 488         appl/popper/Makefile            \
 489         appl/push/Makefile              \
 490         appl/telnet/Makefile            \
 491         appl/telnet/libtelnet/Makefile  \
 492         appl/telnet/telnet/Makefile     \
 493         appl/telnet/telnetd/Makefile    \
 494         appl/afsutil/Makefile           \
 495         doc/Makefile                    \
 496 )
 497
 498 dnl
 499 dnl This is the release version name-number[beta]
 500 dnl
 501 HEIMDALVERSION="$PACKAGE-$VERSION"
 502
 503 cat > include/newversion.h.in <<EOF
 504 char *heimdal_long_version = "@(#)\$Version: $HEIMDALVERSION by @USER@ on @HOST@ ($host) @DATE@ \$";
 505 char *heimdal_version = "$HEIMDALVERSION";
 506 EOF
 507
 508 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 509         echo "include/version.h is unchanged"
 510         rm -f include/newversion.h.in
 511 else
 512         echo "creating include/version.h"
 513         User=${USER-${LOGNAME}}
 514         Host=`(hostname || uname -n) 2>/dev/null | sed 1q`
 515         Date=`date`
 516         mv -f include/newversion.h.in include/version.h.in
 517         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 518 fi