configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.3.99],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17 AC_PROG_LIBTOOL
  18
  19 AC_PREFIX_DEFAULT(/usr/heimdal)
  20
  21 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  22 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  23
  24 AC_CANONICAL_HOST
  25 CANONICAL_HOST=$host
  26 AC_SUBST(CANONICAL_HOST)
  27
  28 dnl Hints for autobuild
  29 AB_INIT
  30
  31 rk_SYS_LARGEFILE
  32
  33 rk_AIX
  34 rk_IRIX
  35 rk_SUNOS
  36
  37 dnl
  38 dnl this is needed to run the configure tests against glibc
  39 dnl
  40 AC_DEFINE([_GNU_SOURCE], 1,
  41         [Define to enable extensions on glibc-based systems such as Linux.])
  42
  43 AC_OBJEXT
  44 AC_EXEEXT
  45
  46 dnl AC_KRB_PROG_YACC
  47 AC_PROG_YACC
  48 AM_PROG_LEX
  49 dnl AC_PROG_RANLIB
  50 AC_PROG_AWK
  51 AC_KRB_PROG_LN_S
  52
  53 AC_MIPS_ABI
  54 CC="$CC $abi"
  55 libdir="$libdir$abilibdirext"
  56
  57 AC_C___ATTRIBUTE__
  58
  59 LT_PREREQ([2.2])
  60 LT_INIT([shared static win32-dll])
  61
  62 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  63 rk_VERSIONSCRIPT
  64
  65 dnl
  66 dnl Helper bits for cross compiling
  67 dnl
  68
  69
  70
  71 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  72
  73 AC_ARG_WITH(cross-tools,
  74         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  75         [if test "$withval" = "yes"; then
  76                 AC_MSG_ERROR([Need path to cross tools])
  77         fi
  78         with_cross_tools="${with_cross_tools}/"
  79         ])
  80
  81 if test "${cross_compiling}" != yes ; then
  82
  83    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  84    SLC="\$(top_builddir)/lib/sl/slc"
  85
  86    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  87    SLC_DEP="\$(SLC)"
  88 else
  89    ASN1_COMPILE="${with_cross_tools}asn1_compile"
  90    SLC="${with_cross_tools}slc"
  91
  92    ASN1_COMPILE_DEP=
  93    SLC_DEP=
  94 fi
  95
  96 AC_SUBST([ASN1_COMPILE])
  97 AC_SUBST([ASN1_COMPILE_DEP])
  98 AC_SUBST([SLC])
  99 AC_SUBST([SLC_DEP])
 100
 101
 102 dnl ---
 103
 104 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 105
 106 rk_TEST_PACKAGE(openldap,
 107 [#include <lber.h>
 108 #include <ldap.h>],
 109 [-lldap -llber],,,OPENLDAP)
 110
 111 AC_ARG_ENABLE(hdb-openldap-module,
 112         AS_HELP_STRING([--enable-hdb-openldap-module],
 113                 [if you want support to build openldap hdb as shared object]))
 114 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 115     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 116 fi
 117 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 118
 119 dnl
 120 dnl Optional modules, pk-init, digest, kx509
 121 dnl
 122
 123 AC_ARG_ENABLE(pk-init,
 124         AS_HELP_STRING([--disable-pk-init],
 125                 [if you want disable to PK-INIT support]))
 126 if test "$enable_pk_init" != no ;then
 127         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 128 fi
 129 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 130
 131 AC_ARG_ENABLE(digest,
 132         AS_HELP_STRING([--disable-digest],
 133                 [if you want disable to DIGEST support]))
 134 if test "$enable_digest" != no ;then
 135         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 136 fi
 137
 138 AC_ARG_ENABLE(kx509,
 139         AS_HELP_STRING([--disable-kx509],
 140                 [if you want disable to kx509 support]))
 141 if test "$enable_kx509" != no ;then
 142         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 143 fi
 144
 145 AC_ARG_ENABLE(krb4,
 146         AS_HELP_STRING([--disable-krb4],
 147                 [if you want disable to krb4 support]))
 148 if test "$enable_krb4" != no ;then
 149         AC_DEFINE([KRB4], 1, [Define to enable Kerberos 4.])
 150 fi
 151
 152
 153 dnl Check for sqlite
 154 rk_TEST_PACKAGE(sqlite3,
 155 [#include <sqlite3.h>
 156 #ifndef SQLITE_OPEN_CREATE
 157 #error "old version"
 158 #endif],
 159 [-lsqlite3],,,SQLITE3)
 160
 161 if test "X$with_sqlite3" != Xyes ; then
 162    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 163    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 164 fi
 165 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 166
 167 AC_ARG_ENABLE(sqlite-cache,
 168         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 169 if test "$enable_sqlite_cache" != no; then
 170     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for DCE/DFS PAG's.])
 171 fi
 172 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 173
 174
 175 dnl check for libintl
 176 rk_TEST_PACKAGE(libintl,
 177 [#include <libintl.h>],
 178 [-lintl],,,LIBINTL)
 179
 180 dnl path where the hdb directory is stored
 181 AC_ARG_WITH([hdbdir],
 182         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 183         [],
 184         [with_hdbdir=/var/heimdal])
 185 DIR_hdbdir="$with_hdbdir"
 186 AC_SUBST([DIR_hdbdir])
 187
 188
 189 dnl no kerberos4 any more
 190 with_krb4=no
 191 AC_SUBST(INCLUDE_krb4)
 192 AC_SUBST(LIB_krb4)
 193 AM_CONDITIONAL(KRB4, false)
 194
 195 AM_CONDITIONAL(KRB5, true)
 196 AM_CONDITIONAL(do_roken_rename, true)
 197
 198 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 199 AC_SUBST(LIB_kdb)dnl
 200
 201 KRB_CRYPTO
 202
 203 KRB_PTHREADS
 204
 205 AC_ARG_ENABLE(dce,
 206         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 207 if test "$enable_dce" = yes; then
 208     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 209 fi
 210 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 211
 212 ## XXX quite horrible:
 213 if test -f /etc/ibmcxx.cfg; then
 214         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 215         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 216         dpagaix_ldflags=
 217 else
 218         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 219         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 220         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 221 fi
 222 AC_SUBST(dpagaix_cflags)
 223 AC_SUBST(dpagaix_ldadd)
 224 AC_SUBST(dpagaix_ldflags)
 225
 226 AC_ARG_ENABLE([afs-support],
 227         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 228 if test "$enable_afs_support" = no; then
 229         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 230 fi
 231
 232 rk_DB
 233
 234 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 235
 236 rk_ROKEN(lib/roken)
 237 LIBADD_roken="$LIB_roken"
 238 AC_SUBST(LIBADD_roken)dnl
 239 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 240
 241 rk_OTP
 242
 243 rk_LIBDISPATCH
 244
 245 AC_CHECK_OSFC2
 246
 247 AC_ARG_ENABLE(mmap,
 248         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 249 if test "$enable_mmap" = "no"; then
 250         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 251 fi
 252
 253 AC_ARG_ENABLE(afs-string-to-key,
 254         AS_HELP_STRING([--disable-afs-string-to-key],
 255         [disable use of weak AFS string-to-key functions]),
 256         [], [enable_afs_string_to_key=yes])
 257
 258 if test "$enable_afs_string_to_key" = "yes"; then
 259         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 260 fi
 261
 262
 263 rk_CHECK_MAN
 264
 265 rk_TEST_PACKAGE(readline,
 266 [#include <stdio.h>
 267  #include <readline.h>],-lreadline,,, READLINE)
 268
 269 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 270
 271 KRB_C_BIGENDIAN
 272 AC_C_INLINE
 273
 274 KRB_CHECK_X
 275
 276 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 277
 278 AC_CHECK_XAU
 279
 280 dnl AM_C_PROTOTYPES
 281
 282 dnl Checks for typedefs, structures, and compiler characteristics.
 283 AC_C_CONST
 284 AC_TYPE_OFF_T
 285 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 286 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 287 AC_HAVE_TYPE([long long])
 288 AC_HEADER_TIME
 289 AC_STRUCT_TM
 290
 291 dnl Checks for header files.
 292 AC_HEADER_STDC
 293
 294 AC_CHECK_HEADERS([\
 295         arpa/ftp.h                              \
 296         arpa/telnet.h                           \
 297         bind/bitypes.h                          \
 298         bsdsetjmp.h                             \
 299         curses.h                                \
 300         dlfcn.h                                 \
 301         fnmatch.h                               \
 302         inttypes.h                              \
 303         io.h                                    \
 304         libutil.h                               \
 305         limits.h                                \
 306         maillock.h                              \
 307         netgroup.h                              \
 308         netinet/in6_machtypes.h                 \
 309         pthread.h                               \
 310         pty.h                                   \
 311         sac.h                                   \
 312         sgtty.h                                 \
 313         siad.h                                  \
 314         signal.h                                \
 315         strings.h                               \
 316         stropts.h                               \
 317         sys/bitypes.h                           \
 318         sys/category.h                          \
 319         sys/file.h                              \
 320         sys/filio.h                             \
 321         sys/ioccom.h                            \
 322         sys/mman.h                              \
 323         sys/param.h                             \
 324         sys/pty.h                               \
 325         sys/ptyio.h                             \
 326         sys/select.h                            \
 327         sys/socket.h                            \
 328         sys/str_tty.h                           \
 329         sys/stream.h                            \
 330         sys/stropts.h                           \
 331         sys/syscall.h                           \
 332         sys/termio.h                            \
 333         sys/timeb.h                             \
 334         sys/times.h                             \
 335         sys/types.h                             \
 336         sys/un.h                                \
 337         locale.h                                \
 338         termcap.h                               \
 339         termio.h                                \
 340         termios.h                               \
 341         time.h                                  \
 342         tmpdir.h                                \
 343         udb.h                                   \
 344         util.h                                  \
 345         utmp.h                                  \
 346         utmpx.h                                 \
 347 ])
 348
 349 dnl On Solaris 8 there's a compilation warning for term.h because
 350 dnl it doesn't define `bool'.
 351 AC_CHECK_HEADERS(term.h, , , -)
 352
 353 dnl aix have asl.h (A/IX screen library) that we don't want
 354 AC_CHECK_HEADERS(asl.h, , , [
 355 #include <asl.h>
 356 #ifndef ASL_STRING_EMERG
 357 #error ASL_STRING_EMERG missing
 358 #endif])
 359
 360 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 361 #if HAVE_SYS_SOCKET_H
 362 #include <sys/socket.h>
 363 #endif])
 364
 365 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 366 #if HAVE_SYS_TTY_H
 367 #include <sys/tty.h>
 368 #endif])
 369
 370 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 371 #if HAVE_TERMIOS_H
 372 #include <termios.h>
 373 #endif
 374 #if HAVE_SYS_STREAM_H
 375 #include <sys/stream.h>
 376 #endif])
 377
 378 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 379 #if HAVE_SYS_TYPES_H
 380 #include <sys/types.h>
 381 #endif
 382 #if HAVE_SYS_PARAM_H
 383 #include <sys/param.h>
 384 #endif])
 385
 386 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 387 #include <security/pam_appl.h>
 388 ])
 389
 390 dnl export symbols
 391 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 392 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 393 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 394
 395 dnl Checks for libraries.
 396
 397 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 398 #ifdef HAVE_UTIL_H
 399 #include <util.h>
 400 #endif
 401 ],[0,0,0])
 402 AC_FIND_FUNC_NO_LIBS(logout, util,[
 403 #ifdef HAVE_UTIL_H
 404 #include <util.h>
 405 #endif
 406 ],[0])
 407 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 408 #ifdef HAVE_UTIL_H
 409 #include <util.h>
 410 #endif
 411 ],[0,0,0,0,0])
 412
 413 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 414 #ifdef HAVE_TERMCAP_H
 415 #include <termcap.h>
 416 #endif
 417 #ifdef HAVE_CURSES_H
 418 #include <curses.h>
 419 #endif
 420 ],[0,0])
 421
 422 dnl Checks for library functions.
 423
 424 AC_CHECK_FUNCS([                                \
 425         _getpty                                 \
 426         _scrsize                                \
 427         arc4random                              \
 428         fcntl                                   \
 429         getpeereid                              \
 430         getpeerucred                            \
 431         grantpt                                 \
 432         mktime                                  \
 433         ptsname                                 \
 434         rand                                    \
 435         revoke                                  \
 436         select                                  \
 437         setitimer                               \
 438         setpcred                                \
 439         setpgid                                 \
 440         setproctitle                            \
 441         setregid                                \
 442         setresgid                               \
 443         setresuid                               \
 444         setreuid                                \
 445         setsid                                  \
 446         setutent                                \
 447         sigaction                               \
 448         strstr                                  \
 449         ttyname                                 \
 450         ttyslot                                 \
 451         umask                                   \
 452         unlockpt                                \
 453         vhangup                                 \
 454         yp_get_default_domain                   \
 455 ])
 456
 457 AC_FUNC_MMAP
 458
 459 KRB_CAPABILITIES
 460
 461 AC_CHECK_GETPWNAM_R_POSIX
 462
 463 dnl detect doors on solaris
 464 if test "$enable_pthread_support" != no; then
 465    saved_LIBS="$LIBS"
 466    LIBS="$LIBS $PTHREADS_LIBS"
 467    AC_FIND_FUNC_NO_LIBS(door_create, door)
 468    LIBS="$saved_LIBS"
 469 fi
 470
 471 AC_ARG_ENABLE(kcm,
 472         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 473 ,[enable_kcm=yes])
 474
 475 if test "$enable_kcm" = yes ; then
 476    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 477         enable_kcm=no
 478    fi
 479 fi
 480 if test "$enable_kcm" = yes; then
 481        AC_DEFINE(HAVE_KCM, 1,
 482                [Define if you want to use the Kerberos Credentials Manager.])
 483 fi
 484 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 485
 486
 487
 488 dnl Cray stuff
 489 AC_CHECK_FUNCS(getudbnam setlim)
 490
 491 dnl AC_KRB_FUNC_GETCWD_BROKEN
 492
 493 dnl
 494 dnl Check for fields in struct utmp
 495 dnl
 496
 497 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 498 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 499 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 500 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 501 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 502 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 503 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 504 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 505
 506 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 507         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 508         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 509 #ifdef HAVE_INTTYPES_H
 510 #include <inttypes.h>
 511 #endif
 512 #ifdef HAVE_SYS_TYPES_H
 513 #include <sys/types.h>
 514 #endif
 515 #ifdef HAVE_SYS_BITYPES_H
 516 #include <sys/bitypes.h>
 517 #endif
 518 #ifdef HAVE_BIND_BITYPES_H
 519 #include <bind/bitypes.h>
 520 #endif
 521 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 522 #include <netinet/in6_machtypes.h>
 523 #endif
 524 ])
 525
 526 rk_FRAMEWORK_SECURITY
 527
 528 KRB_READLINE
 529
 530 rk_TELNET
 531
 532 dnl Some operating systems already have com_err and compile_et
 533 CHECK_COMPILE_ET
 534
 535 rk_AUTH_MODULES([sia afskauthlib])
 536
 537 rk_DESTDIRS
 538
 539 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 540
 541
 542 AH_BOTTOM([#ifdef ROKEN_RENAME
 543 #include "roken_rename.h"
 544 #endif])
 545
 546 AC_CONFIG_FILES(Makefile                \
 547         etc/Makefile                    \
 548         include/Makefile                \
 549         include/gssapi/Makefile         \
 550         include/hcrypto/Makefile        \
 551         include/kadm5/Makefile          \
 552         lib/Makefile                    \
 553         lib/auth/Makefile               \
 554         lib/auth/afskauthlib/Makefile   \
 555         lib/auth/pam/Makefile           \
 556         lib/auth/sia/Makefile           \
 557         lib/asn1/Makefile               \
 558         lib/com_err/Makefile            \
 559         lib/hcrypto/Makefile            \
 560         lib/editline/Makefile           \
 561         lib/hx509/Makefile              \
 562         lib/gssapi/Makefile             \
 563         lib/ntlm/Makefile               \
 564         lib/hdb/Makefile                \
 565         lib/ipc/Makefile                \
 566         lib/kadm5/Makefile              \
 567         lib/kafs/Makefile               \
 568         lib/kdfs/Makefile               \
 569         lib/krb5/Makefile               \
 570         lib/otp/Makefile                \
 571         lib/roken/Makefile              \
 572         lib/sl/Makefile                 \
 573         lib/sqlite/Makefile             \
 574         lib/vers/Makefile               \
 575         lib/wind/Makefile               \
 576         po/Makefile                     \
 577         kuser/Makefile                  \
 578         kpasswd/Makefile                \
 579         kadmin/Makefile                 \
 580         admin/Makefile                  \
 581         kcm/Makefile                    \
 582         kdc/Makefile                    \
 583         appl/Makefile                   \
 584         appl/afsutil/Makefile           \
 585         appl/ftp/Makefile               \
 586         appl/ftp/common/Makefile        \
 587         appl/ftp/ftp/Makefile           \
 588         appl/ftp/ftpd/Makefile          \
 589         appl/gssmask/Makefile           \
 590         appl/kx/Makefile                \
 591         appl/login/Makefile             \
 592         appl/otp/Makefile               \
 593         appl/popper/Makefile            \
 594         appl/push/Makefile              \
 595         appl/rsh/Makefile               \
 596         appl/rcp/Makefile               \
 597         appl/su/Makefile                \
 598         appl/xnlock/Makefile            \
 599         appl/telnet/Makefile            \
 600         appl/telnet/libtelnet/Makefile  \
 601         appl/telnet/telnet/Makefile     \
 602         appl/telnet/telnetd/Makefile    \
 603         appl/test/Makefile              \
 604         appl/kf/Makefile                \
 605         appl/dceutils/Makefile          \
 606         tests/Makefile                  \
 607         tests/bin/Makefile              \
 608         tests/can/Makefile              \
 609         tests/db/Makefile               \
 610         tests/kdc/Makefile              \
 611         tests/ldap/Makefile             \
 612         tests/gss/Makefile              \
 613         tests/java/Makefile             \
 614         tests/plugin/Makefile           \
 615         packages/Makefile               \
 616         packages/mac/Makefile           \
 617         doc/Makefile                    \
 618         tools/Makefile                  \
 619 )
 620
 621 AC_OUTPUT
 622
 623 dnl
 624 dnl This is the release version name-number[beta]
 625 dnl
 626
 627 cat > include/newversion.h.in <<EOF
 628 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 629 const char *heimdal_version = "AC_PACKAGE_STRING";
 630 EOF
 631
 632 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 633         echo "include/version.h is unchanged"
 634         rm -f include/newversion.h.in
 635 else
 636         echo "creating include/version.h"
 637         User=${USER-${LOGNAME}}
 638         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 639         Date=`date`
 640         mv -f include/newversion.h.in include/version.h.in
 641         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 642 fi