configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_INIT(lib/krb5/send_to_kdc.c)
   4 AM_CONFIG_HEADER(include/config.h)
   5
   6 AM_INIT_AUTOMAKE(heimdal,0.0l)
   7
   8 AC_PREFIX_DEFAULT(/usr/heimdal)
   9
  10 AC_CANONICAL_HOST
  11 CANONICAL_HOST=$host
  12 AC_SUBST(CANONICAL_HOST)
  13
  14 case "$host" in
  15 *-*-sunos4*)
  16         AC_DEFINE(SunOS, 4)
  17         ;;
  18 esac
  19
  20 dnl Checks for programs.
  21 AC_PROG_CC
  22
  23 dnl AC_KRB_PROG_YACC
  24 AC_PROG_YACC
  25 AC_PROG_LEX
  26 AC_PROG_RANLIB
  27 AC_PROG_AWK
  28 AC_KRB_PROG_LN_S
  29
  30 if test "$GCC" = "yes"; then
  31   WFLAGS="-Wall -Wno-unused -Wmissing-prototypes"
  32 fi
  33 AC_SUBST(WFLAGS)
  34 CFLAGS="-g"
  35
  36 berkeley_db=db
  37 AC_ARG_WITH(berkeley-db,
  38 [  --without-berkeley-db   if you don't want berkeley db],[
  39 if test "$withval" = no; then
  40         berkeley_db=""
  41 fi
  42 ])
  43
  44 AC_TEST_PACKAGE(krb4,krb.h,libkrb.a,-lkrb)
  45
  46 if test "$with_krb4"; then
  47         AC_DEFINE(KRB4, 1)
  48         LIB_krb4="$KRB4LIB -ldes"
  49         INCLUDE_krb4="$KRB4INCLUDE"
  50         EXTRA_LIB45=lib45.a
  51         AC_SUBST(EXTRA_LIB45)
  52 fi
  53 AM_CONDITIONAL(KRB4, test "$with_krb4")dnl
  54 AC_SUBST(LIB_krb4)dnl
  55 AC_SUBST(INCLUDE_krb4)dnl
  56 AM_CONDITIONAL(AIX, test `uname` = AIX)dnl
  57
  58 AC_ARG_ENABLE(kaserver,
  59 [  --enable-kaserver      if you want the KDC to try to emulate a kaserver],
  60 [
  61 if test "$enableval" != no; then
  62         AC_DEFINE(KASERVER, 1)
  63         if test "x$with_krb4" = "x"; then
  64                 AC_MSG_ERROR(kaserver requires krb4)
  65                 exit 1
  66         fi
  67 fi
  68 ])
  69
  70 otp=yes
  71 AC_ARG_ENABLE(otp,
  72 [  --disable-otp          if you don't want OTP support],
  73 [
  74 if test "$enableval" = "no"; then
  75         otp=no
  76 fi
  77 ])
  78 if test "$otp" = "yes"; then
  79         AC_DEFINE(OTP)
  80         LIB_otp='-L$(top_builddir)/lib/otp -lotp'
  81         OTP_dir=otp
  82 fi
  83 AC_SUBST(LIB_otp)
  84 AC_SUBST(OTP_dir)
  85
  86 AC_PATH_PROG(NROFF, nroff)
  87 AC_PATH_PROG(GROFF, groff)
  88 AC_CACHE_CHECK(how to format man pages,ac_cv_sys_man_format,
  89 [cat > conftest.1 << END
  90 .Dd January 1, 1970
  91 .Dt CONFTEST 1
  92 .Sh NAME
  93 .Nm conftest
  94 .Nd
  95 foobar
  96 END
  97
  98 if test "$NROFF" ; then
  99         for i in "-mdoc" "-mandoc"; do
 100                 if "$NROFF" $i conftest.1 2> /dev/null | \
 101                         grep Jan > /dev/null 2>&1 ; then
 102                         ac_cv_sys_man_format="$NROFF $i"
 103                         break
 104                 fi
 105         done
 106 fi
 107 if test "$ac_cv_sys_man_format" = "" -a "$GROFF" ; then
 108         for i in "-mdoc" "-mandoc"; do
 109                 if "$GROFF" -Tascii $i conftest.1 2> /dev/null | \
 110                         grep Jan > /dev/null 2>&1 ; then
 111                         ac_cv_sys_man_format="$GROFF -Tascii $i"
 112                         break
 113                 fi
 114         done
 115 fi
 116 if test "$ac_cv_sys_man_format"; then
 117         ac_cv_sys_man_format="$ac_cv_sys_man_format \$< > \$@"
 118 fi
 119 ])
 120 if test "$ac_cv_sys_man_format"; then
 121         CATMAN="$ac_cv_sys_man_format"
 122         AC_SUBST(CATMAN)
 123 fi
 124 AM_CONDITIONAL(CATMAN, test "$CATMAN")
 125 AC_CACHE_CHECK(extension of pre-formatted manual pages,ac_cv_sys_catman_ext,
 126 if grep _suffix /etc/man.conf > /dev/null 2>&1; then
 127         ac_cv_sys_catman_ext=0
 128 else
 129         ac_cv_sys_catman_ext=number
 130 fi
 131 )
 132 if test "$ac_cv_sys_catman_ext" = number; then
 133         CATMANEXT='$$section'
 134 else
 135         CATMANEXT=0
 136 fi
 137 AC_SUBST(CATMANEXT)
 138
 139 AC_TEST_PACKAGE(readline,readline.h,libreadline.a,-lreadline)
 140
 141 AC_C_BIGENDIAN
 142 AC_C_INLINE
 143
 144 AC_PATH_XTRA
 145
 146 dnl AM_C_PROTOTYPES
 147
 148 dnl Checks for typedefs, structures, and compiler characteristics.
 149 AC_C_CONST
 150 AC_TYPE_OFF_T
 151 AC_TYPE_SIZE_T
 152 AC_TYPE_MODE_T
 153 AC_HEADER_TIME
 154 AC_STRUCT_TM
 155 AC_DECL_YYTEXT
 156
 157 dnl Checks for header files.
 158 AC_HEADER_STDC
 159
 160 AC_CHECK_HEADERS(arpa/inet.h arpa/telnet.h bsdsetjmp.h crypt.h)
 161 AC_CHECK_HEADERS(curses.h db.h dbm.h dirent.h err.h errno.h)
 162 AC_CHECK_HEADERS(fcntl.h fnmatch.h grp.h inttypes.h limits.h ndbm.h)
 163 AC_CHECK_HEADERS(net/if.h netdb.h)
 164 AC_CHECK_HEADERS(netinet/in.h netinet/in6.h netinet/in6_var.h)
 165 AC_CHECK_HEADERS(netinet/in6_machtypes.h netinet/in_systm.h)
 166 AC_CHECK_HEADERS(netinet/ip.h netinet/tcp.h netinfo/ni.h netinet6/in6.h paths.h pty.h pwd.h)
 167 AC_CHECK_HEADERS(rpcsvc/dbm.h sac.h sgtty.h shadow.h signal.h stropts.h)
 168 AC_CHECK_HEADERS(sys/bitypes.h sys/file.h sys/filio.h sys/ioctl.h)
 169 AC_CHECK_HEADERS(sys/param.h sys/proc.h sys/pty.h sys/ptyio.h)
 170 AC_CHECK_HEADERS(sys/ptyvar.h sys/resource.h sys/select.h)
 171 AC_CHECK_HEADERS(sys/socket.h sys/sockio.h sys/stat.h sys/stream.h)
 172 AC_CHECK_HEADERS(sys/stropts.h sys/sysctl.h sys/time.h sys/timeb.h)
 173 AC_CHECK_HEADERS(sys/times.h sys/tty.h sys/types.h sys/uio.h)
 174 AC_CHECK_HEADERS(sys/utsname.h sys/wait.h syslog.h termio.h)
 175 AC_CHECK_HEADERS(termios.h tmpdir.h unistd.h util.h utmp.h utmpx.h)
 176
 177 if test "$ac_cv_header_err_h" = no; then
 178         EXTRA_HDRS="$EXTRA_HDRS err.h"
 179         AC_SUBST(EXTRA_HDRS)
 180 fi
 181 if test "$ac_cv_header_fnmatch_h" = no; then
 182         EXTRA_HDRS="$EXTRA_HDRS fnmatch.h"
 183         AC_SUBST(EXTRA_HDRS)
 184 fi
 185
 186 dnl Checks for libraries.
 187
 188 AC_FIND_FUNC(socket, socket)
 189 AC_FIND_FUNC(gethostbyname, nsl)
 190 AC_FIND_FUNC(dbopen, $berkeley_db)
 191 AC_FIND_FUNC(dbm_firstkey, $berkeley_db gdbm ndbm)
 192 AC_FIND_FUNC(syslog, syslog)
 193
 194 AC_FIND_FUNC(logwtmp, util)
 195 AC_FIND_FUNC_NO_LIBS(tgetent, termcap)
 196 AC_FIND_FUNC(gethostbyname2, inet6 ip6)
 197 AC_FIND_FUNC(inet_ntop, inet6 ip6)
 198 AC_CHECK_FUNCS(inet_pton)
 199
 200 dnl Checks for library functions.
 201
 202 AC_BROKEN_SNPRINTF
 203 AC_BROKEN_VSNPRINTF
 204
 205 AC_CHECK_FUNCS(_getpty asnprintf asprintf fcntl gethostname)
 206 AC_CHECK_FUNCS(getmsg grantpt logwtmp mktime ptsname rand random)
 207 AC_CHECK_FUNCS(revoke select setitimer setlogin setpcred setpgid)
 208 AC_CHECK_FUNCS(setsid setsockopt sigaction strstr timegm ttyname umask)
 209 AC_CHECK_FUNCS(unlockpt vasnprintf vasprintf vhangup)
 210
 211 AC_TYPE_SIGNAL
 212 if test "$ac_cv_type_signal" = "void" ; then
 213         AC_DEFINE(VOID_RETSIGTYPE, 1)
 214 fi
 215 AC_SUBST(VOID_RETSIGTYPE)
 216
 217 AC_FIND_IF_NOT_BROKEN(hstrerror, resolv,
 218 [#ifdef HAVE_NETDB_H
 219 #include <netdb.h>
 220 #endif],
 221 17)
 222 if test "$ac_cv_func_hstrerror" = yes; then
 223 AC_NEED_PROTO([
 224 #ifdef HAVE_NETDB_H
 225 #include <netdb.h>
 226 #endif],
 227 hstrerror)
 228 fi
 229
 230 AC_BROKEN(chown daemon err errx fchown flock fnmatch getcwd)
 231 AC_BROKEN(getdtablesize getopt getusershell inet_aton)
 232 AC_BROKEN(initgroups innetgr iruserok lstat memmove mkstemp)
 233 AC_BROKEN(putenv rcmd readv setegid setenv setenv seteuid)
 234 AC_BROKEN(seteuid strcasecmp strdup strerror strftime strlwr)
 235 AC_BROKEN(strnlen strsep strtok_r strupr unsetenv verr verrx)
 236 AC_BROKEN(vsyslog vwarn vwarnx warn warnx writev)
 237
 238 AC_CACHE_CHECK(if realloc if broken, ac_cv_func_realloc_broken, [
 239 ac_cv_func_realloc_broken=no
 240 AC_TRY_RUN([
 241 #include <stddef.h>
 242 #include <stdlib.h>
 243
 244 int main()
 245 {
 246         return realloc(NULL, 17) == NULL;
 247 }
 248 ],:, ac_cv_func_realloc_broken=yes, :)
 249 ])
 250 if test "$ac_cv_func_realloc_broken" = yes ; then
 251         AC_DEFINE(BROKEN_REALLOC)
 252 fi
 253
 254 dnl AC_KRB_FUNC_GETCWD_BROKEN
 255
 256 dnl
 257 dnl Checks for prototypes and declarations
 258 dnl
 259
 260 AC_PROTO_COMPAT([
 261 #ifdef HAVE_SYS_TYPES_H
 262 #include <sys/types.h>
 263 #endif
 264 #ifdef HAVE_SYS_SOCKET_H
 265 #include <sys/socket.h>
 266 #endif
 267 #ifdef HAVE_NETINET_IN_H
 268 #include <netinet/in.h>
 269 #endif
 270 #ifdef HAVE_ARPA_INET_H
 271 #include <arpa/inet.h>
 272 #endif
 273 #ifdef HAVE_NETDB_H
 274 #include <netdb.h>
 275 #endif
 276 ],
 277 gethostbyname, struct hostent *gethostbyname(const char *))
 278
 279 AC_PROTO_COMPAT([
 280 #ifdef HAVE_SYS_TYPES_H
 281 #include <sys/types.h>
 282 #endif
 283 #ifdef HAVE_SYS_SOCKET_H
 284 #include <sys/socket.h>
 285 #endif
 286 #ifdef HAVE_NETINET_IN_H
 287 #include <netinet/in.h>
 288 #endif
 289 #ifdef HAVE_ARPA_INET_H
 290 #include <arpa/inet.h>
 291 #endif
 292 #ifdef HAVE_NETDB_H
 293 #include <netdb.h>
 294 #endif
 295 ],
 296 gethostbyaddr, struct hostent *gethostbyaddr(const void *, size_t, int))
 297
 298 AC_PROTO_COMPAT([
 299 #ifdef HAVE_SYS_TYPES_H
 300 #include <sys/types.h>
 301 #endif
 302 #ifdef HAVE_SYS_SOCKET_H
 303 #include <sys/socket.h>
 304 #endif
 305 #ifdef HAVE_NETINET_IN_H
 306 #include <netinet/in.h>
 307 #endif
 308 #ifdef HAVE_ARPA_INET_H
 309 #include <arpa/inet.h>
 310 #endif
 311 #ifdef HAVE_NETDB_H
 312 #include <netdb.h>
 313 #endif
 314 ],
 315 getservbyname, struct servent *getservbyname(const char *, const char *))
 316
 317 AC_PROTO_COMPAT([
 318 #ifdef HAVE_SYSLOG_H
 319 #include <syslog.h>
 320 #endif
 321 ],
 322 openlog, void openlog(const char *, int, int))
 323
 324 AC_NEED_PROTO([
 325 #ifdef HAVE_CRYPT_H
 326 #include <crypt.h>
 327 #endif
 328 #ifdef HAVE_UNISTD_H
 329 #include <unistd.h>
 330 #endif
 331 ],
 332 crypt)
 333
 334 AC_NEED_PROTO([
 335 #include <string.h>
 336 ],
 337 strtok_r)
 338
 339 AC_CHECK_VAR([#ifdef HAVE_SYS_TYPES_H
 340 #include <sys/types.h>
 341 #endif
 342 #ifdef HAVE_NETDB_H
 343 #include <netdb.h>
 344 #endif],
 345 h_errno)
 346
 347 AC_CHECK_VAR([#ifdef HAVE_NETDB_H
 348 #include <netdb.h>
 349 #endif],
 350 h_errlist)
 351
 352 AC_CHECK_VAR([#ifdef HAVE_NETDB_H
 353 #include <netdb.h>
 354 #endif],
 355 h_nerr)
 356
 357 AC_CHECK_VAR([#ifdef HAVE_ERR_H
 358 #include <err.h>
 359 #endif],[__progname])
 360
 361 AC_CHECK_DECLARATION([#include <stdlib.h>], optarg)
 362 AC_CHECK_DECLARATION([#include <stdlib.h>], optind)
 363 AC_CHECK_DECLARATION([#include <stdlib.h>], opterr)
 364 AC_CHECK_DECLARATION([#include <stdlib.h>], optopt)
 365
 366 dnl
 367 dnl Check for fields in struct utmp
 368 dnl
 369 AC_EGREP_HEADER(ut_user, utmp.h, AC_DEFINE(HAVE_UT_USER))
 370 AC_EGREP_HEADER(ut_host, utmp.h, AC_DEFINE(HAVE_UT_HOST))
 371 AC_EGREP_HEADER(ut_addr, utmp.h, AC_DEFINE(HAVE_UT_ADDR))
 372 AC_EGREP_HEADER(ut_type, utmp.h, AC_DEFINE(HAVE_UT_TYPE))
 373 AC_EGREP_HEADER(ut_pid, utmp.h, AC_DEFINE(HAVE_UT_PID))
 374 AC_EGREP_HEADER(ut_id, utmp.h, AC_DEFINE(HAVE_UT_ID))
 375 AC_EGREP_HEADER(ut_syslen, utmpx.h, AC_DEFINE(HAVE_UT_SYSLEN))
 376
 377 AC_KRB_IPV6
 378
 379 dnl
 380 dnl Check for struct winsize
 381 dnl
 382
 383 AC_KRB_STRUCT_WINSIZE
 384
 385 dnl
 386 dnl Check for sa_len in struct sockaddr
 387 dnl
 388
 389 AC_KRB_STRUCT_SOCKADDR_SA_LEN
 390
 391 dnl
 392 dnl Check for some common types
 393 dnl
 394
 395 AC_TYPE_PID_T
 396 AC_TYPE_UID_T
 397 AC_TYPE_OFF_T
 398 AC_TYPE_SIZE_T
 399 AC_CHECK_TYPE(ssize_t, int)
 400 AC_TYPE_SIG_ATOMIC_T
 401
 402 dnl AC_SUBST(LIBOBJS)
 403
 404 AC_GROK_TYPES(int8_t int16_t int32_t int64_t)
 405 AC_GROK_TYPES(u_int8_t u_int16_t u_int32_t u_int64_t)
 406
 407 dnl
 408 dnl Tests for editline
 409 dnl
 410
 411 AC_FIND_FUNC_NO_LIBS(el_init, edit)
 412 AC_FIND_FUNC_NO_LIBS(readline, readline)
 413
 414 if test "$with_readline"; then
 415         AC_DEFINE(HAVE_READLINE, 1)
 416         editline_OBJS=
 417         LIB_readline="$READLINELIB "'$(LIB_tgetent)'
 418         INCLUDE_readline="$READLINEINCLUDE"
 419 elif test "$ac_cv_func_el_init" = yes; then
 420         AC_DEFINE(HAVE_READLINE, 1)
 421
 422         editline_OBJS=edit_compat.o
 423         LIB_readline='-L$(top_builddir)/lib/editline -leditline '"$LIB_el_init"' $(LIB_tgetent)'
 424
 425         INCLUDE_readline='-I$(top_builddir)/lib/editline -I$(top_srcdir)/lib/editline'
 426 elif test "$ac_cv_func_readline" = yes; then
 427         AC_DEFINE(HAVE_READLINE, 1)
 428         editline_OBJS=
 429         LIB_readline='-lreadline $(LIB_tgetent)'
 430         INCLUDE_readline=
 431 else
 432         AC_DEFINE(HAVE_READLINE, 1)
 433         editline_OBJS="editline.o complete.o sysunix.o"
 434         LIB_readline='-L$(top_builddir)/lib/editline -leditline $(LIB_tgetent)'
 435         INCLUDE_readline='-I$(top_builddir)/lib/editline -I$(top_srcdir)/lib/editline'
 436 fi
 437 AC_SUBST(LIB_tgetent)
 438 AC_SUBST(LIB_readline)
 439 AC_SUBST(INCLUDE_readline)
 440 AC_SUBST(editline_OBJS)
 441
 442 dnl telnet muck --------------------------------------------------
 443
 444 AC_DEFINE(AUTHENTICATION)dnl
 445 AC_DEFINE(KRB5)dnl
 446 AC_DEFINE(ENCRYPTION)dnl
 447 AC_DEFINE(DES_ENCRYPTION)dnl
 448 AC_DEFINE(DIAGNOSTICS)dnl
 449 AC_DEFINE(OLD_ENVIRON)dnl
 450
 451 # Simple test for streamspty, based on the existance of getmsg(), alas
 452 # this breaks on SunOS4 which have streams but BSD-like ptys
 453 #
 454 # And also something wierd has happend with dec-osf1, fallback to bsd-ptys
 455
 456 AC_MSG_CHECKING(for streamspty)
 457 case "`uname -sr`" in
 458 SunOS\ 4*|OSF1*|IRIX\ 4*|HP-UX\ ?.10.*)
 459         krb_cv_sys_streamspty=no
 460         ;;
 461 AIX*)
 462         os_rel=`uname -v`.`uname -r`
 463         if expr "$os_rel" : "3*" >/dev/null 2>&1; then
 464                 krb_cv_sys_streamspty=no
 465         else
 466                 krb_cv_sys_streamspty="$ac_cv_func_getmsg"
 467         fi
 468         ;;
 469 *)
 470         krb_cv_sys_streamspty="$ac_cv_func_getmsg"
 471         ;;
 472 esac
 473 if test "$krb_cv_sys_streamspty" = yes; then
 474         AC_DEFINE(STREAMSPTY)
 475 fi
 476 dnl AC_SUBST(STREAMSPTY)
 477 AC_MSG_RESULT($krb_cv_sys_streamspty)
 478
 479 AC_OUTPUT(Makefile                      \
 480         include/Makefile                \
 481         include/kadm5/Makefile          \
 482         lib/Makefile                    \
 483         lib/roken/Makefile              \
 484         lib/editline/Makefile           \
 485         lib/sl/Makefile                 \
 486         lib/error/Makefile              \
 487         lib/error/compile_et            \
 488         lib/asn1/Makefile               \
 489         lib/des/Makefile                \
 490         lib/krb5/Makefile               \
 491         lib/kadm5/Makefile              \
 492         lib/hdb/Makefile                \
 493         lib/gssapi/Makefile             \
 494         lib/45/Makefile                 \
 495         lib/otp/Makefile                \
 496         lib/kafs/Makefile               \
 497         kuser/Makefile                  \
 498         kpasswd/Makefile                \
 499         kadmin/Makefile                 \
 500         admin/Makefile                  \
 501         kdc/Makefile                    \
 502         appl/Makefile                   \
 503         appl/test/Makefile              \
 504         appl/rsh/Makefile               \
 505         appl/popper/Makefile            \
 506         appl/push/Makefile              \
 507         appl/telnet/Makefile            \
 508         appl/telnet/libtelnet/Makefile  \
 509         appl/telnet/telnet/Makefile     \
 510         appl/telnet/telnetd/Makefile    \
 511         appl/afsutil/Makefile           \
 512         doc/Makefile                    \
 513 )
 514
 515 dnl
 516 dnl This is the release version name-number[beta]
 517 dnl
 518 HEIMDALVERSION="$PACKAGE-$VERSION"
 519
 520 cat > include/newversion.h.in <<EOF
 521 char *heimdal_long_version = "@(#)\$Version: $HEIMDALVERSION by @USER@ on @HOST@ ($host) @DATE@ \$";
 522 char *heimdal_version = "$HEIMDALVERSION";
 523 EOF
 524
 525 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 526         echo "include/version.h is unchanged"
 527         rm -f include/newversion.h.in
 528 else
 529         echo "creating include/version.h"
 530         User=${USER-${LOGNAME}}
 531         Host=`(hostname || uname -n) 2>/dev/null | sed 1q`
 532         Date=`date`
 533         mv -f include/newversion.h.in include/version.h.in
 534         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 535 fi