configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 AC_PREFIX_DEFAULT(/usr/heimdal)
  25
  26 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  27 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  28
  29 AC_CANONICAL_HOST
  30 CANONICAL_HOST=$host
  31 AC_SUBST(CANONICAL_HOST)
  32
  33 rk_SYS_LARGEFILE
  34
  35 rk_AIX
  36 rk_IRIX
  37 rk_SUNOS
  38
  39 dnl
  40 dnl this is needed to run the configure tests against glibc
  41 dnl
  42 AC_DEFINE([_GNU_SOURCE], 1,
  43         [Define to enable extensions on glibc-based systems such as Linux.])
  44
  45 AC_OBJEXT
  46 AC_EXEEXT
  47
  48 dnl
  49 dnl this is needed when der-protos.h or der-private.h has to be generated
  50 dnl
  51 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  52    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  53     AC_KRB_PROG_PERL
  54     AC_KRB_PERL_MOD(Getopt::Std)
  55     AC_KRB_PERL_MOD(File::Compare)
  56     AC_KRB_PERL_MOD(JSON)
  57 fi
  58
  59 dnl AC_KRB_PROG_YACC
  60 AC_PROG_YACC
  61 AM_PROG_LEX
  62 dnl AC_PROG_RANLIB
  63 AC_PROG_AWK
  64 AC_KRB_PROG_LN_S
  65
  66 AC_MIPS_ABI
  67 CC="$CC $abi"
  68 libdir="$libdir$abilibdirext"
  69
  70 AC_C___ATTRIBUTE__
  71
  72 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  73 rk_VERSIONSCRIPT
  74
  75 dnl
  76 dnl Helper bits for cross compiling
  77 dnl
  78
  79
  80
  81 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  82
  83 AC_ARG_WITH(cross-tools,
  84         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  85         [if test "$withval" = "yes"; then
  86                 AC_MSG_ERROR([Need path to cross tools])
  87         fi
  88         with_cross_tools="${with_cross_tools}/"
  89         ])
  90
  91 if test "${cross_compiling}" != yes ; then
  92
  93    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  94    SLC="\$(top_builddir)/lib/sl/slc"
  95
  96    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  97    SLC_DEP="\$(SLC)"
  98 else
  99    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 100    SLC="${with_cross_tools}slc"
 101
 102    ASN1_COMPILE_DEP=
 103    SLC_DEP=
 104
 105    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 106
 107 fi
 108
 109 AC_SUBST([ASN1_COMPILE])
 110 AC_SUBST([ASN1_COMPILE_DEP])
 111 AC_SUBST([SLC])
 112 AC_SUBST([SLC_DEP])
 113
 114 dnl ---
 115
 116 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 117
 118 rk_TEST_PACKAGE(openldap,
 119 [#include <lber.h>
 120 #include <ldap.h>],
 121 [-lldap -llber],,,OPENLDAP)
 122
 123 AC_ARG_ENABLE(hdb-openldap-module,
 124         AS_HELP_STRING([--enable-hdb-openldap-module],
 125                 [if you want support to build openldap hdb as shared object]))
 126 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 127     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 128 fi
 129 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 130
 131 dnl
 132 dnl Optional modules, pk-init, digest, kx509
 133 dnl
 134
 135 AC_ARG_ENABLE(pk-init,
 136         AS_HELP_STRING([--disable-pk-init],
 137                 [if you want disable to PK-INIT support]))
 138 if test "$enable_pk_init" != no ;then
 139         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 140 fi
 141 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 142
 143 AC_ARG_ENABLE(digest,
 144         AS_HELP_STRING([--disable-digest],
 145                 [if you want disable to DIGEST support]))
 146 if test "$enable_digest" != no ;then
 147         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 148 fi
 149
 150 AC_ARG_ENABLE(kx509,
 151         AS_HELP_STRING([--disable-kx509],
 152                 [if you want disable to kx509 support]))
 153 if test "$enable_kx509" != no ;then
 154         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 155 fi
 156
 157 dnl Need to test if pkg-config exists
 158 PKG_PROG_PKG_CONFIG
 159
 160 dnl libcap-ng
 161 AC_ARG_WITH([capng],
 162   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 163   [],
 164   [with_capng=check])
 165 if test "$with_capng" != "no"; then
 166   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 167                     [with_capng=yes],[with_capng=no])
 168 fi
 169 if test "$with_capng" = "yes"; then
 170   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 171 fi
 172 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 173 AC_SUBST([CAPNG_CFLAGS])
 174 AC_SUBST([CAPNG_LIBS])
 175
 176 dnl Check for sqlite
 177 rk_TEST_PACKAGE(sqlite3,
 178 [#include <sqlite3.h>
 179 #ifndef SQLITE_OPEN_CREATE
 180 #error "old version"
 181 #endif],
 182 [-lsqlite3],,,SQLITE3)
 183
 184 if test "X$with_sqlite3" != Xyes ; then
 185    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 186    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 187 fi
 188 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 189
 190 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 191
 192 AC_ARG_ENABLE(sqlite-cache,
 193         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 194 if test "$enable_sqlite_cache" != no; then
 195     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 196 fi
 197 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 198
 199
 200 dnl check for libintl
 201 rk_TEST_PACKAGE(libintl,
 202 [#include <libintl.h>],
 203 [-lintl],,,LIBINTL)
 204
 205 dnl path where the hdb directory is stored
 206 AC_ARG_WITH([hdbdir],
 207         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 208         [],
 209         [with_hdbdir=/var/heimdal])
 210 DIR_hdbdir="$with_hdbdir"
 211 AC_SUBST([DIR_hdbdir])
 212
 213
 214 AM_CONDITIONAL(KRB5, true)
 215 AM_CONDITIONAL(do_roken_rename, true)
 216
 217 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 218
 219
 220 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 221 AC_SUBST(LIB_kdb)dnl
 222
 223 KRB_CRYPTO
 224
 225 KRB_PTHREADS
 226
 227 AC_ARG_ENABLE(dce,
 228         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 229 if test "$enable_dce" = yes; then
 230     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 231 fi
 232 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 233
 234 ## XXX quite horrible:
 235 if test -f /etc/ibmcxx.cfg; then
 236         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 237         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 238         dpagaix_ldflags=
 239 else
 240         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 241         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 242         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 243 fi
 244 AC_SUBST(dpagaix_cflags)
 245 AC_SUBST(dpagaix_ldadd)
 246 AC_SUBST(dpagaix_ldflags)
 247
 248 AC_ARG_ENABLE([afs-support],
 249         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 250 if test "$enable_afs_support" = no; then
 251         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 252         NO_AFS="1"
 253 fi
 254 AC_SUBST(NO_AFS)dnl
 255 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 256
 257 rk_DB
 258
 259 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 260
 261 rk_ROKEN(lib/roken)
 262 LIBADD_roken="$LIB_roken"
 263 AC_SUBST(LIBADD_roken)dnl
 264 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 265
 266 rk_OTP
 267
 268 rk_LIBDISPATCH
 269
 270 AC_CHECK_OSFC2
 271
 272 AC_ARG_ENABLE(mmap,
 273         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 274 if test "$enable_mmap" = "no"; then
 275         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 276 fi
 277
 278 AC_ARG_ENABLE(afs-string-to-key,
 279         AS_HELP_STRING([--disable-afs-string-to-key],
 280         [disable use of weak AFS string-to-key functions]),
 281         [], [enable_afs_string_to_key=yes])
 282
 283 if test "$enable_afs_string_to_key" = "yes"; then
 284         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 285 fi
 286
 287
 288 rk_CHECK_MAN
 289
 290 rk_TEST_PACKAGE(readline,
 291 [#include <stdio.h>
 292 #if defined(HAVE_READLINE_READLINE_H)
 293 #include <readline/readline.h>
 294 #elif defined(HAVE_READLINE_H)
 295 #include <readline.h>
 296 #endif
 297 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 298
 299 rk_TEST_PACKAGE(libedit,
 300 [#include <stdio.h>
 301 #if defined(HAVE_READLINE_READLINE_H)
 302 #include <readline/readline.h>
 303 #elif defined(HAVE_READLINE_H)
 304 #include <readline.h>
 305 #elif defined(HAVE_EDITLINE_READLINE_H)
 306 #include <editline/readline.h>
 307 #endif
 308 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 309
 310 AC_CONFIG_SUBDIRS([lib/libedit])
 311
 312 KRB_C_BIGENDIAN
 313 AC_C_INLINE
 314
 315 dnl AM_C_PROTOTYPES
 316
 317 dnl Checks for typedefs, structures, and compiler characteristics.
 318 AC_C_CONST
 319 AC_TYPE_OFF_T
 320 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 321 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 322 AC_HAVE_TYPE([long long])
 323 AC_HEADER_TIME
 324 AC_STRUCT_TM
 325
 326 dnl Checks for header files.
 327 AC_HEADER_STDC
 328
 329 AC_CHECK_HEADERS([\
 330         CommonCrypto/CommonDigest.h             \
 331         CommonCrypto/CommonCryptor.h            \
 332         arpa/telnet.h                           \
 333         bind/bitypes.h                          \
 334         bsdsetjmp.h                             \
 335         curses.h                                \
 336         dlfcn.h                                 \
 337         execinfo.h                              \
 338         fnmatch.h                               \
 339         inttypes.h                              \
 340         io.h                                    \
 341         libutil.h                               \
 342         limits.h                                \
 343         maillock.h                              \
 344         netgroup.h                              \
 345         netinet/in6_machtypes.h                 \
 346         pthread.h                               \
 347         pty.h                                   \
 348         sac.h                                   \
 349         sgtty.h                                 \
 350         siad.h                                  \
 351         signal.h                                \
 352         strings.h                               \
 353         stropts.h                               \
 354         sys/bitypes.h                           \
 355         sys/category.h                          \
 356         sys/file.h                              \
 357         sys/filio.h                             \
 358         sys/ioccom.h                            \
 359         sys/mman.h                              \
 360         sys/param.h                             \
 361         sys/pty.h                               \
 362         sys/ptyio.h                             \
 363         sys/select.h                            \
 364         sys/socket.h                            \
 365         sys/str_tty.h                           \
 366         sys/stream.h                            \
 367         sys/stropts.h                           \
 368         sys/syscall.h                           \
 369         sys/termio.h                            \
 370         sys/timeb.h                             \
 371         sys/times.h                             \
 372         sys/types.h                             \
 373         sys/un.h                                \
 374         locale.h                                \
 375         termcap.h                               \
 376         termio.h                                \
 377         termios.h                               \
 378         time.h                                  \
 379         tmpdir.h                                \
 380         udb.h                                   \
 381         util.h                                  \
 382 ])
 383
 384 dnl On Solaris 8 there's a compilation warning for term.h because
 385 dnl it doesn't define `bool'.
 386 AC_CHECK_HEADERS(term.h, , , -)
 387
 388 dnl aix have asl.h (A/IX screen library) that we don't want
 389 AC_CHECK_HEADERS(asl.h, , , [
 390 #include <asl.h>
 391 #ifndef ASL_STRING_EMERG
 392 #error ASL_STRING_EMERG missing
 393 #endif])
 394
 395 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 396 #if HAVE_SYS_SOCKET_H
 397 #include <sys/socket.h>
 398 #endif])
 399
 400 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 401 #if HAVE_SYS_TTY_H
 402 #include <sys/tty.h>
 403 #endif])
 404
 405 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 406 #if HAVE_TERMIOS_H
 407 #include <termios.h>
 408 #endif
 409 #if HAVE_SYS_STREAM_H
 410 #include <sys/stream.h>
 411 #endif])
 412
 413 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 414 #if HAVE_SYS_TYPES_H
 415 #include <sys/types.h>
 416 #endif
 417 #if HAVE_SYS_PARAM_H
 418 #include <sys/param.h>
 419 #endif])
 420
 421 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 422 #include <security/pam_appl.h>
 423 ])
 424
 425 dnl export symbols
 426 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 427 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 428 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 429
 430 dnl Checks for libraries.
 431
 432 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 433 #ifdef HAVE_UTIL_H
 434 #include <util.h>
 435 #endif
 436 ],[0,0,0])
 437 AC_FIND_FUNC_NO_LIBS(logout, util,[
 438 #ifdef HAVE_UTIL_H
 439 #include <util.h>
 440 #endif
 441 ],[0])
 442 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 443 #ifdef HAVE_UTIL_H
 444 #include <util.h>
 445 #endif
 446 ],[0,0,0,0,0])
 447
 448 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 449 #ifdef HAVE_TERMCAP_H
 450 #include <termcap.h>
 451 #endif
 452 #ifdef HAVE_CURSES_H
 453 #include <curses.h>
 454 #endif
 455 ],[0,0])
 456
 457 dnl Checks for library functions.
 458
 459 AC_CHECK_FUNCS([                                \
 460         _getpty                                 \
 461         _scrsize                                \
 462         arc4random                              \
 463         backtrace                               \
 464         fcntl                                   \
 465         fork                                    \
 466         getpeereid                              \
 467         getpeerucred                            \
 468         grantpt                                 \
 469         kill                                    \
 470         mktime                                  \
 471         ptsname                                 \
 472         rand                                    \
 473         revoke                                  \
 474         select                                  \
 475         setitimer                               \
 476         setpcred                                \
 477         setpgid                                 \
 478         setproctitle                            \
 479         setregid                                \
 480         setresgid                               \
 481         setresuid                               \
 482         setreuid                                \
 483         setsid                                  \
 484         setutent                                \
 485         sigaction                               \
 486         strstr                                  \
 487         ttyname                                 \
 488         ttyslot                                 \
 489         umask                                   \
 490         unlockpt                                \
 491         vhangup                                 \
 492         waitpid                                 \
 493         yp_get_default_domain                   \
 494 ])
 495
 496 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 497 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 498         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 499         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 500 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 501         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 502 fi
 503 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 504
 505 AC_FUNC_MMAP
 506
 507 KRB_CAPABILITIES
 508 rk_DLADDR
 509
 510 AC_CHECK_GETPWNAM_R_POSIX
 511
 512 dnl detect doors on solaris
 513 if test "$enable_pthread_support" != no; then
 514    saved_LIBS="$LIBS"
 515    LIBS="$LIBS $PTHREADS_LIBS"
 516    AC_FIND_FUNC_NO_LIBS(door_create, door)
 517    LIBS="$saved_LIBS"
 518 fi
 519
 520 AC_ARG_ENABLE(kcm,
 521         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 522 ,[enable_kcm=yes])
 523
 524 if test "$enable_kcm" = yes ; then
 525    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 526         enable_kcm=no
 527    fi
 528 fi
 529 if test "$enable_kcm" = yes; then
 530        AC_DEFINE(HAVE_KCM, 1,
 531                [Define if you want to use the Kerberos Credentials Manager.])
 532 fi
 533 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 534
 535
 536
 537 dnl Cray stuff
 538 AC_CHECK_FUNCS(getudbnam setlim)
 539
 540 dnl AC_KRB_FUNC_GETCWD_BROKEN
 541
 542 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 543         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 544         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 545 #ifdef HAVE_INTTYPES_H
 546 #include <inttypes.h>
 547 #endif
 548 #ifdef HAVE_SYS_TYPES_H
 549 #include <sys/types.h>
 550 #endif
 551 #ifdef HAVE_SYS_BITYPES_H
 552 #include <sys/bitypes.h>
 553 #endif
 554 #ifdef HAVE_BIND_BITYPES_H
 555 #include <bind/bitypes.h>
 556 #endif
 557 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 558 #include <netinet/in6_machtypes.h>
 559 #endif
 560 ])
 561
 562 rk_FRAMEWORK_SECURITY
 563
 564 KRB_READLINE
 565
 566 rk_TELNET
 567
 568 dnl Some operating systems already have com_err and compile_et
 569 CHECK_COMPILE_ET
 570
 571 rk_AUTH_MODULES([sia afskauthlib])
 572
 573 rk_DESTDIRS
 574
 575 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 576
 577
 578 AH_BOTTOM([#ifdef __APPLE__
 579 #include <AvailabilityMacros.h>
 580 #endif])
 581
 582 AH_BOTTOM([#ifdef ROKEN_RENAME
 583 #include "roken_rename.h"
 584 #endif])
 585
 586 AC_ARG_ENABLE(heimdal-documentation,
 587         AS_HELP_STRING([--disable-heimdal-documentation],
 588                 [if you want disable to heimdal documentation]))
 589 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 590
 591 AC_CONFIG_FILES(Makefile                \
 592         etc/Makefile                    \
 593         include/Makefile                \
 594         include/gssapi/Makefile         \
 595         include/hcrypto/Makefile        \
 596         include/kadm5/Makefile          \
 597         lib/Makefile                    \
 598         lib/base/Makefile                       \
 599         lib/asn1/Makefile               \
 600         lib/com_err/Makefile            \
 601         lib/hcrypto/Makefile            \
 602         lib/hx509/Makefile              \
 603         lib/gssapi/Makefile             \
 604         lib/ntlm/Makefile               \
 605         lib/hdb/Makefile                \
 606         lib/ipc/Makefile                \
 607         lib/kadm5/Makefile              \
 608         lib/kafs/Makefile               \
 609         lib/kdfs/Makefile               \
 610         lib/krb5/Makefile               \
 611         lib/otp/Makefile                \
 612         lib/roken/Makefile              \
 613         lib/sl/Makefile                 \
 614         lib/sqlite/Makefile             \
 615         lib/vers/Makefile               \
 616         lib/wind/Makefile               \
 617         po/Makefile                     \
 618         kuser/Makefile                  \
 619         kpasswd/Makefile                \
 620         kadmin/Makefile                 \
 621         admin/Makefile                  \
 622         kcm/Makefile                    \
 623         kdc/Makefile                    \
 624         appl/Makefile                   \
 625         appl/afsutil/Makefile           \
 626         appl/dbutils/Makefile           \
 627         appl/gssmask/Makefile           \
 628         appl/otp/Makefile               \
 629         appl/su/Makefile                \
 630         appl/test/Makefile              \
 631         appl/kf/Makefile                \
 632         appl/dceutils/Makefile          \
 633         tests/Makefile                  \
 634         tests/bin/Makefile              \
 635         tests/can/Makefile              \
 636         tests/db/Makefile               \
 637         tests/kdc/Makefile              \
 638         tests/ldap/Makefile             \
 639         tests/gss/Makefile              \
 640         tests/java/Makefile             \
 641         tests/plugin/Makefile           \
 642         packages/Makefile               \
 643         packages/mac/Makefile           \
 644         doc/Makefile                    \
 645         tools/Makefile                  \
 646 )
 647
 648 AC_OUTPUT
 649
 650 dnl
 651 dnl This is the release version name-number[beta]
 652 dnl
 653
 654 cat > include/newversion.h.in <<EOF
 655 #ifndef VERSION_HIDDEN
 656 #define VERSION_HIDDEN
 657 #endif
 658 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 659 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 660 EOF
 661
 662 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 663         echo "include/version.h is unchanged"
 664         rm -f include/newversion.h.in
 665 else
 666         echo "creating include/version.h"
 667         User=${USER-${LOGNAME}}
 668         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 669         Date=`date`
 670         mv -f include/newversion.h.in include/version.h.in
 671         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 672 fi