configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.5pre1],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10.3])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17 AC_PROG_LIBTOOL
  18
  19 AC_PREFIX_DEFAULT(/usr/heimdal)
  20
  21 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  22 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  23
  24 AC_CANONICAL_HOST
  25 CANONICAL_HOST=$host
  26 AC_SUBST(CANONICAL_HOST)
  27
  28 rk_SYS_LARGEFILE
  29
  30 rk_AIX
  31 rk_IRIX
  32 rk_SUNOS
  33
  34 dnl
  35 dnl this is needed to run the configure tests against glibc
  36 dnl
  37 AC_DEFINE([_GNU_SOURCE], 1,
  38         [Define to enable extensions on glibc-based systems such as Linux.])
  39
  40 AC_OBJEXT
  41 AC_EXEEXT
  42
  43 dnl AC_KRB_PROG_YACC
  44 AC_PROG_YACC
  45 AM_PROG_LEX
  46 dnl AC_PROG_RANLIB
  47 AC_PROG_AWK
  48 AC_KRB_PROG_LN_S
  49
  50 AC_MIPS_ABI
  51 CC="$CC $abi"
  52 libdir="$libdir$abilibdirext"
  53
  54 AC_C___ATTRIBUTE__
  55
  56 LT_PREREQ([2.2])
  57 LT_INIT([shared static win32-dll])
  58
  59 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  60 rk_VERSIONSCRIPT
  61
  62 dnl
  63 dnl Helper bits for cross compiling
  64 dnl
  65
  66
  67
  68 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  69
  70 AC_ARG_WITH(cross-tools,
  71         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  72         [if test "$withval" = "yes"; then
  73                 AC_MSG_ERROR([Need path to cross tools])
  74         fi
  75         with_cross_tools="${with_cross_tools}/"
  76         ])
  77
  78 if test "${cross_compiling}" != yes ; then
  79
  80    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  81    SLC="\$(top_builddir)/lib/sl/slc"
  82
  83    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  84    SLC_DEP="\$(SLC)"
  85 else
  86    ASN1_COMPILE="${with_cross_tools}asn1_compile"
  87    SLC="${with_cross_tools}slc"
  88
  89    ASN1_COMPILE_DEP=
  90    SLC_DEP=
  91 fi
  92
  93 AC_SUBST([ASN1_COMPILE])
  94 AC_SUBST([ASN1_COMPILE_DEP])
  95 AC_SUBST([SLC])
  96 AC_SUBST([SLC_DEP])
  97
  98
  99 dnl ---
 100
 101 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 102
 103 rk_TEST_PACKAGE(openldap,
 104 [#include <lber.h>
 105 #include <ldap.h>],
 106 [-lldap -llber],,,OPENLDAP)
 107
 108 AC_ARG_ENABLE(hdb-openldap-module,
 109         AS_HELP_STRING([--enable-hdb-openldap-module],
 110                 [if you want support to build openldap hdb as shared object]))
 111 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 112     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 113 fi
 114 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 115
 116 dnl
 117 dnl Optional modules, pk-init, digest, kx509
 118 dnl
 119
 120 AC_ARG_ENABLE(pk-init,
 121         AS_HELP_STRING([--disable-pk-init],
 122                 [if you want disable to PK-INIT support]))
 123 if test "$enable_pk_init" != no ;then
 124         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 125 fi
 126 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 127
 128 AC_ARG_ENABLE(digest,
 129         AS_HELP_STRING([--disable-digest],
 130                 [if you want disable to DIGEST support]))
 131 if test "$enable_digest" != no ;then
 132         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 133 fi
 134
 135 AC_ARG_ENABLE(kx509,
 136         AS_HELP_STRING([--disable-kx509],
 137                 [if you want disable to kx509 support]))
 138 if test "$enable_kx509" != no ;then
 139         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 140 fi
 141
 142 dnl Need to test if pkg-config exists
 143 PKG_PROG_PKG_CONFIG
 144
 145 dnl libcap-ng
 146 AC_ARG_WITH([capng],
 147   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 148   [],
 149   [with_capng=check])
 150 if test "$with_capng" != "no"; then
 151   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 152                     [with_capng=yes],[with_capng=no])
 153 fi
 154 if test "$with_capng" = "yes"; then
 155   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 156 fi
 157 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 158 AC_SUBST([CAPNG_CFLAGS])
 159 AC_SUBST([CAPNG_LIBS])
 160
 161 dnl Check for sqlite
 162 rk_TEST_PACKAGE(sqlite3,
 163 [#include <sqlite3.h>
 164 #ifndef SQLITE_OPEN_CREATE
 165 #error "old version"
 166 #endif],
 167 [-lsqlite3],,,SQLITE3)
 168
 169 if test "X$with_sqlite3" != Xyes ; then
 170    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 171    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 172 fi
 173 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 174
 175 AC_ARG_ENABLE(sqlite-cache,
 176         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 177 if test "$enable_sqlite_cache" != no; then
 178     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 179 fi
 180 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 181
 182
 183 dnl check for libintl
 184 rk_TEST_PACKAGE(libintl,
 185 [#include <libintl.h>],
 186 [-lintl],,,LIBINTL)
 187
 188 dnl path where the hdb directory is stored
 189 AC_ARG_WITH([hdbdir],
 190         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 191         [],
 192         [with_hdbdir=/var/heimdal])
 193 DIR_hdbdir="$with_hdbdir"
 194 AC_SUBST([DIR_hdbdir])
 195
 196
 197 dnl no kerberos4 any more
 198 with_krb4=no
 199 AC_SUBST(INCLUDE_krb4)
 200 AC_SUBST(LIB_krb4)
 201 AM_CONDITIONAL(KRB4, false)
 202
 203 AM_CONDITIONAL(KRB5, true)
 204 AM_CONDITIONAL(do_roken_rename, true)
 205
 206 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 207
 208
 209 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 210 AC_SUBST(LIB_kdb)dnl
 211
 212 KRB_CRYPTO
 213
 214 KRB_PTHREADS
 215
 216 AC_ARG_ENABLE(dce,
 217         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 218 if test "$enable_dce" = yes; then
 219     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 220 fi
 221 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 222
 223 ## XXX quite horrible:
 224 if test -f /etc/ibmcxx.cfg; then
 225         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 226         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 227         dpagaix_ldflags=
 228 else
 229         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 230         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 231         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 232 fi
 233 AC_SUBST(dpagaix_cflags)
 234 AC_SUBST(dpagaix_ldadd)
 235 AC_SUBST(dpagaix_ldflags)
 236
 237 AC_ARG_ENABLE([afs-support],
 238         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 239 if test "$enable_afs_support" = no; then
 240         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 241         NO_AFS="1"
 242 fi
 243 AC_SUBST(NO_AFS)dnl
 244
 245 rk_DB
 246
 247 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 248
 249 rk_ROKEN(lib/roken)
 250 LIBADD_roken="$LIB_roken"
 251 AC_SUBST(LIBADD_roken)dnl
 252 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 253
 254 rk_OTP
 255
 256 rk_LIBDISPATCH
 257
 258 AC_CHECK_OSFC2
 259
 260 AC_ARG_ENABLE(mmap,
 261         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 262 if test "$enable_mmap" = "no"; then
 263         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 264 fi
 265
 266 AC_ARG_ENABLE(afs-string-to-key,
 267         AS_HELP_STRING([--disable-afs-string-to-key],
 268         [disable use of weak AFS string-to-key functions]),
 269         [], [enable_afs_string_to_key=yes])
 270
 271 if test "$enable_afs_string_to_key" = "yes"; then
 272         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 273 fi
 274
 275
 276 rk_CHECK_MAN
 277
 278 rk_TEST_PACKAGE(readline,
 279 [#include <stdio.h>
 280 #if defined(HAVE_READLINE_READLINE_H)
 281 #include <readline/readline.h>
 282 #elif defined(HAVE_READLINE_H)
 283 #include <readline.h>
 284 #endif
 285 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 286
 287 rk_TEST_PACKAGE(libedit,
 288 [#include <stdio.h>
 289 #if defined(HAVE_READLINE_READLINE_H)
 290 #include <readline/readline.h>
 291 #elif defined(HAVE_READLINE_H)
 292 #include <readline.h>
 293 #endif
 294 ],-ledit,,, READLINE,, [readline.h readline/readline.h])
 295
 296 AC_CONFIG_SUBDIRS([lib/libedit])
 297
 298 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 299
 300 KRB_C_BIGENDIAN
 301 AC_C_INLINE
 302
 303 KRB_CHECK_X
 304
 305 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 306
 307 AC_CHECK_XAU
 308
 309 dnl AM_C_PROTOTYPES
 310
 311 dnl Checks for typedefs, structures, and compiler characteristics.
 312 AC_C_CONST
 313 AC_TYPE_OFF_T
 314 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 315 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 316 AC_HAVE_TYPE([long long])
 317 AC_HEADER_TIME
 318 AC_STRUCT_TM
 319
 320 dnl Checks for header files.
 321 AC_HEADER_STDC
 322
 323 AC_CHECK_HEADERS([\
 324         CommonCrypto/CommonDigest.h             \
 325         CommonCrypto/CommonCryptor.h            \
 326         arpa/ftp.h                              \
 327         arpa/telnet.h                           \
 328         bind/bitypes.h                          \
 329         bsdsetjmp.h                             \
 330         curses.h                                \
 331         dlfcn.h                                 \
 332         fnmatch.h                               \
 333         inttypes.h                              \
 334         io.h                                    \
 335         libutil.h                               \
 336         limits.h                                \
 337         maillock.h                              \
 338         netgroup.h                              \
 339         netinet/in6_machtypes.h                 \
 340         pthread.h                               \
 341         pty.h                                   \
 342         sac.h                                   \
 343         sgtty.h                                 \
 344         siad.h                                  \
 345         signal.h                                \
 346         strings.h                               \
 347         stropts.h                               \
 348         sys/bitypes.h                           \
 349         sys/category.h                          \
 350         sys/file.h                              \
 351         sys/filio.h                             \
 352         sys/ioccom.h                            \
 353         sys/mman.h                              \
 354         sys/param.h                             \
 355         sys/pty.h                               \
 356         sys/ptyio.h                             \
 357         sys/select.h                            \
 358         sys/socket.h                            \
 359         sys/str_tty.h                           \
 360         sys/stream.h                            \
 361         sys/stropts.h                           \
 362         sys/syscall.h                           \
 363         sys/termio.h                            \
 364         sys/timeb.h                             \
 365         sys/times.h                             \
 366         sys/types.h                             \
 367         sys/un.h                                \
 368         locale.h                                \
 369         termcap.h                               \
 370         termio.h                                \
 371         termios.h                               \
 372         time.h                                  \
 373         tmpdir.h                                \
 374         udb.h                                   \
 375         util.h                                  \
 376         utmp.h                                  \
 377         utmpx.h                                 \
 378 ])
 379
 380 dnl On Solaris 8 there's a compilation warning for term.h because
 381 dnl it doesn't define `bool'.
 382 AC_CHECK_HEADERS(term.h, , , -)
 383
 384 dnl aix have asl.h (A/IX screen library) that we don't want
 385 AC_CHECK_HEADERS(asl.h, , , [
 386 #include <asl.h>
 387 #ifndef ASL_STRING_EMERG
 388 #error ASL_STRING_EMERG missing
 389 #endif])
 390
 391 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 392 #if HAVE_SYS_SOCKET_H
 393 #include <sys/socket.h>
 394 #endif])
 395
 396 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 397 #if HAVE_SYS_TTY_H
 398 #include <sys/tty.h>
 399 #endif])
 400
 401 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 402 #if HAVE_TERMIOS_H
 403 #include <termios.h>
 404 #endif
 405 #if HAVE_SYS_STREAM_H
 406 #include <sys/stream.h>
 407 #endif])
 408
 409 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 410 #if HAVE_SYS_TYPES_H
 411 #include <sys/types.h>
 412 #endif
 413 #if HAVE_SYS_PARAM_H
 414 #include <sys/param.h>
 415 #endif])
 416
 417 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 418 #include <security/pam_appl.h>
 419 ])
 420
 421 dnl export symbols
 422 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 423 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 424 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 425
 426 dnl Checks for libraries.
 427
 428 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 429 #ifdef HAVE_UTIL_H
 430 #include <util.h>
 431 #endif
 432 ],[0,0,0])
 433 AC_FIND_FUNC_NO_LIBS(logout, util,[
 434 #ifdef HAVE_UTIL_H
 435 #include <util.h>
 436 #endif
 437 ],[0])
 438 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 439 #ifdef HAVE_UTIL_H
 440 #include <util.h>
 441 #endif
 442 ],[0,0,0,0,0])
 443
 444 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 445 #ifdef HAVE_TERMCAP_H
 446 #include <termcap.h>
 447 #endif
 448 #ifdef HAVE_CURSES_H
 449 #include <curses.h>
 450 #endif
 451 ],[0,0])
 452
 453 dnl Checks for library functions.
 454
 455 AC_CHECK_FUNCS([                                \
 456         _getpty                                 \
 457         _scrsize                                \
 458         arc4random                              \
 459         fcntl                                   \
 460         getpeereid                              \
 461         getpeerucred                            \
 462         grantpt                                 \
 463         mktime                                  \
 464         ptsname                                 \
 465         rand                                    \
 466         revoke                                  \
 467         select                                  \
 468         setitimer                               \
 469         setpcred                                \
 470         setpgid                                 \
 471         setproctitle                            \
 472         setregid                                \
 473         setresgid                               \
 474         setresuid                               \
 475         setreuid                                \
 476         setsid                                  \
 477         setutent                                \
 478         sigaction                               \
 479         strstr                                  \
 480         ttyname                                 \
 481         ttyslot                                 \
 482         umask                                   \
 483         unlockpt                                \
 484         vhangup                                 \
 485         yp_get_default_domain                   \
 486 ])
 487
 488 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 489 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 490         [[unsigned int foo; __sync_add_and_fetch(&foo, 1);]])],
 491         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 492 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 493         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 494 fi
 495 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 496
 497 AC_FUNC_MMAP
 498
 499 KRB_CAPABILITIES
 500
 501 AC_CHECK_GETPWNAM_R_POSIX
 502
 503 dnl detect doors on solaris
 504 if test "$enable_pthread_support" != no; then
 505    saved_LIBS="$LIBS"
 506    LIBS="$LIBS $PTHREADS_LIBS"
 507    AC_FIND_FUNC_NO_LIBS(door_create, door)
 508    LIBS="$saved_LIBS"
 509 fi
 510
 511 AC_ARG_ENABLE(kcm,
 512         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 513 ,[enable_kcm=yes])
 514
 515 if test "$enable_kcm" = yes ; then
 516    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 517         enable_kcm=no
 518    fi
 519 fi
 520 if test "$enable_kcm" = yes; then
 521        AC_DEFINE(HAVE_KCM, 1,
 522                [Define if you want to use the Kerberos Credentials Manager.])
 523 fi
 524 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 525
 526
 527
 528 dnl Cray stuff
 529 AC_CHECK_FUNCS(getudbnam setlim)
 530
 531 dnl AC_KRB_FUNC_GETCWD_BROKEN
 532
 533 dnl
 534 dnl Check for fields in struct utmp
 535 dnl
 536
 537 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 538 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 539 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 540 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 541 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 542 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 543 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_host, [#include <utmpx.h>])
 544 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_id, [#include <utmpx.h>])
 545 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_line, [#include <utmpx.h>])
 546 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_pid, [#include <utmpx.h>])
 547 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_tv, [#include <utmpx.h>])
 548 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_type, [#include <utmpx.h>])
 549 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_user, [#include <utmpx.h>])
 550 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 551 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 552
 553 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 554         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 555         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 556 #ifdef HAVE_INTTYPES_H
 557 #include <inttypes.h>
 558 #endif
 559 #ifdef HAVE_SYS_TYPES_H
 560 #include <sys/types.h>
 561 #endif
 562 #ifdef HAVE_SYS_BITYPES_H
 563 #include <sys/bitypes.h>
 564 #endif
 565 #ifdef HAVE_BIND_BITYPES_H
 566 #include <bind/bitypes.h>
 567 #endif
 568 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 569 #include <netinet/in6_machtypes.h>
 570 #endif
 571 ])
 572
 573 rk_FRAMEWORK_SECURITY
 574
 575 KRB_READLINE
 576
 577 rk_TELNET
 578
 579 dnl Some operating systems already have com_err and compile_et
 580 CHECK_COMPILE_ET
 581
 582 rk_AUTH_MODULES([sia afskauthlib])
 583
 584 rk_DESTDIRS
 585
 586 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 587
 588
 589 AH_BOTTOM([#ifdef __APPLE__
 590 #include <AvailabilityMacros.h>
 591 #endif])
 592
 593 AH_BOTTOM([#ifdef ROKEN_RENAME
 594 #include "roken_rename.h"
 595 #endif])
 596
 597 AC_CONFIG_FILES(Makefile                \
 598         etc/Makefile                    \
 599         include/Makefile                \
 600         include/gssapi/Makefile         \
 601         include/hcrypto/Makefile        \
 602         include/kadm5/Makefile          \
 603         lib/Makefile                    \
 604         base/Makefile                   \
 605         lib/asn1/Makefile               \
 606         lib/com_err/Makefile            \
 607         lib/hcrypto/Makefile            \
 608         lib/hx509/Makefile              \
 609         lib/gssapi/Makefile             \
 610         lib/ntlm/Makefile               \
 611         lib/hdb/Makefile                \
 612         lib/ipc/Makefile                \
 613         lib/kadm5/Makefile              \
 614         lib/kafs/Makefile               \
 615         lib/kdfs/Makefile               \
 616         lib/krb5/Makefile               \
 617         lib/otp/Makefile                \
 618         lib/roken/Makefile              \
 619         lib/sl/Makefile                 \
 620         lib/sqlite/Makefile             \
 621         lib/vers/Makefile               \
 622         lib/wind/Makefile               \
 623         po/Makefile                     \
 624         kuser/Makefile                  \
 625         kpasswd/Makefile                \
 626         kadmin/Makefile                 \
 627         admin/Makefile                  \
 628         kcm/Makefile                    \
 629         kdc/Makefile                    \
 630         appl/Makefile                   \
 631         appl/afsutil/Makefile           \
 632         appl/ftp/Makefile               \
 633         appl/ftp/common/Makefile        \
 634         appl/ftp/ftp/Makefile           \
 635         appl/ftp/ftpd/Makefile          \
 636         appl/gssmask/Makefile           \
 637         appl/kx/Makefile                \
 638         appl/login/Makefile             \
 639         appl/otp/Makefile               \
 640         appl/popper/Makefile            \
 641         appl/push/Makefile              \
 642         appl/rsh/Makefile               \
 643         appl/rcp/Makefile               \
 644         appl/su/Makefile                \
 645         appl/xnlock/Makefile            \
 646         appl/telnet/Makefile            \
 647         appl/telnet/libtelnet/Makefile  \
 648         appl/telnet/telnet/Makefile     \
 649         appl/telnet/telnetd/Makefile    \
 650         appl/test/Makefile              \
 651         appl/kf/Makefile                \
 652         appl/dceutils/Makefile          \
 653         tests/Makefile                  \
 654         tests/bin/Makefile              \
 655         tests/can/Makefile              \
 656         tests/db/Makefile               \
 657         tests/kdc/Makefile              \
 658         tests/ldap/Makefile             \
 659         tests/gss/Makefile              \
 660         tests/java/Makefile             \
 661         tests/plugin/Makefile           \
 662         packages/Makefile               \
 663         packages/mac/Makefile           \
 664         doc/Makefile                    \
 665         tools/Makefile                  \
 666 )
 667
 668 AC_OUTPUT
 669
 670 dnl
 671 dnl This is the release version name-number[beta]
 672 dnl
 673
 674 cat > include/newversion.h.in <<EOF
 675 #ifndef VERSION_HIDDEN
 676 #define VERSION_HIDDEN
 677 #endif
 678 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 679 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 680 EOF
 681
 682 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 683         echo "include/version.h is unchanged"
 684         rm -f include/newversion.h.in
 685 else
 686         echo "creating include/version.h"
 687         User=${USER-${LOGNAME}}
 688         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 689         Date=`date`
 690         mv -f include/newversion.h.in include/version.h.in
 691         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 692 fi