cf/check-x.m4

   1 dnl
   2 dnl See if there is any X11 present
   3 dnl
   4 dnl $Id$
   5
   6 AC_DEFUN([KRB_CHECK_X],[
   7 AC_PATH_XTRA
   8
   9 # try to figure out if we need any additional ld flags, like -R
  10 # and yes, the autoconf X test is utterly broken
  11 if test "$no_x" != yes; then
  12         AC_CACHE_CHECK(for special X linker flags,krb_cv_sys_x_libs_rpath,[
  13         ac_save_libs="$LIBS"
  14         ac_save_cflags="$CFLAGS"
  15         CFLAGS="$CFLAGS $X_CFLAGS"
  16         krb_cv_sys_x_libs_rpath=""
  17         krb_cv_sys_x_libs=""
  18         for rflag in "" "-R" "-R " "-rpath "; do
  19                 if test "$rflag" = ""; then
  20                         foo="$X_LIBS"
  21                 else
  22                         foo=""
  23                         for flag in $X_LIBS; do
  24                         case $flag in
  25                         -L*)
  26                                 foo="$foo $flag `echo $flag | sed \"s/-L/$rflag/\"`"
  27                                 ;;
  28                         *)
  29                                 foo="$foo $flag"
  30                                 ;;
  31                         esac
  32                         done
  33                 fi
  34                 LIBS="$ac_save_libs $foo $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
  35                 AC_LANG(C)
  36                 AC_RUN_IFELSE([AC_LANG_SOURCE([
  37                 #include <X11/Xlib.h>
  38                 foo(void)
  39                 {
  40                 XOpenDisplay(NULL);
  41                 }
  42                 main(int argc, char **argv)
  43                 {
  44                 return 0;
  45                 }
  46                 ])],krb_cv_sys_x_libs_rpath="$rflag"; krb_cv_sys_x_libs="$foo"; break,:,
  47                 krb_cv_sys_x_libs_rpath="" ; krb_cv_sys_x_libs="" ; break)
  48         done
  49         LIBS="$ac_save_libs"
  50         CFLAGS="$ac_save_cflags"
  51         ])
  52         X_LIBS="$krb_cv_sys_x_libs"
  53 fi
  54 ])