configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.3.2rc2],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10.3])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17 AC_PROG_LIBTOOL
  18
  19 AC_PREFIX_DEFAULT(/usr/heimdal)
  20
  21 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  22 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  23
  24 AC_CANONICAL_HOST
  25 CANONICAL_HOST=$host
  26 AC_SUBST(CANONICAL_HOST)
  27
  28 dnl Hints for autobuild
  29 AB_INIT
  30
  31 rk_SYS_LARGEFILE
  32
  33 rk_AIX
  34 rk_IRIX
  35 rk_SUNOS
  36
  37 dnl
  38 dnl this is needed to run the configure tests against glibc
  39 dnl
  40 AC_DEFINE([_GNU_SOURCE], 1,
  41         [Define to enable extensions on glibc-based systems such as Linux.])
  42
  43 AC_OBJEXT
  44 AC_EXEEXT
  45
  46 dnl AC_KRB_PROG_YACC
  47 AC_PROG_YACC
  48 AM_PROG_LEX
  49 dnl AC_PROG_RANLIB
  50 AC_PROG_AWK
  51 AC_KRB_PROG_LN_S
  52
  53 AC_MIPS_ABI
  54 CC="$CC $abi"
  55 libdir="$libdir$abilibdirext"
  56
  57 AC_C___ATTRIBUTE__
  58
  59 LT_PREREQ([2.2])
  60 LT_INIT([shared static win32-dll])
  61
  62 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  63 rk_VERSIONSCRIPT
  64
  65 dnl
  66 dnl Helper bits for cross compiling
  67 dnl
  68
  69
  70
  71 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  72
  73 AC_ARG_WITH(cross-tools,
  74         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  75         [if test "$withval" = "yes"; then
  76                 AC_MSG_ERROR([Need path to cross tools])
  77         fi
  78         with_cross_tools="${with_cross_tools}/"
  79         ])
  80
  81 if test "${cross_compiling}" != yes ; then
  82
  83    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  84    SLC="\$(top_builddir)/lib/sl/slc"
  85
  86    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  87    SLC_DEP="\$(SLC)"
  88 else
  89    ASN1_COMPILE="${with_cross_tools}asn1_compile"
  90    SLC="${with_cross_tools}slc"
  91
  92    ASN1_COMPILE_DEP=
  93    SLC_DEP=
  94 fi
  95
  96 AC_SUBST([ASN1_COMPILE])
  97 AC_SUBST([ASN1_COMPILE_DEP])
  98 AC_SUBST([SLC])
  99 AC_SUBST([SLC_DEP])
 100
 101
 102 dnl ---
 103
 104 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 105
 106 rk_TEST_PACKAGE(openldap,
 107 [#include <lber.h>
 108 #include <ldap.h>],
 109 [-lldap -llber],,,OPENLDAP)
 110
 111 AC_ARG_ENABLE(hdb-openldap-module,
 112         AS_HELP_STRING([--enable-hdb-openldap-module],
 113                 [if you want support to build openldap hdb as shared object]))
 114 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 115     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 116 fi
 117 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 118
 119 dnl
 120 dnl Optional modules, pk-init, digest, kx509
 121 dnl
 122
 123 AC_ARG_ENABLE(pk-init,
 124         AS_HELP_STRING([--disable-pk-init],
 125                 [if you want disable to PK-INIT support]))
 126 if test "$enable_pk_init" != no ;then
 127         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 128 fi
 129 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 130
 131 AC_ARG_ENABLE(digest,
 132         AS_HELP_STRING([--disable-digest],
 133                 [if you want disable to DIGEST support]))
 134 if test "$enable_digest" != no ;then
 135         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 136 fi
 137
 138 AC_ARG_ENABLE(kx509,
 139         AS_HELP_STRING([--disable-kx509],
 140                 [if you want disable to kx509 support]))
 141 if test "$enable_kx509" != no ;then
 142         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 143 fi
 144
 145 AC_ARG_ENABLE(krb4,
 146         AS_HELP_STRING([--disable-krb4],
 147                 [if you want disable to krb4 support]))
 148 if test "$enable_krb4" != no ;then
 149         AC_DEFINE([KRB4], 1, [Define to enable Kerberos 4.])
 150 fi
 151
 152
 153 dnl Check for sqlite
 154 rk_TEST_PACKAGE(sqlite3,
 155 [#include <sqlite3.h>
 156 #ifndef SQLITE_OPEN_CREATE
 157 #error "old version"
 158 #endif],
 159 [-lsqlite3],,,SQLITE3)
 160
 161 if test "X$with_sqlite3" != Xyes ; then
 162    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 163    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 164 fi
 165 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 166
 167 dnl check for libintl
 168 rk_TEST_PACKAGE(libintl,
 169 [#include <libintl.h>],
 170 [-lintl],,,LIBINTL)
 171
 172 dnl path where the hdb directory is stored
 173 AC_ARG_WITH([hdbdir],
 174         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 175         [],
 176         [with_hdbdir=/var/heimdal])
 177 DIR_hdbdir="$with_hdbdir"
 178 AC_SUBST([DIR_hdbdir])
 179
 180
 181 dnl no kerberos4 any more
 182 with_krb4=no
 183 AC_SUBST(INCLUDE_krb4)
 184 AC_SUBST(LIB_krb4)
 185 AM_CONDITIONAL(KRB4, false)
 186
 187 AM_CONDITIONAL(KRB5, true)
 188 AM_CONDITIONAL(do_roken_rename, true)
 189
 190 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 191 AC_SUBST(LIB_kdb)dnl
 192
 193 KRB_CRYPTO
 194
 195 KRB_PTHREADS
 196
 197 AC_ARG_ENABLE(dce,
 198         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 199 if test "$enable_dce" = yes; then
 200     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 201 fi
 202 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 203
 204 ## XXX quite horrible:
 205 if test -f /etc/ibmcxx.cfg; then
 206         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 207         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 208         dpagaix_ldflags=
 209 else
 210         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 211         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 212         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 213 fi
 214 AC_SUBST(dpagaix_cflags)
 215 AC_SUBST(dpagaix_ldadd)
 216 AC_SUBST(dpagaix_ldflags)
 217
 218 AC_ARG_ENABLE([afs-support],
 219         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 220 if test "$enable_afs_support" = no; then
 221         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 222 fi
 223
 224 rk_DB
 225
 226 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 227
 228 rk_ROKEN(lib/roken)
 229 LIBADD_roken="$LIB_roken"
 230 AC_SUBST(LIBADD_roken)dnl
 231 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 232
 233 rk_OTP
 234
 235 AC_CHECK_OSFC2
 236
 237 AC_ARG_ENABLE(mmap,
 238         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 239 if test "$enable_mmap" = "no"; then
 240         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 241 fi
 242
 243 AC_ARG_ENABLE(afs-string-to-key,
 244         AS_HELP_STRING([--disable-afs-string-to-key],
 245         [disable use of weak AFS string-to-key functions]),
 246         [], [enable_afs_string_to_key=yes])
 247
 248 if test "$enable_afs_string_to_key" = "yes"; then
 249         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 250 fi
 251
 252
 253 rk_CHECK_MAN
 254
 255 rk_TEST_PACKAGE(readline,
 256 [#include <stdio.h>
 257  #include <readline.h>],-lreadline,,, READLINE)
 258
 259 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 260
 261 KRB_C_BIGENDIAN
 262 AC_C_INLINE
 263
 264 KRB_CHECK_X
 265
 266 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 267
 268 AC_CHECK_XAU
 269
 270 dnl AM_C_PROTOTYPES
 271
 272 dnl Checks for typedefs, structures, and compiler characteristics.
 273 AC_C_CONST
 274 AC_TYPE_OFF_T
 275 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 276 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 277 AC_HAVE_TYPE([long long])
 278 AC_HEADER_TIME
 279 AC_STRUCT_TM
 280
 281 dnl Checks for header files.
 282 AC_HEADER_STDC
 283
 284 AC_CHECK_HEADERS([\
 285         CommonCrypto/CommonDigest.h             \
 286         arpa/ftp.h                              \
 287         arpa/telnet.h                           \
 288         bind/bitypes.h                          \
 289         bsdsetjmp.h                             \
 290         curses.h                                \
 291         dlfcn.h                                 \
 292         fnmatch.h                               \
 293         inttypes.h                              \
 294         io.h                                    \
 295         libutil.h                               \
 296         limits.h                                \
 297         maillock.h                              \
 298         netgroup.h                              \
 299         netinet/in6_machtypes.h                 \
 300         pthread.h                               \
 301         pty.h                                   \
 302         sac.h                                   \
 303         sgtty.h                                 \
 304         siad.h                                  \
 305         signal.h                                \
 306         strings.h                               \
 307         stropts.h                               \
 308         sys/bitypes.h                           \
 309         sys/category.h                          \
 310         sys/file.h                              \
 311         sys/filio.h                             \
 312         sys/ioccom.h                            \
 313         sys/mman.h                              \
 314         sys/param.h                             \
 315         sys/pty.h                               \
 316         sys/ptyio.h                             \
 317         sys/select.h                            \
 318         sys/socket.h                            \
 319         sys/str_tty.h                           \
 320         sys/stream.h                            \
 321         sys/stropts.h                           \
 322         sys/syscall.h                           \
 323         sys/termio.h                            \
 324         sys/timeb.h                             \
 325         sys/times.h                             \
 326         sys/types.h                             \
 327         sys/un.h                                \
 328         locale.h                                \
 329         termcap.h                               \
 330         termio.h                                \
 331         termios.h                               \
 332         time.h                                  \
 333         tmpdir.h                                \
 334         udb.h                                   \
 335         util.h                                  \
 336         utmp.h                                  \
 337         utmpx.h                                 \
 338 ])
 339
 340 dnl On Solaris 8 there's a compilation warning for term.h because
 341 dnl it doesn't define `bool'.
 342 AC_CHECK_HEADERS(term.h, , , -)
 343
 344 dnl aix have asl.h (A/IX screen library) that we don't want
 345 AC_CHECK_HEADERS(asl.h, , , [
 346 #include <asl.h>
 347 #ifndef ASL_STRING_EMERG
 348 #error ASL_STRING_EMERG missing
 349 #endif])
 350
 351 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 352 #if HAVE_SYS_SOCKET_H
 353 #include <sys/socket.h>
 354 #endif])
 355
 356 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 357 #if HAVE_SYS_TTY_H
 358 #include <sys/tty.h>
 359 #endif])
 360
 361 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 362 #if HAVE_TERMIOS_H
 363 #include <termios.h>
 364 #endif
 365 #if HAVE_SYS_STREAM_H
 366 #include <sys/stream.h>
 367 #endif])
 368
 369 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 370 #if HAVE_SYS_TYPES_H
 371 #include <sys/types.h>
 372 #endif
 373 #if HAVE_SYS_PARAM_H
 374 #include <sys/param.h>
 375 #endif])
 376
 377 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 378 #include <security/pam_appl.h>
 379 ])
 380
 381 dnl export symbols
 382 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 383 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 384 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 385
 386 dnl Checks for libraries.
 387
 388 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 389 #ifdef HAVE_UTIL_H
 390 #include <util.h>
 391 #endif
 392 ],[0,0,0])
 393 AC_FIND_FUNC_NO_LIBS(logout, util,[
 394 #ifdef HAVE_UTIL_H
 395 #include <util.h>
 396 #endif
 397 ],[0])
 398 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 399 #ifdef HAVE_UTIL_H
 400 #include <util.h>
 401 #endif
 402 ],[0,0,0,0,0])
 403
 404 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 405 #ifdef HAVE_TERMCAP_H
 406 #include <termcap.h>
 407 #endif
 408 #ifdef HAVE_CURSES_H
 409 #include <curses.h>
 410 #endif
 411 ],[0,0])
 412
 413 dnl Checks for library functions.
 414
 415 AC_CHECK_FUNCS([                                \
 416         _getpty                                 \
 417         _scrsize                                \
 418         arc4random                              \
 419         fcntl                                   \
 420         getpeereid                              \
 421         getpeerucred                            \
 422         grantpt                                 \
 423         mktime                                  \
 424         ptsname                                 \
 425         rand                                    \
 426         revoke                                  \
 427         select                                  \
 428         setitimer                               \
 429         setpcred                                \
 430         setpgid                                 \
 431         setproctitle                            \
 432         setregid                                \
 433         setresgid                               \
 434         setresuid                               \
 435         setreuid                                \
 436         setsid                                  \
 437         setutent                                \
 438         sigaction                               \
 439         strstr                                  \
 440         ttyname                                 \
 441         ttyslot                                 \
 442         umask                                   \
 443         unlockpt                                \
 444         vhangup                                 \
 445         yp_get_default_domain                   \
 446 ])
 447
 448 AC_FUNC_MMAP
 449
 450 KRB_CAPABILITIES
 451
 452 AC_CHECK_GETPWNAM_R_POSIX
 453
 454 dnl detect doors on solaris
 455 if test "$enable_pthread_support" != no; then
 456    saved_LIBS="$LIBS"
 457    LIBS="$LIBS $PTHREADS_LIBS"
 458    AC_FIND_FUNC_NO_LIBS(door_create, door)
 459    LIBS="$saved_LIBS"
 460 fi
 461
 462 AC_ARG_ENABLE(kcm,
 463         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 464 ,[enable_kcm=yes])
 465
 466 if test "$enable_kcm" = yes ; then
 467    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 468         enable_kcm=no
 469    fi
 470 fi
 471 if test "$enable_kcm" = yes; then
 472        AC_DEFINE(HAVE_KCM, 1,
 473                [Define if you want to use the Kerberos Credentials Manager.])
 474 fi
 475 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 476
 477
 478
 479 dnl Cray stuff
 480 AC_CHECK_FUNCS(getudbnam setlim)
 481
 482 dnl AC_KRB_FUNC_GETCWD_BROKEN
 483
 484 dnl
 485 dnl Check for fields in struct utmp
 486 dnl
 487
 488 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 489 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 490 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 491 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 492 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 493 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 494 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 495 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 496
 497 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 498         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 499         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 500 #ifdef HAVE_INTTYPES_H
 501 #include <inttypes.h>
 502 #endif
 503 #ifdef HAVE_SYS_TYPES_H
 504 #include <sys/types.h>
 505 #endif
 506 #ifdef HAVE_SYS_BITYPES_H
 507 #include <sys/bitypes.h>
 508 #endif
 509 #ifdef HAVE_BIND_BITYPES_H
 510 #include <bind/bitypes.h>
 511 #endif
 512 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 513 #include <netinet/in6_machtypes.h>
 514 #endif
 515 ])
 516
 517 rk_FRAMEWORK_SECURITY
 518
 519 KRB_READLINE
 520
 521 rk_TELNET
 522
 523 dnl Some operating systems already have com_err and compile_et
 524 CHECK_COMPILE_ET
 525
 526 rk_AUTH_MODULES([sia afskauthlib])
 527
 528 rk_DESTDIRS
 529
 530 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 531
 532
 533 AH_BOTTOM([#ifdef ROKEN_RENAME
 534 #include "roken_rename.h"
 535 #endif])
 536
 537 AC_CONFIG_FILES(Makefile                \
 538         etc/Makefile                    \
 539         include/Makefile                \
 540         include/gssapi/Makefile         \
 541         include/hcrypto/Makefile        \
 542         include/kadm5/Makefile          \
 543         lib/Makefile                    \
 544         lib/auth/Makefile               \
 545         lib/auth/afskauthlib/Makefile   \
 546         lib/auth/pam/Makefile           \
 547         lib/auth/sia/Makefile           \
 548         lib/asn1/Makefile               \
 549         lib/com_err/Makefile            \
 550         lib/hcrypto/Makefile            \
 551         lib/editline/Makefile           \
 552         lib/hx509/Makefile              \
 553         lib/gssapi/Makefile             \
 554         lib/ntlm/Makefile               \
 555         lib/hdb/Makefile                \
 556         lib/kadm5/Makefile              \
 557         lib/kafs/Makefile               \
 558         lib/kdfs/Makefile               \
 559         lib/krb5/Makefile               \
 560         lib/otp/Makefile                \
 561         lib/roken/Makefile              \
 562         lib/sl/Makefile                 \
 563         lib/sqlite/Makefile             \
 564         lib/vers/Makefile               \
 565         lib/wind/Makefile               \
 566         po/Makefile                     \
 567         kuser/Makefile                  \
 568         kpasswd/Makefile                \
 569         kadmin/Makefile                 \
 570         admin/Makefile                  \
 571         kcm/Makefile                    \
 572         kdc/Makefile                    \
 573         appl/Makefile                   \
 574         appl/afsutil/Makefile           \
 575         appl/ftp/Makefile               \
 576         appl/ftp/common/Makefile        \
 577         appl/ftp/ftp/Makefile           \
 578         appl/ftp/ftpd/Makefile          \
 579         appl/gssmask/Makefile           \
 580         appl/kx/Makefile                \
 581         appl/login/Makefile             \
 582         appl/otp/Makefile               \
 583         appl/popper/Makefile            \
 584         appl/push/Makefile              \
 585         appl/rsh/Makefile               \
 586         appl/rcp/Makefile               \
 587         appl/su/Makefile                \
 588         appl/xnlock/Makefile            \
 589         appl/telnet/Makefile            \
 590         appl/telnet/libtelnet/Makefile  \
 591         appl/telnet/telnet/Makefile     \
 592         appl/telnet/telnetd/Makefile    \
 593         appl/test/Makefile              \
 594         appl/kf/Makefile                \
 595         appl/dceutils/Makefile          \
 596         tests/Makefile                  \
 597         tests/bin/Makefile              \
 598         tests/can/Makefile              \
 599         tests/db/Makefile               \
 600         tests/kdc/Makefile              \
 601         tests/ldap/Makefile             \
 602         tests/gss/Makefile              \
 603         tests/java/Makefile             \
 604         tests/plugin/Makefile           \
 605         packages/Makefile               \
 606         packages/mac/Makefile           \
 607         doc/Makefile                    \
 608         tools/Makefile                  \
 609 )
 610
 611 AC_OUTPUT
 612
 613 dnl
 614 dnl This is the release version name-number[beta]
 615 dnl
 616
 617 cat > include/newversion.h.in <<EOF
 618 #ifndef VERSION_HIDDEN
 619 #define VERSION_HIDDEN
 620 #endif
 621 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 622 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 623 EOF
 624
 625 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 626         echo "include/version.h is unchanged"
 627         rm -f include/newversion.h.in
 628 else
 629         echo "creating include/version.h"
 630         User=${USER-${LOGNAME}}
 631         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 632         Date=`date`
 633         mv -f include/newversion.h.in include/version.h.in
 634         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 635 fi