configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_INIT(lib/krb5/send_to_kdc.c)
   4 AM_CONFIG_HEADER(include/config.h)
   5
   6 AM_INIT_AUTOMAKE(heimdal,0.0k)
   7
   8 AC_PREFIX_DEFAULT(/usr/heimdal)
   9
  10 AC_CANONICAL_HOST
  11 CANONICAL_HOST=$host
  12 AC_SUBST(CANONICAL_HOST)
  13
  14 case "$host" in
  15 *-*-sunos4*)
  16         AC_DEFINE(SunOS, 4)
  17         ;;
  18 esac
  19
  20 dnl Checks for programs.
  21 AC_PROG_CC
  22
  23 dnl AC_KRB_PROG_YACC
  24 AC_PROG_YACC
  25 AC_PROG_LEX
  26 AC_PROG_RANLIB
  27 AC_PROG_AWK
  28 AC_KRB_PROG_LN_S
  29
  30 if test "$GCC" = "yes"; then
  31   WFLAGS="-Wall -Wno-unused -Wmissing-prototypes"
  32 fi
  33 AC_SUBST(WFLAGS)
  34 CFLAGS="-g"
  35
  36 berkeley_db=db
  37 AC_ARG_WITH(berkeley-db,
  38 [  --without-berkeley-db   if you don't want berkeley db],[
  39 if test "$withval" = no; then
  40         berkeley_db=""
  41 fi
  42 ])
  43
  44 AC_TEST_PACKAGE(krb4,krb.h,libkrb.a,-lkrb)
  45
  46 if test "$with_krb4"; then
  47         AC_DEFINE(KRB4, 1)
  48         LIB_krb4="$KRB4LIB -ldes"
  49         INCLUDE_krb4="$KRB4INCLUDE"
  50         EXTRA_LIB45=lib45.a
  51         AC_SUBST(EXTRA_LIB45)
  52 fi
  53 AM_CONDITIONAL(KRB4, test "$with_krb4")dnl
  54 AC_SUBST(LIB_krb4)dnl
  55 AC_SUBST(INCLUDE_krb4)dnl
  56 AM_CONDITIONAL(AIX, test `uname` = AIX)dnl
  57
  58 AC_ARG_ENABLE(kaserver,
  59 [  --enable-kaserver      if you want the KDC to try to emulate a kaserver],
  60 [
  61 if test "$enableval" != no; then
  62         AC_DEFINE(KASERVER, 1)
  63         if test "x$with_krb4" = "x"; then
  64                 AC_MSG_ERROR(kaserver requires krb4)
  65                 exit 1
  66         fi
  67 fi
  68 ])
  69
  70 otp=yes
  71 AC_ARG_ENABLE(otp,
  72 [  --disable-otp          if you don't want OTP support],
  73 [
  74 if test "$enableval" = "no"; then
  75         otp=no
  76 fi
  77 ])
  78 if test "$otp" = "yes"; then
  79         AC_DEFINE(OTP)
  80         LIB_otp='-L$(top_builddir)/lib/otp -lotp'
  81         OTP_dir=otp
  82 fi
  83 AC_SUBST(LIB_otp)
  84 AC_SUBST(OTP_dir)
  85
  86 AC_PATH_PROG(NROFF, nroff)
  87 AC_PATH_PROG(GROFF, groff)
  88 AC_CACHE_CHECK(how to format man pages,ac_cv_sys_man_format,
  89 [cat > conftest.1 << END
  90 .Dd January 1, 1970
  91 .Dt CONFTEST 1
  92 .Sh NAME
  93 .Nm conftest
  94 .Nd
  95 foobar
  96 END
  97
  98 if test "$NROFF" ; then
  99         for i in "-mdoc" "-mandoc"; do
 100                 if "$NROFF" $i conftest.1 2> /dev/null | \
 101                         grep Jan > /dev/null 2>&1 ; then
 102                         ac_cv_sys_man_format="$NROFF $i"
 103                         break
 104                 fi
 105         done
 106 fi
 107 if test "$ac_cv_sys_man_format" = "" -a "$GROFF" ; then
 108         for i in "-mdoc" "-mandoc"; do
 109                 if "$GROFF" -Tascii $i conftest.1 2> /dev/null | \
 110                         grep Jan > /dev/null 2>&1 ; then
 111                         ac_cv_sys_man_format="$GROFF -Tascii $i"
 112                         break
 113                 fi
 114         done
 115 fi
 116 if test "$ac_cv_sys_man_format"; then
 117         ac_cv_sys_man_format="$ac_cv_sys_man_format \$< > \$@"
 118 fi
 119 ])
 120 if test "$ac_cv_sys_man_format"; then
 121         CATMAN="$ac_cv_sys_man_format"
 122         AC_SUBST(CATMAN)
 123 fi
 124 AM_CONDITIONAL(CATMAN, test "$CATMAN")
 125 AC_CACHE_CHECK(extension of pre-formatted manual pages,ac_cv_sys_catman_ext,
 126 if grep _suffix /etc/man.conf > /dev/null 2>&1; then
 127         ac_cv_sys_catman_ext=0
 128 else
 129         ac_cv_sys_catman_ext=number
 130 fi
 131 )
 132 if test "$ac_cv_sys_catman_ext" = number; then
 133         CATMANEXT='$$section'
 134 else
 135         CATMANEXT=0
 136 fi
 137 AC_SUBST(CATMANEXT)
 138
 139 AC_TEST_PACKAGE(readline,readline.h,libreadline.a,-lreadline)
 140
 141 AC_C_BIGENDIAN
 142 AC_C_INLINE
 143
 144 AC_PATH_XTRA
 145
 146 dnl AM_C_PROTOTYPES
 147
 148 dnl Checks for typedefs, structures, and compiler characteristics.
 149 AC_C_CONST
 150 AC_TYPE_OFF_T
 151 AC_TYPE_SIZE_T
 152 AC_TYPE_MODE_T
 153 AC_HEADER_TIME
 154 AC_STRUCT_TM
 155 AC_DECL_YYTEXT
 156
 157 dnl Checks for header files.
 158 AC_HEADER_STDC
 159
 160 AC_CHECK_HEADERS(arpa/inet.h arpa/telnet.h bsdsetjmp.h crypt.h)
 161 AC_CHECK_HEADERS(curses.h db.h dbm.h dirent.h err.h errno.h)
 162 AC_CHECK_HEADERS(fcntl.h fnmatch.h grp.h inttypes.h limits.h ndbm.h)
 163 AC_CHECK_HEADERS(net/if.h netdb.h)
 164 AC_CHECK_HEADERS(netinet/in.h netinet/in6.h netinet/in6_var.h)
 165 AC_CHECK_HEADERS(netinet/in6_machtypes.h netinet/in_systm.h)
 166 AC_CHECK_HEADERS(netinet/ip.h netinet/tcp.h netinfo/ni.h netinet6/in6.h paths.h pty.h pwd.h)
 167 AC_CHECK_HEADERS(rpcsvc/dbm.h sac.h sgtty.h shadow.h signal.h stropts.h)
 168 AC_CHECK_HEADERS(sys/bitypes.h sys/file.h sys/filio.h sys/ioctl.h)
 169 AC_CHECK_HEADERS(sys/param.h sys/proc.h sys/pty.h sys/ptyio.h)
 170 AC_CHECK_HEADERS(sys/ptyvar.h sys/resource.h sys/select.h)
 171 AC_CHECK_HEADERS(sys/socket.h sys/sockio.h sys/stat.h sys/stream.h)
 172 AC_CHECK_HEADERS(sys/stropts.h sys/sysctl.h sys/time.h sys/timeb.h)
 173 AC_CHECK_HEADERS(sys/times.h sys/tty.h sys/types.h sys/uio.h)
 174 AC_CHECK_HEADERS(sys/utsname.h sys/wait.h syslog.h termio.h)
 175 AC_CHECK_HEADERS(termios.h tmpdir.h unistd.h util.h utmp.h utmpx.h)
 176
 177 if test "$ac_cv_header_err_h" = no; then
 178         EXTRA_HDRS="$EXTRA_HDRS err.h"
 179         AC_SUBST(EXTRA_HDRS)
 180 fi
 181 if test "$ac_cv_header_fnmatch_h" = no; then
 182         EXTRA_HDRS="$EXTRA_HDRS fnmatch.h"
 183         AC_SUBST(EXTRA_HDRS)
 184 fi
 185
 186 dnl Checks for libraries.
 187
 188 AC_FIND_FUNC(socket, socket)
 189 AC_FIND_FUNC(gethostbyname, nsl)
 190 AC_FIND_FUNC(dbopen, $berkeley_db)
 191 AC_FIND_FUNC(dbm_firstkey, $berkeley_db gdbm ndbm)
 192 AC_FIND_FUNC(syslog, syslog)
 193
 194 AC_FIND_FUNC(logwtmp, util)
 195 AC_FIND_FUNC_NO_LIBS(tgetent, termcap)
 196 AC_FIND_FUNC(gethostbyname2, inet6 ip6)
 197 AC_FIND_FUNC(inet_ntop, inet6 ip6)
 198 AC_CHECK_FUNCS(inet_pton)
 199
 200 dnl Checks for library functions.
 201
 202 AC_BROKEN_SNPRINTF
 203 AC_BROKEN_VSNPRINTF
 204
 205 AC_CHECK_FUNCS(_getpty asnprintf asprintf fcntl gethostname)
 206 AC_CHECK_FUNCS(getmsg grantpt logwtmp mktime ptsname rand random)
 207 AC_CHECK_FUNCS(revoke select setitimer setlogin setpcred setpgid)
 208 AC_CHECK_FUNCS(setsid setsockopt sigaction strstr timegm ttyname umask)
 209 AC_CHECK_FUNCS(unlockpt vasnprintf vasprintf vhangup)
 210
 211 AC_TYPE_SIGNAL
 212 if test "$ac_cv_type_signal" = "void" ; then
 213         AC_DEFINE(VOID_RETSIGTYPE, 1)
 214 fi
 215 AC_SUBST(VOID_RETSIGTYPE)
 216
 217 AC_FIND_IF_NOT_BROKEN(hstrerror, resolv,
 218 [#ifdef HAVE_NETDB_H
 219 #include <netdb.h>
 220 #endif],
 221 17)
 222 if test "$ac_cv_func_hstrerror" = yes; then
 223 AC_NEED_PROTO([
 224 #ifdef HAVE_NETDB_H
 225 #include <netdb.h>
 226 #endif],
 227 hstrerror)
 228 fi
 229
 230 AC_BROKEN(chown daemon err errx fchown flock fnmatch getcwd)
 231 AC_BROKEN(getdtablesize getopt getusershell inet_aton initgroups iruserok)
 232 AC_BROKEN(lstat memmove mkstemp putenv rcmd readv setegid setenv)
 233 AC_BROKEN(seteuid setenv seteuid strcasecmp strdup strerror strftime)
 234 AC_BROKEN(strlwr strnlen strsep strtok_r strupr unsetenv)
 235 AC_BROKEN(verr verrx vsyslog vwarn vwarnx warn warnx writev)
 236
 237 AC_CACHE_CHECK(if realloc if broken, ac_cv_func_realloc_broken, [
 238 ac_cv_func_realloc_broken=no
 239 AC_TRY_RUN([
 240 #include <stddef.h>
 241 #include <stdlib.h>
 242
 243 int main()
 244 {
 245         return realloc(NULL, 17) == NULL;
 246 }
 247 ],:, ac_cv_func_realloc_broken=yes, :)
 248 ])
 249 if test "$ac_cv_func_realloc_broken" = yes ; then
 250         AC_DEFINE(BROKEN_REALLOC)
 251 fi
 252
 253 dnl AC_KRB_FUNC_GETCWD_BROKEN
 254
 255 dnl
 256 dnl Checks for prototypes and declarations
 257 dnl
 258
 259 AC_PROTO_COMPAT([
 260 #ifdef HAVE_SYS_TYPES_H
 261 #include <sys/types.h>
 262 #endif
 263 #ifdef HAVE_SYS_SOCKET_H
 264 #include <sys/socket.h>
 265 #endif
 266 #ifdef HAVE_NETINET_IN_H
 267 #include <netinet/in.h>
 268 #endif
 269 #ifdef HAVE_ARPA_INET_H
 270 #include <arpa/inet.h>
 271 #endif
 272 #ifdef HAVE_NETDB_H
 273 #include <netdb.h>
 274 #endif
 275 ],
 276 gethostbyname, struct hostent *gethostbyname(const char *))
 277
 278 AC_PROTO_COMPAT([
 279 #ifdef HAVE_SYS_TYPES_H
 280 #include <sys/types.h>
 281 #endif
 282 #ifdef HAVE_SYS_SOCKET_H
 283 #include <sys/socket.h>
 284 #endif
 285 #ifdef HAVE_NETINET_IN_H
 286 #include <netinet/in.h>
 287 #endif
 288 #ifdef HAVE_ARPA_INET_H
 289 #include <arpa/inet.h>
 290 #endif
 291 #ifdef HAVE_NETDB_H
 292 #include <netdb.h>
 293 #endif
 294 ],
 295 gethostbyaddr, struct hostent *gethostbyaddr(const void *, size_t, int))
 296
 297 AC_PROTO_COMPAT([
 298 #ifdef HAVE_SYS_TYPES_H
 299 #include <sys/types.h>
 300 #endif
 301 #ifdef HAVE_SYS_SOCKET_H
 302 #include <sys/socket.h>
 303 #endif
 304 #ifdef HAVE_NETINET_IN_H
 305 #include <netinet/in.h>
 306 #endif
 307 #ifdef HAVE_ARPA_INET_H
 308 #include <arpa/inet.h>
 309 #endif
 310 #ifdef HAVE_NETDB_H
 311 #include <netdb.h>
 312 #endif
 313 ],
 314 getservbyname, struct servent *getservbyname(const char *, const char *))
 315
 316 AC_PROTO_COMPAT([
 317 #ifdef HAVE_SYSLOG_H
 318 #include <syslog.h>
 319 #endif
 320 ],
 321 openlog, void openlog(const char *, int, int))
 322
 323 AC_NEED_PROTO([
 324 #ifdef HAVE_CRYPT_H
 325 #include <crypt.h>
 326 #endif
 327 #ifdef HAVE_UNISTD_H
 328 #include <unistd.h>
 329 #endif
 330 ],
 331 crypt)
 332
 333 AC_NEED_PROTO([
 334 #include <string.h>
 335 ],
 336 strtok_r)
 337
 338 AC_CHECK_VAR([#ifdef HAVE_SYS_TYPES_H
 339 #include <sys/types.h>
 340 #endif
 341 #ifdef HAVE_NETDB_H
 342 #include <netdb.h>
 343 #endif],
 344 h_errno)
 345
 346 AC_CHECK_VAR([#ifdef HAVE_NETDB_H
 347 #include <netdb.h>
 348 #endif],
 349 h_errlist)
 350
 351 AC_CHECK_VAR([#ifdef HAVE_NETDB_H
 352 #include <netdb.h>
 353 #endif],
 354 h_nerr)
 355
 356 AC_CHECK_VAR([#ifdef HAVE_ERR_H
 357 #include <err.h>
 358 #endif],[__progname])
 359
 360 AC_CHECK_DECLARATION([#include <stdlib.h>], optarg)
 361 AC_CHECK_DECLARATION([#include <stdlib.h>], optind)
 362 AC_CHECK_DECLARATION([#include <stdlib.h>], opterr)
 363 AC_CHECK_DECLARATION([#include <stdlib.h>], optopt)
 364
 365 dnl
 366 dnl Check for fields in struct utmp
 367 dnl
 368 AC_EGREP_HEADER(ut_user, utmp.h, AC_DEFINE(HAVE_UT_USER))
 369 AC_EGREP_HEADER(ut_host, utmp.h, AC_DEFINE(HAVE_UT_HOST))
 370 AC_EGREP_HEADER(ut_addr, utmp.h, AC_DEFINE(HAVE_UT_ADDR))
 371 AC_EGREP_HEADER(ut_type, utmp.h, AC_DEFINE(HAVE_UT_TYPE))
 372 AC_EGREP_HEADER(ut_pid, utmp.h, AC_DEFINE(HAVE_UT_PID))
 373 AC_EGREP_HEADER(ut_id, utmp.h, AC_DEFINE(HAVE_UT_ID))
 374 AC_EGREP_HEADER(ut_syslen, utmpx.h, AC_DEFINE(HAVE_UT_SYSLEN))
 375
 376 AC_KRB_IPV6
 377
 378 dnl
 379 dnl Check for struct winsize
 380 dnl
 381
 382 AC_KRB_STRUCT_WINSIZE
 383
 384 dnl
 385 dnl Check for sa_len in struct sockaddr
 386 dnl
 387
 388 AC_KRB_STRUCT_SOCKADDR_SA_LEN
 389
 390 dnl
 391 dnl Check for some common types
 392 dnl
 393
 394 AC_TYPE_PID_T
 395 AC_TYPE_UID_T
 396 AC_TYPE_OFF_T
 397 AC_TYPE_SIZE_T
 398 AC_CHECK_TYPE(ssize_t, int)
 399 AC_TYPE_SIG_ATOMIC_T
 400
 401 dnl AC_SUBST(LIBOBJS)
 402
 403 AC_GROK_TYPES(int8_t int16_t int32_t int64_t)
 404 AC_GROK_TYPES(u_int8_t u_int16_t u_int32_t u_int64_t)
 405
 406 dnl
 407 dnl Tests for editline
 408 dnl
 409
 410 AC_FIND_FUNC_NO_LIBS(el_init, edit)
 411 AC_FIND_FUNC_NO_LIBS(readline, readline)
 412
 413 if test "$with_readline"; then
 414         AC_DEFINE(HAVE_READLINE, 1)
 415         editline_OBJS=
 416         LIB_readline="$READLINELIB "'$(LIB_tgetent)'
 417         INCLUDE_readline="$READLINEINCLUDE"
 418 elif test "$ac_cv_func_el_init" = yes; then
 419         AC_DEFINE(HAVE_READLINE, 1)
 420
 421         editline_OBJS=edit_compat.o
 422         LIB_readline='-L$(top_builddir)/lib/editline -leditline '"$LIB_el_init"' $(LIB_tgetent)'
 423
 424         INCLUDE_readline='-I$(top_builddir)/lib/editline -I$(top_srcdir)/lib/editline'
 425 elif test "$ac_cv_func_readline" = yes; then
 426         AC_DEFINE(HAVE_READLINE, 1)
 427         editline_OBJS=
 428         LIB_readline='-lreadline $(LIB_tgetent)'
 429         INCLUDE_readline=
 430 else
 431         AC_DEFINE(HAVE_READLINE, 1)
 432         editline_OBJS="editline.o complete.o sysunix.o"
 433         LIB_readline='-L$(top_builddir)/lib/editline -leditline $(LIB_tgetent)'
 434         INCLUDE_readline='-I$(top_builddir)/lib/editline -I$(top_srcdir)/lib/editline'
 435 fi
 436 AC_SUBST(LIB_tgetent)
 437 AC_SUBST(LIB_readline)
 438 AC_SUBST(INCLUDE_readline)
 439 AC_SUBST(editline_OBJS)
 440
 441 dnl telnet muck --------------------------------------------------
 442
 443 AC_DEFINE(AUTHENTICATION)dnl
 444 AC_DEFINE(KRB5)dnl
 445 AC_DEFINE(ENCRYPTION)dnl
 446 AC_DEFINE(DES_ENCRYPTION)dnl
 447 AC_DEFINE(DIAGNOSTICS)dnl
 448 AC_DEFINE(OLD_ENVIRON)dnl
 449
 450 # Simple test for streamspty, based on the existance of getmsg(), alas
 451 # this breaks on SunOS4 which have streams but BSD-like ptys
 452 #
 453 # And also something wierd has happend with dec-osf1, fallback to bsd-ptys
 454
 455 AC_MSG_CHECKING(for streamspty)
 456 case "`uname -sr`" in
 457 SunOS\ 4*|OSF1*|IRIX\ 4*|HP-UX\ ?.10.*)
 458         krb_cv_sys_streamspty=no
 459         ;;
 460 AIX*)
 461         os_rel=`uname -v`.`uname -r`
 462         if expr "$os_rel" : "3*" >/dev/null 2>&1; then
 463                 krb_cv_sys_streamspty=no
 464         else
 465                 krb_cv_sys_streamspty="$ac_cv_func_getmsg"
 466         fi
 467         ;;
 468 *)
 469         krb_cv_sys_streamspty="$ac_cv_func_getmsg"
 470         ;;
 471 esac
 472 if test "$krb_cv_sys_streamspty" = yes; then
 473         AC_DEFINE(STREAMSPTY)
 474 fi
 475 dnl AC_SUBST(STREAMSPTY)
 476 AC_MSG_RESULT($krb_cv_sys_streamspty)
 477
 478 AC_OUTPUT(Makefile                      \
 479         include/Makefile                \
 480         include/kadm5/Makefile          \
 481         lib/Makefile                    \
 482         lib/roken/Makefile              \
 483         lib/editline/Makefile           \
 484         lib/sl/Makefile                 \
 485         lib/error/Makefile              \
 486         lib/error/compile_et            \
 487         lib/asn1/Makefile               \
 488         lib/des/Makefile                \
 489         lib/krb5/Makefile               \
 490         lib/kadm5/Makefile              \
 491         lib/hdb/Makefile                \
 492         lib/gssapi/Makefile             \
 493         lib/45/Makefile                 \
 494         lib/otp/Makefile                \
 495         lib/kafs/Makefile               \
 496         kuser/Makefile                  \
 497         kpasswd/Makefile                \
 498         kadmin/Makefile                 \
 499         admin/Makefile                  \
 500         kdc/Makefile                    \
 501         appl/Makefile                   \
 502         appl/test/Makefile              \
 503         appl/rsh/Makefile               \
 504         appl/popper/Makefile            \
 505         appl/push/Makefile              \
 506         appl/telnet/Makefile            \
 507         appl/telnet/libtelnet/Makefile  \
 508         appl/telnet/telnet/Makefile     \
 509         appl/telnet/telnetd/Makefile    \
 510         appl/afsutil/Makefile           \
 511         doc/Makefile                    \
 512 )
 513
 514 dnl
 515 dnl This is the release version name-number[beta]
 516 dnl
 517 HEIMDALVERSION="$PACKAGE-$VERSION"
 518
 519 cat > include/newversion.h.in <<EOF
 520 char *heimdal_long_version = "@(#)\$Version: $HEIMDALVERSION by @USER@ on @HOST@ ($host) @DATE@ \$";
 521 char *heimdal_version = "$HEIMDALVERSION";
 522 EOF
 523
 524 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 525         echo "include/version.h is unchanged"
 526         rm -f include/newversion.h.in
 527 else
 528         echo "creating include/version.h"
 529         User=${USER-${LOGNAME}}
 530         Host=`(hostname || uname -n) 2>/dev/null | sed 1q`
 531         Date=`date`
 532         mv -f include/newversion.h.in include/version.h.in
 533         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 534 fi