configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.4.99],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10.3])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17 AC_PROG_LIBTOOL
  18
  19 AC_PREFIX_DEFAULT(/usr/heimdal)
  20
  21 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  22 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  23
  24 AC_CANONICAL_HOST
  25 CANONICAL_HOST=$host
  26 AC_SUBST(CANONICAL_HOST)
  27
  28 rk_SYS_LARGEFILE
  29
  30 rk_AIX
  31 rk_IRIX
  32 rk_SUNOS
  33
  34 dnl
  35 dnl this is needed to run the configure tests against glibc
  36 dnl
  37 AC_DEFINE([_GNU_SOURCE], 1,
  38         [Define to enable extensions on glibc-based systems such as Linux.])
  39
  40 AC_OBJEXT
  41 AC_EXEEXT
  42
  43 dnl AC_KRB_PROG_YACC
  44 AC_PROG_YACC
  45 AM_PROG_LEX
  46 dnl AC_PROG_RANLIB
  47 AC_PROG_AWK
  48 AC_KRB_PROG_LN_S
  49
  50 AC_MIPS_ABI
  51 CC="$CC $abi"
  52 libdir="$libdir$abilibdirext"
  53
  54 AC_C___ATTRIBUTE__
  55
  56 LT_PREREQ([2.2])
  57 LT_INIT([shared static win32-dll])
  58
  59 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  60 rk_VERSIONSCRIPT
  61
  62 dnl
  63 dnl Helper bits for cross compiling
  64 dnl
  65
  66
  67
  68 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  69
  70 AC_ARG_WITH(cross-tools,
  71         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  72         [if test "$withval" = "yes"; then
  73                 AC_MSG_ERROR([Need path to cross tools])
  74         fi
  75         with_cross_tools="${with_cross_tools}/"
  76         ])
  77
  78 if test "${cross_compiling}" != yes ; then
  79
  80    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  81    SLC="\$(top_builddir)/lib/sl/slc"
  82
  83    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  84    SLC_DEP="\$(SLC)"
  85 else
  86    ASN1_COMPILE="${with_cross_tools}asn1_compile"
  87    SLC="${with_cross_tools}slc"
  88
  89    ASN1_COMPILE_DEP=
  90    SLC_DEP=
  91 fi
  92
  93 AC_SUBST([ASN1_COMPILE])
  94 AC_SUBST([ASN1_COMPILE_DEP])
  95 AC_SUBST([SLC])
  96 AC_SUBST([SLC_DEP])
  97
  98
  99 dnl ---
 100
 101 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 102
 103 rk_TEST_PACKAGE(openldap,
 104 [#include <lber.h>
 105 #include <ldap.h>],
 106 [-lldap -llber],,,OPENLDAP)
 107
 108 AC_ARG_ENABLE(hdb-openldap-module,
 109         AS_HELP_STRING([--enable-hdb-openldap-module],
 110                 [if you want support to build openldap hdb as shared object]))
 111 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 112     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 113 fi
 114 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 115
 116 dnl
 117 dnl Optional modules, pk-init, digest, kx509
 118 dnl
 119
 120 AC_ARG_ENABLE(pk-init,
 121         AS_HELP_STRING([--disable-pk-init],
 122                 [if you want disable to PK-INIT support]))
 123 if test "$enable_pk_init" != no ;then
 124         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 125 fi
 126 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 127
 128 AC_ARG_ENABLE(digest,
 129         AS_HELP_STRING([--disable-digest],
 130                 [if you want disable to DIGEST support]))
 131 if test "$enable_digest" != no ;then
 132         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 133 fi
 134
 135 AC_ARG_ENABLE(kx509,
 136         AS_HELP_STRING([--disable-kx509],
 137                 [if you want disable to kx509 support]))
 138 if test "$enable_kx509" != no ;then
 139         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 140 fi
 141
 142 AC_ARG_ENABLE(krb4,
 143         AS_HELP_STRING([--disable-krb4],
 144                 [if you want disable to krb4 support]))
 145 if test "$enable_krb4" != no ;then
 146         AC_DEFINE([KRB4], 1, [Define to enable Kerberos 4.])
 147 fi
 148
 149 dnl Need to test if pkg-config exists
 150 PKG_PROG_PKG_CONFIG
 151
 152 dnl libcap-ng
 153 AC_ARG_WITH([capng],
 154   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 155   [],
 156   [with_capng=check])
 157 if test "$with_capng" != "no"; then
 158   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 159                     [with_capng=yes],[with_capng=no])
 160 fi
 161 if test "$with_capng" = "yes"; then
 162   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 163 fi
 164 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 165 AC_SUBST([CAPNG_CFLAGS])
 166 AC_SUBST([CAPNG_LIBS])
 167
 168 dnl Check for sqlite
 169 rk_TEST_PACKAGE(sqlite3,
 170 [#include <sqlite3.h>
 171 #ifndef SQLITE_OPEN_CREATE
 172 #error "old version"
 173 #endif],
 174 [-lsqlite3],,,SQLITE3)
 175
 176 if test "X$with_sqlite3" != Xyes ; then
 177    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 178    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 179 fi
 180 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 181
 182 AC_ARG_ENABLE(sqlite-cache,
 183         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 184 if test "$enable_sqlite_cache" != no; then
 185     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 186 fi
 187 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 188
 189
 190 dnl check for libintl
 191 rk_TEST_PACKAGE(libintl,
 192 [#include <libintl.h>],
 193 [-lintl],,,LIBINTL)
 194
 195 dnl path where the hdb directory is stored
 196 AC_ARG_WITH([hdbdir],
 197         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 198         [],
 199         [with_hdbdir=/var/heimdal])
 200 DIR_hdbdir="$with_hdbdir"
 201 AC_SUBST([DIR_hdbdir])
 202
 203
 204 dnl no kerberos4 any more
 205 with_krb4=no
 206 AC_SUBST(INCLUDE_krb4)
 207 AC_SUBST(LIB_krb4)
 208 AM_CONDITIONAL(KRB4, false)
 209
 210 AM_CONDITIONAL(KRB5, true)
 211 AM_CONDITIONAL(do_roken_rename, true)
 212
 213 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 214
 215
 216 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 217 AC_SUBST(LIB_kdb)dnl
 218
 219 KRB_CRYPTO
 220
 221 KRB_PTHREADS
 222
 223 AC_ARG_ENABLE(dce,
 224         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 225 if test "$enable_dce" = yes; then
 226     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 227 fi
 228 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 229
 230 ## XXX quite horrible:
 231 if test -f /etc/ibmcxx.cfg; then
 232         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 233         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 234         dpagaix_ldflags=
 235 else
 236         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 237         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 238         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 239 fi
 240 AC_SUBST(dpagaix_cflags)
 241 AC_SUBST(dpagaix_ldadd)
 242 AC_SUBST(dpagaix_ldflags)
 243
 244 AC_ARG_ENABLE([afs-support],
 245         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 246 if test "$enable_afs_support" = no; then
 247         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 248         NO_AFS="1"
 249 fi
 250 AC_SUBST(NO_AFS)dnl
 251
 252 rk_DB
 253
 254 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 255
 256 rk_ROKEN(lib/roken)
 257 LIBADD_roken="$LIB_roken"
 258 AC_SUBST(LIBADD_roken)dnl
 259 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 260
 261 rk_OTP
 262
 263 rk_LIBDISPATCH
 264
 265 AC_CHECK_OSFC2
 266
 267 AC_ARG_ENABLE(mmap,
 268         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 269 if test "$enable_mmap" = "no"; then
 270         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 271 fi
 272
 273 AC_ARG_ENABLE(afs-string-to-key,
 274         AS_HELP_STRING([--disable-afs-string-to-key],
 275         [disable use of weak AFS string-to-key functions]),
 276         [], [enable_afs_string_to_key=yes])
 277
 278 if test "$enable_afs_string_to_key" = "yes"; then
 279         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 280 fi
 281
 282
 283 rk_CHECK_MAN
 284
 285 rk_TEST_PACKAGE(readline,
 286 [#include <stdio.h>
 287  #include <readline.h>],-lreadline,,, READLINE)
 288
 289 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 290
 291 KRB_C_BIGENDIAN
 292 AC_C_INLINE
 293
 294 KRB_CHECK_X
 295
 296 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 297
 298 AC_CHECK_XAU
 299
 300 dnl AM_C_PROTOTYPES
 301
 302 dnl Checks for typedefs, structures, and compiler characteristics.
 303 AC_C_CONST
 304 AC_TYPE_OFF_T
 305 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 306 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 307 AC_HAVE_TYPE([long long])
 308 AC_HEADER_TIME
 309 AC_STRUCT_TM
 310
 311 dnl Checks for header files.
 312 AC_HEADER_STDC
 313
 314 AC_CHECK_HEADERS([\
 315         CommonCrypto/CommonDigest.h             \
 316         CommonCrypto/CommonCryptor.h            \
 317         arpa/ftp.h                              \
 318         arpa/telnet.h                           \
 319         bind/bitypes.h                          \
 320         bsdsetjmp.h                             \
 321         curses.h                                \
 322         dlfcn.h                                 \
 323         fnmatch.h                               \
 324         inttypes.h                              \
 325         io.h                                    \
 326         libutil.h                               \
 327         limits.h                                \
 328         maillock.h                              \
 329         netgroup.h                              \
 330         netinet/in6_machtypes.h                 \
 331         pthread.h                               \
 332         pty.h                                   \
 333         sac.h                                   \
 334         sgtty.h                                 \
 335         siad.h                                  \
 336         signal.h                                \
 337         strings.h                               \
 338         stropts.h                               \
 339         sys/bitypes.h                           \
 340         sys/category.h                          \
 341         sys/file.h                              \
 342         sys/filio.h                             \
 343         sys/ioccom.h                            \
 344         sys/mman.h                              \
 345         sys/param.h                             \
 346         sys/pty.h                               \
 347         sys/ptyio.h                             \
 348         sys/select.h                            \
 349         sys/socket.h                            \
 350         sys/str_tty.h                           \
 351         sys/stream.h                            \
 352         sys/stropts.h                           \
 353         sys/syscall.h                           \
 354         sys/termio.h                            \
 355         sys/timeb.h                             \
 356         sys/times.h                             \
 357         sys/types.h                             \
 358         sys/un.h                                \
 359         locale.h                                \
 360         termcap.h                               \
 361         termio.h                                \
 362         termios.h                               \
 363         time.h                                  \
 364         tmpdir.h                                \
 365         udb.h                                   \
 366         util.h                                  \
 367         utmp.h                                  \
 368         utmpx.h                                 \
 369 ])
 370
 371 dnl On Solaris 8 there's a compilation warning for term.h because
 372 dnl it doesn't define `bool'.
 373 AC_CHECK_HEADERS(term.h, , , -)
 374
 375 dnl aix have asl.h (A/IX screen library) that we don't want
 376 AC_CHECK_HEADERS(asl.h, , , [
 377 #include <asl.h>
 378 #ifndef ASL_STRING_EMERG
 379 #error ASL_STRING_EMERG missing
 380 #endif])
 381
 382 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 383 #if HAVE_SYS_SOCKET_H
 384 #include <sys/socket.h>
 385 #endif])
 386
 387 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 388 #if HAVE_SYS_TTY_H
 389 #include <sys/tty.h>
 390 #endif])
 391
 392 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 393 #if HAVE_TERMIOS_H
 394 #include <termios.h>
 395 #endif
 396 #if HAVE_SYS_STREAM_H
 397 #include <sys/stream.h>
 398 #endif])
 399
 400 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 401 #if HAVE_SYS_TYPES_H
 402 #include <sys/types.h>
 403 #endif
 404 #if HAVE_SYS_PARAM_H
 405 #include <sys/param.h>
 406 #endif])
 407
 408 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 409 #include <security/pam_appl.h>
 410 ])
 411
 412 dnl export symbols
 413 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 414 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 415 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 416
 417 dnl Checks for libraries.
 418
 419 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 420 #ifdef HAVE_UTIL_H
 421 #include <util.h>
 422 #endif
 423 ],[0,0,0])
 424 AC_FIND_FUNC_NO_LIBS(logout, util,[
 425 #ifdef HAVE_UTIL_H
 426 #include <util.h>
 427 #endif
 428 ],[0])
 429 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 430 #ifdef HAVE_UTIL_H
 431 #include <util.h>
 432 #endif
 433 ],[0,0,0,0,0])
 434
 435 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 436 #ifdef HAVE_TERMCAP_H
 437 #include <termcap.h>
 438 #endif
 439 #ifdef HAVE_CURSES_H
 440 #include <curses.h>
 441 #endif
 442 ],[0,0])
 443
 444 dnl Checks for library functions.
 445
 446 AC_CHECK_FUNCS([                                \
 447         _getpty                                 \
 448         _scrsize                                \
 449         arc4random                              \
 450         fcntl                                   \
 451         getpeereid                              \
 452         getpeerucred                            \
 453         grantpt                                 \
 454         mktime                                  \
 455         ptsname                                 \
 456         rand                                    \
 457         revoke                                  \
 458         select                                  \
 459         setitimer                               \
 460         setpcred                                \
 461         setpgid                                 \
 462         setproctitle                            \
 463         setregid                                \
 464         setresgid                               \
 465         setresuid                               \
 466         setreuid                                \
 467         setsid                                  \
 468         setutent                                \
 469         sigaction                               \
 470         strstr                                  \
 471         ttyname                                 \
 472         ttyslot                                 \
 473         umask                                   \
 474         unlockpt                                \
 475         vhangup                                 \
 476         yp_get_default_domain                   \
 477 ])
 478
 479 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 480 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 481         [[unsigned int foo; __sync_add_and_fetch(&foo, 1);]])],
 482         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 483 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 484         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 485 fi
 486 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 487
 488 AC_FUNC_MMAP
 489
 490 KRB_CAPABILITIES
 491
 492 AC_CHECK_GETPWNAM_R_POSIX
 493
 494 dnl detect doors on solaris
 495 if test "$enable_pthread_support" != no; then
 496    saved_LIBS="$LIBS"
 497    LIBS="$LIBS $PTHREADS_LIBS"
 498    AC_FIND_FUNC_NO_LIBS(door_create, door)
 499    LIBS="$saved_LIBS"
 500 fi
 501
 502 AC_ARG_ENABLE(kcm,
 503         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 504 ,[enable_kcm=yes])
 505
 506 if test "$enable_kcm" = yes ; then
 507    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 508         enable_kcm=no
 509    fi
 510 fi
 511 if test "$enable_kcm" = yes; then
 512        AC_DEFINE(HAVE_KCM, 1,
 513                [Define if you want to use the Kerberos Credentials Manager.])
 514 fi
 515 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 516
 517
 518
 519 dnl Cray stuff
 520 AC_CHECK_FUNCS(getudbnam setlim)
 521
 522 dnl AC_KRB_FUNC_GETCWD_BROKEN
 523
 524 dnl
 525 dnl Check for fields in struct utmp
 526 dnl
 527
 528 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 529 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 530 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 531 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 532 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 533 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 534 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_host, [#include <utmpx.h>])
 535 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_id, [#include <utmpx.h>])
 536 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_line, [#include <utmpx.h>])
 537 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_pid, [#include <utmpx.h>])
 538 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_tv, [#include <utmpx.h>])
 539 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_type, [#include <utmpx.h>])
 540 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_user, [#include <utmpx.h>])
 541 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 542 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 543
 544 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 545         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 546         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 547 #ifdef HAVE_INTTYPES_H
 548 #include <inttypes.h>
 549 #endif
 550 #ifdef HAVE_SYS_TYPES_H
 551 #include <sys/types.h>
 552 #endif
 553 #ifdef HAVE_SYS_BITYPES_H
 554 #include <sys/bitypes.h>
 555 #endif
 556 #ifdef HAVE_BIND_BITYPES_H
 557 #include <bind/bitypes.h>
 558 #endif
 559 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 560 #include <netinet/in6_machtypes.h>
 561 #endif
 562 ])
 563
 564 rk_FRAMEWORK_SECURITY
 565
 566 KRB_READLINE
 567
 568 rk_TELNET
 569
 570 dnl Some operating systems already have com_err and compile_et
 571 CHECK_COMPILE_ET
 572
 573 rk_AUTH_MODULES([sia afskauthlib])
 574
 575 rk_DESTDIRS
 576
 577 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 578
 579
 580 AH_BOTTOM([#ifdef __APPLE__
 581 #include <AvailabilityMacros.h>
 582 #endif])
 583
 584 AH_BOTTOM([#ifdef ROKEN_RENAME
 585 #include "roken_rename.h"
 586 #endif])
 587
 588 AC_CONFIG_FILES(Makefile                \
 589         etc/Makefile                    \
 590         include/Makefile                \
 591         include/gssapi/Makefile         \
 592         include/hcrypto/Makefile        \
 593         include/kadm5/Makefile          \
 594         lib/Makefile                    \
 595         base/Makefile                   \
 596         lib/asn1/Makefile               \
 597         lib/com_err/Makefile            \
 598         lib/hcrypto/Makefile            \
 599         lib/editline/Makefile           \
 600         lib/hx509/Makefile              \
 601         lib/gssapi/Makefile             \
 602         lib/ntlm/Makefile               \
 603         lib/hdb/Makefile                \
 604         lib/ipc/Makefile                \
 605         lib/kadm5/Makefile              \
 606         lib/kafs/Makefile               \
 607         lib/kdfs/Makefile               \
 608         lib/krb5/Makefile               \
 609         lib/otp/Makefile                \
 610         lib/roken/Makefile              \
 611         lib/sl/Makefile                 \
 612         lib/sqlite/Makefile             \
 613         lib/vers/Makefile               \
 614         lib/wind/Makefile               \
 615         po/Makefile                     \
 616         kuser/Makefile                  \
 617         kpasswd/Makefile                \
 618         kadmin/Makefile                 \
 619         admin/Makefile                  \
 620         kcm/Makefile                    \
 621         kdc/Makefile                    \
 622         appl/Makefile                   \
 623         appl/afsutil/Makefile           \
 624         appl/ftp/Makefile               \
 625         appl/ftp/common/Makefile        \
 626         appl/ftp/ftp/Makefile           \
 627         appl/ftp/ftpd/Makefile          \
 628         appl/gssmask/Makefile           \
 629         appl/kx/Makefile                \
 630         appl/login/Makefile             \
 631         appl/otp/Makefile               \
 632         appl/popper/Makefile            \
 633         appl/push/Makefile              \
 634         appl/rsh/Makefile               \
 635         appl/rcp/Makefile               \
 636         appl/su/Makefile                \
 637         appl/xnlock/Makefile            \
 638         appl/telnet/Makefile            \
 639         appl/telnet/libtelnet/Makefile  \
 640         appl/telnet/telnet/Makefile     \
 641         appl/telnet/telnetd/Makefile    \
 642         appl/test/Makefile              \
 643         appl/kf/Makefile                \
 644         appl/dceutils/Makefile          \
 645         tests/Makefile                  \
 646         tests/bin/Makefile              \
 647         tests/can/Makefile              \
 648         tests/db/Makefile               \
 649         tests/kdc/Makefile              \
 650         tests/ldap/Makefile             \
 651         tests/gss/Makefile              \
 652         tests/java/Makefile             \
 653         tests/plugin/Makefile           \
 654         packages/Makefile               \
 655         packages/mac/Makefile           \
 656         doc/Makefile                    \
 657         tools/Makefile                  \
 658 )
 659
 660 AC_OUTPUT
 661
 662 dnl
 663 dnl This is the release version name-number[beta]
 664 dnl
 665
 666 cat > include/newversion.h.in <<EOF
 667 #ifndef VERSION_HIDDEN
 668 #define VERSION_HIDDEN
 669 #endif
 670 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 671 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 672 EOF
 673
 674 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 675         echo "include/version.h is unchanged"
 676         rm -f include/newversion.h.in
 677 else
 678         echo "creating include/version.h"
 679         User=${USER-${LOGNAME}}
 680         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 681         Date=`date`
 682         mv -f include/newversion.h.in include/version.h.in
 683         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 684 fi