configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.3.0pre9],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17
  18 AC_PREFIX_DEFAULT(/usr/heimdal)
  19
  20 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  21 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  22
  23 AC_CANONICAL_HOST
  24 CANONICAL_HOST=$host
  25 AC_SUBST(CANONICAL_HOST)
  26
  27 dnl Hints for autobuild
  28 AB_INIT
  29
  30 rk_SYS_LARGEFILE
  31
  32 rk_AIX
  33 rk_IRIX
  34 rk_SUNOS
  35
  36 dnl
  37 dnl this is needed to run the configure tests against glibc
  38 dnl
  39 AC_DEFINE([_GNU_SOURCE], 1,
  40         [Define to enable extensions on glibc-based systems such as Linux.])
  41
  42 AC_OBJEXT
  43 AC_EXEEXT
  44
  45 dnl AC_KRB_PROG_YACC
  46 AC_PROG_YACC
  47 AM_PROG_LEX
  48 dnl AC_PROG_RANLIB
  49 AC_PROG_AWK
  50 AC_KRB_PROG_LN_S
  51
  52 AC_MIPS_ABI
  53 CC="$CC $abi"
  54 libdir="$libdir$abilibdirext"
  55
  56 AC_C___ATTRIBUTE__
  57
  58 LT_PREREQ([2.2])
  59 LT_INIT([shared static win32-dll])
  60
  61 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  62 rk_VERSIONSCRIPT
  63
  64 dnl
  65 dnl Helper bits for cross compiling
  66 dnl
  67
  68 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  69
  70 if test "${cross_compiling}" != yes ; then
  71    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  72    SLC="\$(top_builddir)/lib/sl/slc"
  73 else
  74    ASN1_COMPILE="asn1_compile"
  75    SLC="slc"
  76 fi
  77
  78 AC_SUBST([ASN1_COMPILE])
  79 AC_SUBST([SLC])
  80
  81
  82 dnl ---
  83
  84 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
  85
  86 rk_TEST_PACKAGE(openldap,
  87 [#include <lber.h>
  88 #include <ldap.h>],
  89 [-lldap -llber],,,OPENLDAP)
  90
  91 AC_ARG_ENABLE(hdb-openldap-module,
  92         AS_HELP_STRING([--enable-hdb-openldap-module],
  93                 [if you want support to build openldap hdb as shared object]))
  94 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
  95     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
  96 fi
  97 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
  98
  99 dnl
 100 dnl Optional modules, pk-init, digest, kx509
 101 dnl
 102
 103 AC_ARG_ENABLE(pk-init,
 104         AS_HELP_STRING([--disable-pk-init],
 105                 [if you want disable to PK-INIT support]))
 106 if test "$enable_pk_init" != no ;then
 107         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 108 fi
 109 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 110
 111 AC_ARG_ENABLE(digest,
 112         AS_HELP_STRING([--disable-digest],
 113                 [if you want disable to DIGEST support]))
 114 if test "$enable_digest" != no ;then
 115         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 116 fi
 117
 118 AC_ARG_ENABLE(kx509,
 119         AS_HELP_STRING([--disable-kx509],
 120                 [if you want disable to kx509 support]))
 121 if test "$enable_kx509" != no ;then
 122         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 123 fi
 124
 125 AC_ARG_ENABLE(krb4,
 126         AS_HELP_STRING([--disable-krb4],
 127                 [if you want disable to krb4 support]))
 128 if test "$enable_krb4" != no ;then
 129         AC_DEFINE([KRB4], 1, [Define to enable Kerberos 4.])
 130 fi
 131
 132
 133 dnl Check for sqlite
 134 rk_TEST_PACKAGE(sqlite3,
 135 [#include <sqlite3.h>
 136 #ifndef SQLITE_OPEN_CREATE
 137 #error "old version"
 138 #endif],
 139 [-lsqlite3],,,SQLITE3)
 140
 141 if test "X$with_sqlite3" != Xyes ; then
 142    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 143    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 144 fi
 145 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 146
 147 dnl check for libintl
 148 rk_TEST_PACKAGE(libintl,
 149 [#include <libintl.h>],
 150 [-lintl],,,LIBINTL)
 151
 152 dnl path where the hdb directory is stored
 153 AC_ARG_WITH([hdbdir],
 154         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 155         [],
 156         [with_hdbdir=/var/heimdal])
 157 DIR_hdbdir="$with_hdbdir"
 158 AC_SUBST([DIR_hdbdir])
 159
 160
 161 dnl no kerberos4 any more
 162 with_krb4=no
 163 AC_SUBST(INCLUDE_krb4)
 164 AC_SUBST(LIB_krb4)
 165 AM_CONDITIONAL(KRB4, false)
 166
 167 AM_CONDITIONAL(KRB5, true)
 168 AM_CONDITIONAL(do_roken_rename, true)
 169
 170 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 171 AC_SUBST(LIB_kdb)dnl
 172
 173 KRB_CRYPTO
 174
 175 KRB_PTHREADS
 176
 177 AC_ARG_ENABLE(dce,
 178         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 179 if test "$enable_dce" = yes; then
 180     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 181 fi
 182 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 183
 184 ## XXX quite horrible:
 185 if test -f /etc/ibmcxx.cfg; then
 186         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 187         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 188         dpagaix_ldflags=
 189 else
 190         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 191         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 192         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 193 fi
 194 AC_SUBST(dpagaix_cflags)
 195 AC_SUBST(dpagaix_ldadd)
 196 AC_SUBST(dpagaix_ldflags)
 197
 198 AC_ARG_ENABLE([afs-support],
 199         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 200 if test "$enable_afs_support" = no; then
 201         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 202 fi
 203
 204 rk_DB
 205
 206 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 207
 208 rk_ROKEN(lib/roken)
 209 LIBADD_roken="$LIB_roken"
 210 AC_SUBST(LIBADD_roken)dnl
 211 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 212
 213 rk_OTP
 214
 215 AC_CHECK_OSFC2
 216
 217 AC_ARG_ENABLE(mmap,
 218         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 219 if test "$enable_mmap" = "no"; then
 220         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 221 fi
 222
 223 AC_ARG_ENABLE(afs-string-to-key,
 224         AS_HELP_STRING([--disable-afs-string-to-key],
 225         [disable use of weak AFS string-to-key functions]),
 226         [], [enable_afs_string_to_key=yes])
 227
 228 if test "$enable_afs_string_to_key" = "yes"; then
 229         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 230 fi
 231
 232
 233 rk_CHECK_MAN
 234
 235 rk_TEST_PACKAGE(readline,
 236 [#include <stdio.h>
 237  #include <readline.h>],-lreadline,,, READLINE)
 238
 239 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 240
 241 KRB_C_BIGENDIAN
 242 AC_C_INLINE
 243
 244 KRB_CHECK_X
 245
 246 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 247
 248 AC_CHECK_XAU
 249
 250 dnl AM_C_PROTOTYPES
 251
 252 dnl Checks for typedefs, structures, and compiler characteristics.
 253 AC_C_CONST
 254 AC_TYPE_OFF_T
 255 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 256 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 257 AC_HAVE_TYPE([long long])
 258 AC_HEADER_TIME
 259 AC_STRUCT_TM
 260
 261 dnl Checks for header files.
 262 AC_HEADER_STDC
 263
 264 AC_CHECK_HEADERS([\
 265         arpa/ftp.h                              \
 266         arpa/telnet.h                           \
 267         bind/bitypes.h                          \
 268         bsdsetjmp.h                             \
 269         curses.h                                \
 270         dlfcn.h                                 \
 271         fnmatch.h                               \
 272         inttypes.h                              \
 273         io.h                                    \
 274         libutil.h                               \
 275         limits.h                                \
 276         maillock.h                              \
 277         netgroup.h                              \
 278         netinet/in6_machtypes.h                 \
 279         pthread.h                               \
 280         pty.h                                   \
 281         sac.h                                   \
 282         sgtty.h                                 \
 283         siad.h                                  \
 284         signal.h                                \
 285         strings.h                               \
 286         stropts.h                               \
 287         sys/bitypes.h                           \
 288         sys/category.h                          \
 289         sys/file.h                              \
 290         sys/filio.h                             \
 291         sys/ioccom.h                            \
 292         sys/mman.h                              \
 293         sys/param.h                             \
 294         sys/pty.h                               \
 295         sys/ptyio.h                             \
 296         sys/select.h                            \
 297         sys/socket.h                            \
 298         sys/str_tty.h                           \
 299         sys/stream.h                            \
 300         sys/stropts.h                           \
 301         sys/syscall.h                           \
 302         sys/termio.h                            \
 303         sys/timeb.h                             \
 304         sys/times.h                             \
 305         sys/types.h                             \
 306         sys/un.h                                \
 307         locale.h                                \
 308         termcap.h                               \
 309         termio.h                                \
 310         termios.h                               \
 311         time.h                                  \
 312         tmpdir.h                                \
 313         udb.h                                   \
 314         util.h                                  \
 315         utmp.h                                  \
 316         utmpx.h                                 \
 317 ])
 318
 319 dnl On Solaris 8 there's a compilation warning for term.h because
 320 dnl it doesn't define `bool'.
 321 AC_CHECK_HEADERS(term.h, , , -)
 322
 323 dnl aix have asl.h (A/IX screen library) that we don't want
 324 AC_CHECK_HEADERS(asl.h, , , [
 325 #include <asl.h>
 326 #ifndef ASL_STRING_EMERG
 327 #error ASL_STRING_EMERG missing
 328 #endif])
 329
 330 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 331 #if HAVE_SYS_SOCKET_H
 332 #include <sys/socket.h>
 333 #endif])
 334
 335 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 336 #if HAVE_SYS_TTY_H
 337 #include <sys/tty.h>
 338 #endif])
 339
 340 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 341 #if HAVE_TERMIOS_H
 342 #include <termios.h>
 343 #endif
 344 #if HAVE_SYS_STREAM_H
 345 #include <sys/stream.h>
 346 #endif])
 347
 348 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 349 #if HAVE_SYS_TYPES_H
 350 #include <sys/types.h>
 351 #endif
 352 #if HAVE_SYS_PARAM_H
 353 #include <sys/param.h>
 354 #endif])
 355
 356 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 357 #include <security/pam_appl.h>
 358 ])
 359
 360 dnl export symbols
 361 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 362 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 363 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 364
 365 dnl Checks for libraries.
 366
 367 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 368 #ifdef HAVE_UTIL_H
 369 #include <util.h>
 370 #endif
 371 ],[0,0,0])
 372 AC_FIND_FUNC_NO_LIBS(logout, util,[
 373 #ifdef HAVE_UTIL_H
 374 #include <util.h>
 375 #endif
 376 ],[0])
 377 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 378 #ifdef HAVE_UTIL_H
 379 #include <util.h>
 380 #endif
 381 ],[0,0,0,0,0])
 382
 383 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 384 #ifdef HAVE_TERMCAP_H
 385 #include <termcap.h>
 386 #endif
 387 #ifdef HAVE_CURSES_H
 388 #include <curses.h>
 389 #endif
 390 ],[0,0])
 391
 392 dnl Checks for library functions.
 393
 394 AC_CHECK_FUNCS([                                \
 395         _getpty                                 \
 396         _scrsize                                \
 397         arc4random                              \
 398         fcntl                                   \
 399         getpeereid                              \
 400         getpeerucred                            \
 401         grantpt                                 \
 402         mktime                                  \
 403         ptsname                                 \
 404         rand                                    \
 405         revoke                                  \
 406         select                                  \
 407         setitimer                               \
 408         setpcred                                \
 409         setpgid                                 \
 410         setproctitle                            \
 411         setregid                                \
 412         setresgid                               \
 413         setresuid                               \
 414         setreuid                                \
 415         setsid                                  \
 416         setutent                                \
 417         sigaction                               \
 418         strstr                                  \
 419         ttyname                                 \
 420         ttyslot                                 \
 421         umask                                   \
 422         unlockpt                                \
 423         vhangup                                 \
 424         yp_get_default_domain                   \
 425 ])
 426
 427 AC_FUNC_MMAP
 428
 429 KRB_CAPABILITIES
 430
 431 AC_CHECK_GETPWNAM_R_POSIX
 432
 433 dnl detect doors on solaris
 434 if test "$enable_pthread_support" != no; then
 435    saved_LIBS="$LIBS"
 436    LIBS="$LIBS $PTHREADS_LIBS"
 437    AC_FIND_FUNC_NO_LIBS(door_create, door)
 438    LIBS="$saved_LIBS"
 439 fi
 440
 441 AC_ARG_ENABLE(kcm,
 442         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 443 ,[enable_kcm=yes])
 444
 445 if test "$enable_kcm" = yes ; then
 446    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 447         enable_kcm=no
 448    fi
 449 fi
 450 if test "$enable_kcm" = yes; then
 451        AC_DEFINE(HAVE_KCM, 1,
 452                [Define if you want to use the Kerberos Credentials Manager.])
 453 fi
 454 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 455
 456
 457
 458 dnl Cray stuff
 459 AC_CHECK_FUNCS(getudbnam setlim)
 460
 461 dnl AC_KRB_FUNC_GETCWD_BROKEN
 462
 463 dnl
 464 dnl Check for fields in struct utmp
 465 dnl
 466
 467 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 468 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 469 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 470 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 471 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 472 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 473 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 474 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 475
 476 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 477         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 478         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 479 #ifdef HAVE_INTTYPES_H
 480 #include <inttypes.h>
 481 #endif
 482 #ifdef HAVE_SYS_TYPES_H
 483 #include <sys/types.h>
 484 #endif
 485 #ifdef HAVE_SYS_BITYPES_H
 486 #include <sys/bitypes.h>
 487 #endif
 488 #ifdef HAVE_BIND_BITYPES_H
 489 #include <bind/bitypes.h>
 490 #endif
 491 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 492 #include <netinet/in6_machtypes.h>
 493 #endif
 494 ])
 495
 496 rk_FRAMEWORK_SECURITY
 497
 498 KRB_READLINE
 499
 500 rk_TELNET
 501
 502 dnl Some operating systems already have com_err and compile_et
 503 CHECK_COMPILE_ET
 504
 505 rk_AUTH_MODULES([sia afskauthlib])
 506
 507 rk_DESTDIRS
 508
 509 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 510
 511
 512 AH_BOTTOM([#ifdef ROKEN_RENAME
 513 #include "roken_rename.h"
 514 #endif])
 515
 516 AC_CONFIG_FILES(Makefile                \
 517         etc/Makefile                    \
 518         include/Makefile                \
 519         include/gssapi/Makefile         \
 520         include/hcrypto/Makefile        \
 521         include/kadm5/Makefile          \
 522         lib/Makefile                    \
 523         lib/auth/Makefile               \
 524         lib/auth/afskauthlib/Makefile   \
 525         lib/auth/pam/Makefile           \
 526         lib/auth/sia/Makefile           \
 527         lib/asn1/Makefile               \
 528         lib/com_err/Makefile            \
 529         lib/hcrypto/Makefile            \
 530         lib/editline/Makefile           \
 531         lib/hx509/Makefile              \
 532         lib/gssapi/Makefile             \
 533         lib/ntlm/Makefile               \
 534         lib/hdb/Makefile                \
 535         lib/kadm5/Makefile              \
 536         lib/kafs/Makefile               \
 537         lib/kdfs/Makefile               \
 538         lib/krb5/Makefile               \
 539         lib/otp/Makefile                \
 540         lib/roken/Makefile              \
 541         lib/sl/Makefile                 \
 542         lib/sqlite/Makefile             \
 543         lib/vers/Makefile               \
 544         lib/wind/Makefile               \
 545         po/Makefile                     \
 546         kuser/Makefile                  \
 547         kpasswd/Makefile                \
 548         kadmin/Makefile                 \
 549         admin/Makefile                  \
 550         kcm/Makefile                    \
 551         kdc/Makefile                    \
 552         appl/Makefile                   \
 553         appl/afsutil/Makefile           \
 554         appl/ftp/Makefile               \
 555         appl/ftp/common/Makefile        \
 556         appl/ftp/ftp/Makefile           \
 557         appl/ftp/ftpd/Makefile          \
 558         appl/gssmask/Makefile           \
 559         appl/kx/Makefile                \
 560         appl/login/Makefile             \
 561         appl/otp/Makefile               \
 562         appl/popper/Makefile            \
 563         appl/push/Makefile              \
 564         appl/rsh/Makefile               \
 565         appl/rcp/Makefile               \
 566         appl/su/Makefile                \
 567         appl/xnlock/Makefile            \
 568         appl/telnet/Makefile            \
 569         appl/telnet/libtelnet/Makefile  \
 570         appl/telnet/telnet/Makefile     \
 571         appl/telnet/telnetd/Makefile    \
 572         appl/test/Makefile              \
 573         appl/kf/Makefile                \
 574         appl/dceutils/Makefile          \
 575         tests/Makefile                  \
 576         tests/bin/Makefile              \
 577         tests/can/Makefile              \
 578         tests/db/Makefile               \
 579         tests/kdc/Makefile              \
 580         tests/ldap/Makefile             \
 581         tests/gss/Makefile              \
 582         tests/java/Makefile             \
 583         tests/plugin/Makefile           \
 584         packages/Makefile               \
 585         packages/mac/Makefile           \
 586         doc/Makefile                    \
 587         tools/Makefile                  \
 588 )
 589
 590 AC_OUTPUT
 591
 592 dnl
 593 dnl This is the release version name-number[beta]
 594 dnl
 595
 596 cat > include/newversion.h.in <<EOF
 597 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 598 const char *heimdal_version = "AC_PACKAGE_STRING";
 599 EOF
 600
 601 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 602         echo "include/version.h is unchanged"
 603         rm -f include/newversion.h.in
 604 else
 605         echo "creating include/version.h"
 606         User=${USER-${LOGNAME}}
 607         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 608         Date=`date`
 609         mv -f include/newversion.h.in include/version.h.in
 610         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 611 fi