configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21 AM_PATH_PYTHON
  22 AC_CHECK_PROG(CLANG_FORMAT, clang-format, [clang-format], [no])
  23
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 AC_PREFIX_DEFAULT(/usr/heimdal)
  27
  28 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  29 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  30
  31 AC_CANONICAL_HOST
  32 CANONICAL_HOST=$host
  33 AC_SUBST(CANONICAL_HOST)
  34
  35 rk_SYS_LARGEFILE
  36
  37 rk_AIX
  38 rk_IRIX
  39 rk_SUNOS
  40
  41 dnl
  42 dnl this is needed to run the configure tests against glibc
  43 dnl
  44 AC_DEFINE([_GNU_SOURCE], 1,
  45         [Define to enable extensions on glibc-based systems such as Linux.])
  46
  47 AC_OBJEXT
  48 AC_EXEEXT
  49
  50 dnl
  51 dnl this is needed when der-protos.h or der-private.h has to be generated
  52 dnl
  53 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  54    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  55     AC_KRB_PROG_PERL
  56     AC_KRB_PERL_MOD(Getopt::Std)
  57     AC_KRB_PERL_MOD(File::Compare)
  58     AC_KRB_PERL_MOD(JSON)
  59 fi
  60
  61 dnl AC_KRB_PROG_YACC
  62 AC_PROG_YACC
  63 AM_PROG_LEX
  64 AS_IF([$LEX --nounput -V > /dev/null 2>&1 && test $? -eq 0],
  65       [AC_SUBST([FLEXNOUNPUTARGS], ["--nounput"])],
  66       [AC_SUBST([FLEXNOUNPUTARGS], [""])])
  67 dnl AC_PROG_RANLIB
  68 AC_PROG_AWK
  69 AC_KRB_PROG_LN_S
  70
  71 AC_MIPS_ABI
  72 CC="$CC $abi"
  73 libdir="$libdir$abilibdirext"
  74
  75 AC_C___ATTRIBUTE__
  76
  77 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  78 rk_VERSIONSCRIPT
  79
  80 dnl Code coverage
  81 AC_ARG_ENABLE([gcov],
  82         AC_HELP_STRING([--enable-gcov], [enable gcov code coverage tool]))
  83 AM_CONDITIONAL([ENABLE_GCOV], [test "x$enable_gcov" = xyes])
  84
  85
  86 dnl
  87 dnl Helper bits for cross compiling
  88 dnl
  89
  90 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  91
  92 AC_ARG_WITH(cross-tools,
  93         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  94         [if test "$withval" = "yes"; then
  95                 AC_MSG_ERROR([Need path to cross tools])
  96         fi
  97         with_cross_tools="${with_cross_tools}/"
  98         ])
  99
 100 if test "${cross_compiling}" != yes ; then
 101
 102    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
 103    SLC="\$(top_builddir)/lib/sl/slc"
 104
 105    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
 106    SLC_DEP="\$(SLC)"
 107 else
 108    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 109    SLC="${with_cross_tools}slc"
 110
 111    ASN1_COMPILE_DEP=
 112    SLC_DEP=
 113
 114    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 115
 116 fi
 117
 118 AX_CHECK_COMPILE_FLAG([-Wno-error=enum-conversion],
 119                       [WFLAGS_ENUM_CONV=-Wno-error=enum-conversion],
 120                       [WFLAGS_ENUM_CONV=], [-Werror])
 121 AX_CHECK_COMPILE_FLAG([-Wno-unused-but-set-variable],
 122                       [WFLAGS_UNUSED_BUT_SET_VAR=-Wno-unused-but-set-variable],
 123                       [WFLAGS_UNUSED_BUT_SET_VAR=], [-Werror])
 124
 125 AC_SUBST([WFLAGS_ENUM_CONV])
 126 AC_SUBST([ASN1_COMPILE])
 127 AC_SUBST([ASN1_COMPILE_DEP])
 128 AC_SUBST([SLC])
 129 AC_SUBST([SLC_DEP])
 130
 131 dnl ---
 132
 133 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 134
 135 rk_TEST_PACKAGE(openldap,
 136 [#include <lber.h>
 137 #include <ldap.h>],
 138 [-lldap -llber],,,OPENLDAP)
 139 AM_CONDITIONAL(OPENLDAP, test "$with_openldap" != "no")
 140
 141 AC_ARG_ENABLE(hdb-openldap-module,
 142         AS_HELP_STRING([--enable-hdb-openldap-module],
 143                 [if you want support to build openldap hdb as shared object]))
 144 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 145     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 146 fi
 147 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 148
 149 AC_ARG_ENABLE(asn1-templating,
 150         AS_HELP_STRING([--disable-asn1-templating],
 151                 [if you want disable to use of the ASN.1 templating compiler]))
 152 AM_CONDITIONAL(ASN1_TEMPLATING, test "x$enable_asn1_templating" != xno)
 153
 154 dnl
 155 dnl Optional modules, pk-init, digest, kx509
 156 dnl
 157
 158 AC_ARG_ENABLE(pk-init,
 159         AS_HELP_STRING([--disable-pk-init],
 160                 [if you want disable to PK-INIT support]))
 161 if test "$enable_pk_init" != no ;then
 162         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 163 fi
 164 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 165
 166 AC_ARG_ENABLE(digest,
 167         AS_HELP_STRING([--disable-digest],
 168                 [if you want disable to DIGEST support]))
 169 if test "$enable_digest" != no ;then
 170         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 171 fi
 172
 173 AC_ARG_ENABLE(kx509,
 174         AS_HELP_STRING([--disable-kx509],
 175                 [if you want disable to kx509 support]))
 176 if test "$enable_kx509" != no ;then
 177         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 178 fi
 179
 180 dnl Need to test if pkg-config exists
 181 PKG_PROG_PKG_CONFIG
 182
 183 dnl libcap-ng
 184 AC_ARG_WITH([capng],
 185   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 186   [],
 187   [with_capng=check])
 188 if test "$with_capng" != "no"; then
 189   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 190                     [with_capng=yes],[with_capng=no])
 191 fi
 192 if test "$with_capng" = "yes"; then
 193   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 194 fi
 195 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 196 AC_SUBST([CAPNG_CFLAGS])
 197 AC_SUBST([CAPNG_LIBS])
 198
 199 dnl libmicrohttpd
 200 AC_ARG_WITH([microhttpd],
 201   AC_HELP_STRING([--with-microhttpd], [use microhttpd to serve KDC REST API @<:@default=check@:>@]),
 202   [],
 203   [with_microhttpd=check])
 204 if test "$with_microhttpd" != "no"; then
 205   PKG_CHECK_MODULES([MICROHTTPD], [libmicrohttpd >= 0.9.37],
 206                     [with_microhttpd=yes],[with_microhttpd=no])
 207 fi
 208 if test "$with_microhttpd" = "yes"; then
 209   AC_DEFINE_UNQUOTED([HAVE_MICROHTTPD], 1, [whether libmicrohttpd is available for KDC REST API])
 210 fi
 211 AM_CONDITIONAL([HAVE_MICROHTTPD], [test "$with_microhttpd" != "no"])
 212 AC_SUBST([MICROHTTPD_CFLAGS])
 213 AC_SUBST([MICROHTTPD_LIBS])
 214
 215 dnl libcjwt
 216 AC_ARG_WITH([cjwt],
 217   AC_HELP_STRING([--with-cjwt], [(Experimental) use cjwt to validate JWT tokens @<:@default=check@:>@]),
 218   [],
 219   [with_cjwt=check])
 220 if test "$with_cjwt" != "no"; then
 221   PKG_CHECK_MODULES([CJWT], [libcjwt >= 1.0.0],
 222                     [with_cjwt=yes],[with_cjwt=no])
 223 fi
 224 if test "$with_cjwt" = "yes"; then
 225   AC_DEFINE_UNQUOTED([HAVE_CJWT], 1, [whether libcjwt is available for KDC REST API])
 226 fi
 227 AM_CONDITIONAL([HAVE_CJWT], [test "$with_cjwt" != "no"])
 228 AC_SUBST([CJWT_CFLAGS])
 229 AC_SUBST([CJWT_LIBS])
 230
 231 dnl libcjson
 232 AC_ARG_WITH([cjson],
 233   AC_HELP_STRING([--with-cjson], [(Experimental) use cJSON to extract private claims from JWT tokens @<:@default=check@:>@]),
 234   [],
 235   [with_cjson=check])
 236 if test "$with_cjson" != "no"; then
 237   PKG_CHECK_MODULES([CJSON], [libcjson >= 1.0.0],
 238                     [with_cjson=yes],[with_cjson=no])
 239 fi
 240 if test "$with_cjson" = "yes"; then
 241   AC_DEFINE_UNQUOTED([HAVE_CJSON], 1, [whether libcjson is available for KDC REST API])
 242 fi
 243 AM_CONDITIONAL([HAVE_CJSON], [test "$with_cjson" != "no"])
 244 AC_SUBST([CJSON_CFLAGS])
 245 AC_SUBST([CJSON_LIBS])
 246
 247 dnl Check for sqlite
 248 rk_TEST_PACKAGE(sqlite3,
 249 [#include <sqlite3.h>
 250 #ifndef SQLITE_OPEN_CREATE
 251 #error "old version"
 252 #endif],
 253 [-lsqlite3],,,SQLITE3)
 254
 255 if test "X$with_sqlite3" != Xyes ; then
 256    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 257    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 258 fi
 259 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 260
 261 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 262
 263 AC_ARG_ENABLE(sqlite-cache,
 264         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 265 if test "$enable_sqlite_cache" != no; then
 266     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 267 fi
 268 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 269
 270
 271 dnl check for libintl
 272 rk_TEST_PACKAGE(libintl,
 273 [#include <libintl.h>],
 274 [-lintl],,,LIBINTL)
 275
 276 dnl path where the hdb directory is stored
 277 AC_ARG_WITH([hdbdir],
 278         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 279         [],
 280         [with_hdbdir=/var/heimdal])
 281 DIR_hdbdir="$with_hdbdir"
 282 AC_SUBST([DIR_hdbdir])
 283
 284
 285 AM_CONDITIONAL(KRB5, true)
 286 AM_CONDITIONAL(do_roken_rename, true)
 287
 288 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 289
 290
 291 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 292 AC_SUBST(LIB_kdb)dnl
 293
 294 KRB_CRYPTO
 295
 296 KRB_PTHREADS
 297
 298 AC_ARG_ENABLE(dce,
 299         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 300 if test "$enable_dce" = yes; then
 301     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 302 fi
 303 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 304
 305 ## XXX quite horrible:
 306 if test -f /etc/ibmcxx.cfg; then
 307         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 308         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 309         dpagaix_ldflags=
 310 else
 311         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 312         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 313         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 314 fi
 315 AC_SUBST(dpagaix_cflags)
 316 AC_SUBST(dpagaix_ldadd)
 317 AC_SUBST(dpagaix_ldflags)
 318
 319 AC_ARG_ENABLE([afs-support],
 320         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 321 if test "$enable_afs_support" = no; then
 322         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 323         NO_AFS="1"
 324 fi
 325 AC_SUBST(NO_AFS)dnl
 326 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 327
 328 rk_DB
 329
 330 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 331
 332 rk_ROKEN(lib/roken)
 333 LIBADD_roken="$LIB_roken"
 334 AC_SUBST(LIBADD_roken)dnl
 335 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 336
 337 rk_OTP
 338
 339 rk_LIBDISPATCH
 340
 341 AC_CHECK_OSFC2
 342
 343 AC_ARG_ENABLE(mmap,
 344         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 345 if test "$enable_mmap" = "no"; then
 346         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 347 fi
 348
 349 AC_ARG_ENABLE(afs-string-to-key,
 350         AS_HELP_STRING([--disable-afs-string-to-key],
 351         [disable use of weak AFS string-to-key functions]),
 352         [], [enable_afs_string_to_key=yes])
 353
 354 if test "$enable_afs_string_to_key" = "yes"; then
 355         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 356         ENABLE_AFS_STRING_TO_KEY=1
 357 fi
 358 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 359
 360
 361 rk_CHECK_MAN
 362
 363 rk_TEST_PACKAGE(readline,
 364 [#include <stdio.h>
 365 #if defined(HAVE_READLINE_READLINE_H)
 366 #include <readline/readline.h>
 367 #elif defined(HAVE_READLINE_H)
 368 #include <readline.h>
 369 #endif
 370 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 371
 372 rk_TEST_PACKAGE(libedit,
 373 [#include <stdio.h>
 374 #if defined(HAVE_READLINE_READLINE_H)
 375 #include <readline/readline.h>
 376 #elif defined(HAVE_READLINE_H)
 377 #include <readline.h>
 378 #elif defined(HAVE_EDITLINE_READLINE_H)
 379 #include <editline/readline.h>
 380 #endif
 381 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 382
 383 AC_CONFIG_SUBDIRS([lib/libedit])
 384
 385 KRB_C_BIGENDIAN
 386 AC_C_INLINE
 387
 388 dnl AM_C_PROTOTYPES
 389
 390 dnl Checks for typedefs, structures, and compiler characteristics.
 391 AC_C_CONST
 392 AC_TYPE_OFF_T
 393 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 394 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 395 AC_HAVE_TYPE([long long])
 396 AC_HEADER_TIME
 397 AC_STRUCT_TM
 398
 399 dnl Checks for header files.
 400 AC_HEADER_STDC
 401
 402 AC_CHECK_HEADERS([\
 403         CommonCrypto/CommonDigest.h             \
 404         CommonCrypto/CommonCryptor.h            \
 405         arpa/telnet.h                           \
 406         bind/bitypes.h                          \
 407         bsdsetjmp.h                             \
 408         curses.h                                \
 409         dlfcn.h                                 \
 410         execinfo.h                              \
 411         fnmatch.h                               \
 412         inttypes.h                              \
 413         io.h                                    \
 414         keyutils.h                              \
 415         libutil.h                               \
 416         limits.h                                \
 417         maillock.h                              \
 418         netgroup.h                              \
 419         netinet/in6_machtypes.h                 \
 420         netinet/tcp.h                           \
 421         pthread.h                               \
 422         pty.h                                   \
 423         sac.h                                   \
 424         sgtty.h                                 \
 425         siad.h                                  \
 426         signal.h                                \
 427         strings.h                               \
 428         stropts.h                               \
 429         stdatomic.h                             \
 430         sys/bitypes.h                           \
 431         sys/category.h                          \
 432         sys/file.h                              \
 433         sys/filio.h                             \
 434         sys/ioccom.h                            \
 435         sys/mman.h                              \
 436         sys/param.h                             \
 437         sys/pty.h                               \
 438         sys/ptyio.h                             \
 439         sys/select.h                            \
 440         sys/socket.h                            \
 441         sys/str_tty.h                           \
 442         sys/stream.h                            \
 443         sys/stropts.h                           \
 444         sys/syscall.h                           \
 445         sys/termio.h                            \
 446         sys/timeb.h                             \
 447         sys/times.h                             \
 448         sys/types.h                             \
 449         sys/un.h                                \
 450         locale.h                                \
 451         termcap.h                               \
 452         termio.h                                \
 453         termios.h                               \
 454         time.h                                  \
 455         tmpdir.h                                \
 456         udb.h                                   \
 457         util.h                                  \
 458 ])
 459
 460 dnl On Solaris 8 there's a compilation warning for term.h because
 461 dnl it doesn't define `bool'.
 462 AC_CHECK_HEADERS(term.h, , , -)
 463
 464 dnl aix have asl.h (A/IX screen library) that we don't want
 465 AC_CHECK_HEADERS(asl.h, , , [
 466 #include <asl.h>
 467 #ifndef ASL_STRING_EMERG
 468 #error ASL_STRING_EMERG missing
 469 #endif])
 470
 471 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 472 #if HAVE_SYS_SOCKET_H
 473 #include <sys/socket.h>
 474 #endif])
 475
 476 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 477 #if HAVE_SYS_TTY_H
 478 #include <sys/tty.h>
 479 #endif])
 480
 481 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 482 #if HAVE_TERMIOS_H
 483 #include <termios.h>
 484 #endif
 485 #if HAVE_SYS_STREAM_H
 486 #include <sys/stream.h>
 487 #endif])
 488
 489 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 490 #if HAVE_SYS_TYPES_H
 491 #include <sys/types.h>
 492 #endif
 493 #if HAVE_SYS_PARAM_H
 494 #include <sys/param.h>
 495 #endif])
 496
 497 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 498 #include <security/pam_appl.h>
 499 ])
 500
 501 dnl export symbols
 502 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 503 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 504 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 505 rk_WIN32_EXPORT(BUILD_KDC_LIB, KDC_LIB)
 506
 507 dnl Deal with switch FALLTHROUGH
 508 AH_TOP([
 509 #if defined(__GNUC__)
 510 #if __GNUC__ >= 7
 511 # define fallthrough __attribute__((fallthrough));
 512 #else
 513 # define fallthrough
 514 #endif
 515 #else
 516 # define fallthrough
 517 #endif
 518 ])
 519
 520 dnl Checks for libraries.
 521
 522 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 523 #ifdef HAVE_UTIL_H
 524 #include <util.h>
 525 #endif
 526 ],[0,0,0,0,0])
 527
 528 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses tinfo,[
 529 #ifdef HAVE_TERMCAP_H
 530 #include <termcap.h>
 531 #endif
 532 #ifdef HAVE_CURSES_H
 533 #include <curses.h>
 534 #endif
 535 ],[0,0])
 536
 537 dnl Checks for library functions.
 538
 539 AC_CHECK_FUNCS([                                \
 540         _scrsize                                \
 541         arc4random                              \
 542         backtrace                               \
 543         fcntl                                   \
 544         fork                                    \
 545         fseeko                                  \
 546         ftello                                  \
 547         getpeereid                              \
 548         getpeerucred                            \
 549         getresgid                               \
 550         getresuid                               \
 551         grantpt                                 \
 552         ptsname_r                               \
 553         rand                                    \
 554         setitimer                               \
 555         setregid                                \
 556         setresgid                               \
 557         setresuid                               \
 558         setreuid                                \
 559         setsid                                  \
 560         sigaction                               \
 561         unlockpt                                \
 562         waitpid                                 \
 563 ])
 564
 565 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 566 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 567         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 568         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 569 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 570         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 571 fi
 572 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 573
 574 AC_FUNC_MMAP
 575
 576 rk_DLADDR
 577
 578 AC_CHECK_GETPWNAM_R_POSIX
 579 AC_CHECK_GETPWUID_R_POSIX
 580
 581 dnl detect doors on solaris
 582 if test "$enable_pthread_support" != no; then
 583    saved_LIBS="$LIBS"
 584    LIBS="$LIBS $PTHREADS_LIBS"
 585    AC_FIND_FUNC_NO_LIBS(door_create, door)
 586    LIBS="$saved_LIBS"
 587 fi
 588
 589 AC_ARG_ENABLE(kcm,
 590         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 591 ,[enable_kcm=yes])
 592
 593 if test "$enable_kcm" = yes ; then
 594    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 595         enable_kcm=no
 596    fi
 597 fi
 598 if test "$enable_kcm" = yes; then
 599        AC_DEFINE(HAVE_KCM, 1,
 600                [Define if you want to use the Kerberos Credentials Manager.])
 601 fi
 602 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 603
 604 dnl detect keyring on Linux
 605 if test "$ac_cv_header_keyutils_h" = yes; then
 606     AC_CHECK_SIZEOF([key_serial_t],,[
 607         #ifdef HAVE_INTTYPES_H
 608         #include <inttypes.h>
 609         #endif
 610         #ifdef HAVE_SYS_TYPES_H
 611         #include <sys/types.h>
 612         #endif
 613         #include <keyutils.h>
 614     ])
 615 fi
 616
 617 AC_FIND_FUNC_NO_LIBS(add_key, keyutils)
 618 if test -n "$LIB_add_key"; then
 619     saved_LIBS="$LIBS"
 620     LIBS="$LIBS $LIB_add_key"
 621     AC_CHECK_FUNCS(keyctl_get_persistent)
 622     LIBS="$saved_LIBS"
 623 fi
 624 AM_CONDITIONAL(HAVE_KEYUTILS, test "$ac_cv_func_keyctl_get_persistent" = yes)
 625
 626 AC_CHECK_SIZEOF([time_t])
 627
 628 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 629         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 630         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 631 #ifdef HAVE_INTTYPES_H
 632 #include <inttypes.h>
 633 #endif
 634 #ifdef HAVE_SYS_TYPES_H
 635 #include <sys/types.h>
 636 #endif
 637 #ifdef HAVE_SYS_BITYPES_H
 638 #include <sys/bitypes.h>
 639 #endif
 640 #ifdef HAVE_BIND_BITYPES_H
 641 #include <bind/bitypes.h>
 642 #endif
 643 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 644 #include <netinet/in6_machtypes.h>
 645 #endif
 646 ])
 647
 648 rk_FRAMEWORK_SECURITY
 649 rk_FRAMEWORK_COREFOUNDATION
 650
 651 KRB_READLINE
 652
 653 rk_TELNET
 654
 655 dnl Some operating systems already have com_err and compile_et
 656 CHECK_COMPILE_ET
 657
 658 rk_AUTH_MODULES([sia afskauthlib])
 659
 660 rk_DESTDIRS
 661
 662 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 663
 664
 665 AH_BOTTOM([#ifdef __APPLE__
 666 #include <AvailabilityMacros.h>
 667 #endif])
 668
 669 AH_BOTTOM([#ifdef ROKEN_RENAME
 670 #include "roken_rename.h"
 671 #endif])
 672
 673 AC_ARG_ENABLE(heimdal-documentation,
 674         AS_HELP_STRING([--disable-heimdal-documentation],
 675                 [if you want disable to heimdal documentation]))
 676 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 677
 678 AC_CONFIG_FILES(Makefile                \
 679         etc/Makefile                    \
 680         include/Makefile                \
 681         include/gssapi/Makefile         \
 682         include/hcrypto/Makefile        \
 683         include/kadm5/Makefile          \
 684         lib/Makefile                    \
 685         lib/base/Makefile                       \
 686         lib/asn1/Makefile               \
 687         lib/com_err/Makefile            \
 688         lib/hcrypto/Makefile            \
 689         lib/hx509/Makefile              \
 690         lib/gssapi/Makefile             \
 691         lib/ntlm/Makefile               \
 692         lib/hdb/Makefile                \
 693         lib/ipc/Makefile                \
 694         lib/kadm5/Makefile              \
 695         lib/kafs/Makefile               \
 696         lib/kdfs/Makefile               \
 697         lib/krb5/Makefile               \
 698         lib/otp/Makefile                \
 699         lib/roken/Makefile              \
 700         lib/sl/Makefile                 \
 701         lib/sqlite/Makefile             \
 702         lib/vers/Makefile               \
 703         lib/wind/Makefile               \
 704         lib/gss_preauth/Makefile        \
 705         po/Makefile                     \
 706         kuser/Makefile                  \
 707         kpasswd/Makefile                \
 708         kadmin/Makefile                 \
 709         admin/Makefile                  \
 710         kcm/Makefile                    \
 711         kdc/Makefile                    \
 712         appl/Makefile                   \
 713         appl/afsutil/Makefile           \
 714         appl/dbutils/Makefile           \
 715         appl/gssmask/Makefile           \
 716         appl/otp/Makefile               \
 717         appl/test/Makefile              \
 718         appl/kf/Makefile                \
 719         appl/dceutils/Makefile          \
 720         tests/Makefile                  \
 721         tests/bin/Makefile              \
 722         tests/can/Makefile              \
 723         tests/db/Makefile               \
 724         tests/kdc/Makefile              \
 725         tests/ldap/Makefile             \
 726         tests/gss/Makefile              \
 727         tests/java/Makefile             \
 728         tests/plugin/Makefile           \
 729         packages/Makefile               \
 730         packages/mac/Makefile           \
 731         doc/Makefile                    \
 732         tools/Makefile                  \
 733 )
 734
 735 AC_OUTPUT
 736
 737 dnl
 738 dnl This is the release version name-number[beta]
 739 dnl
 740
 741 if test -d "$srcdir/.git"; then
 742     cat > include/newversion.h.in <<EOF
 743 #ifndef VERSION_HIDDEN
 744 #define VERSION_HIDDEN
 745 #endif
 746 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ @BRANCH@ @TAG@ ($host) @COMMIT@ @DATE@ \$";
 747 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 748 EOF
 749 else
 750     cat > include/newversion.h.in <<EOF
 751 #ifndef VERSION_HIDDEN
 752 #define VERSION_HIDDEN
 753 #endif
 754 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 755 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 756 EOF
 757 fi
 758
 759 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 760         echo "include/version.h is unchanged"
 761         rm -f include/newversion.h.in
 762 else
 763         echo "creating include/version.h"
 764         if test -n "$SOURCE_DATE_EPOCH"; then
 765             Date=`
 766                   # BSD, OS X
 767                   date -u -r "$SOURCE_DATE_EPOCH" "+%Y-%m-%dT%H:%M:%SZ" 2>/dev/null ||
 768                   # Linux
 769                   date -u -d "@${SOURCE_DATE_EPOCH}" 2>/dev/null ||
 770                   # Illumos -- sorry, no -r/-d here
 771                   date -u ||
 772                   date`
 773         else
 774             Date=`date -u "+%Y-%m-%dT%H:%M:%SZ"`
 775         fi
 776         if test -n "$SOURCE_HOST"; then
 777             Host=$SOURCE_HOST
 778         else
 779             Host=`uname -n`
 780         fi
 781         if test -n "$SOURCE_USER"; then
 782             User=$SOURCE_USER
 783         else
 784             User=${USER:-${LOGNAME:-`id -nu`}}
 785         fi
 786         if test -d "$srcdir/.git"; then
 787             GitCommit=`cd $srcdir && git rev-parse HEAD`
 788             GitBranch=`cd $srcdir && git rev-parse --abbrev-ref HEAD`
 789             if test "x$GitBranch" = master; then
 790                 GitDesc=`cd $srcdir && git describe --all --dirty`
 791             else
 792                 GitDesc=`cd $srcdir && \
 793                          git describe --tags --match 'heimdal-*' --dirty`
 794             fi
 795         else
 796             GitCommit='<commit-unknown>'
 797             GitBranch='<branch-unknown>'
 798             GitDesc='<tag-unknown>'
 799         fi
 800         mv -f include/newversion.h.in include/version.h.in
 801         sed -e "s/@HOST@/$Host/" \
 802             -e "s;@USER@;$User;" \
 803             -e "s;@DATE@;$Date;" \
 804             -e "s;@BRANCH@;$GitBranch;" \
 805             -e "s;@TAG@;$GitDesc;" \
 806             -e "s;@COMMIT@;$GitCommit;" \
 807             include/version.h.in > include/version.h
 808 fi