configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.5pre1],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10.3])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17 AC_PROG_LIBTOOL
  18
  19 AC_PREFIX_DEFAULT(/usr/heimdal)
  20
  21 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  22 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  23
  24 AC_CANONICAL_HOST
  25 CANONICAL_HOST=$host
  26 AC_SUBST(CANONICAL_HOST)
  27
  28 rk_SYS_LARGEFILE
  29
  30 rk_AIX
  31 rk_IRIX
  32 rk_SUNOS
  33
  34 dnl
  35 dnl this is needed to run the configure tests against glibc
  36 dnl
  37 AC_DEFINE([_GNU_SOURCE], 1,
  38         [Define to enable extensions on glibc-based systems such as Linux.])
  39
  40 AC_OBJEXT
  41 AC_EXEEXT
  42
  43 dnl AC_KRB_PROG_YACC
  44 AC_PROG_YACC
  45 AM_PROG_LEX
  46 dnl AC_PROG_RANLIB
  47 AC_PROG_AWK
  48 AC_KRB_PROG_LN_S
  49
  50 AC_MIPS_ABI
  51 CC="$CC $abi"
  52 libdir="$libdir$abilibdirext"
  53
  54 AC_C___ATTRIBUTE__
  55
  56 LT_PREREQ([2.2])
  57 LT_INIT([shared static win32-dll])
  58
  59 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  60 rk_VERSIONSCRIPT
  61
  62 dnl
  63 dnl Helper bits for cross compiling
  64 dnl
  65
  66
  67
  68 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  69
  70 AC_ARG_WITH(cross-tools,
  71         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  72         [if test "$withval" = "yes"; then
  73                 AC_MSG_ERROR([Need path to cross tools])
  74         fi
  75         with_cross_tools="${with_cross_tools}/"
  76         ])
  77
  78 if test "${cross_compiling}" != yes ; then
  79
  80    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  81    SLC="\$(top_builddir)/lib/sl/slc"
  82
  83    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  84    SLC_DEP="\$(SLC)"
  85 else
  86    ASN1_COMPILE="${with_cross_tools}asn1_compile"
  87    SLC="${with_cross_tools}slc"
  88
  89    ASN1_COMPILE_DEP=
  90    SLC_DEP=
  91 fi
  92
  93 AC_SUBST([ASN1_COMPILE])
  94 AC_SUBST([ASN1_COMPILE_DEP])
  95 AC_SUBST([SLC])
  96 AC_SUBST([SLC_DEP])
  97
  98
  99 dnl ---
 100
 101 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 102
 103 rk_TEST_PACKAGE(openldap,
 104 [#include <lber.h>
 105 #include <ldap.h>],
 106 [-lldap -llber],,,OPENLDAP)
 107
 108 AC_ARG_ENABLE(hdb-openldap-module,
 109         AS_HELP_STRING([--enable-hdb-openldap-module],
 110                 [if you want support to build openldap hdb as shared object]))
 111 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 112     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 113 fi
 114 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 115
 116 dnl
 117 dnl Optional modules, pk-init, digest, kx509
 118 dnl
 119
 120 AC_ARG_ENABLE(pk-init,
 121         AS_HELP_STRING([--disable-pk-init],
 122                 [if you want disable to PK-INIT support]))
 123 if test "$enable_pk_init" != no ;then
 124         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 125 fi
 126 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 127
 128 AC_ARG_ENABLE(digest,
 129         AS_HELP_STRING([--disable-digest],
 130                 [if you want disable to DIGEST support]))
 131 if test "$enable_digest" != no ;then
 132         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 133 fi
 134
 135 AC_ARG_ENABLE(kx509,
 136         AS_HELP_STRING([--disable-kx509],
 137                 [if you want disable to kx509 support]))
 138 if test "$enable_kx509" != no ;then
 139         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 140 fi
 141
 142 dnl Need to test if pkg-config exists
 143 PKG_PROG_PKG_CONFIG
 144
 145 dnl libcap-ng
 146 AC_ARG_WITH([capng],
 147   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 148   [],
 149   [with_capng=check])
 150 if test "$with_capng" != "no"; then
 151   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 152                     [with_capng=yes],[with_capng=no])
 153 fi
 154 if test "$with_capng" = "yes"; then
 155   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 156 fi
 157 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 158 AC_SUBST([CAPNG_CFLAGS])
 159 AC_SUBST([CAPNG_LIBS])
 160
 161 dnl Check for sqlite
 162 rk_TEST_PACKAGE(sqlite3,
 163 [#include <sqlite3.h>
 164 #ifndef SQLITE_OPEN_CREATE
 165 #error "old version"
 166 #endif],
 167 [-lsqlite3],,,SQLITE3)
 168
 169 if test "X$with_sqlite3" != Xyes ; then
 170    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 171    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 172 fi
 173 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 174
 175 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 176
 177 AC_ARG_ENABLE(sqlite-cache,
 178         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 179 if test "$enable_sqlite_cache" != no; then
 180     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 181 fi
 182 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 183
 184
 185 dnl check for libintl
 186 rk_TEST_PACKAGE(libintl,
 187 [#include <libintl.h>],
 188 [-lintl],,,LIBINTL)
 189
 190 dnl path where the hdb directory is stored
 191 AC_ARG_WITH([hdbdir],
 192         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 193         [],
 194         [with_hdbdir=/var/heimdal])
 195 DIR_hdbdir="$with_hdbdir"
 196 AC_SUBST([DIR_hdbdir])
 197
 198
 199 dnl no kerberos4 any more
 200 with_krb4=no
 201 AC_SUBST(INCLUDE_krb4)
 202 AC_SUBST(LIB_krb4)
 203 AM_CONDITIONAL(KRB4, false)
 204
 205 AM_CONDITIONAL(KRB5, true)
 206 AM_CONDITIONAL(do_roken_rename, true)
 207
 208 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 209
 210
 211 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 212 AC_SUBST(LIB_kdb)dnl
 213
 214 KRB_CRYPTO
 215
 216 KRB_PTHREADS
 217
 218 AC_ARG_ENABLE(dce,
 219         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 220 if test "$enable_dce" = yes; then
 221     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 222 fi
 223 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 224
 225 ## XXX quite horrible:
 226 if test -f /etc/ibmcxx.cfg; then
 227         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 228         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 229         dpagaix_ldflags=
 230 else
 231         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 232         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 233         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 234 fi
 235 AC_SUBST(dpagaix_cflags)
 236 AC_SUBST(dpagaix_ldadd)
 237 AC_SUBST(dpagaix_ldflags)
 238
 239 AC_ARG_ENABLE([afs-support],
 240         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 241 if test "$enable_afs_support" = no; then
 242         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 243         NO_AFS="1"
 244 fi
 245 AC_SUBST(NO_AFS)dnl
 246
 247 rk_DB
 248
 249 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 250
 251 rk_ROKEN(lib/roken)
 252 LIBADD_roken="$LIB_roken"
 253 AC_SUBST(LIBADD_roken)dnl
 254 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 255
 256 rk_OTP
 257
 258 rk_LIBDISPATCH
 259
 260 AC_CHECK_OSFC2
 261
 262 AC_ARG_ENABLE(mmap,
 263         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 264 if test "$enable_mmap" = "no"; then
 265         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 266 fi
 267
 268 AC_ARG_ENABLE(afs-string-to-key,
 269         AS_HELP_STRING([--disable-afs-string-to-key],
 270         [disable use of weak AFS string-to-key functions]),
 271         [], [enable_afs_string_to_key=yes])
 272
 273 if test "$enable_afs_string_to_key" = "yes"; then
 274         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 275 fi
 276
 277
 278 rk_CHECK_MAN
 279
 280 rk_TEST_PACKAGE(readline,
 281 [#include <stdio.h>
 282 #if defined(HAVE_READLINE_READLINE_H)
 283 #include <readline/readline.h>
 284 #elif defined(HAVE_READLINE_H)
 285 #include <readline.h>
 286 #endif
 287 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 288
 289 rk_TEST_PACKAGE(libedit,
 290 [#include <stdio.h>
 291 #if defined(HAVE_READLINE_READLINE_H)
 292 #include <readline/readline.h>
 293 #elif defined(HAVE_READLINE_H)
 294 #include <readline.h>
 295 #endif
 296 ],-ledit,,, READLINE,, [readline.h readline/readline.h])
 297
 298 AC_CONFIG_SUBDIRS([lib/libedit])
 299
 300 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 301
 302 KRB_C_BIGENDIAN
 303 AC_C_INLINE
 304
 305 KRB_CHECK_X
 306
 307 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 308
 309 AC_CHECK_XAU
 310
 311 dnl AM_C_PROTOTYPES
 312
 313 dnl Checks for typedefs, structures, and compiler characteristics.
 314 AC_C_CONST
 315 AC_TYPE_OFF_T
 316 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 317 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 318 AC_HAVE_TYPE([long long])
 319 AC_HEADER_TIME
 320 AC_STRUCT_TM
 321
 322 dnl Checks for header files.
 323 AC_HEADER_STDC
 324
 325 AC_CHECK_HEADERS([\
 326         CommonCrypto/CommonDigest.h             \
 327         CommonCrypto/CommonCryptor.h            \
 328         arpa/ftp.h                              \
 329         arpa/telnet.h                           \
 330         bind/bitypes.h                          \
 331         bsdsetjmp.h                             \
 332         curses.h                                \
 333         dlfcn.h                                 \
 334         fnmatch.h                               \
 335         inttypes.h                              \
 336         io.h                                    \
 337         libutil.h                               \
 338         limits.h                                \
 339         maillock.h                              \
 340         netgroup.h                              \
 341         netinet/in6_machtypes.h                 \
 342         pthread.h                               \
 343         pty.h                                   \
 344         sac.h                                   \
 345         sgtty.h                                 \
 346         siad.h                                  \
 347         signal.h                                \
 348         strings.h                               \
 349         stropts.h                               \
 350         sys/bitypes.h                           \
 351         sys/category.h                          \
 352         sys/file.h                              \
 353         sys/filio.h                             \
 354         sys/ioccom.h                            \
 355         sys/mman.h                              \
 356         sys/param.h                             \
 357         sys/pty.h                               \
 358         sys/ptyio.h                             \
 359         sys/select.h                            \
 360         sys/socket.h                            \
 361         sys/str_tty.h                           \
 362         sys/stream.h                            \
 363         sys/stropts.h                           \
 364         sys/syscall.h                           \
 365         sys/termio.h                            \
 366         sys/timeb.h                             \
 367         sys/times.h                             \
 368         sys/types.h                             \
 369         sys/un.h                                \
 370         locale.h                                \
 371         termcap.h                               \
 372         termio.h                                \
 373         termios.h                               \
 374         time.h                                  \
 375         tmpdir.h                                \
 376         udb.h                                   \
 377         util.h                                  \
 378         utmp.h                                  \
 379         utmpx.h                                 \
 380 ])
 381
 382 dnl On Solaris 8 there's a compilation warning for term.h because
 383 dnl it doesn't define `bool'.
 384 AC_CHECK_HEADERS(term.h, , , -)
 385
 386 dnl aix have asl.h (A/IX screen library) that we don't want
 387 AC_CHECK_HEADERS(asl.h, , , [
 388 #include <asl.h>
 389 #ifndef ASL_STRING_EMERG
 390 #error ASL_STRING_EMERG missing
 391 #endif])
 392
 393 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 394 #if HAVE_SYS_SOCKET_H
 395 #include <sys/socket.h>
 396 #endif])
 397
 398 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 399 #if HAVE_SYS_TTY_H
 400 #include <sys/tty.h>
 401 #endif])
 402
 403 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 404 #if HAVE_TERMIOS_H
 405 #include <termios.h>
 406 #endif
 407 #if HAVE_SYS_STREAM_H
 408 #include <sys/stream.h>
 409 #endif])
 410
 411 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 412 #if HAVE_SYS_TYPES_H
 413 #include <sys/types.h>
 414 #endif
 415 #if HAVE_SYS_PARAM_H
 416 #include <sys/param.h>
 417 #endif])
 418
 419 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 420 #include <security/pam_appl.h>
 421 ])
 422
 423 dnl export symbols
 424 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 425 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 426 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 427
 428 dnl Checks for libraries.
 429
 430 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 431 #ifdef HAVE_UTIL_H
 432 #include <util.h>
 433 #endif
 434 ],[0,0,0])
 435 AC_FIND_FUNC_NO_LIBS(logout, util,[
 436 #ifdef HAVE_UTIL_H
 437 #include <util.h>
 438 #endif
 439 ],[0])
 440 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 441 #ifdef HAVE_UTIL_H
 442 #include <util.h>
 443 #endif
 444 ],[0,0,0,0,0])
 445
 446 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 447 #ifdef HAVE_TERMCAP_H
 448 #include <termcap.h>
 449 #endif
 450 #ifdef HAVE_CURSES_H
 451 #include <curses.h>
 452 #endif
 453 ],[0,0])
 454
 455 dnl Checks for library functions.
 456
 457 AC_CHECK_FUNCS([                                \
 458         _getpty                                 \
 459         _scrsize                                \
 460         arc4random                              \
 461         fcntl                                   \
 462         getpeereid                              \
 463         getpeerucred                            \
 464         grantpt                                 \
 465         mktime                                  \
 466         ptsname                                 \
 467         rand                                    \
 468         revoke                                  \
 469         select                                  \
 470         setitimer                               \
 471         setpcred                                \
 472         setpgid                                 \
 473         setproctitle                            \
 474         setregid                                \
 475         setresgid                               \
 476         setresuid                               \
 477         setreuid                                \
 478         setsid                                  \
 479         setutent                                \
 480         sigaction                               \
 481         strstr                                  \
 482         ttyname                                 \
 483         ttyslot                                 \
 484         umask                                   \
 485         unlockpt                                \
 486         vhangup                                 \
 487         yp_get_default_domain                   \
 488 ])
 489
 490 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 491 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 492         [[unsigned int foo; __sync_add_and_fetch(&foo, 1);]])],
 493         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 494 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 495         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 496 fi
 497 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 498
 499 AC_FUNC_MMAP
 500
 501 KRB_CAPABILITIES
 502
 503 AC_CHECK_GETPWNAM_R_POSIX
 504
 505 dnl detect doors on solaris
 506 if test "$enable_pthread_support" != no; then
 507    saved_LIBS="$LIBS"
 508    LIBS="$LIBS $PTHREADS_LIBS"
 509    AC_FIND_FUNC_NO_LIBS(door_create, door)
 510    LIBS="$saved_LIBS"
 511 fi
 512
 513 AC_ARG_ENABLE(kcm,
 514         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 515 ,[enable_kcm=yes])
 516
 517 if test "$enable_kcm" = yes ; then
 518    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 519         enable_kcm=no
 520    fi
 521 fi
 522 if test "$enable_kcm" = yes; then
 523        AC_DEFINE(HAVE_KCM, 1,
 524                [Define if you want to use the Kerberos Credentials Manager.])
 525 fi
 526 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 527
 528
 529
 530 dnl Cray stuff
 531 AC_CHECK_FUNCS(getudbnam setlim)
 532
 533 dnl AC_KRB_FUNC_GETCWD_BROKEN
 534
 535 dnl
 536 dnl Check for fields in struct utmp
 537 dnl
 538
 539 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 540 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 541 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 542 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 543 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 544 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 545 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_host, [#include <utmpx.h>])
 546 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_id, [#include <utmpx.h>])
 547 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_line, [#include <utmpx.h>])
 548 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_pid, [#include <utmpx.h>])
 549 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_tv, [#include <utmpx.h>])
 550 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_type, [#include <utmpx.h>])
 551 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_user, [#include <utmpx.h>])
 552 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 553 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 554
 555 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 556         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 557         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 558 #ifdef HAVE_INTTYPES_H
 559 #include <inttypes.h>
 560 #endif
 561 #ifdef HAVE_SYS_TYPES_H
 562 #include <sys/types.h>
 563 #endif
 564 #ifdef HAVE_SYS_BITYPES_H
 565 #include <sys/bitypes.h>
 566 #endif
 567 #ifdef HAVE_BIND_BITYPES_H
 568 #include <bind/bitypes.h>
 569 #endif
 570 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 571 #include <netinet/in6_machtypes.h>
 572 #endif
 573 ])
 574
 575 rk_FRAMEWORK_SECURITY
 576
 577 KRB_READLINE
 578
 579 rk_TELNET
 580
 581 dnl Some operating systems already have com_err and compile_et
 582 CHECK_COMPILE_ET
 583
 584 rk_AUTH_MODULES([sia afskauthlib])
 585
 586 rk_DESTDIRS
 587
 588 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 589
 590
 591 AH_BOTTOM([#ifdef __APPLE__
 592 #include <AvailabilityMacros.h>
 593 #endif])
 594
 595 AH_BOTTOM([#ifdef ROKEN_RENAME
 596 #include "roken_rename.h"
 597 #endif])
 598
 599 AC_CONFIG_FILES(Makefile                \
 600         etc/Makefile                    \
 601         include/Makefile                \
 602         include/gssapi/Makefile         \
 603         include/hcrypto/Makefile        \
 604         include/kadm5/Makefile          \
 605         lib/Makefile                    \
 606         base/Makefile                   \
 607         lib/asn1/Makefile               \
 608         lib/com_err/Makefile            \
 609         lib/hcrypto/Makefile            \
 610         lib/hx509/Makefile              \
 611         lib/gssapi/Makefile             \
 612         lib/ntlm/Makefile               \
 613         lib/hdb/Makefile                \
 614         lib/ipc/Makefile                \
 615         lib/kadm5/Makefile              \
 616         lib/kafs/Makefile               \
 617         lib/kdfs/Makefile               \
 618         lib/krb5/Makefile               \
 619         lib/otp/Makefile                \
 620         lib/roken/Makefile              \
 621         lib/sl/Makefile                 \
 622         lib/sqlite/Makefile             \
 623         lib/vers/Makefile               \
 624         lib/wind/Makefile               \
 625         po/Makefile                     \
 626         kuser/Makefile                  \
 627         kpasswd/Makefile                \
 628         kadmin/Makefile                 \
 629         admin/Makefile                  \
 630         kcm/Makefile                    \
 631         kdc/Makefile                    \
 632         appl/Makefile                   \
 633         appl/afsutil/Makefile           \
 634         appl/ftp/Makefile               \
 635         appl/ftp/common/Makefile        \
 636         appl/ftp/ftp/Makefile           \
 637         appl/ftp/ftpd/Makefile          \
 638         appl/gssmask/Makefile           \
 639         appl/kx/Makefile                \
 640         appl/login/Makefile             \
 641         appl/otp/Makefile               \
 642         appl/popper/Makefile            \
 643         appl/push/Makefile              \
 644         appl/rsh/Makefile               \
 645         appl/rcp/Makefile               \
 646         appl/su/Makefile                \
 647         appl/xnlock/Makefile            \
 648         appl/telnet/Makefile            \
 649         appl/telnet/libtelnet/Makefile  \
 650         appl/telnet/telnet/Makefile     \
 651         appl/telnet/telnetd/Makefile    \
 652         appl/test/Makefile              \
 653         appl/kf/Makefile                \
 654         appl/dceutils/Makefile          \
 655         tests/Makefile                  \
 656         tests/bin/Makefile              \
 657         tests/can/Makefile              \
 658         tests/db/Makefile               \
 659         tests/kdc/Makefile              \
 660         tests/ldap/Makefile             \
 661         tests/gss/Makefile              \
 662         tests/java/Makefile             \
 663         tests/plugin/Makefile           \
 664         packages/Makefile               \
 665         packages/mac/Makefile           \
 666         doc/Makefile                    \
 667         tools/Makefile                  \
 668 )
 669
 670 AC_OUTPUT
 671
 672 dnl
 673 dnl This is the release version name-number[beta]
 674 dnl
 675
 676 cat > include/newversion.h.in <<EOF
 677 #ifndef VERSION_HIDDEN
 678 #define VERSION_HIDDEN
 679 #endif
 680 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 681 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 682 EOF
 683
 684 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 685         echo "include/version.h is unchanged"
 686         rm -f include/newversion.h.in
 687 else
 688         echo "creating include/version.h"
 689         User=${USER-${LOGNAME}}
 690         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 691         Date=`date`
 692         mv -f include/newversion.h.in include/version.h.in
 693         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 694 fi