configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21 AC_CHECK_PROG(CLANG_FORMAT, clang-format, [clang-format], [no])
  22
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24
  25 AC_PREFIX_DEFAULT(/usr/heimdal)
  26
  27 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  28 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  29
  30 AC_CANONICAL_HOST
  31 CANONICAL_HOST=$host
  32 AC_SUBST(CANONICAL_HOST)
  33
  34 rk_SYS_LARGEFILE
  35
  36 rk_AIX
  37 rk_IRIX
  38 rk_SUNOS
  39
  40 dnl
  41 dnl this is needed to run the configure tests against glibc
  42 dnl
  43 AC_DEFINE([_GNU_SOURCE], 1,
  44         [Define to enable extensions on glibc-based systems such as Linux.])
  45
  46 AC_OBJEXT
  47 AC_EXEEXT
  48
  49 dnl
  50 dnl this is needed when der-protos.h or der-private.h has to be generated
  51 dnl
  52 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  53    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  54     AC_KRB_PROG_PERL
  55     AC_KRB_PERL_MOD(Getopt::Std)
  56     AC_KRB_PERL_MOD(File::Compare)
  57     AC_KRB_PERL_MOD(JSON)
  58 fi
  59
  60 dnl AC_KRB_PROG_YACC
  61 AC_PROG_YACC
  62 AM_PROG_LEX
  63 AS_IF([$LEX --nounput -V > /dev/null 2>&1 && test $? -eq 0],
  64       [AC_SUBST([FLEXNOUNPUTARGS], ["--nounput"])],
  65       [AC_SUBST([FLEXNOUNPUTARGS], [""])])
  66 dnl AC_PROG_RANLIB
  67 AC_PROG_AWK
  68 AC_KRB_PROG_LN_S
  69
  70 AC_MIPS_ABI
  71 CC="$CC $abi"
  72 libdir="$libdir$abilibdirext"
  73
  74 AC_C___ATTRIBUTE__
  75
  76 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  77 rk_VERSIONSCRIPT
  78
  79 dnl Code coverage
  80 AC_ARG_ENABLE([gcov],
  81         AC_HELP_STRING([--enable-gcov], [enable gcov code coverage tool]))
  82 AM_CONDITIONAL([ENABLE_GCOV], [test "x$enable_gcov" = xyes])
  83
  84
  85 dnl
  86 dnl Helper bits for cross compiling
  87 dnl
  88
  89
  90
  91 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  92
  93 AC_ARG_WITH(cross-tools,
  94         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  95         [if test "$withval" = "yes"; then
  96                 AC_MSG_ERROR([Need path to cross tools])
  97         fi
  98         with_cross_tools="${with_cross_tools}/"
  99         ])
 100
 101 if test "${cross_compiling}" != yes ; then
 102
 103    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
 104    SLC="\$(top_builddir)/lib/sl/slc"
 105
 106    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
 107    SLC_DEP="\$(SLC)"
 108 else
 109    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 110    SLC="${with_cross_tools}slc"
 111
 112    ASN1_COMPILE_DEP=
 113    SLC_DEP=
 114
 115    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 116
 117 fi
 118
 119 AC_SUBST([ASN1_COMPILE])
 120 AC_SUBST([ASN1_COMPILE_DEP])
 121 AC_SUBST([SLC])
 122 AC_SUBST([SLC_DEP])
 123
 124 dnl ---
 125
 126 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 127
 128 rk_TEST_PACKAGE(openldap,
 129 [#include <lber.h>
 130 #include <ldap.h>],
 131 [-lldap -llber],,,OPENLDAP)
 132
 133 AC_ARG_ENABLE(hdb-openldap-module,
 134         AS_HELP_STRING([--enable-hdb-openldap-module],
 135                 [if you want support to build openldap hdb as shared object]))
 136 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 137     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 138 fi
 139 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 140
 141 AC_ARG_ENABLE(asn1-templating,
 142         AS_HELP_STRING([--disable-asn1-templating],
 143                 [if you want disable to use of the ASN.1 templating compiler]))
 144 AM_CONDITIONAL(ASN1_TEMPLATING, test "x$enable_asn1_templating" != xno)
 145
 146 dnl
 147 dnl Optional modules, pk-init, digest, kx509
 148 dnl
 149
 150 AC_ARG_ENABLE(pk-init,
 151         AS_HELP_STRING([--disable-pk-init],
 152                 [if you want disable to PK-INIT support]))
 153 if test "$enable_pk_init" != no ;then
 154         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 155 fi
 156 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 157
 158 AC_ARG_ENABLE(digest,
 159         AS_HELP_STRING([--disable-digest],
 160                 [if you want disable to DIGEST support]))
 161 if test "$enable_digest" != no ;then
 162         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 163 fi
 164
 165 AC_ARG_ENABLE(kx509,
 166         AS_HELP_STRING([--disable-kx509],
 167                 [if you want disable to kx509 support]))
 168 if test "$enable_kx509" != no ;then
 169         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 170 fi
 171
 172 dnl Need to test if pkg-config exists
 173 PKG_PROG_PKG_CONFIG
 174
 175 dnl libcap-ng
 176 AC_ARG_WITH([capng],
 177   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 178   [],
 179   [with_capng=check])
 180 if test "$with_capng" != "no"; then
 181   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 182                     [with_capng=yes],[with_capng=no])
 183 fi
 184 if test "$with_capng" = "yes"; then
 185   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 186 fi
 187 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 188 AC_SUBST([CAPNG_CFLAGS])
 189 AC_SUBST([CAPNG_LIBS])
 190
 191 dnl libmicrohttpd
 192 AC_ARG_WITH([microhttpd],
 193   AC_HELP_STRING([--with-microhttpd], [use microhttpd to serve KDC REST API @<:@default=check@:>@]),
 194   [],
 195   [with_microhttpd=check])
 196 if test "$with_microhttpd" != "no"; then
 197   PKG_CHECK_MODULES([MICROHTTPD], [libmicrohttpd >= 0.9.37],
 198                     [with_microhttpd=yes],[with_microhttpd=no])
 199 fi
 200 if test "$with_microhttpd" = "yes"; then
 201   AC_DEFINE_UNQUOTED([HAVE_MICROHTTPD], 1, [whether libmicrohttpd is available for KDC REST API])
 202 fi
 203 AM_CONDITIONAL([HAVE_MICROHTTPD], [test "$with_microhttpd" != "no"])
 204 AC_SUBST([MICROHTTPD_CFLAGS])
 205 AC_SUBST([MICROHTTPD_LIBS])
 206
 207 dnl libcjwt
 208 AC_ARG_WITH([cjwt],
 209   AC_HELP_STRING([--with-cjwt], [(Experimental) use cjwt to validate JWT tokens @<:@default=check@:>@]),
 210   [],
 211   [with_cjwt=check])
 212 if test "$with_cjwt" != "no"; then
 213   PKG_CHECK_MODULES([CJWT], [libcjwt >= 1.0.0],
 214                     [with_cjwt=yes],[with_cjwt=no])
 215 fi
 216 if test "$with_cjwt" = "yes"; then
 217   AC_DEFINE_UNQUOTED([HAVE_CJWT], 1, [whether libcjwt is available for KDC REST API])
 218 fi
 219 AM_CONDITIONAL([HAVE_CJWT], [test "$with_cjwt" != "no"])
 220 AC_SUBST([CJWT_CFLAGS])
 221 AC_SUBST([CJWT_LIBS])
 222
 223 dnl libcjson
 224 AC_ARG_WITH([cjson],
 225   AC_HELP_STRING([--with-cjson], [(Experimental) use cJSON to extract private claims from JWT tokens @<:@default=check@:>@]),
 226   [],
 227   [with_cjson=check])
 228 if test "$with_cjson" != "no"; then
 229   PKG_CHECK_MODULES([CJSON], [libcjson >= 1.0.0],
 230                     [with_cjson=yes],[with_cjson=no])
 231 fi
 232 if test "$with_cjson" = "yes"; then
 233   AC_DEFINE_UNQUOTED([HAVE_CJSON], 1, [whether libcjson is available for KDC REST API])
 234 fi
 235 AM_CONDITIONAL([HAVE_CJSON], [test "$with_cjson" != "no"])
 236 AC_SUBST([CJSON_CFLAGS])
 237 AC_SUBST([CJSON_LIBS])
 238
 239 dnl Check for sqlite
 240 rk_TEST_PACKAGE(sqlite3,
 241 [#include <sqlite3.h>
 242 #ifndef SQLITE_OPEN_CREATE
 243 #error "old version"
 244 #endif],
 245 [-lsqlite3],,,SQLITE3)
 246
 247 if test "X$with_sqlite3" != Xyes ; then
 248    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 249    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 250 fi
 251 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 252
 253 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 254
 255 AC_ARG_ENABLE(sqlite-cache,
 256         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 257 if test "$enable_sqlite_cache" != no; then
 258     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 259 fi
 260 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 261
 262
 263 dnl check for libintl
 264 rk_TEST_PACKAGE(libintl,
 265 [#include <libintl.h>],
 266 [-lintl],,,LIBINTL)
 267
 268 dnl path where the hdb directory is stored
 269 AC_ARG_WITH([hdbdir],
 270         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 271         [],
 272         [with_hdbdir=/var/heimdal])
 273 DIR_hdbdir="$with_hdbdir"
 274 AC_SUBST([DIR_hdbdir])
 275
 276
 277 AM_CONDITIONAL(KRB5, true)
 278 AM_CONDITIONAL(do_roken_rename, true)
 279
 280 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 281
 282
 283 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 284 AC_SUBST(LIB_kdb)dnl
 285
 286 KRB_CRYPTO
 287
 288 KRB_PTHREADS
 289
 290 AC_ARG_ENABLE(dce,
 291         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 292 if test "$enable_dce" = yes; then
 293     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 294 fi
 295 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 296
 297 ## XXX quite horrible:
 298 if test -f /etc/ibmcxx.cfg; then
 299         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 300         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 301         dpagaix_ldflags=
 302 else
 303         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 304         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 305         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 306 fi
 307 AC_SUBST(dpagaix_cflags)
 308 AC_SUBST(dpagaix_ldadd)
 309 AC_SUBST(dpagaix_ldflags)
 310
 311 AC_ARG_ENABLE([afs-support],
 312         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 313 if test "$enable_afs_support" = no; then
 314         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 315         NO_AFS="1"
 316 fi
 317 AC_SUBST(NO_AFS)dnl
 318 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 319
 320 rk_DB
 321
 322 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 323
 324 rk_ROKEN(lib/roken)
 325 LIBADD_roken="$LIB_roken"
 326 AC_SUBST(LIBADD_roken)dnl
 327 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 328
 329 rk_OTP
 330
 331 rk_LIBDISPATCH
 332
 333 AC_CHECK_OSFC2
 334
 335 AC_ARG_ENABLE(mmap,
 336         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 337 if test "$enable_mmap" = "no"; then
 338         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 339 fi
 340
 341 AC_ARG_ENABLE(afs-string-to-key,
 342         AS_HELP_STRING([--disable-afs-string-to-key],
 343         [disable use of weak AFS string-to-key functions]),
 344         [], [enable_afs_string_to_key=yes])
 345
 346 if test "$enable_afs_string_to_key" = "yes"; then
 347         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 348         ENABLE_AFS_STRING_TO_KEY=1
 349 fi
 350 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 351
 352
 353 rk_CHECK_MAN
 354
 355 rk_TEST_PACKAGE(readline,
 356 [#include <stdio.h>
 357 #if defined(HAVE_READLINE_READLINE_H)
 358 #include <readline/readline.h>
 359 #elif defined(HAVE_READLINE_H)
 360 #include <readline.h>
 361 #endif
 362 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 363
 364 rk_TEST_PACKAGE(libedit,
 365 [#include <stdio.h>
 366 #if defined(HAVE_READLINE_READLINE_H)
 367 #include <readline/readline.h>
 368 #elif defined(HAVE_READLINE_H)
 369 #include <readline.h>
 370 #elif defined(HAVE_EDITLINE_READLINE_H)
 371 #include <editline/readline.h>
 372 #endif
 373 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 374
 375 AC_CONFIG_SUBDIRS([lib/libedit])
 376
 377 KRB_C_BIGENDIAN
 378 AC_C_INLINE
 379
 380 dnl AM_C_PROTOTYPES
 381
 382 dnl Checks for typedefs, structures, and compiler characteristics.
 383 AC_C_CONST
 384 AC_TYPE_OFF_T
 385 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 386 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 387 AC_HAVE_TYPE([long long])
 388 AC_HEADER_TIME
 389 AC_STRUCT_TM
 390
 391 dnl Checks for header files.
 392 AC_HEADER_STDC
 393
 394 AC_CHECK_HEADERS([\
 395         CommonCrypto/CommonDigest.h             \
 396         CommonCrypto/CommonCryptor.h            \
 397         arpa/telnet.h                           \
 398         bind/bitypes.h                          \
 399         bsdsetjmp.h                             \
 400         curses.h                                \
 401         dlfcn.h                                 \
 402         execinfo.h                              \
 403         fnmatch.h                               \
 404         inttypes.h                              \
 405         io.h                                    \
 406         keyutils.h                              \
 407         libutil.h                               \
 408         limits.h                                \
 409         maillock.h                              \
 410         netgroup.h                              \
 411         netinet/in6_machtypes.h                 \
 412         netinet/tcp.h                           \
 413         pthread.h                               \
 414         pty.h                                   \
 415         sac.h                                   \
 416         sgtty.h                                 \
 417         siad.h                                  \
 418         signal.h                                \
 419         strings.h                               \
 420         stropts.h                               \
 421         stdatomic.h                             \
 422         sys/bitypes.h                           \
 423         sys/category.h                          \
 424         sys/file.h                              \
 425         sys/filio.h                             \
 426         sys/ioccom.h                            \
 427         sys/mman.h                              \
 428         sys/param.h                             \
 429         sys/pty.h                               \
 430         sys/ptyio.h                             \
 431         sys/select.h                            \
 432         sys/socket.h                            \
 433         sys/str_tty.h                           \
 434         sys/stream.h                            \
 435         sys/stropts.h                           \
 436         sys/syscall.h                           \
 437         sys/termio.h                            \
 438         sys/timeb.h                             \
 439         sys/times.h                             \
 440         sys/types.h                             \
 441         sys/un.h                                \
 442         locale.h                                \
 443         termcap.h                               \
 444         termio.h                                \
 445         termios.h                               \
 446         time.h                                  \
 447         tmpdir.h                                \
 448         udb.h                                   \
 449         util.h                                  \
 450 ])
 451
 452 dnl On Solaris 8 there's a compilation warning for term.h because
 453 dnl it doesn't define `bool'.
 454 AC_CHECK_HEADERS(term.h, , , -)
 455
 456 dnl aix have asl.h (A/IX screen library) that we don't want
 457 AC_CHECK_HEADERS(asl.h, , , [
 458 #include <asl.h>
 459 #ifndef ASL_STRING_EMERG
 460 #error ASL_STRING_EMERG missing
 461 #endif])
 462
 463 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 464 #if HAVE_SYS_SOCKET_H
 465 #include <sys/socket.h>
 466 #endif])
 467
 468 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 469 #if HAVE_SYS_TTY_H
 470 #include <sys/tty.h>
 471 #endif])
 472
 473 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 474 #if HAVE_TERMIOS_H
 475 #include <termios.h>
 476 #endif
 477 #if HAVE_SYS_STREAM_H
 478 #include <sys/stream.h>
 479 #endif])
 480
 481 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 482 #if HAVE_SYS_TYPES_H
 483 #include <sys/types.h>
 484 #endif
 485 #if HAVE_SYS_PARAM_H
 486 #include <sys/param.h>
 487 #endif])
 488
 489 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 490 #include <security/pam_appl.h>
 491 ])
 492
 493 dnl export symbols
 494 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 495 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 496 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 497
 498 dnl Checks for libraries.
 499
 500 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 501 #ifdef HAVE_UTIL_H
 502 #include <util.h>
 503 #endif
 504 ],[0,0,0])
 505 AC_FIND_FUNC_NO_LIBS(logout, util,[
 506 #ifdef HAVE_UTIL_H
 507 #include <util.h>
 508 #endif
 509 ],[0])
 510 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 511 #ifdef HAVE_UTIL_H
 512 #include <util.h>
 513 #endif
 514 ],[0,0,0,0,0])
 515
 516 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses tinfo,[
 517 #ifdef HAVE_TERMCAP_H
 518 #include <termcap.h>
 519 #endif
 520 #ifdef HAVE_CURSES_H
 521 #include <curses.h>
 522 #endif
 523 ],[0,0])
 524
 525 dnl Checks for library functions.
 526
 527 AC_CHECK_FUNCS([                                \
 528         _getpty                                 \
 529         _scrsize                                \
 530         arc4random                              \
 531         backtrace                               \
 532         fcntl                                   \
 533         fork                                    \
 534         fseeko                                  \
 535         ftello                                  \
 536         getpeereid                              \
 537         getpeerucred                            \
 538         getresgid                               \
 539         getresuid                               \
 540         grantpt                                 \
 541         kill                                    \
 542         mktime                                  \
 543         ptsname                                 \
 544         rand                                    \
 545         revoke                                  \
 546         select                                  \
 547         setitimer                               \
 548         setpcred                                \
 549         setpgid                                 \
 550         setproctitle                            \
 551         setregid                                \
 552         setresgid                               \
 553         setresuid                               \
 554         setreuid                                \
 555         setsid                                  \
 556         setutent                                \
 557         sigaction                               \
 558         strstr                                  \
 559         ttyname                                 \
 560         ttyslot                                 \
 561         umask                                   \
 562         unlockpt                                \
 563         vhangup                                 \
 564         waitpid                                 \
 565         yp_get_default_domain                   \
 566 ])
 567
 568 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 569 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 570         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 571         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 572 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 573         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 574 fi
 575 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 576
 577 AC_FUNC_MMAP
 578
 579 KRB_CAPABILITIES
 580 rk_DLADDR
 581
 582 AC_CHECK_GETPWNAM_R_POSIX
 583 AC_CHECK_GETPWUID_R_POSIX
 584
 585 dnl detect doors on solaris
 586 if test "$enable_pthread_support" != no; then
 587    saved_LIBS="$LIBS"
 588    LIBS="$LIBS $PTHREADS_LIBS"
 589    AC_FIND_FUNC_NO_LIBS(door_create, door)
 590    LIBS="$saved_LIBS"
 591 fi
 592
 593 AC_ARG_ENABLE(kcm,
 594         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 595 ,[enable_kcm=yes])
 596
 597 if test "$enable_kcm" = yes ; then
 598    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 599         enable_kcm=no
 600    fi
 601 fi
 602 if test "$enable_kcm" = yes; then
 603        AC_DEFINE(HAVE_KCM, 1,
 604                [Define if you want to use the Kerberos Credentials Manager.])
 605 fi
 606 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 607
 608 dnl detect keyring on Linux
 609 if test "$ac_cv_header_keyutils_h" = yes; then
 610     AC_CHECK_SIZEOF([key_serial_t],,[
 611         #ifdef HAVE_INTTYPES_H
 612         #include <inttypes.h>
 613         #endif
 614         #ifdef HAVE_SYS_TYPES_H
 615         #include <sys/types.h>
 616         #endif
 617         #include <keyutils.h>
 618     ])
 619 fi
 620
 621 AC_FIND_FUNC_NO_LIBS(add_key, keyutils)
 622 if test -n "$LIB_add_key"; then
 623     saved_LIBS="$LIBS"
 624     LIBS="$LIBS $LIB_add_key"
 625     AC_CHECK_FUNCS(keyctl_get_persistent)
 626     LIBS="$saved_LIBS"
 627 fi
 628
 629 AC_CHECK_SIZEOF([time_t])
 630
 631 dnl Cray stuff
 632 AC_CHECK_FUNCS(getudbnam setlim)
 633
 634 dnl AC_KRB_FUNC_GETCWD_BROKEN
 635
 636 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 637         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 638         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 639 #ifdef HAVE_INTTYPES_H
 640 #include <inttypes.h>
 641 #endif
 642 #ifdef HAVE_SYS_TYPES_H
 643 #include <sys/types.h>
 644 #endif
 645 #ifdef HAVE_SYS_BITYPES_H
 646 #include <sys/bitypes.h>
 647 #endif
 648 #ifdef HAVE_BIND_BITYPES_H
 649 #include <bind/bitypes.h>
 650 #endif
 651 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 652 #include <netinet/in6_machtypes.h>
 653 #endif
 654 ])
 655
 656 rk_FRAMEWORK_SECURITY
 657 rk_FRAMEWORK_COREFOUNDATION
 658
 659 KRB_READLINE
 660
 661 rk_TELNET
 662
 663 dnl Some operating systems already have com_err and compile_et
 664 CHECK_COMPILE_ET
 665
 666 rk_AUTH_MODULES([sia afskauthlib])
 667
 668 rk_DESTDIRS
 669
 670 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 671
 672
 673 AH_BOTTOM([#ifdef __APPLE__
 674 #include <AvailabilityMacros.h>
 675 #endif])
 676
 677 AH_BOTTOM([#ifdef ROKEN_RENAME
 678 #include "roken_rename.h"
 679 #endif])
 680
 681 AC_ARG_ENABLE(heimdal-documentation,
 682         AS_HELP_STRING([--disable-heimdal-documentation],
 683                 [if you want disable to heimdal documentation]))
 684 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 685
 686 AC_CONFIG_FILES(Makefile                \
 687         etc/Makefile                    \
 688         include/Makefile                \
 689         include/gssapi/Makefile         \
 690         include/hcrypto/Makefile        \
 691         include/kadm5/Makefile          \
 692         lib/Makefile                    \
 693         lib/base/Makefile                       \
 694         lib/asn1/Makefile               \
 695         lib/com_err/Makefile            \
 696         lib/hcrypto/Makefile            \
 697         lib/hx509/Makefile              \
 698         lib/gssapi/Makefile             \
 699         lib/ntlm/Makefile               \
 700         lib/hdb/Makefile                \
 701         lib/ipc/Makefile                \
 702         lib/kadm5/Makefile              \
 703         lib/kafs/Makefile               \
 704         lib/kdfs/Makefile               \
 705         lib/krb5/Makefile               \
 706         lib/otp/Makefile                \
 707         lib/roken/Makefile              \
 708         lib/sl/Makefile                 \
 709         lib/sqlite/Makefile             \
 710         lib/vers/Makefile               \
 711         lib/wind/Makefile               \
 712         po/Makefile                     \
 713         kuser/Makefile                  \
 714         kpasswd/Makefile                \
 715         kadmin/Makefile                 \
 716         admin/Makefile                  \
 717         kcm/Makefile                    \
 718         kdc/Makefile                    \
 719         appl/Makefile                   \
 720         appl/afsutil/Makefile           \
 721         appl/dbutils/Makefile           \
 722         appl/gssmask/Makefile           \
 723         appl/otp/Makefile               \
 724         appl/test/Makefile              \
 725         appl/kf/Makefile                \
 726         appl/dceutils/Makefile          \
 727         tests/Makefile                  \
 728         tests/bin/Makefile              \
 729         tests/can/Makefile              \
 730         tests/db/Makefile               \
 731         tests/kdc/Makefile              \
 732         tests/ldap/Makefile             \
 733         tests/gss/Makefile              \
 734         tests/java/Makefile             \
 735         tests/plugin/Makefile           \
 736         packages/Makefile               \
 737         packages/mac/Makefile           \
 738         doc/Makefile                    \
 739         tools/Makefile                  \
 740 )
 741
 742 AC_OUTPUT
 743
 744 dnl
 745 dnl This is the release version name-number[beta]
 746 dnl
 747
 748 if test -d "$srcdir/.git"; then
 749     cat > include/newversion.h.in <<EOF
 750 #ifndef VERSION_HIDDEN
 751 #define VERSION_HIDDEN
 752 #endif
 753 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ @BRANCH@ @TAG@ ($host) @COMMIT@ @DATE@ \$";
 754 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 755 EOF
 756 else
 757     cat > include/newversion.h.in <<EOF
 758 #ifndef VERSION_HIDDEN
 759 #define VERSION_HIDDEN
 760 #endif
 761 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 762 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 763 EOF
 764 fi
 765
 766 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 767         echo "include/version.h is unchanged"
 768         rm -f include/newversion.h.in
 769 else
 770         echo "creating include/version.h"
 771         if test -n "$SOURCE_DATE_EPOCH"; then
 772             Date=`
 773                   # BSD, OS X
 774                   date -u -r "$SOURCE_DATE_EPOCH" "+%Y-%m-%dT%H:%M:%SZ" 2>/dev/null ||
 775                   # Linux
 776                   date -u -d "@${SOURCE_DATE_EPOCH}" 2>/dev/null ||
 777                   # Illumos -- sorry, no -r/-d here
 778                   date -u ||
 779                   date`
 780         else
 781             Date=`date -u "+%Y-%m-%dT%H:%M:%SZ"`
 782         fi
 783         if test -n "$SOURCE_HOST"; then
 784             Host=$SOURCE_HOST
 785         else
 786             Host=`uname -n`
 787         fi
 788         if test -n "$SOURCE_USER"; then
 789             User=$SOURCE_USER
 790         else
 791             User=${USER:-${LOGNAME:-`id -nu`}}
 792         fi
 793         if test -d "$srcdir/.git"; then
 794             GitCommit=`cd $srcdir && git rev-parse HEAD`
 795             GitBranch=`cd $srcdir && git rev-parse --abbrev-ref HEAD`
 796             if test "x$GitBranch" = master; then
 797                 GitDesc=`cd $srcdir && git describe --all --dirty`
 798             else
 799                 GitDesc=`cd $srcdir && \
 800                          git describe --tags --match 'heimdal-*' --dirty`
 801             fi
 802         else
 803             GitCommit='<commit-unknown>'
 804             GitBranch='<branch-unknown>'
 805             GitDesc='<tag-unknown>'
 806         fi
 807         mv -f include/newversion.h.in include/version.h.in
 808         sed -e "s/@HOST@/$Host/" \
 809             -e "s;@USER@;$User;" \
 810             -e "s;@DATE@;$Date;" \
 811             -e "s;@BRANCH@;$GitBranch;" \
 812             -e "s;@TAG@;$GitDesc;" \
 813             -e "s;@COMMIT@;$GitCommit;" \
 814             include/version.h.in > include/version.h
 815 fi