lib/com_err/parse.y

   1 %{
   2 /*
   3  * Copyright (c) 1998 - 2000 Kungliga Tekniska Högskolan
   4  * (Royal Institute of Technology, Stockholm, Sweden).
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  *
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  *
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  *
  18  * 3. Neither the name of the Institute nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE INSTITUTE AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE INSTITUTE OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include "compile_et.h"
  36 #include "lex.h"
  37
  38 void yyerror (char *s);
  39 static long name2number(const char *str);
  40
  41 extern char *yytext;
  42
  43 /* This is for bison */
  44
  45 #if !defined(alloca) && !defined(HAVE_ALLOCA)
  46 #define alloca(x) malloc(x)
  47 #endif
  48
  49 %}
  50
  51 %union {
  52   char *string;
  53   int number;
  54 }
  55
  56 %token ET INDEX PREFIX EC ID END
  57 %token <string> STRING
  58 %token <number> NUMBER
  59
  60 %%
  61
  62 file            : /* */
  63                 | header statements
  64                 ;
  65
  66 header          : id et
  67                 | et
  68                 ;
  69
  70 id              : ID STRING
  71                 {
  72                     id_str = $2;
  73                 }
  74                 ;
  75
  76 et              : ET STRING
  77                 {
  78                     base_id = name2number($2);
  79                     strlcpy(name, $2, sizeof(name));
  80                     free($2);
  81                 }
  82                 | ET STRING STRING
  83                 {
  84                     base_id = name2number($2);
  85                     strlcpy(name, $3, sizeof(name));
  86                     free($2);
  87                     free($3);
  88                 }
  89                 ;
  90
  91 statements      : statement
  92                 | statements statement
  93                 ;
  94
  95 statement       : INDEX NUMBER
  96                 {
  97                         number = $2;
  98                 }
  99                 | PREFIX STRING
 100                 {
 101                     free(prefix);
 102                     asprintf (&prefix, "%s_", $2);
 103                     if (prefix == NULL)
 104                         errx(1, "malloc");
 105                     free($2);
 106                 }
 107                 | PREFIX
 108                 {
 109                     prefix = realloc(prefix, 1);
 110                     if (prefix == NULL)
 111                         errx(1, "malloc");
 112                     *prefix = '\0';
 113                 }
 114                 | EC STRING ',' STRING
 115                 {
 116                     struct error_code *ec = malloc(sizeof(*ec));
 117
 118                     if (ec == NULL)
 119                         errx(1, "malloc");
 120
 121                     ec->next = NULL;
 122                     ec->number = number;
 123                     if(prefix && *prefix != '\0') {
 124                         asprintf (&ec->name, "%s%s", prefix, $2);
 125                         if (ec->name == NULL)
 126                             errx(1, "malloc");
 127                         free($2);
 128                     } else
 129                         ec->name = $2;
 130                     ec->string = $4;
 131                     APPEND(codes, ec);
 132                     number++;
 133                 }
 134                 | END
 135                 {
 136                         YYACCEPT;
 137                 }
 138                 ;
 139
 140 %%
 141
 142 static long
 143 name2number(const char *str)
 144 {
 145     const char *p;
 146     long num = 0;
 147     const char *x = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 148         "abcdefghijklmnopqrstuvwxyz0123456789_";
 149     if(strlen(str) > 4) {
 150         yyerror("table name too long");
 151         return 0;
 152     }
 153     for(p = str; *p; p++){
 154         char *q = strchr(x, *p);
 155         if(q == NULL) {
 156             yyerror("invalid character in table name");
 157             return 0;
 158         }
 159         num = (num << 6) + (q - x) + 1;
 160     }
 161     num <<= 8;
 162     if(num > 0x7fffffff)
 163         num = -(0xffffffff - num + 1);
 164     return num;
 165 }
 166
 167 void
 168 yyerror (char *s)
 169 {
 170      error_message ("%s\n", s);
 171 }