configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.3.0pre9],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17
  18 AC_PREFIX_DEFAULT(/usr/heimdal)
  19
  20 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  21 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  22
  23 AC_CANONICAL_HOST
  24 CANONICAL_HOST=$host
  25 AC_SUBST(CANONICAL_HOST)
  26
  27 dnl Hints for autobuild
  28 AB_INIT
  29
  30 rk_SYS_LARGEFILE
  31
  32 rk_AIX
  33 rk_IRIX
  34 rk_SUNOS
  35
  36 dnl
  37 dnl this is needed to run the configure tests against glibc
  38 dnl
  39 AC_DEFINE([_GNU_SOURCE], 1,
  40         [Define to enable extensions on glibc-based systems such as Linux.])
  41
  42 AC_OBJEXT
  43 AC_EXEEXT
  44
  45 dnl AC_KRB_PROG_YACC
  46 AC_PROG_YACC
  47 AM_PROG_LEX
  48 dnl AC_PROG_RANLIB
  49 AC_PROG_AWK
  50 AC_KRB_PROG_LN_S
  51
  52 AC_MIPS_ABI
  53 CC="$CC $abi"
  54 libdir="$libdir$abilibdirext"
  55
  56 AC_C___ATTRIBUTE__
  57
  58 LT_PREREQ([2.2])
  59 LT_INIT([shared static win32-dll])
  60
  61 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  62 rk_VERSIONSCRIPT
  63
  64 dnl
  65 dnl Helper bits for cross compiling
  66 dnl
  67
  68 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  69
  70 if test "${cross_compiling}" != yes ; then
  71    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  72    SLC="\$(top_builddir)/lib/sl/slc"
  73
  74    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  75    SLC_DEP="\$(SLC)"
  76 else
  77    ASN1_COMPILE="asn1_compile"
  78    SLC="slc"
  79
  80    ASN1_COMPILE_DEP=
  81    SLC_DEP=
  82 fi
  83
  84 AC_SUBST([ASN1_COMPILE])
  85 AC_SUBST([ASN1_COMPILE_DEP])
  86 AC_SUBST([SLC])
  87 AC_SUBST([SLC_DEP])
  88
  89
  90 dnl ---
  91
  92 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
  93
  94 rk_TEST_PACKAGE(openldap,
  95 [#include <lber.h>
  96 #include <ldap.h>],
  97 [-lldap -llber],,,OPENLDAP)
  98
  99 AC_ARG_ENABLE(hdb-openldap-module,
 100         AS_HELP_STRING([--enable-hdb-openldap-module],
 101                 [if you want support to build openldap hdb as shared object]))
 102 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 103     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 104 fi
 105 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 106
 107 dnl
 108 dnl Optional modules, pk-init, digest, kx509
 109 dnl
 110
 111 AC_ARG_ENABLE(pk-init,
 112         AS_HELP_STRING([--disable-pk-init],
 113                 [if you want disable to PK-INIT support]))
 114 if test "$enable_pk_init" != no ;then
 115         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 116 fi
 117 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 118
 119 AC_ARG_ENABLE(digest,
 120         AS_HELP_STRING([--disable-digest],
 121                 [if you want disable to DIGEST support]))
 122 if test "$enable_digest" != no ;then
 123         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 124 fi
 125
 126 AC_ARG_ENABLE(kx509,
 127         AS_HELP_STRING([--disable-kx509],
 128                 [if you want disable to kx509 support]))
 129 if test "$enable_kx509" != no ;then
 130         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 131 fi
 132
 133 AC_ARG_ENABLE(krb4,
 134         AS_HELP_STRING([--disable-krb4],
 135                 [if you want disable to krb4 support]))
 136 if test "$enable_krb4" != no ;then
 137         AC_DEFINE([KRB4], 1, [Define to enable Kerberos 4.])
 138 fi
 139
 140
 141 dnl Check for sqlite
 142 rk_TEST_PACKAGE(sqlite3,
 143 [#include <sqlite3.h>
 144 #ifndef SQLITE_OPEN_CREATE
 145 #error "old version"
 146 #endif],
 147 [-lsqlite3],,,SQLITE3)
 148
 149 if test "X$with_sqlite3" != Xyes ; then
 150    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 151    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 152 fi
 153 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 154
 155 dnl check for libintl
 156 rk_TEST_PACKAGE(libintl,
 157 [#include <libintl.h>],
 158 [-lintl],,,LIBINTL)
 159
 160 dnl path where the hdb directory is stored
 161 AC_ARG_WITH([hdbdir],
 162         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 163         [],
 164         [with_hdbdir=/var/heimdal])
 165 DIR_hdbdir="$with_hdbdir"
 166 AC_SUBST([DIR_hdbdir])
 167
 168
 169 dnl no kerberos4 any more
 170 with_krb4=no
 171 AC_SUBST(INCLUDE_krb4)
 172 AC_SUBST(LIB_krb4)
 173 AM_CONDITIONAL(KRB4, false)
 174
 175 AM_CONDITIONAL(KRB5, true)
 176 AM_CONDITIONAL(do_roken_rename, true)
 177
 178 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 179 AC_SUBST(LIB_kdb)dnl
 180
 181 KRB_CRYPTO
 182
 183 KRB_PTHREADS
 184
 185 AC_ARG_ENABLE(dce,
 186         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 187 if test "$enable_dce" = yes; then
 188     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 189 fi
 190 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 191
 192 ## XXX quite horrible:
 193 if test -f /etc/ibmcxx.cfg; then
 194         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 195         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 196         dpagaix_ldflags=
 197 else
 198         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 199         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 200         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 201 fi
 202 AC_SUBST(dpagaix_cflags)
 203 AC_SUBST(dpagaix_ldadd)
 204 AC_SUBST(dpagaix_ldflags)
 205
 206 AC_ARG_ENABLE([afs-support],
 207         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 208 if test "$enable_afs_support" = no; then
 209         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 210 fi
 211
 212 rk_DB
 213
 214 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 215
 216 rk_ROKEN(lib/roken)
 217 LIBADD_roken="$LIB_roken"
 218 AC_SUBST(LIBADD_roken)dnl
 219 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 220
 221 rk_OTP
 222
 223 AC_CHECK_OSFC2
 224
 225 AC_ARG_ENABLE(mmap,
 226         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 227 if test "$enable_mmap" = "no"; then
 228         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 229 fi
 230
 231 AC_ARG_ENABLE(afs-string-to-key,
 232         AS_HELP_STRING([--disable-afs-string-to-key],
 233         [disable use of weak AFS string-to-key functions]),
 234         [], [enable_afs_string_to_key=yes])
 235
 236 if test "$enable_afs_string_to_key" = "yes"; then
 237         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 238 fi
 239
 240
 241 rk_CHECK_MAN
 242
 243 rk_TEST_PACKAGE(readline,
 244 [#include <stdio.h>
 245  #include <readline.h>],-lreadline,,, READLINE)
 246
 247 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 248
 249 KRB_C_BIGENDIAN
 250 AC_C_INLINE
 251
 252 KRB_CHECK_X
 253
 254 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 255
 256 AC_CHECK_XAU
 257
 258 dnl AM_C_PROTOTYPES
 259
 260 dnl Checks for typedefs, structures, and compiler characteristics.
 261 AC_C_CONST
 262 AC_TYPE_OFF_T
 263 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 264 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 265 AC_HAVE_TYPE([long long])
 266 AC_HEADER_TIME
 267 AC_STRUCT_TM
 268
 269 dnl Checks for header files.
 270 AC_HEADER_STDC
 271
 272 AC_CHECK_HEADERS([\
 273         arpa/ftp.h                              \
 274         arpa/telnet.h                           \
 275         bind/bitypes.h                          \
 276         bsdsetjmp.h                             \
 277         curses.h                                \
 278         dlfcn.h                                 \
 279         fnmatch.h                               \
 280         inttypes.h                              \
 281         io.h                                    \
 282         libutil.h                               \
 283         limits.h                                \
 284         maillock.h                              \
 285         netgroup.h                              \
 286         netinet/in6_machtypes.h                 \
 287         pthread.h                               \
 288         pty.h                                   \
 289         sac.h                                   \
 290         sgtty.h                                 \
 291         siad.h                                  \
 292         signal.h                                \
 293         strings.h                               \
 294         stropts.h                               \
 295         sys/bitypes.h                           \
 296         sys/category.h                          \
 297         sys/file.h                              \
 298         sys/filio.h                             \
 299         sys/ioccom.h                            \
 300         sys/mman.h                              \
 301         sys/param.h                             \
 302         sys/pty.h                               \
 303         sys/ptyio.h                             \
 304         sys/select.h                            \
 305         sys/socket.h                            \
 306         sys/str_tty.h                           \
 307         sys/stream.h                            \
 308         sys/stropts.h                           \
 309         sys/syscall.h                           \
 310         sys/termio.h                            \
 311         sys/timeb.h                             \
 312         sys/times.h                             \
 313         sys/types.h                             \
 314         sys/un.h                                \
 315         locale.h                                \
 316         termcap.h                               \
 317         termio.h                                \
 318         termios.h                               \
 319         time.h                                  \
 320         tmpdir.h                                \
 321         udb.h                                   \
 322         util.h                                  \
 323         utmp.h                                  \
 324         utmpx.h                                 \
 325 ])
 326
 327 dnl On Solaris 8 there's a compilation warning for term.h because
 328 dnl it doesn't define `bool'.
 329 AC_CHECK_HEADERS(term.h, , , -)
 330
 331 dnl aix have asl.h (A/IX screen library) that we don't want
 332 AC_CHECK_HEADERS(asl.h, , , [
 333 #include <asl.h>
 334 #ifndef ASL_STRING_EMERG
 335 #error ASL_STRING_EMERG missing
 336 #endif])
 337
 338 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 339 #if HAVE_SYS_SOCKET_H
 340 #include <sys/socket.h>
 341 #endif])
 342
 343 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 344 #if HAVE_SYS_TTY_H
 345 #include <sys/tty.h>
 346 #endif])
 347
 348 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 349 #if HAVE_TERMIOS_H
 350 #include <termios.h>
 351 #endif
 352 #if HAVE_SYS_STREAM_H
 353 #include <sys/stream.h>
 354 #endif])
 355
 356 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 357 #if HAVE_SYS_TYPES_H
 358 #include <sys/types.h>
 359 #endif
 360 #if HAVE_SYS_PARAM_H
 361 #include <sys/param.h>
 362 #endif])
 363
 364 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 365 #include <security/pam_appl.h>
 366 ])
 367
 368 dnl export symbols
 369 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 370 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 371 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 372
 373 dnl Checks for libraries.
 374
 375 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 376 #ifdef HAVE_UTIL_H
 377 #include <util.h>
 378 #endif
 379 ],[0,0,0])
 380 AC_FIND_FUNC_NO_LIBS(logout, util,[
 381 #ifdef HAVE_UTIL_H
 382 #include <util.h>
 383 #endif
 384 ],[0])
 385 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 386 #ifdef HAVE_UTIL_H
 387 #include <util.h>
 388 #endif
 389 ],[0,0,0,0,0])
 390
 391 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 392 #ifdef HAVE_TERMCAP_H
 393 #include <termcap.h>
 394 #endif
 395 #ifdef HAVE_CURSES_H
 396 #include <curses.h>
 397 #endif
 398 ],[0,0])
 399
 400 dnl Checks for library functions.
 401
 402 AC_CHECK_FUNCS([                                \
 403         _getpty                                 \
 404         _scrsize                                \
 405         arc4random                              \
 406         fcntl                                   \
 407         getpeereid                              \
 408         getpeerucred                            \
 409         grantpt                                 \
 410         mktime                                  \
 411         ptsname                                 \
 412         rand                                    \
 413         revoke                                  \
 414         select                                  \
 415         setitimer                               \
 416         setpcred                                \
 417         setpgid                                 \
 418         setproctitle                            \
 419         setregid                                \
 420         setresgid                               \
 421         setresuid                               \
 422         setreuid                                \
 423         setsid                                  \
 424         setutent                                \
 425         sigaction                               \
 426         strstr                                  \
 427         ttyname                                 \
 428         ttyslot                                 \
 429         umask                                   \
 430         unlockpt                                \
 431         vhangup                                 \
 432         yp_get_default_domain                   \
 433 ])
 434
 435 AC_FUNC_MMAP
 436
 437 KRB_CAPABILITIES
 438
 439 AC_CHECK_GETPWNAM_R_POSIX
 440
 441 dnl detect doors on solaris
 442 if test "$enable_pthread_support" != no; then
 443    saved_LIBS="$LIBS"
 444    LIBS="$LIBS $PTHREADS_LIBS"
 445    AC_FIND_FUNC_NO_LIBS(door_create, door)
 446    LIBS="$saved_LIBS"
 447 fi
 448
 449 AC_ARG_ENABLE(kcm,
 450         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 451 ,[enable_kcm=yes])
 452
 453 if test "$enable_kcm" = yes ; then
 454    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 455         enable_kcm=no
 456    fi
 457 fi
 458 if test "$enable_kcm" = yes; then
 459        AC_DEFINE(HAVE_KCM, 1,
 460                [Define if you want to use the Kerberos Credentials Manager.])
 461 fi
 462 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 463
 464
 465
 466 dnl Cray stuff
 467 AC_CHECK_FUNCS(getudbnam setlim)
 468
 469 dnl AC_KRB_FUNC_GETCWD_BROKEN
 470
 471 dnl
 472 dnl Check for fields in struct utmp
 473 dnl
 474
 475 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 476 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 477 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 478 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 479 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 480 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 481 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 482 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 483
 484 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 485         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 486         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 487 #ifdef HAVE_INTTYPES_H
 488 #include <inttypes.h>
 489 #endif
 490 #ifdef HAVE_SYS_TYPES_H
 491 #include <sys/types.h>
 492 #endif
 493 #ifdef HAVE_SYS_BITYPES_H
 494 #include <sys/bitypes.h>
 495 #endif
 496 #ifdef HAVE_BIND_BITYPES_H
 497 #include <bind/bitypes.h>
 498 #endif
 499 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 500 #include <netinet/in6_machtypes.h>
 501 #endif
 502 ])
 503
 504 rk_FRAMEWORK_SECURITY
 505
 506 KRB_READLINE
 507
 508 rk_TELNET
 509
 510 dnl Some operating systems already have com_err and compile_et
 511 CHECK_COMPILE_ET
 512
 513 rk_AUTH_MODULES([sia afskauthlib])
 514
 515 rk_DESTDIRS
 516
 517 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 518
 519
 520 AH_BOTTOM([#ifdef ROKEN_RENAME
 521 #include "roken_rename.h"
 522 #endif])
 523
 524 AC_CONFIG_FILES(Makefile                \
 525         etc/Makefile                    \
 526         include/Makefile                \
 527         include/gssapi/Makefile         \
 528         include/hcrypto/Makefile        \
 529         include/kadm5/Makefile          \
 530         lib/Makefile                    \
 531         lib/auth/Makefile               \
 532         lib/auth/afskauthlib/Makefile   \
 533         lib/auth/pam/Makefile           \
 534         lib/auth/sia/Makefile           \
 535         lib/asn1/Makefile               \
 536         lib/com_err/Makefile            \
 537         lib/hcrypto/Makefile            \
 538         lib/editline/Makefile           \
 539         lib/hx509/Makefile              \
 540         lib/gssapi/Makefile             \
 541         lib/ntlm/Makefile               \
 542         lib/hdb/Makefile                \
 543         lib/kadm5/Makefile              \
 544         lib/kafs/Makefile               \
 545         lib/kdfs/Makefile               \
 546         lib/krb5/Makefile               \
 547         lib/otp/Makefile                \
 548         lib/roken/Makefile              \
 549         lib/sl/Makefile                 \
 550         lib/sqlite/Makefile             \
 551         lib/vers/Makefile               \
 552         lib/wind/Makefile               \
 553         po/Makefile                     \
 554         kuser/Makefile                  \
 555         kpasswd/Makefile                \
 556         kadmin/Makefile                 \
 557         admin/Makefile                  \
 558         kcm/Makefile                    \
 559         kdc/Makefile                    \
 560         appl/Makefile                   \
 561         appl/afsutil/Makefile           \
 562         appl/ftp/Makefile               \
 563         appl/ftp/common/Makefile        \
 564         appl/ftp/ftp/Makefile           \
 565         appl/ftp/ftpd/Makefile          \
 566         appl/gssmask/Makefile           \
 567         appl/kx/Makefile                \
 568         appl/login/Makefile             \
 569         appl/otp/Makefile               \
 570         appl/popper/Makefile            \
 571         appl/push/Makefile              \
 572         appl/rsh/Makefile               \
 573         appl/rcp/Makefile               \
 574         appl/su/Makefile                \
 575         appl/xnlock/Makefile            \
 576         appl/telnet/Makefile            \
 577         appl/telnet/libtelnet/Makefile  \
 578         appl/telnet/telnet/Makefile     \
 579         appl/telnet/telnetd/Makefile    \
 580         appl/test/Makefile              \
 581         appl/kf/Makefile                \
 582         appl/dceutils/Makefile          \
 583         tests/Makefile                  \
 584         tests/bin/Makefile              \
 585         tests/can/Makefile              \
 586         tests/db/Makefile               \
 587         tests/kdc/Makefile              \
 588         tests/ldap/Makefile             \
 589         tests/gss/Makefile              \
 590         tests/java/Makefile             \
 591         tests/plugin/Makefile           \
 592         packages/Makefile               \
 593         packages/mac/Makefile           \
 594         doc/Makefile                    \
 595         tools/Makefile                  \
 596 )
 597
 598 AC_OUTPUT
 599
 600 dnl
 601 dnl This is the release version name-number[beta]
 602 dnl
 603
 604 cat > include/newversion.h.in <<EOF
 605 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 606 const char *heimdal_version = "AC_PACKAGE_STRING";
 607 EOF
 608
 609 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 610         echo "include/version.h is unchanged"
 611         rm -f include/newversion.h.in
 612 else
 613         echo "creating include/version.h"
 614         User=${USER-${LOGNAME}}
 615         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 616         Date=`date`
 617         mv -f include/newversion.h.in include/version.h.in
 618         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 619 fi