configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_INIT(lib/krb5/send_to_kdc.c)
   4 AM_CONFIG_HEADER(include/config.h)
   5
   6 AM_INIT_AUTOMAKE(heimdal,0.0j)
   7
   8 AC_PREFIX_DEFAULT(/usr/heimdal)
   9
  10 AC_CANONICAL_HOST
  11 CANONICAL_HOST=$host
  12 AC_SUBST(CANONICAL_HOST)
  13
  14 case "$host" in
  15 *-*-sunos4*)
  16         AC_DEFINE(SunOS, 4)
  17         ;;
  18 esac
  19
  20 dnl Checks for programs.
  21 AC_PROG_CC
  22
  23 dnl AC_KRB_PROG_YACC
  24 AC_PROG_YACC
  25 AC_PROG_LEX
  26 AC_PROG_RANLIB
  27 AC_PROG_AWK
  28 AC_KRB_PROG_LN_S
  29
  30 if test "$GCC" = "yes"; then
  31   WFLAGS="-Wall -Wno-unused -Wmissing-prototypes"
  32 fi
  33 AC_SUBST(WFLAGS)
  34 CFLAGS="-g"
  35
  36 berkeley_db=db
  37 AC_ARG_WITH(berkeley-db,
  38 [  --without-berkeley-db   if you don't want berkeley db],[
  39 if test "$withval" = no; then
  40         berkeley_db=""
  41 fi
  42 ])
  43
  44 AC_TEST_PACKAGE(krb4,krb.h,libkrb.a,-lkrb)
  45
  46 if test "$with_krb4"; then
  47         AC_DEFINE(KRB4, 1)
  48         LIB_krb4="$KRB4LIB -ldes"
  49         INCLUDE_krb4="$KRB4INCLUDE"
  50         EXTRA_LIB45=lib45.a
  51         AC_SUBST(EXTRA_LIB45)
  52 fi
  53 AM_CONDITIONAL(KRB4, test "$with_krb4")
  54 AC_SUBST(LIB_krb4)
  55 AC_SUBST(INCLUDE_krb4)
  56
  57 AC_ARG_ENABLE(kaserver,
  58 [  --enable-kaserver       if you want the KDC to try to emulate a kaserver],
  59 [
  60 if test "$enableval" != no; then
  61         AC_DEFINE(KASERVER, 1)
  62         if test "x$with_krb4" = "x"; then
  63                 AC_MSG_ERROR(kaserver requires krb4)
  64                 exit 1
  65         fi
  66 fi
  67 ])
  68
  69 AC_PATH_PROG(NROFF, nroff)
  70 AC_PATH_PROG(GROFF, groff)
  71 AC_CACHE_CHECK(how to format man pages,ac_cv_sys_man_format,
  72 [cat > conftest.1 << END
  73 .Dd January 1, 1970
  74 .Dt CONFTEST 1
  75 .Sh NAME
  76 .Nm conftest
  77 .Nd
  78 foobar
  79 END
  80
  81 if test "$NROFF" ; then
  82         for i in "-mdoc" "-mandoc"; do
  83                 if "$NROFF" $i conftest.1 2> /dev/null | \
  84                         grep Jan > /dev/null 2>&1 ; then
  85                         ac_cv_sys_man_format="$NROFF $i"
  86                         break
  87                 fi
  88         done
  89 fi
  90 if test "$ac_cv_sys_man_format" = "" -a "$GROFF" ; then
  91         for i in "-mdoc" "-mandoc"; do
  92                 if "$GROFF" -Tascii $i conftest.1 2> /dev/null | \
  93                         grep Jan > /dev/null 2>&1 ; then
  94                         ac_cv_sys_man_format="$GROFF -Tascii $i"
  95                         break
  96                 fi
  97         done
  98 fi
  99 if test "$ac_cv_sys_man_format"; then
 100         ac_cv_sys_man_format="$ac_cv_sys_man_format \$< > \$@"
 101 fi
 102 ])
 103 if test "$ac_cv_sys_man_format"; then
 104         CATMAN="$ac_cv_sys_man_format"
 105         AC_SUBST(CATMAN)
 106 fi
 107 AM_CONDITIONAL(CATMAN, test "$CATMAN")
 108 AC_CACHE_CHECK(extension of pre-formatted manual pages,ac_cv_sys_catman_ext,
 109 if grep _suffix /etc/man.conf > /dev/null 2>&1; then
 110         ac_cv_sys_catman_ext=0
 111 else
 112         ac_cv_sys_catman_ext=number
 113 fi
 114 )
 115 if test "$ac_cv_sys_catman_ext" = number; then
 116         CATMANEXT='$$section'
 117 else
 118         CATMANEXT=0
 119 fi
 120 AC_SUBST(CATMANEXT)
 121
 122 AC_TEST_PACKAGE(readline,readline.h,libreadline.a,-lreadline)
 123
 124 AC_C_BIGENDIAN
 125 AC_C_INLINE
 126
 127 AC_PATH_XTRA
 128
 129 dnl AM_C_PROTOTYPES
 130
 131 dnl Checks for typedefs, structures, and compiler characteristics.
 132 AC_C_CONST
 133 AC_TYPE_OFF_T
 134 AC_TYPE_SIZE_T
 135 AC_TYPE_MODE_T
 136 AC_HEADER_TIME
 137 AC_STRUCT_TM
 138 AC_DECL_YYTEXT
 139
 140 dnl Checks for header files.
 141 AC_HEADER_STDC
 142
 143 AC_CHECK_HEADERS(arpa/inet.h arpa/telnet.h bsdsetjmp.h crypt.h)
 144 AC_CHECK_HEADERS(curses.h db.h dbm.h dirent.h err.h errno.h)
 145 AC_CHECK_HEADERS(fcntl.h grp.h inttypes.h limits.h ndbm.h net/if.h netdb.h)
 146 AC_CHECK_HEADERS(netinet/in.h netinet/in6.h netinet/in6_var.h)
 147 AC_CHECK_HEADERS(netinet/in6_machtypes.h netinet/in_systm.h)
 148 AC_CHECK_HEADERS(netinet/ip.h netinet/tcp.h netinfo/ni.h netinet6/in6.h paths.h pty.h pwd.h)
 149 AC_CHECK_HEADERS(rpcsvc/dbm.h sac.h sgtty.h shadow.h signal.h stropts.h)
 150 AC_CHECK_HEADERS(sys/bitypes.h sys/file.h sys/filio.h sys/ioctl.h)
 151 AC_CHECK_HEADERS(sys/param.h sys/proc.h sys/pty.h sys/ptyio.h)
 152 AC_CHECK_HEADERS(sys/ptyvar.h sys/resource.h sys/select.h)
 153 AC_CHECK_HEADERS(sys/socket.h sys/sockio.h sys/stat.h sys/stream.h)
 154 AC_CHECK_HEADERS(sys/stropts.h sys/sysctl.h sys/time.h sys/timeb.h)
 155 AC_CHECK_HEADERS(sys/times.h sys/tty.h sys/types.h sys/uio.h)
 156 AC_CHECK_HEADERS(sys/utsname.h sys/wait.h syslog.h termio.h)
 157 AC_CHECK_HEADERS(termios.h tmpdir.h unistd.h util.h utmp.h utmpx.h)
 158
 159 if test "$ac_cv_header_err_h" = no; then
 160         EXTRA_HDRS="$EXTRA_HDRS err.h"
 161         AC_SUBST(EXTRA_HDRS)
 162 fi
 163
 164 dnl Checks for libraries.
 165
 166 AC_FIND_FUNC(socket, socket)
 167 AC_FIND_FUNC(gethostbyname, nsl)
 168 AC_FIND_FUNC(dbopen, $berkeley_db)
 169 AC_FIND_FUNC(dbm_firstkey, $berkeley_db gdbm ndbm)
 170 AC_FIND_FUNC(syslog, syslog)
 171
 172 AC_FIND_FUNC(logwtmp, util)
 173 AC_FIND_FUNC_NO_LIBS(tgetent, termcap)
 174 AC_FIND_FUNC(gethostbyname2, inet6 ip6)
 175 AC_FIND_FUNC(inet_ntop, inet6 ip6)
 176 AC_CHECK_FUNCS(inet_pton)
 177
 178 dnl Checks for library functions.
 179
 180 AC_BROKEN_SNPRINTF
 181 AC_BROKEN_VSNPRINTF
 182
 183 AC_CHECK_FUNCS(_getpty asnprintf asprintf fcntl gethostname)
 184 AC_CHECK_FUNCS(getmsg grantpt logwtmp mktime ptsname rand random)
 185 AC_CHECK_FUNCS(revoke select setitimer setlogin setpcred setpgid)
 186 AC_CHECK_FUNCS(setsid setsockopt sigaction strstr timegm ttyname umask)
 187 AC_CHECK_FUNCS(unlockpt vasnprintf vasprintf vhangup)
 188
 189 AC_TYPE_SIGNAL
 190 if test "$ac_cv_type_signal" = "void" ; then
 191         AC_DEFINE(VOID_RETSIGTYPE, 1)
 192 fi
 193 AC_SUBST(VOID_RETSIGTYPE)
 194
 195 AC_FIND_IF_NOT_BROKEN(hstrerror, resolv,
 196 [#ifdef HAVE_NETDB_H
 197 #include <netdb.h>
 198 #endif],
 199 17)
 200
 201 AC_BROKEN(chown daemon err errx fchown flock getcwd)
 202 AC_BROKEN(getdtablesize getusershell inet_aton initgroups)
 203 AC_BROKEN(lstat memmove mkstemp putenv rcmd setegid setenv)
 204 AC_BROKEN(seteuid strcasecmp strdup strerror strftime)
 205 AC_BROKEN(strlwr strnlen strsep strtok_r strupr unsetenv)
 206 AC_BROKEN(verr verrx vsyslog vwarn vwarnx warn warnx)
 207
 208 AC_CACHE_CHECK(if realloc if broken, ac_cv_func_realloc_broken, [
 209 ac_cv_func_realloc_broken=no
 210 AC_TRY_RUN([
 211 #include <stddef.h>
 212 #include <stdlib.h>
 213
 214 int main()
 215 {
 216         return realloc(NULL, 17) == NULL;
 217 }
 218 ],:, ac_cv_func_realloc_broken=yes, :)
 219 ])
 220 if test "$ac_cv_func_realloc_broken" = yes ; then
 221         AC_DEFINE(BROKEN_REALLOC)
 222 fi
 223
 224 dnl AC_KRB_FUNC_GETCWD_BROKEN
 225
 226 dnl
 227 dnl Checks for prototypes and declarations
 228 dnl
 229
 230 AC_NEED_PROTO([
 231 #ifdef HAVE_CRYPT_H
 232 #include <crypt.h>
 233 #endif
 234 #ifdef HAVE_UNISTD_H
 235 #include <unistd.h>
 236 #endif
 237 ],
 238 crypt)
 239
 240 AC_NEED_PROTO([
 241 #include <string.h>
 242 ],
 243 strtok_r)
 244
 245 AC_CHECK_VAR([#ifdef HAVE_SYS_TYPES_H
 246 #include <sys/types.h>
 247 #endif
 248 #ifdef HAVE_NETDB_H
 249 #include <netdb.h>
 250 #endif],
 251 h_errno)
 252
 253 AC_CHECK_VAR([#ifdef HAVE_NETDB_H
 254 #include <netdb.h>
 255 #endif],
 256 h_errlist)
 257
 258 AC_CHECK_VAR([#ifdef HAVE_NETDB_H
 259 #include <netdb.h>
 260 #endif],
 261 h_nerr)
 262
 263 AC_CHECK_VAR([#ifdef HAVE_ERR_H
 264 #include <err.h>
 265 #endif],[__progname])
 266
 267 AC_CHECK_DECLARATION([#include <stdlib.h>], optarg)
 268 AC_CHECK_DECLARATION([#include <stdlib.h>], optind)
 269 AC_CHECK_DECLARATION([#include <stdlib.h>], opterr)
 270 AC_CHECK_DECLARATION([#include <stdlib.h>], optopt)
 271
 272 dnl
 273 dnl Check for fields in struct utmp
 274 dnl
 275 AC_EGREP_HEADER(ut_user, utmp.h, AC_DEFINE(HAVE_UT_USER))
 276 AC_EGREP_HEADER(ut_host, utmp.h, AC_DEFINE(HAVE_UT_HOST))
 277 AC_EGREP_HEADER(ut_addr, utmp.h, AC_DEFINE(HAVE_UT_ADDR))
 278 AC_EGREP_HEADER(ut_type, utmp.h, AC_DEFINE(HAVE_UT_TYPE))
 279 AC_EGREP_HEADER(ut_pid, utmp.h, AC_DEFINE(HAVE_UT_PID))
 280 AC_EGREP_HEADER(ut_id, utmp.h, AC_DEFINE(HAVE_UT_ID))
 281 AC_EGREP_HEADER(ut_syslen, utmpx.h, AC_DEFINE(HAVE_UT_SYSLEN))
 282
 283 AC_KRB_IPV6
 284
 285 dnl
 286 dnl Check for struct winsize
 287 dnl
 288
 289 AC_KRB_STRUCT_WINSIZE
 290
 291 dnl
 292 dnl Check for sa_len in struct sockaddr
 293 dnl
 294
 295 AC_KRB_STRUCT_SOCKADDR_SA_LEN
 296
 297 dnl
 298 dnl Check for some common types
 299 dnl
 300
 301 AC_TYPE_PID_T
 302 AC_TYPE_UID_T
 303 AC_TYPE_OFF_T
 304 AC_TYPE_SIZE_T
 305 AC_CHECK_TYPE(ssize_t, int)
 306 AC_TYPE_SIG_ATOMIC_T
 307
 308 dnl AC_SUBST(LIBOBJS)
 309
 310 AC_GROK_TYPES(int8_t int16_t int32_t int64_t)
 311 AC_GROK_TYPES(u_int8_t u_int16_t u_int32_t u_int64_t)
 312
 313 dnl
 314 dnl Tests for editline
 315 dnl
 316
 317 AC_FIND_FUNC_NO_LIBS(el_init, edit)
 318 AC_FIND_FUNC_NO_LIBS(readline, readline)
 319
 320 if test "$with_readline"; then
 321         AC_DEFINE(HAVE_READLINE, 1)
 322         editline_OBJS=
 323         LIB_readline="$READLINELIB "'$(LIB_tgetent)'
 324         INCLUDE_readline="$READLINEINCLUDE"
 325 elif test "$ac_cv_func_el_init" = yes; then
 326         AC_DEFINE(HAVE_READLINE, 1)
 327
 328         editline_OBJS=edit_compat.o
 329         LIB_readline='-L$(top_builddir)/lib/editline -leditline '"$LIB_el_init"' $(LIB_tgetent)'
 330
 331         INCLUDE_readline='-I$(top_builddir)/lib/editline -I$(top_srcdir)/lib/editline'
 332 elif test "$ac_cv_func_readline" = yes; then
 333         AC_DEFINE(HAVE_READLINE, 1)
 334         editline_OBJS=
 335         LIB_readline='-lreadline $(LIB_tgetent)'
 336         INCLUDE_readline=
 337 else
 338         AC_DEFINE(HAVE_READLINE, 1)
 339         editline_OBJS="editline.o complete.o sysunix.o"
 340         LIB_readline='-L$(top_builddir)/lib/editline -leditline $(LIB_tgetent)'
 341         INCLUDE_readline='-I$(top_builddir)/lib/editline -I$(top_srcdir)/lib/editline'
 342 fi
 343 AC_SUBST(LIB_tgetent)
 344 AC_SUBST(LIB_readline)
 345 AC_SUBST(INCLUDE_readline)
 346 AC_SUBST(editline_OBJS)
 347
 348 dnl telnet muck --------------------------------------------------
 349
 350 AC_DEFINE(AUTHENTICATION)dnl
 351 AC_DEFINE(KRB5)dnl
 352 AC_DEFINE(ENCRYPTION)dnl
 353 AC_DEFINE(DES_ENCRYPTION)dnl
 354 AC_DEFINE(DIAGNOSTICS)dnl
 355 AC_DEFINE(OLD_ENVIRON)dnl
 356
 357 # Simple test for streamspty, based on the existance of getmsg(), alas
 358 # this breaks on SunOS4 which have streams but BSD-like ptys
 359 #
 360 # And also something wierd has happend with dec-osf1, fallback to bsd-ptys
 361
 362 AC_MSG_CHECKING(for streamspty)
 363 case "`uname -sr`" in
 364 SunOS\ 4*|OSF1*|IRIX\ 4*|HP-UX\ ?.10.*)
 365         krb_cv_sys_streamspty=no
 366         ;;
 367 AIX*)
 368         os_rel=`uname -v`.`uname -r`
 369         if expr "$os_rel" : "3*" >/dev/null 2>&1; then
 370                 krb_cv_sys_streamspty=no
 371         else
 372                 krb_cv_sys_streamspty="$ac_cv_func_getmsg"
 373         fi
 374         ;;
 375 *)
 376         krb_cv_sys_streamspty="$ac_cv_func_getmsg"
 377         ;;
 378 esac
 379 if test "$krb_cv_sys_streamspty" = yes; then
 380         AC_DEFINE(STREAMSPTY)
 381 fi
 382 dnl AC_SUBST(STREAMSPTY)
 383 AC_MSG_RESULT($krb_cv_sys_streamspty)
 384
 385 AC_OUTPUT(Makefile                      \
 386         include/Makefile                \
 387         lib/Makefile                    \
 388         lib/roken/Makefile              \
 389         lib/editline/Makefile           \
 390         lib/sl/Makefile                 \
 391         lib/error/Makefile              \
 392         lib/error/compile_et            \
 393         lib/asn1/Makefile               \
 394         lib/des/Makefile                \
 395         lib/krb5/Makefile               \
 396         lib/hdb/Makefile                \
 397         lib/gssapi/Makefile             \
 398         lib/45/Makefile                 \
 399         lib/otp/Makefile                \
 400         lib/kafs/Makefile               \
 401         kuser/Makefile                  \
 402         kpasswd/Makefile                \
 403         admin/Makefile                  \
 404         kdc/Makefile                    \
 405         appl/Makefile                   \
 406         appl/test/Makefile              \
 407         appl/rsh/Makefile               \
 408         appl/popper/Makefile            \
 409         appl/push/Makefile              \
 410         appl/telnet/Makefile            \
 411         appl/telnet/libtelnet/Makefile  \
 412         appl/telnet/telnet/Makefile     \
 413         appl/telnet/telnetd/Makefile    \
 414         appl/afsutil/Makefile           \
 415         doc/Makefile                    \
 416 )
 417
 418 dnl
 419 dnl This is the release version name-number[beta]
 420 dnl
 421 HEIMDALVERSION="$PACKAGE-$VERSION"
 422
 423 cat > include/newversion.h.in <<EOF
 424 char *heimdal_long_version = "@(#)\$Version: $HEIMDALVERSION by @USER@ on @HOST@ ($host) @DATE@ \$";
 425 char *heimdal_version = "$HEIMDALVERSION";
 426 EOF
 427
 428 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 429         echo "include/version.h is unchanged"
 430         rm -f include/newversion.h.in
 431 else
 432         echo "creating include/version.h"
 433         User=${USER-${LOGNAME}}
 434         Host=`(hostname || uname -n) 2>/dev/null | sed 1q`
 435         Date=`date`
 436         mv -f include/newversion.h.in include/version.h.in
 437         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 438 fi