configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ([2.59])
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.1.99],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8
   9 AM_INIT_AUTOMAKE([foreign no-dependencies 1.8])
  10 AM_MAINTAINER_MODE
  11
  12 dnl Checks for programs.
  13 AC_PROG_CC
  14 AM_PROG_CC_C_O
  15 AC_PROG_CPP
  16
  17 AC_PREFIX_DEFAULT(/usr/heimdal)
  18
  19 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  20 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  21
  22 AC_CANONICAL_HOST
  23 CANONICAL_HOST=$host
  24 AC_SUBST(CANONICAL_HOST)
  25
  26 dnl Hints for autobuild
  27 AB_INIT
  28
  29 rk_SYS_LARGEFILE
  30
  31 dnl
  32 dnl this is needed to run the configure tests against glibc
  33 dnl
  34 AC_DEFINE([_GNU_SOURCE], 1,
  35         [Define to enable extensions on glibc-based systems such as Linux.])
  36
  37 AC_OBJEXT
  38 AC_EXEEXT
  39
  40 dnl AC_KRB_PROG_YACC
  41 AC_PROG_YACC
  42 AM_PROG_LEX
  43 dnl AC_PROG_RANLIB
  44 AC_PROG_AWK
  45 AC_KRB_PROG_LN_S
  46
  47 AC_MIPS_ABI
  48 CC="$CC $abi"
  49 libdir="$libdir$abilibdirext"
  50
  51 AC_C___ATTRIBUTE__
  52
  53 AC_PROG_LIBTOOL
  54
  55 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  56 rk_VERSIONSCRIPT
  57
  58 rk_TEST_PACKAGE(openldap,
  59 [#include <lber.h>
  60 #include <ldap.h>],
  61 [-lldap -llber],,,OPENLDAP)
  62
  63 AC_ARG_ENABLE(hdb-openldap-module,
  64         AS_HELP_STRING([--enable-hdb-openldap-module],
  65                 [if you want support to build openldap hdb as shared object]))
  66 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
  67     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
  68 fi
  69 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
  70
  71 AC_ARG_ENABLE(pk-init,
  72         AS_HELP_STRING([--disable-pk-init],
  73                 [if you want disable to PK-INIT support]))
  74 if test "$enable_pk_init" != no ;then
  75         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
  76 fi
  77 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
  78
  79
  80 dnl path where the hdb directory is stored
  81 AC_ARG_WITH([hdbdir],
  82         [AC_HELP_STRING([--with-hdbdir],
  83                 [Default location for KDC database @<:@default=/var/heimdal@:>@])],
  84         [],
  85         [with_hdbdir=/var/heimdal])
  86 DIR_hdbdir="$with_hdbdir"
  87 AC_SUBST([DIR_hdbdir])
  88
  89
  90 dnl no kerberos4 any more
  91 with_krb4=no
  92 AC_SUBST(INCLUDE_krb4)
  93 AC_SUBST(LIB_krb4)
  94 AM_CONDITIONAL(KRB4, false)
  95
  96 AM_CONDITIONAL(KRB5, true)
  97 AM_CONDITIONAL(do_roken_rename, true)
  98
  99 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 100 AC_SUBST(LIB_kdb)dnl
 101
 102 KRB_CRYPTO
 103
 104 KRB_PTHREADS
 105
 106 AC_ARG_ENABLE(dce,
 107         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 108 if test "$enable_dce" = yes; then
 109     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 110 fi
 111 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 112
 113 ## XXX quite horrible:
 114 if test -f /etc/ibmcxx.cfg; then
 115         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 116         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 117         dpagaix_ldflags=
 118 else
 119         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 120         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 121         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 122 fi
 123 AC_SUBST(dpagaix_cflags)
 124 AC_SUBST(dpagaix_ldadd)
 125 AC_SUBST(dpagaix_ldflags)
 126
 127 AC_ARG_ENABLE([afs-support],
 128         AC_HELP_STRING([--disable-afs-support],
 129                 [if you don't want support for AFS]))
 130 if test "$enable_afs_support" = no; then
 131         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 132 fi
 133
 134 rk_DB
 135
 136 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 137
 138 rk_ROKEN(lib/roken)
 139 LIBADD_roken="$LIB_roken"
 140 AC_SUBST(LIBADD_roken)dnl
 141 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 142
 143 rk_OTP
 144
 145 AC_CHECK_OSFC2
 146
 147 AC_ARG_ENABLE(mmap,
 148         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 149 if test "$enable_mmap" = "no"; then
 150         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 151 fi
 152
 153 AC_ARG_ENABLE(afs-string-to-key,
 154         AS_HELP_STRING([--disable-afs-string-to-key],
 155         [disable use of weak AFS string-to-key functions]),
 156         [], [enable_afs_string_to_key=yes])
 157
 158 if test "$enable_afs_string_to_key" = "yes"; then
 159         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 160 fi
 161
 162
 163 rk_CHECK_MAN
 164
 165 rk_TEST_PACKAGE(readline,
 166 [#include <stdio.h>
 167  #include <readline.h>],-lreadline,,, READLINE)
 168
 169 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 170
 171 KRB_C_BIGENDIAN
 172 AC_C_INLINE
 173
 174 rk_AIX
 175 rk_IRIX
 176 rk_SUNOS
 177
 178 KRB_CHECK_X
 179
 180 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 181
 182 AC_CHECK_XAU
 183
 184 dnl AM_C_PROTOTYPES
 185
 186 dnl Checks for typedefs, structures, and compiler characteristics.
 187 AC_C_CONST
 188 AC_TYPE_OFF_T
 189 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 190 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 191 AC_HAVE_TYPE([long long])
 192 AC_HEADER_TIME
 193 AC_STRUCT_TM
 194
 195 dnl Checks for header files.
 196 AC_HEADER_STDC
 197
 198 AC_CHECK_HEADERS([\
 199         arpa/ftp.h                              \
 200         arpa/telnet.h                           \
 201         asl.h                                   \
 202         bind/bitypes.h                          \
 203         bsdsetjmp.h                             \
 204         curses.h                                \
 205         dlfcn.h                                 \
 206         fnmatch.h                               \
 207         inttypes.h                              \
 208         io.h                                    \
 209         libutil.h                               \
 210         limits.h                                \
 211         maillock.h                              \
 212         netgroup.h                              \
 213         netinet/in6_machtypes.h                 \
 214         netinfo/ni.h                            \
 215         pthread.h                               \
 216         pty.h                                   \
 217         sac.h                                   \
 218         sgtty.h                                 \
 219         siad.h                                  \
 220         signal.h                                \
 221         strings.h                               \
 222         stropts.h                               \
 223         sys/bitypes.h                           \
 224         sys/category.h                          \
 225         sys/file.h                              \
 226         sys/filio.h                             \
 227         sys/ioccom.h                            \
 228         sys/mman.h                              \
 229         sys/param.h                             \
 230         sys/pty.h                               \
 231         sys/ptyio.h                             \
 232         sys/select.h                            \
 233         sys/socket.h                            \
 234         sys/str_tty.h                           \
 235         sys/stream.h                            \
 236         sys/stropts.h                           \
 237         sys/syscall.h                           \
 238         sys/termio.h                            \
 239         sys/timeb.h                             \
 240         sys/times.h                             \
 241         sys/types.h                             \
 242         sys/un.h                                \
 243         termcap.h                               \
 244         termio.h                                \
 245         termios.h                               \
 246         time.h                                  \
 247         tmpdir.h                                \
 248         udb.h                                   \
 249         util.h                                  \
 250         utmp.h                                  \
 251         utmpx.h                                 \
 252 ])
 253
 254 dnl On Solaris 8 there's a compilation warning for term.h because
 255 dnl it doesn't define `bool'.
 256 AC_CHECK_HEADERS(term.h, , , -)
 257
 258 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 259 #if HAVE_SYS_SOCKET_H
 260 #include <sys/socket.h>
 261 #endif])
 262
 263 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 264 #if HAVE_SYS_TTY_H
 265 #include <sys/tty.h>
 266 #endif])
 267
 268 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 269 #if HAVE_TERMIOS_H
 270 #include <termios.h>
 271 #endif
 272 #if HAVE_SYS_STREAM_H
 273 #include <sys/stream.h>
 274 #endif])
 275
 276 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 277 #if HAVE_SYS_TYPES_H
 278 #include <sys/types.h>
 279 #endif
 280 #if HAVE_SYS_PARAM_H
 281 #include <sys/param.h>
 282 #endif])
 283
 284 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 285 #include <security/pam_appl.h>
 286 ])
 287
 288 AC_ARG_ENABLE(netinfo,
 289         AS_HELP_STRING([--enable-netinfo],[enable netinfo for configuration lookup]))
 290
 291 if test "$ac_cv_header_netinfo_ni_h" = yes -a "$enable_netinfo" = yes; then
 292        AC_DEFINE(HAVE_NETINFO, 1,
 293                [Define if you want to use Netinfo instead of krb5.conf.])
 294 fi
 295
 296 dnl export symbols
 297 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB_FUNCTION)
 298 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB_FUNCTION)
 299
 300 dnl Checks for libraries.
 301
 302 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 303 #ifdef HAVE_UTIL_H
 304 #include <util.h>
 305 #endif
 306 ],[0,0,0])
 307 AC_FIND_FUNC_NO_LIBS(logout, util,[
 308 #ifdef HAVE_UTIL_H
 309 #include <util.h>
 310 #endif
 311 ],[0])
 312 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 313 #ifdef HAVE_UTIL_H
 314 #include <util.h>
 315 #endif
 316 ],[0,0,0,0,0])
 317
 318 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 319 #ifdef HAVE_TERMCAP_H
 320 #include <termcap.h>
 321 #endif
 322 #ifdef HAVE_CURSES_H
 323 #include <curses.h>
 324 #endif
 325 ],[0,0])
 326
 327 dnl Checks for library functions.
 328
 329 AC_CHECK_FUNCS([                                \
 330         _getpty                                 \
 331         _scrsize                                \
 332         arc4random                              \
 333         fcntl                                   \
 334         getpeereid                              \
 335         getpeerucred                            \
 336         grantpt                                 \
 337         mktime                                  \
 338         ptsname                                 \
 339         rand                                    \
 340         revoke                                  \
 341         select                                  \
 342         setitimer                               \
 343         setpcred                                \
 344         setpgid                                 \
 345         setproctitle                            \
 346         setregid                                \
 347         setresgid                               \
 348         setresuid                               \
 349         setreuid                                \
 350         setsid                                  \
 351         setutent                                \
 352         sigaction                               \
 353         strstr                                  \
 354         ttyname                                 \
 355         ttyslot                                 \
 356         umask                                   \
 357         unlockpt                                \
 358         vhangup                                 \
 359         yp_get_default_domain                   \
 360 ])
 361
 362 AC_FUNC_MMAP
 363
 364 KRB_CAPABILITIES
 365
 366 AC_CHECK_GETPWNAM_R_POSIX
 367
 368 dnl detect doors on solaris
 369 if test "$enable_pthread_support" != no; then
 370    saved_LIBS="$LIBS"
 371    LIBS="$LIBS $PTHREADS_LIBS"
 372    AC_FIND_FUNC_NO_LIBS(door_create, door)
 373    LIBS="$saved_LIBS"
 374 fi
 375
 376 AC_ARG_ENABLE(kcm,
 377         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 378 ,[enable_kcm=yes])
 379
 380 if test "$enable_kcm" = yes ; then
 381    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 382         enable_kcm=no
 383    fi
 384 fi
 385 if test "$enable_kcm" = yes; then
 386        AC_DEFINE(HAVE_KCM, 1,
 387                [Define if you want to use the Kerberos Credentials Manager.])
 388 fi
 389 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 390
 391
 392
 393 dnl Cray stuff
 394 AC_CHECK_FUNCS(getudbnam setlim)
 395
 396 dnl AC_KRB_FUNC_GETCWD_BROKEN
 397
 398 dnl
 399 dnl Check for fields in struct utmp
 400 dnl
 401
 402 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 403 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 404 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 405 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 406 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 407 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 408 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 409 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 410
 411 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 412         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 413         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 414 #ifdef HAVE_INTTYPES_H
 415 #include <inttypes.h>
 416 #endif
 417 #ifdef HAVE_SYS_TYPES_H
 418 #include <sys/types.h>
 419 #endif
 420 #ifdef HAVE_SYS_BITYPES_H
 421 #include <sys/bitypes.h>
 422 #endif
 423 #ifdef HAVE_BIND_BITYPES_H
 424 #include <bind/bitypes.h>
 425 #endif
 426 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 427 #include <netinet/in6_machtypes.h>
 428 #endif
 429 ])
 430
 431 rk_FRAMEWORK_SECURITY
 432
 433 KRB_READLINE
 434
 435 rk_TELNET
 436
 437 dnl Some operating systems already have com_err and compile_et
 438 CHECK_COMPILE_ET
 439
 440 rk_AUTH_MODULES([sia afskauthlib])
 441
 442 rk_DESTDIRS
 443
 444 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 445
 446
 447 AH_BOTTOM([#ifdef ROKEN_RENAME
 448 #include "roken_rename.h"
 449 #endif])
 450
 451 AC_CONFIG_FILES(Makefile                \
 452         etc/Makefile                    \
 453         include/Makefile                \
 454         include/gssapi/Makefile         \
 455         include/hcrypto/Makefile        \
 456         include/kadm5/Makefile          \
 457         lib/Makefile                    \
 458         lib/45/Makefile                 \
 459         lib/auth/Makefile               \
 460         lib/auth/afskauthlib/Makefile   \
 461         lib/auth/pam/Makefile           \
 462         lib/auth/sia/Makefile           \
 463         lib/asn1/Makefile               \
 464         lib/com_err/Makefile            \
 465         lib/hcrypto/Makefile            \
 466         lib/editline/Makefile           \
 467         lib/hx509/Makefile              \
 468         lib/gssapi/Makefile             \
 469         lib/ntlm/Makefile               \
 470         lib/hdb/Makefile                \
 471         lib/kadm5/Makefile              \
 472         lib/kafs/Makefile               \
 473         lib/kdfs/Makefile               \
 474         lib/krb5/Makefile               \
 475         lib/otp/Makefile                \
 476         lib/roken/Makefile              \
 477         lib/sl/Makefile                 \
 478         lib/sqlite/Makefile             \
 479         lib/vers/Makefile               \
 480         lib/wind/Makefile               \
 481         kuser/Makefile                  \
 482         kpasswd/Makefile                \
 483         kadmin/Makefile                 \
 484         admin/Makefile                  \
 485         kcm/Makefile                    \
 486         kdc/Makefile                    \
 487         appl/Makefile                   \
 488         appl/afsutil/Makefile           \
 489         appl/ftp/Makefile               \
 490         appl/ftp/common/Makefile        \
 491         appl/ftp/ftp/Makefile           \
 492         appl/ftp/ftpd/Makefile          \
 493         appl/gssmask/Makefile           \
 494         appl/kx/Makefile                \
 495         appl/login/Makefile             \
 496         appl/otp/Makefile               \
 497         appl/popper/Makefile            \
 498         appl/push/Makefile              \
 499         appl/rsh/Makefile               \
 500         appl/rcp/Makefile               \
 501         appl/su/Makefile                \
 502         appl/xnlock/Makefile            \
 503         appl/telnet/Makefile            \
 504         appl/telnet/libtelnet/Makefile  \
 505         appl/telnet/telnet/Makefile     \
 506         appl/telnet/telnetd/Makefile    \
 507         appl/test/Makefile              \
 508         appl/kf/Makefile                \
 509         appl/dceutils/Makefile          \
 510         tests/Makefile                  \
 511         tests/can/Makefile              \
 512         tests/db/Makefile               \
 513         tests/kdc/Makefile              \
 514         tests/ldap/Makefile             \
 515         tests/gss/Makefile              \
 516         tests/java/Makefile             \
 517         tests/plugin/Makefile           \
 518         packages/Makefile               \
 519         packages/mac/Makefile           \
 520         packages/debian/Makefile        \
 521         doc/Makefile                    \
 522         tools/Makefile                  \
 523 )
 524
 525 AC_OUTPUT
 526
 527 dnl
 528 dnl This is the release version name-number[beta]
 529 dnl
 530
 531 cat > include/newversion.h.in <<EOF
 532 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 533 const char *heimdal_version = "AC_PACKAGE_STRING";
 534 EOF
 535
 536 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 537         echo "include/version.h is unchanged"
 538         rm -f include/newversion.h.in
 539 else
 540         echo "creating include/version.h"
 541         User=${USER-${LOGNAME}}
 542         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 543         Date=`date`
 544         mv -f include/newversion.h.in include/version.h.in
 545         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 546 fi