configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21 AC_CHECK_PROG(CLANG_FORMAT, clang-format, [clang-format], [no])
  22
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24
  25 AC_PREFIX_DEFAULT(/usr/heimdal)
  26
  27 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  28 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  29
  30 AC_CANONICAL_HOST
  31 CANONICAL_HOST=$host
  32 AC_SUBST(CANONICAL_HOST)
  33
  34 rk_SYS_LARGEFILE
  35
  36 rk_AIX
  37 rk_IRIX
  38 rk_SUNOS
  39
  40 dnl
  41 dnl this is needed to run the configure tests against glibc
  42 dnl
  43 AC_DEFINE([_GNU_SOURCE], 1,
  44         [Define to enable extensions on glibc-based systems such as Linux.])
  45
  46 AC_OBJEXT
  47 AC_EXEEXT
  48
  49 dnl
  50 dnl this is needed when der-protos.h or der-private.h has to be generated
  51 dnl
  52 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  53    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  54     AC_KRB_PROG_PERL
  55     AC_KRB_PERL_MOD(Getopt::Std)
  56     AC_KRB_PERL_MOD(File::Compare)
  57     AC_KRB_PERL_MOD(JSON)
  58 fi
  59
  60 dnl AC_KRB_PROG_YACC
  61 AC_PROG_YACC
  62 AM_PROG_LEX
  63 AS_IF([$LEX --nounput -V > /dev/null 2>&1 && test $? -eq 0],
  64       [AC_SUBST([FLEXNOUNPUTARGS], ["--nounput"])],
  65       [AC_SUBST([FLEXNOUNPUTARGS], [""])])
  66 dnl AC_PROG_RANLIB
  67 AC_PROG_AWK
  68 AC_KRB_PROG_LN_S
  69
  70 AC_MIPS_ABI
  71 CC="$CC $abi"
  72 libdir="$libdir$abilibdirext"
  73
  74 AC_C___ATTRIBUTE__
  75
  76 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  77 rk_VERSIONSCRIPT
  78
  79 dnl Code coverage
  80 AC_ARG_ENABLE([gcov],
  81         AC_HELP_STRING([--enable-gcov], [enable gcov code coverage tool]))
  82 AM_CONDITIONAL([ENABLE_GCOV], [test "x$enable_gcov" = xyes])
  83
  84
  85 dnl
  86 dnl Helper bits for cross compiling
  87 dnl
  88
  89
  90
  91 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  92
  93 AC_ARG_WITH(cross-tools,
  94         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  95         [if test "$withval" = "yes"; then
  96                 AC_MSG_ERROR([Need path to cross tools])
  97         fi
  98         with_cross_tools="${with_cross_tools}/"
  99         ])
 100
 101 if test "${cross_compiling}" != yes ; then
 102
 103    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
 104    SLC="\$(top_builddir)/lib/sl/slc"
 105
 106    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
 107    SLC_DEP="\$(SLC)"
 108 else
 109    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 110    SLC="${with_cross_tools}slc"
 111
 112    ASN1_COMPILE_DEP=
 113    SLC_DEP=
 114
 115    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 116
 117 fi
 118
 119 AC_SUBST([ASN1_COMPILE])
 120 AC_SUBST([ASN1_COMPILE_DEP])
 121 AC_SUBST([SLC])
 122 AC_SUBST([SLC_DEP])
 123
 124 dnl ---
 125
 126 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 127
 128 rk_TEST_PACKAGE(openldap,
 129 [#include <lber.h>
 130 #include <ldap.h>],
 131 [-lldap -llber],,,OPENLDAP)
 132 AM_CONDITIONAL(OPENLDAP, test "$with_openldap" != "no")
 133
 134 AC_ARG_ENABLE(hdb-openldap-module,
 135         AS_HELP_STRING([--enable-hdb-openldap-module],
 136                 [if you want support to build openldap hdb as shared object]))
 137 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 138     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 139 fi
 140 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 141
 142 AC_ARG_ENABLE(asn1-templating,
 143         AS_HELP_STRING([--disable-asn1-templating],
 144                 [if you want disable to use of the ASN.1 templating compiler]))
 145 AM_CONDITIONAL(ASN1_TEMPLATING, test "x$enable_asn1_templating" != xno)
 146
 147 dnl
 148 dnl Optional modules, pk-init, digest, kx509
 149 dnl
 150
 151 AC_ARG_ENABLE(pk-init,
 152         AS_HELP_STRING([--disable-pk-init],
 153                 [if you want disable to PK-INIT support]))
 154 if test "$enable_pk_init" != no ;then
 155         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 156 fi
 157 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 158
 159 AC_ARG_ENABLE(digest,
 160         AS_HELP_STRING([--disable-digest],
 161                 [if you want disable to DIGEST support]))
 162 if test "$enable_digest" != no ;then
 163         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 164 fi
 165
 166 AC_ARG_ENABLE(kx509,
 167         AS_HELP_STRING([--disable-kx509],
 168                 [if you want disable to kx509 support]))
 169 if test "$enable_kx509" != no ;then
 170         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 171 fi
 172
 173 dnl Need to test if pkg-config exists
 174 PKG_PROG_PKG_CONFIG
 175
 176 dnl libcap-ng
 177 AC_ARG_WITH([capng],
 178   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 179   [],
 180   [with_capng=check])
 181 if test "$with_capng" != "no"; then
 182   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 183                     [with_capng=yes],[with_capng=no])
 184 fi
 185 if test "$with_capng" = "yes"; then
 186   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 187 fi
 188 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 189 AC_SUBST([CAPNG_CFLAGS])
 190 AC_SUBST([CAPNG_LIBS])
 191
 192 dnl libmicrohttpd
 193 AC_ARG_WITH([microhttpd],
 194   AC_HELP_STRING([--with-microhttpd], [use microhttpd to serve KDC REST API @<:@default=check@:>@]),
 195   [],
 196   [with_microhttpd=check])
 197 if test "$with_microhttpd" != "no"; then
 198   PKG_CHECK_MODULES([MICROHTTPD], [libmicrohttpd >= 0.9.37],
 199                     [with_microhttpd=yes],[with_microhttpd=no])
 200 fi
 201 if test "$with_microhttpd" = "yes"; then
 202   AC_DEFINE_UNQUOTED([HAVE_MICROHTTPD], 1, [whether libmicrohttpd is available for KDC REST API])
 203 fi
 204 AM_CONDITIONAL([HAVE_MICROHTTPD], [test "$with_microhttpd" != "no"])
 205 AC_SUBST([MICROHTTPD_CFLAGS])
 206 AC_SUBST([MICROHTTPD_LIBS])
 207
 208 dnl libcjwt
 209 AC_ARG_WITH([cjwt],
 210   AC_HELP_STRING([--with-cjwt], [(Experimental) use cjwt to validate JWT tokens @<:@default=check@:>@]),
 211   [],
 212   [with_cjwt=check])
 213 if test "$with_cjwt" != "no"; then
 214   PKG_CHECK_MODULES([CJWT], [libcjwt >= 1.0.0],
 215                     [with_cjwt=yes],[with_cjwt=no])
 216 fi
 217 if test "$with_cjwt" = "yes"; then
 218   AC_DEFINE_UNQUOTED([HAVE_CJWT], 1, [whether libcjwt is available for KDC REST API])
 219 fi
 220 AM_CONDITIONAL([HAVE_CJWT], [test "$with_cjwt" != "no"])
 221 AC_SUBST([CJWT_CFLAGS])
 222 AC_SUBST([CJWT_LIBS])
 223
 224 dnl libcjson
 225 AC_ARG_WITH([cjson],
 226   AC_HELP_STRING([--with-cjson], [(Experimental) use cJSON to extract private claims from JWT tokens @<:@default=check@:>@]),
 227   [],
 228   [with_cjson=check])
 229 if test "$with_cjson" != "no"; then
 230   PKG_CHECK_MODULES([CJSON], [libcjson >= 1.0.0],
 231                     [with_cjson=yes],[with_cjson=no])
 232 fi
 233 if test "$with_cjson" = "yes"; then
 234   AC_DEFINE_UNQUOTED([HAVE_CJSON], 1, [whether libcjson is available for KDC REST API])
 235 fi
 236 AM_CONDITIONAL([HAVE_CJSON], [test "$with_cjson" != "no"])
 237 AC_SUBST([CJSON_CFLAGS])
 238 AC_SUBST([CJSON_LIBS])
 239
 240 dnl Check for sqlite
 241 rk_TEST_PACKAGE(sqlite3,
 242 [#include <sqlite3.h>
 243 #ifndef SQLITE_OPEN_CREATE
 244 #error "old version"
 245 #endif],
 246 [-lsqlite3],,,SQLITE3)
 247
 248 if test "X$with_sqlite3" != Xyes ; then
 249    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 250    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 251 fi
 252 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 253
 254 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 255
 256 AC_ARG_ENABLE(sqlite-cache,
 257         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 258 if test "$enable_sqlite_cache" != no; then
 259     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 260 fi
 261 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 262
 263
 264 dnl check for libintl
 265 rk_TEST_PACKAGE(libintl,
 266 [#include <libintl.h>],
 267 [-lintl],,,LIBINTL)
 268
 269 dnl path where the hdb directory is stored
 270 AC_ARG_WITH([hdbdir],
 271         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 272         [],
 273         [with_hdbdir=/var/heimdal])
 274 DIR_hdbdir="$with_hdbdir"
 275 AC_SUBST([DIR_hdbdir])
 276
 277
 278 AM_CONDITIONAL(KRB5, true)
 279 AM_CONDITIONAL(do_roken_rename, true)
 280
 281 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 282
 283
 284 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 285 AC_SUBST(LIB_kdb)dnl
 286
 287 KRB_CRYPTO
 288
 289 KRB_PTHREADS
 290
 291 AC_ARG_ENABLE(dce,
 292         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 293 if test "$enable_dce" = yes; then
 294     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 295 fi
 296 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 297
 298 ## XXX quite horrible:
 299 if test -f /etc/ibmcxx.cfg; then
 300         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 301         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 302         dpagaix_ldflags=
 303 else
 304         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 305         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 306         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 307 fi
 308 AC_SUBST(dpagaix_cflags)
 309 AC_SUBST(dpagaix_ldadd)
 310 AC_SUBST(dpagaix_ldflags)
 311
 312 AC_ARG_ENABLE([afs-support],
 313         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 314 if test "$enable_afs_support" = no; then
 315         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 316         NO_AFS="1"
 317 fi
 318 AC_SUBST(NO_AFS)dnl
 319 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 320
 321 rk_DB
 322
 323 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 324
 325 rk_ROKEN(lib/roken)
 326 LIBADD_roken="$LIB_roken"
 327 AC_SUBST(LIBADD_roken)dnl
 328 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 329
 330 rk_OTP
 331
 332 rk_LIBDISPATCH
 333
 334 AC_CHECK_OSFC2
 335
 336 AC_ARG_ENABLE(mmap,
 337         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 338 if test "$enable_mmap" = "no"; then
 339         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 340 fi
 341
 342 AC_ARG_ENABLE(afs-string-to-key,
 343         AS_HELP_STRING([--disable-afs-string-to-key],
 344         [disable use of weak AFS string-to-key functions]),
 345         [], [enable_afs_string_to_key=yes])
 346
 347 if test "$enable_afs_string_to_key" = "yes"; then
 348         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 349         ENABLE_AFS_STRING_TO_KEY=1
 350 fi
 351 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 352
 353
 354 rk_CHECK_MAN
 355
 356 rk_TEST_PACKAGE(readline,
 357 [#include <stdio.h>
 358 #if defined(HAVE_READLINE_READLINE_H)
 359 #include <readline/readline.h>
 360 #elif defined(HAVE_READLINE_H)
 361 #include <readline.h>
 362 #endif
 363 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 364
 365 rk_TEST_PACKAGE(libedit,
 366 [#include <stdio.h>
 367 #if defined(HAVE_READLINE_READLINE_H)
 368 #include <readline/readline.h>
 369 #elif defined(HAVE_READLINE_H)
 370 #include <readline.h>
 371 #elif defined(HAVE_EDITLINE_READLINE_H)
 372 #include <editline/readline.h>
 373 #endif
 374 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 375
 376 AC_CONFIG_SUBDIRS([lib/libedit])
 377
 378 KRB_C_BIGENDIAN
 379 AC_C_INLINE
 380
 381 dnl AM_C_PROTOTYPES
 382
 383 dnl Checks for typedefs, structures, and compiler characteristics.
 384 AC_C_CONST
 385 AC_TYPE_OFF_T
 386 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 387 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 388 AC_HAVE_TYPE([long long])
 389 AC_HEADER_TIME
 390 AC_STRUCT_TM
 391
 392 dnl Checks for header files.
 393 AC_HEADER_STDC
 394
 395 AC_CHECK_HEADERS([\
 396         CommonCrypto/CommonDigest.h             \
 397         CommonCrypto/CommonCryptor.h            \
 398         arpa/telnet.h                           \
 399         bind/bitypes.h                          \
 400         bsdsetjmp.h                             \
 401         curses.h                                \
 402         dlfcn.h                                 \
 403         execinfo.h                              \
 404         fnmatch.h                               \
 405         inttypes.h                              \
 406         io.h                                    \
 407         keyutils.h                              \
 408         libutil.h                               \
 409         limits.h                                \
 410         maillock.h                              \
 411         netgroup.h                              \
 412         netinet/in6_machtypes.h                 \
 413         netinet/tcp.h                           \
 414         pthread.h                               \
 415         pty.h                                   \
 416         sac.h                                   \
 417         sgtty.h                                 \
 418         siad.h                                  \
 419         signal.h                                \
 420         strings.h                               \
 421         stropts.h                               \
 422         stdatomic.h                             \
 423         sys/bitypes.h                           \
 424         sys/category.h                          \
 425         sys/file.h                              \
 426         sys/filio.h                             \
 427         sys/ioccom.h                            \
 428         sys/mman.h                              \
 429         sys/param.h                             \
 430         sys/pty.h                               \
 431         sys/ptyio.h                             \
 432         sys/select.h                            \
 433         sys/socket.h                            \
 434         sys/str_tty.h                           \
 435         sys/stream.h                            \
 436         sys/stropts.h                           \
 437         sys/syscall.h                           \
 438         sys/termio.h                            \
 439         sys/timeb.h                             \
 440         sys/times.h                             \
 441         sys/types.h                             \
 442         sys/un.h                                \
 443         locale.h                                \
 444         termcap.h                               \
 445         termio.h                                \
 446         termios.h                               \
 447         time.h                                  \
 448         tmpdir.h                                \
 449         udb.h                                   \
 450         util.h                                  \
 451 ])
 452
 453 dnl On Solaris 8 there's a compilation warning for term.h because
 454 dnl it doesn't define `bool'.
 455 AC_CHECK_HEADERS(term.h, , , -)
 456
 457 dnl aix have asl.h (A/IX screen library) that we don't want
 458 AC_CHECK_HEADERS(asl.h, , , [
 459 #include <asl.h>
 460 #ifndef ASL_STRING_EMERG
 461 #error ASL_STRING_EMERG missing
 462 #endif])
 463
 464 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 465 #if HAVE_SYS_SOCKET_H
 466 #include <sys/socket.h>
 467 #endif])
 468
 469 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 470 #if HAVE_SYS_TTY_H
 471 #include <sys/tty.h>
 472 #endif])
 473
 474 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 475 #if HAVE_TERMIOS_H
 476 #include <termios.h>
 477 #endif
 478 #if HAVE_SYS_STREAM_H
 479 #include <sys/stream.h>
 480 #endif])
 481
 482 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 483 #if HAVE_SYS_TYPES_H
 484 #include <sys/types.h>
 485 #endif
 486 #if HAVE_SYS_PARAM_H
 487 #include <sys/param.h>
 488 #endif])
 489
 490 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 491 #include <security/pam_appl.h>
 492 ])
 493
 494 dnl export symbols
 495 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 496 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 497 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 498
 499 dnl Checks for libraries.
 500
 501 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 502 #ifdef HAVE_UTIL_H
 503 #include <util.h>
 504 #endif
 505 ],[0,0,0])
 506 AC_FIND_FUNC_NO_LIBS(logout, util,[
 507 #ifdef HAVE_UTIL_H
 508 #include <util.h>
 509 #endif
 510 ],[0])
 511 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 512 #ifdef HAVE_UTIL_H
 513 #include <util.h>
 514 #endif
 515 ],[0,0,0,0,0])
 516
 517 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses tinfo,[
 518 #ifdef HAVE_TERMCAP_H
 519 #include <termcap.h>
 520 #endif
 521 #ifdef HAVE_CURSES_H
 522 #include <curses.h>
 523 #endif
 524 ],[0,0])
 525
 526 dnl Checks for library functions.
 527
 528 AC_CHECK_FUNCS([                                \
 529         _getpty                                 \
 530         _scrsize                                \
 531         arc4random                              \
 532         backtrace                               \
 533         fcntl                                   \
 534         fork                                    \
 535         fseeko                                  \
 536         ftello                                  \
 537         getpeereid                              \
 538         getpeerucred                            \
 539         getresgid                               \
 540         getresuid                               \
 541         grantpt                                 \
 542         kill                                    \
 543         mktime                                  \
 544         ptsname                                 \
 545         rand                                    \
 546         revoke                                  \
 547         select                                  \
 548         setitimer                               \
 549         setpcred                                \
 550         setpgid                                 \
 551         setproctitle                            \
 552         setregid                                \
 553         setresgid                               \
 554         setresuid                               \
 555         setreuid                                \
 556         setsid                                  \
 557         setutent                                \
 558         sigaction                               \
 559         strstr                                  \
 560         ttyname                                 \
 561         ttyslot                                 \
 562         umask                                   \
 563         unlockpt                                \
 564         vhangup                                 \
 565         waitpid                                 \
 566         yp_get_default_domain                   \
 567 ])
 568
 569 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 570 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 571         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 572         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 573 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 574         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 575 fi
 576 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 577
 578 AC_FUNC_MMAP
 579
 580 KRB_CAPABILITIES
 581 rk_DLADDR
 582
 583 AC_CHECK_GETPWNAM_R_POSIX
 584 AC_CHECK_GETPWUID_R_POSIX
 585
 586 dnl detect doors on solaris
 587 if test "$enable_pthread_support" != no; then
 588    saved_LIBS="$LIBS"
 589    LIBS="$LIBS $PTHREADS_LIBS"
 590    AC_FIND_FUNC_NO_LIBS(door_create, door)
 591    LIBS="$saved_LIBS"
 592 fi
 593
 594 AC_ARG_ENABLE(kcm,
 595         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 596 ,[enable_kcm=yes])
 597
 598 if test "$enable_kcm" = yes ; then
 599    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 600         enable_kcm=no
 601    fi
 602 fi
 603 if test "$enable_kcm" = yes; then
 604        AC_DEFINE(HAVE_KCM, 1,
 605                [Define if you want to use the Kerberos Credentials Manager.])
 606 fi
 607 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 608
 609 dnl detect keyring on Linux
 610 if test "$ac_cv_header_keyutils_h" = yes; then
 611     AC_CHECK_SIZEOF([key_serial_t],,[
 612         #ifdef HAVE_INTTYPES_H
 613         #include <inttypes.h>
 614         #endif
 615         #ifdef HAVE_SYS_TYPES_H
 616         #include <sys/types.h>
 617         #endif
 618         #include <keyutils.h>
 619     ])
 620 fi
 621
 622 AC_FIND_FUNC_NO_LIBS(add_key, keyutils)
 623 if test -n "$LIB_add_key"; then
 624     saved_LIBS="$LIBS"
 625     LIBS="$LIBS $LIB_add_key"
 626     AC_CHECK_FUNCS(keyctl_get_persistent)
 627     LIBS="$saved_LIBS"
 628 fi
 629
 630 AC_CHECK_SIZEOF([time_t])
 631
 632 dnl Cray stuff
 633 AC_CHECK_FUNCS(getudbnam setlim)
 634
 635 dnl AC_KRB_FUNC_GETCWD_BROKEN
 636
 637 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 638         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 639         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 640 #ifdef HAVE_INTTYPES_H
 641 #include <inttypes.h>
 642 #endif
 643 #ifdef HAVE_SYS_TYPES_H
 644 #include <sys/types.h>
 645 #endif
 646 #ifdef HAVE_SYS_BITYPES_H
 647 #include <sys/bitypes.h>
 648 #endif
 649 #ifdef HAVE_BIND_BITYPES_H
 650 #include <bind/bitypes.h>
 651 #endif
 652 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 653 #include <netinet/in6_machtypes.h>
 654 #endif
 655 ])
 656
 657 rk_FRAMEWORK_SECURITY
 658 rk_FRAMEWORK_COREFOUNDATION
 659
 660 KRB_READLINE
 661
 662 rk_TELNET
 663
 664 dnl Some operating systems already have com_err and compile_et
 665 CHECK_COMPILE_ET
 666
 667 rk_AUTH_MODULES([sia afskauthlib])
 668
 669 rk_DESTDIRS
 670
 671 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 672
 673
 674 AH_BOTTOM([#ifdef __APPLE__
 675 #include <AvailabilityMacros.h>
 676 #endif])
 677
 678 AH_BOTTOM([#ifdef ROKEN_RENAME
 679 #include "roken_rename.h"
 680 #endif])
 681
 682 AC_ARG_ENABLE(heimdal-documentation,
 683         AS_HELP_STRING([--disable-heimdal-documentation],
 684                 [if you want disable to heimdal documentation]))
 685 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 686
 687 AC_CONFIG_FILES(Makefile                \
 688         etc/Makefile                    \
 689         include/Makefile                \
 690         include/gssapi/Makefile         \
 691         include/hcrypto/Makefile        \
 692         include/kadm5/Makefile          \
 693         lib/Makefile                    \
 694         lib/base/Makefile                       \
 695         lib/asn1/Makefile               \
 696         lib/com_err/Makefile            \
 697         lib/hcrypto/Makefile            \
 698         lib/hx509/Makefile              \
 699         lib/gssapi/Makefile             \
 700         lib/ntlm/Makefile               \
 701         lib/hdb/Makefile                \
 702         lib/ipc/Makefile                \
 703         lib/kadm5/Makefile              \
 704         lib/kafs/Makefile               \
 705         lib/kdfs/Makefile               \
 706         lib/krb5/Makefile               \
 707         lib/otp/Makefile                \
 708         lib/roken/Makefile              \
 709         lib/sl/Makefile                 \
 710         lib/sqlite/Makefile             \
 711         lib/vers/Makefile               \
 712         lib/wind/Makefile               \
 713         lib/gss_preauth/Makefile        \
 714         po/Makefile                     \
 715         kuser/Makefile                  \
 716         kpasswd/Makefile                \
 717         kadmin/Makefile                 \
 718         admin/Makefile                  \
 719         kcm/Makefile                    \
 720         kdc/Makefile                    \
 721         appl/Makefile                   \
 722         appl/afsutil/Makefile           \
 723         appl/dbutils/Makefile           \
 724         appl/gssmask/Makefile           \
 725         appl/otp/Makefile               \
 726         appl/test/Makefile              \
 727         appl/kf/Makefile                \
 728         appl/dceutils/Makefile          \
 729         tests/Makefile                  \
 730         tests/bin/Makefile              \
 731         tests/can/Makefile              \
 732         tests/db/Makefile               \
 733         tests/kdc/Makefile              \
 734         tests/ldap/Makefile             \
 735         tests/gss/Makefile              \
 736         tests/java/Makefile             \
 737         tests/plugin/Makefile           \
 738         packages/Makefile               \
 739         packages/mac/Makefile           \
 740         doc/Makefile                    \
 741         tools/Makefile                  \
 742 )
 743
 744 AC_OUTPUT
 745
 746 dnl
 747 dnl This is the release version name-number[beta]
 748 dnl
 749
 750 if test -d "$srcdir/.git"; then
 751     cat > include/newversion.h.in <<EOF
 752 #ifndef VERSION_HIDDEN
 753 #define VERSION_HIDDEN
 754 #endif
 755 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ @BRANCH@ @TAG@ ($host) @COMMIT@ @DATE@ \$";
 756 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 757 EOF
 758 else
 759     cat > include/newversion.h.in <<EOF
 760 #ifndef VERSION_HIDDEN
 761 #define VERSION_HIDDEN
 762 #endif
 763 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 764 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 765 EOF
 766 fi
 767
 768 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 769         echo "include/version.h is unchanged"
 770         rm -f include/newversion.h.in
 771 else
 772         echo "creating include/version.h"
 773         if test -n "$SOURCE_DATE_EPOCH"; then
 774             Date=`
 775                   # BSD, OS X
 776                   date -u -r "$SOURCE_DATE_EPOCH" "+%Y-%m-%dT%H:%M:%SZ" 2>/dev/null ||
 777                   # Linux
 778                   date -u -d "@${SOURCE_DATE_EPOCH}" 2>/dev/null ||
 779                   # Illumos -- sorry, no -r/-d here
 780                   date -u ||
 781                   date`
 782         else
 783             Date=`date -u "+%Y-%m-%dT%H:%M:%SZ"`
 784         fi
 785         if test -n "$SOURCE_HOST"; then
 786             Host=$SOURCE_HOST
 787         else
 788             Host=`uname -n`
 789         fi
 790         if test -n "$SOURCE_USER"; then
 791             User=$SOURCE_USER
 792         else
 793             User=${USER:-${LOGNAME:-`id -nu`}}
 794         fi
 795         if test -d "$srcdir/.git"; then
 796             GitCommit=`cd $srcdir && git rev-parse HEAD`
 797             GitBranch=`cd $srcdir && git rev-parse --abbrev-ref HEAD`
 798             if test "x$GitBranch" = master; then
 799                 GitDesc=`cd $srcdir && git describe --all --dirty`
 800             else
 801                 GitDesc=`cd $srcdir && \
 802                          git describe --tags --match 'heimdal-*' --dirty`
 803             fi
 804         else
 805             GitCommit='<commit-unknown>'
 806             GitBranch='<branch-unknown>'
 807             GitDesc='<tag-unknown>'
 808         fi
 809         mv -f include/newversion.h.in include/version.h.in
 810         sed -e "s/@HOST@/$Host/" \
 811             -e "s;@USER@;$User;" \
 812             -e "s;@DATE@;$Date;" \
 813             -e "s;@BRANCH@;$GitBranch;" \
 814             -e "s;@TAG@;$GitDesc;" \
 815             -e "s;@COMMIT@;$GitCommit;" \
 816             include/version.h.in > include/version.h
 817 fi