configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 AC_PREFIX_DEFAULT(/usr/heimdal)
  25
  26 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  27 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  28
  29 AC_CANONICAL_HOST
  30 CANONICAL_HOST=$host
  31 AC_SUBST(CANONICAL_HOST)
  32
  33 rk_SYS_LARGEFILE
  34
  35 rk_AIX
  36 rk_IRIX
  37 rk_SUNOS
  38
  39 dnl
  40 dnl this is needed to run the configure tests against glibc
  41 dnl
  42 AC_DEFINE([_GNU_SOURCE], 1,
  43         [Define to enable extensions on glibc-based systems such as Linux.])
  44
  45 AC_OBJEXT
  46 AC_EXEEXT
  47
  48 dnl
  49 dnl this is needed when der-protos.h or der-private.h has to be generated
  50 dnl
  51 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  52    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  53     AC_KRB_PROG_PERL
  54     AC_KRB_PERL_MOD(Getopt::Std)
  55     AC_KRB_PERL_MOD(File::Compare)
  56     AC_KRB_PERL_MOD(JSON)
  57 fi
  58
  59 dnl AC_KRB_PROG_YACC
  60 AC_PROG_YACC
  61 AM_PROG_LEX
  62 AS_IF([$LEX --nounput -V > /dev/null 2>&1 && test $? -eq 0],
  63       [AC_SUBST([FLEXNOUNPUTARGS], ["--nounput"])],
  64       [AC_SUBST([FLEXNOUNPUTARGS], [""])])
  65 dnl AC_PROG_RANLIB
  66 AC_PROG_AWK
  67 AC_KRB_PROG_LN_S
  68
  69 AC_MIPS_ABI
  70 CC="$CC $abi"
  71 libdir="$libdir$abilibdirext"
  72
  73 AC_C___ATTRIBUTE__
  74
  75 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  76 rk_VERSIONSCRIPT
  77
  78 dnl Code coverage
  79 AC_ARG_ENABLE([gcov],
  80         AC_HELP_STRING([--enable-gcov], [enable gcov code coverage tool]))
  81 AM_CONDITIONAL([ENABLE_GCOV], [test "x$enable_gcov" = xyes])
  82
  83
  84 dnl
  85 dnl Helper bits for cross compiling
  86 dnl
  87
  88
  89
  90 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  91
  92 AC_ARG_WITH(cross-tools,
  93         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  94         [if test "$withval" = "yes"; then
  95                 AC_MSG_ERROR([Need path to cross tools])
  96         fi
  97         with_cross_tools="${with_cross_tools}/"
  98         ])
  99
 100 if test "${cross_compiling}" != yes ; then
 101
 102    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
 103    SLC="\$(top_builddir)/lib/sl/slc"
 104
 105    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
 106    SLC_DEP="\$(SLC)"
 107 else
 108    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 109    SLC="${with_cross_tools}slc"
 110
 111    ASN1_COMPILE_DEP=
 112    SLC_DEP=
 113
 114    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 115
 116 fi
 117
 118 AC_SUBST([ASN1_COMPILE])
 119 AC_SUBST([ASN1_COMPILE_DEP])
 120 AC_SUBST([SLC])
 121 AC_SUBST([SLC_DEP])
 122
 123 dnl ---
 124
 125 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 126
 127 rk_TEST_PACKAGE(openldap,
 128 [#include <lber.h>
 129 #include <ldap.h>],
 130 [-lldap -llber],,,OPENLDAP)
 131
 132 AC_ARG_ENABLE(hdb-openldap-module,
 133         AS_HELP_STRING([--enable-hdb-openldap-module],
 134                 [if you want support to build openldap hdb as shared object]))
 135 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 136     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 137 fi
 138 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 139
 140 dnl
 141 dnl Optional modules, pk-init, digest, kx509
 142 dnl
 143
 144 AC_ARG_ENABLE(pk-init,
 145         AS_HELP_STRING([--disable-pk-init],
 146                 [if you want disable to PK-INIT support]))
 147 if test "$enable_pk_init" != no ;then
 148         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 149 fi
 150 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 151
 152 AC_ARG_ENABLE(digest,
 153         AS_HELP_STRING([--disable-digest],
 154                 [if you want disable to DIGEST support]))
 155 if test "$enable_digest" != no ;then
 156         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 157 fi
 158
 159 AC_ARG_ENABLE(kx509,
 160         AS_HELP_STRING([--disable-kx509],
 161                 [if you want disable to kx509 support]))
 162 if test "$enable_kx509" != no ;then
 163         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 164 fi
 165
 166 dnl Need to test if pkg-config exists
 167 PKG_PROG_PKG_CONFIG
 168
 169 dnl libcap-ng
 170 AC_ARG_WITH([capng],
 171   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 172   [],
 173   [with_capng=check])
 174 if test "$with_capng" != "no"; then
 175   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 176                     [with_capng=yes],[with_capng=no])
 177 fi
 178 if test "$with_capng" = "yes"; then
 179   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 180 fi
 181 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 182 AC_SUBST([CAPNG_CFLAGS])
 183 AC_SUBST([CAPNG_LIBS])
 184
 185 dnl Check for sqlite
 186 rk_TEST_PACKAGE(sqlite3,
 187 [#include <sqlite3.h>
 188 #ifndef SQLITE_OPEN_CREATE
 189 #error "old version"
 190 #endif],
 191 [-lsqlite3],,,SQLITE3)
 192
 193 if test "X$with_sqlite3" != Xyes ; then
 194    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 195    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 196 fi
 197 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 198
 199 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 200
 201 AC_ARG_ENABLE(sqlite-cache,
 202         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 203 if test "$enable_sqlite_cache" != no; then
 204     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 205 fi
 206 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 207
 208
 209 dnl check for libintl
 210 rk_TEST_PACKAGE(libintl,
 211 [#include <libintl.h>],
 212 [-lintl],,,LIBINTL)
 213
 214 dnl path where the hdb directory is stored
 215 AC_ARG_WITH([hdbdir],
 216         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 217         [],
 218         [with_hdbdir=/var/heimdal])
 219 DIR_hdbdir="$with_hdbdir"
 220 AC_SUBST([DIR_hdbdir])
 221
 222
 223 AM_CONDITIONAL(KRB5, true)
 224 AM_CONDITIONAL(do_roken_rename, true)
 225
 226 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 227
 228
 229 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 230 AC_SUBST(LIB_kdb)dnl
 231
 232 KRB_CRYPTO
 233
 234 KRB_PTHREADS
 235
 236 AC_ARG_ENABLE(dce,
 237         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 238 if test "$enable_dce" = yes; then
 239     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 240 fi
 241 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 242
 243 ## XXX quite horrible:
 244 if test -f /etc/ibmcxx.cfg; then
 245         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 246         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 247         dpagaix_ldflags=
 248 else
 249         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 250         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 251         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 252 fi
 253 AC_SUBST(dpagaix_cflags)
 254 AC_SUBST(dpagaix_ldadd)
 255 AC_SUBST(dpagaix_ldflags)
 256
 257 AC_ARG_ENABLE([afs-support],
 258         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 259 if test "$enable_afs_support" = no; then
 260         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 261         NO_AFS="1"
 262 fi
 263 AC_SUBST(NO_AFS)dnl
 264 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 265
 266 rk_DB
 267
 268 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 269
 270 rk_ROKEN(lib/roken)
 271 LIBADD_roken="$LIB_roken"
 272 AC_SUBST(LIBADD_roken)dnl
 273 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 274
 275 rk_OTP
 276
 277 rk_LIBDISPATCH
 278
 279 AC_CHECK_OSFC2
 280
 281 AC_ARG_ENABLE(mmap,
 282         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 283 if test "$enable_mmap" = "no"; then
 284         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 285 fi
 286
 287 AC_ARG_ENABLE(afs-string-to-key,
 288         AS_HELP_STRING([--disable-afs-string-to-key],
 289         [disable use of weak AFS string-to-key functions]),
 290         [], [enable_afs_string_to_key=yes])
 291
 292 if test "$enable_afs_string_to_key" = "yes"; then
 293         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 294         ENABLE_AFS_STRING_TO_KEY=1
 295 fi
 296 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 297
 298
 299 rk_CHECK_MAN
 300
 301 rk_TEST_PACKAGE(readline,
 302 [#include <stdio.h>
 303 #if defined(HAVE_READLINE_READLINE_H)
 304 #include <readline/readline.h>
 305 #elif defined(HAVE_READLINE_H)
 306 #include <readline.h>
 307 #endif
 308 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 309
 310 rk_TEST_PACKAGE(libedit,
 311 [#include <stdio.h>
 312 #if defined(HAVE_READLINE_READLINE_H)
 313 #include <readline/readline.h>
 314 #elif defined(HAVE_READLINE_H)
 315 #include <readline.h>
 316 #elif defined(HAVE_EDITLINE_READLINE_H)
 317 #include <editline/readline.h>
 318 #endif
 319 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 320
 321 AC_CONFIG_SUBDIRS([lib/libedit])
 322
 323 KRB_C_BIGENDIAN
 324 AC_C_INLINE
 325
 326 dnl AM_C_PROTOTYPES
 327
 328 dnl Checks for typedefs, structures, and compiler characteristics.
 329 AC_C_CONST
 330 AC_TYPE_OFF_T
 331 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 332 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 333 AC_HAVE_TYPE([long long])
 334 AC_HEADER_TIME
 335 AC_STRUCT_TM
 336
 337 dnl Checks for header files.
 338 AC_HEADER_STDC
 339
 340 AC_CHECK_HEADERS([\
 341         CommonCrypto/CommonDigest.h             \
 342         CommonCrypto/CommonCryptor.h            \
 343         arpa/telnet.h                           \
 344         bind/bitypes.h                          \
 345         bsdsetjmp.h                             \
 346         curses.h                                \
 347         dlfcn.h                                 \
 348         execinfo.h                              \
 349         fnmatch.h                               \
 350         inttypes.h                              \
 351         io.h                                    \
 352         keyutils.h                              \
 353         libutil.h                               \
 354         limits.h                                \
 355         maillock.h                              \
 356         netgroup.h                              \
 357         netinet/in6_machtypes.h                 \
 358         netinet/tcp.h                           \
 359         pthread.h                               \
 360         pty.h                                   \
 361         sac.h                                   \
 362         sgtty.h                                 \
 363         siad.h                                  \
 364         signal.h                                \
 365         strings.h                               \
 366         stropts.h                               \
 367         sys/bitypes.h                           \
 368         sys/category.h                          \
 369         sys/file.h                              \
 370         sys/filio.h                             \
 371         sys/ioccom.h                            \
 372         sys/mman.h                              \
 373         sys/param.h                             \
 374         sys/pty.h                               \
 375         sys/ptyio.h                             \
 376         sys/select.h                            \
 377         sys/socket.h                            \
 378         sys/str_tty.h                           \
 379         sys/stream.h                            \
 380         sys/stropts.h                           \
 381         sys/syscall.h                           \
 382         sys/termio.h                            \
 383         sys/timeb.h                             \
 384         sys/times.h                             \
 385         sys/types.h                             \
 386         sys/un.h                                \
 387         locale.h                                \
 388         termcap.h                               \
 389         termio.h                                \
 390         termios.h                               \
 391         time.h                                  \
 392         tmpdir.h                                \
 393         udb.h                                   \
 394         util.h                                  \
 395 ])
 396
 397 dnl On Solaris 8 there's a compilation warning for term.h because
 398 dnl it doesn't define `bool'.
 399 AC_CHECK_HEADERS(term.h, , , -)
 400
 401 dnl aix have asl.h (A/IX screen library) that we don't want
 402 AC_CHECK_HEADERS(asl.h, , , [
 403 #include <asl.h>
 404 #ifndef ASL_STRING_EMERG
 405 #error ASL_STRING_EMERG missing
 406 #endif])
 407
 408 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 409 #if HAVE_SYS_SOCKET_H
 410 #include <sys/socket.h>
 411 #endif])
 412
 413 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 414 #if HAVE_SYS_TTY_H
 415 #include <sys/tty.h>
 416 #endif])
 417
 418 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 419 #if HAVE_TERMIOS_H
 420 #include <termios.h>
 421 #endif
 422 #if HAVE_SYS_STREAM_H
 423 #include <sys/stream.h>
 424 #endif])
 425
 426 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 427 #if HAVE_SYS_TYPES_H
 428 #include <sys/types.h>
 429 #endif
 430 #if HAVE_SYS_PARAM_H
 431 #include <sys/param.h>
 432 #endif])
 433
 434 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 435 #include <security/pam_appl.h>
 436 ])
 437
 438 dnl export symbols
 439 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 440 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 441 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 442
 443 dnl Checks for libraries.
 444
 445 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 446 #ifdef HAVE_UTIL_H
 447 #include <util.h>
 448 #endif
 449 ],[0,0,0])
 450 AC_FIND_FUNC_NO_LIBS(logout, util,[
 451 #ifdef HAVE_UTIL_H
 452 #include <util.h>
 453 #endif
 454 ],[0])
 455 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 456 #ifdef HAVE_UTIL_H
 457 #include <util.h>
 458 #endif
 459 ],[0,0,0,0,0])
 460
 461 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses tinfo,[
 462 #ifdef HAVE_TERMCAP_H
 463 #include <termcap.h>
 464 #endif
 465 #ifdef HAVE_CURSES_H
 466 #include <curses.h>
 467 #endif
 468 ],[0,0])
 469
 470 dnl Checks for library functions.
 471
 472 AC_CHECK_FUNCS([                                \
 473         _getpty                                 \
 474         _scrsize                                \
 475         arc4random                              \
 476         backtrace                               \
 477         fcntl                                   \
 478         fork                                    \
 479         fseeko                                  \
 480         ftello                                  \
 481         getpeereid                              \
 482         getpeerucred                            \
 483         getresgid                               \
 484         getresuid                               \
 485         grantpt                                 \
 486         kill                                    \
 487         mktime                                  \
 488         ptsname                                 \
 489         rand                                    \
 490         revoke                                  \
 491         select                                  \
 492         setitimer                               \
 493         setpcred                                \
 494         setpgid                                 \
 495         setproctitle                            \
 496         setregid                                \
 497         setresgid                               \
 498         setresuid                               \
 499         setreuid                                \
 500         setsid                                  \
 501         setutent                                \
 502         sigaction                               \
 503         strstr                                  \
 504         ttyname                                 \
 505         ttyslot                                 \
 506         umask                                   \
 507         unlockpt                                \
 508         vhangup                                 \
 509         waitpid                                 \
 510         yp_get_default_domain                   \
 511 ])
 512
 513 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 514 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 515         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 516         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 517 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 518         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 519 fi
 520 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 521
 522 AC_FUNC_MMAP
 523
 524 KRB_CAPABILITIES
 525 rk_DLADDR
 526
 527 AC_CHECK_GETPWNAM_R_POSIX
 528 AC_CHECK_GETPWUID_R_POSIX
 529
 530 dnl detect doors on solaris
 531 if test "$enable_pthread_support" != no; then
 532    saved_LIBS="$LIBS"
 533    LIBS="$LIBS $PTHREADS_LIBS"
 534    AC_FIND_FUNC_NO_LIBS(door_create, door)
 535    LIBS="$saved_LIBS"
 536 fi
 537
 538 AC_ARG_ENABLE(kcm,
 539         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 540 ,[enable_kcm=yes])
 541
 542 if test "$enable_kcm" = yes ; then
 543    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 544         enable_kcm=no
 545    fi
 546 fi
 547 if test "$enable_kcm" = yes; then
 548        AC_DEFINE(HAVE_KCM, 1,
 549                [Define if you want to use the Kerberos Credentials Manager.])
 550 fi
 551 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 552
 553 dnl detect keyring on Linux
 554 if test "$ac_cv_header_keyutils_h" = yes; then
 555     AC_CHECK_SIZEOF([key_serial_t],,[
 556         #ifdef HAVE_INTTYPES_H
 557         #include <inttypes.h>
 558         #endif
 559         #ifdef HAVE_SYS_TYPES_H
 560         #include <sys/types.h>
 561         #endif
 562         #include <keyutils.h>
 563     ])
 564 fi
 565
 566 AC_FIND_FUNC_NO_LIBS(add_key, keyutils)
 567 if test -n "$LIB_add_key"; then
 568     saved_LIBS="$LIBS"
 569     LIBS="$LIBS $LIB_add_key"
 570     AC_CHECK_FUNCS(keyctl_get_persistent)
 571     LIBS="$saved_LIBS"
 572 fi
 573
 574 AC_CHECK_SIZEOF([time_t])
 575
 576 dnl Cray stuff
 577 AC_CHECK_FUNCS(getudbnam setlim)
 578
 579 dnl AC_KRB_FUNC_GETCWD_BROKEN
 580
 581 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 582         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 583         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 584 #ifdef HAVE_INTTYPES_H
 585 #include <inttypes.h>
 586 #endif
 587 #ifdef HAVE_SYS_TYPES_H
 588 #include <sys/types.h>
 589 #endif
 590 #ifdef HAVE_SYS_BITYPES_H
 591 #include <sys/bitypes.h>
 592 #endif
 593 #ifdef HAVE_BIND_BITYPES_H
 594 #include <bind/bitypes.h>
 595 #endif
 596 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 597 #include <netinet/in6_machtypes.h>
 598 #endif
 599 ])
 600
 601 rk_FRAMEWORK_SECURITY
 602 rk_FRAMEWORK_COREFOUNDATION
 603
 604 KRB_READLINE
 605
 606 rk_TELNET
 607
 608 dnl Some operating systems already have com_err and compile_et
 609 CHECK_COMPILE_ET
 610
 611 rk_AUTH_MODULES([sia afskauthlib])
 612
 613 rk_DESTDIRS
 614
 615 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 616
 617
 618 AH_BOTTOM([#ifdef __APPLE__
 619 #include <AvailabilityMacros.h>
 620 #endif])
 621
 622 AH_BOTTOM([#ifdef ROKEN_RENAME
 623 #include "roken_rename.h"
 624 #endif])
 625
 626 AC_ARG_ENABLE(heimdal-documentation,
 627         AS_HELP_STRING([--disable-heimdal-documentation],
 628                 [if you want disable to heimdal documentation]))
 629 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 630
 631 AC_CONFIG_FILES(Makefile                \
 632         etc/Makefile                    \
 633         include/Makefile                \
 634         include/gssapi/Makefile         \
 635         include/hcrypto/Makefile        \
 636         include/kadm5/Makefile          \
 637         lib/Makefile                    \
 638         lib/base/Makefile                       \
 639         lib/asn1/Makefile               \
 640         lib/com_err/Makefile            \
 641         lib/hcrypto/Makefile            \
 642         lib/hx509/Makefile              \
 643         lib/gssapi/Makefile             \
 644         lib/ntlm/Makefile               \
 645         lib/hdb/Makefile                \
 646         lib/ipc/Makefile                \
 647         lib/kadm5/Makefile              \
 648         lib/kafs/Makefile               \
 649         lib/kdfs/Makefile               \
 650         lib/krb5/Makefile               \
 651         lib/otp/Makefile                \
 652         lib/roken/Makefile              \
 653         lib/sl/Makefile                 \
 654         lib/sqlite/Makefile             \
 655         lib/vers/Makefile               \
 656         lib/wind/Makefile               \
 657         po/Makefile                     \
 658         kuser/Makefile                  \
 659         kpasswd/Makefile                \
 660         kadmin/Makefile                 \
 661         admin/Makefile                  \
 662         kcm/Makefile                    \
 663         kdc/Makefile                    \
 664         appl/Makefile                   \
 665         appl/afsutil/Makefile           \
 666         appl/dbutils/Makefile           \
 667         appl/gssmask/Makefile           \
 668         appl/otp/Makefile               \
 669         appl/test/Makefile              \
 670         appl/kf/Makefile                \
 671         appl/dceutils/Makefile          \
 672         tests/Makefile                  \
 673         tests/bin/Makefile              \
 674         tests/can/Makefile              \
 675         tests/db/Makefile               \
 676         tests/kdc/Makefile              \
 677         tests/ldap/Makefile             \
 678         tests/gss/Makefile              \
 679         tests/java/Makefile             \
 680         tests/plugin/Makefile           \
 681         packages/Makefile               \
 682         packages/mac/Makefile           \
 683         doc/Makefile                    \
 684         tools/Makefile                  \
 685 )
 686
 687 AC_OUTPUT
 688
 689 dnl
 690 dnl This is the release version name-number[beta]
 691 dnl
 692
 693 if test -d "$srcdir/.git"; then
 694     cat > include/newversion.h.in <<EOF
 695 #ifndef VERSION_HIDDEN
 696 #define VERSION_HIDDEN
 697 #endif
 698 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ @BRANCH@ @TAG@ ($host) @COMMIT@ @DATE@ \$";
 699 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 700 EOF
 701 else
 702     cat > include/newversion.h.in <<EOF
 703 #ifndef VERSION_HIDDEN
 704 #define VERSION_HIDDEN
 705 #endif
 706 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 707 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 708 EOF
 709 fi
 710
 711 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 712         echo "include/version.h is unchanged"
 713         rm -f include/newversion.h.in
 714 else
 715         echo "creating include/version.h"
 716         if test -n "$SOURCE_DATE_EPOCH"; then
 717             Date=`
 718                   # BSD, OS X
 719                   date -u -r "$SOURCE_DATE_EPOCH" "+%Y-%m-%dT%H:%M:%SZ" 2>/dev/null ||
 720                   # Linux
 721                   date -u -d "@${SOURCE_DATE_EPOCH}" 2>/dev/null ||
 722                   # Illumos -- sorry, no -r/-d here
 723                   date -u ||
 724                   date`
 725         else
 726             Date=`date -u "+%Y-%m-%dT%H:%M:%SZ"`
 727         fi
 728         if test -n "$SOURCE_HOST"; then
 729             Host=$SOURCE_HOST
 730         else
 731             Host=`uname -n`
 732         fi
 733         if test -n "$SOURCE_USER"; then
 734             User=$SOURCE_USER
 735         else
 736             User=${USER:-${LOGNAME:-`id -nu`}}
 737         fi
 738         if test -d "$srcdir/.git"; then
 739             GitCommit=`cd $srcdir && git rev-parse HEAD`
 740             GitBranch=`cd $srcdir && git rev-parse --abbrev-ref HEAD`
 741             if test "x$GitBranch" = master; then
 742                 GitDesc=`cd $srcdir && git describe --all --dirty`
 743             else
 744                 GitDesc=`cd $srcdir && \
 745                          git describe --tags --match 'heimdal-*' --dirty`
 746             fi
 747         else
 748             GitCommit='<commit-unknown>'
 749             GitBranch='<branch-unknown>'
 750             GitDesc='<tag-unknown>'
 751         fi
 752         mv -f include/newversion.h.in include/version.h.in
 753         sed -e "s/@HOST@/$Host/" \
 754             -e "s;@USER@;$User;" \
 755             -e "s;@DATE@;$Date;" \
 756             -e "s;@BRANCH@;$GitBranch;" \
 757             -e "s;@TAG@;$GitDesc;" \
 758             -e "s;@COMMIT@;$GitCommit;" \
 759             include/version.h.in > include/version.h
 760 fi