configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ([2.59])
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[0.7rc1],[heimdal-bugs@pdc.kth.se])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8
   9 dnl Checks for programs.
  10 AC_PROG_CC
  11 AC_PROG_CPP
  12
  13 AM_INIT_AUTOMAKE([foreign no-dependencies 1.8])
  14 AM_MAINTAINER_MODE
  15
  16 AC_PREFIX_DEFAULT(/usr/heimdal)
  17
  18 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  19 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  20
  21 AC_CANONICAL_HOST
  22 CANONICAL_HOST=$host
  23 AC_SUBST(CANONICAL_HOST)
  24
  25 rk_SYS_LARGEFILE
  26
  27 dnl
  28 dnl this is needed to run the configure tests against glibc
  29 dnl
  30 AC_DEFINE([_GNU_SOURCE], 1,
  31         [Define to enable extensions on glibc-based systems such as Linux.])
  32
  33 if test -f $srcdir/lib/asn1/pkcs12.asn1 ; then
  34         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
  35 fi
  36
  37 AC_OBJEXT
  38 AC_EXEEXT
  39
  40 dnl AC_KRB_PROG_YACC
  41 AC_PROG_YACC
  42 AM_PROG_LEX
  43 dnl AC_PROG_RANLIB
  44 AC_PROG_AWK
  45 AC_KRB_PROG_LN_S
  46
  47 AC_MIPS_ABI
  48 CC="$CC $abi"
  49 libdir="$libdir$abilibdirext"
  50
  51 AC_C___ATTRIBUTE__
  52
  53 AC_ENABLE_SHARED(no)
  54 AC_PROG_LIBTOOL
  55
  56 rk_WFLAGS(-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs)
  57
  58 rk_TEST_PACKAGE(openldap,
  59 [#include <lber.h>
  60 #include <ldap.h>],
  61 [-lldap -llber],,,OPENLDAP)
  62
  63 AC_ARG_ENABLE(hdb-openldap-module,
  64         AS_HELP_STRING([--enable-hdb-openldap-module],
  65                 [if you want support to build openldap hdb as shared object]))
  66 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
  67     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
  68 fi
  69 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
  70
  71 rk_TEST_PACKAGE(krb4,[#include <krb.h>],-lkrb,-ldes,/usr/athena, KRB4, krb4-config)
  72
  73 LIB_kdb=
  74 if test "$with_krb4" != "no"; then
  75         save_CFLAGS="$CFLAGS"
  76         CFLAGS="$CFLAGS $INCLUDE_krb4"
  77         save_LIBS="$LIBS"
  78         LIBS="$LIB_krb4 $LIBS"
  79         EXTRA_LIB45=lib45.a
  80         AC_SUBST(EXTRA_LIB45)
  81         AC_CACHE_CHECK(for four valued krb_put_int, ac_cv_func_krb_put_int_four,
  82                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <krb.h>]], [[
  83                 char tmp[4];
  84                 krb_put_int(17, tmp, 4, sizeof(tmp));]])],
  85                 [ac_cv_func_krb_put_int_four=yes],
  86                 [ac_cv_func_krb_put_int_four=no])
  87         ])
  88         if test "$ac_cv_func_krb_put_int_four" = yes; then
  89                 AC_DEFINE(HAVE_FOUR_VALUED_KRB_PUT_INT, 1,
  90                         [define if krb_put_int takes four arguments.])
  91         fi
  92         AH_BOTTOM([#if defined(HAVE_FOUR_VALUED_KRB_PUT_INT) || !defined(KRB4)
  93 #define KRB_PUT_INT(F, T, L, S) krb_put_int((F), (T), (L), (S))
  94 #else
  95 #define KRB_PUT_INT(F, T, L, S) krb_put_int((F), (T), (S))
  96 #endif
  97 ])
  98         AC_CACHE_CHECK(for KRB_VERIFY_SECURE, ac_cv_func_krb_verify_secure,
  99                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <krb.h>]], [[
 100                 int x = KRB_VERIFY_SECURE]])],
 101                 [ac_cv_func_krb_verify_secure=yes],
 102                 [ac_cv_func_krb_verify_secure=no])
 103         ])
 104         if test "$ac_cv_func_krb_verify_secure" != yes; then
 105                 AC_DEFINE(KRB_VERIFY_SECURE, 1,
 106                         [Define to one if your krb.h doesn't])
 107                 AC_DEFINE(KRB_VERIFY_SECURE_FAIL, 2,
 108                         [Define to two if your krb.h doesn't])
 109         fi
 110         AC_CACHE_CHECK(for KRB_VERIFY_NOT_SECURE,
 111                 ac_cv_func_krb_verify_not_secure,
 112                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <krb.h>]], [[
 113                 int x = KRB_VERIFY_NOT_SECURE]])],
 114                 [ac_cv_func_krb_verify_not_secure=yes],
 115                 [ac_cv_func_krb_verify_not_secure=no])
 116         ])
 117         if test "$ac_cv_func_krb_verify_not_secure" != yes; then
 118                 AC_DEFINE(KRB_VERIFY_NOT_SECURE, 0,
 119                         [Define to zero if your krb.h doesn't])
 120         fi
 121         AC_FIND_FUNC(krb_enable_debug)
 122         AC_FIND_FUNC(krb_disable_debug)
 123         AC_FIND_FUNC(krb_get_our_ip_for_realm)
 124         AC_FIND_FUNC(krb_kdctimeofday)
 125         AH_BOTTOM(
 126         [#ifndef HAVE_KRB_KDCTIMEOFDAY
 127 #define krb_kdctimeofday(X) gettimeofday((X), NULL)
 128 #endif])
 129         AC_FIND_FUNC(krb_get_kdc_time_diff)
 130         AH_BOTTOM(
 131         [#ifndef HAVE_KRB_GET_KDC_TIME_DIFF
 132 #define krb_get_kdc_time_diff() (0)
 133 #endif])
 134         AC_CACHE_CHECK([for KRB_SENDAUTH_VERS],
 135                 ac_cv_func_krb_sendauth_vers,
 136                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <krb.h>
 137                         #include <prot.h>]], [[
 138                 char *x = KRB_SENDAUTH_VERS]])],
 139                 [ac_cv_func_krb_sendauth_vers=yes],
 140                 [ac_cv_func_krb_sendauth_vers=no])
 141         ])
 142         if test "$ac_cv_func_krb_sendauth_vers" != yes; then
 143                 AC_DEFINE(KRB_SENDAUTH_VERS, ["AUTHV0.1"],
 144                         [This is the krb4 sendauth version.])
 145         fi
 146         AC_CACHE_CHECK(for krb_mk_req with const arguments,
 147                 ac_cv_func_krb_mk_req_const,
 148                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <krb.h>
 149                 int krb_mk_req(KTEXT a, const char *s, const char *i,
 150                                const char *r, int32_t checksum)
 151                 { return 17; }]], [[]])],
 152                 [ac_cv_func_krb_mk_req_const=yes],
 153                 [ac_cv_func_krb_mk_req_const=no])
 154         ])
 155         if test "$ac_cv_func_krb_mk_req_const" = "yes"; then
 156                 AC_DEFINE(KRB_MK_REQ_CONST, 1,
 157                         [Define if krb_mk_req takes const char *])
 158         fi
 159
 160         LIBS="$save_LIBS"
 161         CFLAGS="$save_CFLAGS"
 162         LIB_kdb="-lkdb -lkrb"
 163 fi
 164 AM_CONDITIONAL(KRB4, test "$with_krb4" != "no")
 165 AM_CONDITIONAL(KRB5, true)
 166 AM_CONDITIONAL(do_roken_rename, true)
 167
 168 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 169 AC_SUBST(LIB_kdb)dnl
 170
 171 KRB_CRYPTO
 172
 173 KRB_PTHREADS
 174
 175 AC_ARG_ENABLE(dce,
 176         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 177 if test "$enable_dce" = yes; then
 178     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 179 fi
 180 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 181
 182 ## XXX quite horrible:
 183 if test -f /etc/ibmcxx.cfg; then
 184         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 185         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 186         dpagaix_ldflags=
 187 else
 188         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 189         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 190         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 191 fi
 192 AC_SUBST(dpagaix_cflags)
 193 AC_SUBST(dpagaix_ldadd)
 194 AC_SUBST(dpagaix_ldflags)
 195
 196 rk_DB
 197
 198 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 199
 200 rk_ROKEN(lib/roken)
 201 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 202
 203 rk_OTP
 204
 205 AC_CHECK_OSFC2
 206
 207 AC_ARG_ENABLE(mmap,
 208         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 209 if test "$enable_mmap" = "no"; then
 210         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 211 fi
 212
 213 rk_CHECK_MAN
 214
 215 rk_TEST_PACKAGE(readline,
 216 [#include <stdio.h>
 217  #include <readline.h>],-lreadline,,, READLINE)
 218
 219 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 220
 221 KRB_C_BIGENDIAN
 222 AC_C_INLINE
 223
 224 rk_AIX
 225 rk_IRIX
 226 rk_SUNOS
 227
 228 KRB_CHECK_X
 229
 230 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 231
 232 AC_CHECK_XAU
 233
 234 dnl AM_C_PROTOTYPES
 235
 236 dnl Checks for typedefs, structures, and compiler characteristics.
 237 AC_C_CONST
 238 AC_TYPE_OFF_T
 239 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 240 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 241 AC_HAVE_TYPE([long long])
 242 AC_HEADER_TIME
 243 AC_STRUCT_TM
 244
 245 dnl Checks for header files.
 246 AC_HEADER_STDC
 247
 248 AC_CHECK_HEADERS([\
 249         arpa/ftp.h                              \
 250         arpa/telnet.h                           \
 251         bind/bitypes.h                          \
 252         bsdsetjmp.h                             \
 253         curses.h                                \
 254         dlfcn.h                                 \
 255         fnmatch.h                               \
 256         inttypes.h                              \
 257         io.h                                    \
 258         libutil.h                               \
 259         limits.h                                \
 260         maillock.h                              \
 261         netgroup.h                              \
 262         netinet/in6_machtypes.h                 \
 263         netinfo/ni.h                            \
 264         pthread.h                               \
 265         pty.h                                   \
 266         sac.h                                   \
 267         sgtty.h                                 \
 268         siad.h                                  \
 269         signal.h                                \
 270         stropts.h                               \
 271         sys/bitypes.h                           \
 272         sys/category.h                          \
 273         sys/file.h                              \
 274         sys/filio.h                             \
 275         sys/ioccom.h                            \
 276         sys/mman.h                              \
 277         sys/pty.h                               \
 278         sys/ptyio.h                             \
 279         sys/select.h                            \
 280         sys/socket.h                            \
 281         sys/str_tty.h                           \
 282         sys/stream.h                            \
 283         sys/stropts.h                           \
 284         sys/syscall.h                           \
 285         sys/termio.h                            \
 286         sys/timeb.h                             \
 287         sys/times.h                             \
 288         sys/un.h                                \
 289         termcap.h                               \
 290         termio.h                                \
 291         termios.h                               \
 292         time.h                                  \
 293         tmpdir.h                                \
 294         udb.h                                   \
 295         utmp.h                                  \
 296         utmpx.h                                 \
 297 ])
 298
 299 dnl On Solaris 8 there's a compilation warning for term.h because
 300 dnl it doesn't define `bool'.
 301 AC_CHECK_HEADERS(term.h, , , -)
 302
 303 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 304 #if HAVE_SYS_SOCKET_H
 305 #include <sys/socket.h>
 306 #endif])
 307
 308 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 309 #if HAVE_SYS_TTY_H
 310 #include <sys/tty.h>
 311 #endif])
 312
 313 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 314 #if HAVE_TERMIOS_H
 315 #include <termios.h>
 316 #endif
 317 #if HAVE_SYS_STREAM_H
 318 #include <sys/stream.h>
 319 #endif])
 320
 321 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 322 #include <security/pam_appl.h>
 323 ])
 324
 325 AC_ARG_ENABLE(netinfo,
 326         AS_HELP_STRING([--enable-netinfo],[enable netinfo for configuration lookup]))
 327
 328 if test "$ac_cv_header_netinfo_ni_h" = yes -a "$enable_netinfo" = yes; then
 329        AC_DEFINE(HAVE_NETINFO, 1,
 330                [Define if you want to use Netinfo instead of krb5.conf.])
 331 fi
 332
 333 AC_ARG_ENABLE(kcm,
 334         AC_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]))
 335
 336 if test "$ac_cv_header_sys_un_h" = yes -a "$enable_kcm" = yes; then
 337        AC_DEFINE(HAVE_KCM, 1,
 338                [Define if you want to use the Kerberos Credentials Manager.])
 339 fi
 340 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 341
 342 dnl export symbols
 343 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB_FUNCTION)
 344 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB_FUNCTION)
 345
 346 dnl Checks for libraries.
 347
 348 AC_FIND_FUNC_NO_LIBS(logwtmp, util)
 349 AC_FIND_FUNC_NO_LIBS(logout, util)
 350 AC_FIND_FUNC_NO_LIBS(openpty, util)
 351 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses)
 352
 353 dnl Checks for library functions.
 354
 355 AC_CHECK_FUNCS([                                \
 356         _getpty                                 \
 357         _scrsize                                \
 358         fcntl                                   \
 359         getpeereid                              \
 360         getpeerucred                            \
 361         grantpt                                 \
 362         mktime                                  \
 363         ptsname                                 \
 364         rand                                    \
 365         revoke                                  \
 366         select                                  \
 367         setitimer                               \
 368         setpcred                                \
 369         setpgid                                 \
 370         setproctitle                            \
 371         setregid                                \
 372         setresgid                               \
 373         setresuid                               \
 374         setreuid                                \
 375         setsid                                  \
 376         setutent                                \
 377         sigaction                               \
 378         strstr                                  \
 379         timegm                                  \
 380         ttyname                                 \
 381         ttyslot                                 \
 382         umask                                   \
 383         unlockpt                                \
 384         vhangup                                 \
 385         yp_get_default_domain                   \
 386 ])
 387
 388 AC_FUNC_MMAP
 389
 390 KRB_CAPABILITIES
 391
 392 AC_CHECK_GETPWNAM_R_POSIX
 393
 394 dnl detect doors on solaris
 395 if test "$enable_pthread_support" != no; then
 396    saved_LIBS="$LIBS"
 397    LIBS="$LIBS $PTHREADS_LIBS"
 398    AC_FIND_FUNC_NO_LIBS(door_create, door)
 399    LIBS="$saved_LIBS"
 400 fi
 401
 402 dnl Cray stuff
 403 AC_CHECK_FUNCS(getudbnam setlim)
 404
 405 dnl AC_KRB_FUNC_GETCWD_BROKEN
 406
 407 dnl
 408 dnl Check for fields in struct utmp
 409 dnl
 410
 411 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 412 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 413 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 414 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 415 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 416 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 417 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 418 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 419
 420 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 421         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 422         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 423 #ifdef HAVE_INTTYPES_H
 424 #include <inttypes.h>
 425 #endif
 426 #ifdef HAVE_SYS_TYPES_H
 427 #include <sys/types.h>
 428 #endif
 429 #ifdef HAVE_SYS_BITYPES_H
 430 #include <sys/bitypes.h>
 431 #endif
 432 #ifdef HAVE_BIND_BITYPES_H
 433 #include <bind/bitypes.h>
 434 #endif
 435 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 436 #include <netinet/in6_machtypes.h>
 437 #endif
 438 ])
 439
 440 KRB_READLINE
 441
 442 rk_TELNET
 443
 444 dnl Some operating systems already have com_err and compile_et
 445 CHECK_COMPILE_ET
 446
 447 rk_AUTH_MODULES([sia afskauthlib])
 448
 449 rk_DESTDIRS
 450
 451 AH_BOTTOM([#ifdef ROKEN_RENAME
 452 #include "roken_rename.h"
 453 #endif])
 454
 455 AC_CONFIG_FILES(Makefile                \
 456         include/Makefile                \
 457         include/kadm5/Makefile          \
 458         lib/Makefile                    \
 459         lib/45/Makefile                 \
 460         lib/auth/Makefile               \
 461         lib/auth/afskauthlib/Makefile   \
 462         lib/auth/pam/Makefile           \
 463         lib/auth/sia/Makefile           \
 464         lib/asn1/Makefile               \
 465         lib/com_err/Makefile            \
 466         lib/des/Makefile                \
 467         lib/editline/Makefile           \
 468         lib/gssapi/Makefile             \
 469         lib/hdb/Makefile                \
 470         lib/kadm5/Makefile              \
 471         lib/kafs/Makefile               \
 472         lib/kdfs/Makefile               \
 473         lib/krb5/Makefile               \
 474         lib/otp/Makefile                \
 475         lib/roken/Makefile              \
 476         lib/sl/Makefile                 \
 477         lib/vers/Makefile               \
 478         kuser/Makefile                  \
 479         kpasswd/Makefile                \
 480         kadmin/Makefile                 \
 481         admin/Makefile                  \
 482         kcm/Makefile                    \
 483         kdc/Makefile                    \
 484         appl/Makefile                   \
 485         appl/afsutil/Makefile           \
 486         appl/ftp/Makefile               \
 487         appl/ftp/common/Makefile        \
 488         appl/ftp/ftp/Makefile           \
 489         appl/ftp/ftpd/Makefile          \
 490         appl/kx/Makefile                \
 491         appl/login/Makefile             \
 492         appl/otp/Makefile               \
 493         appl/popper/Makefile            \
 494         appl/push/Makefile              \
 495         appl/rsh/Makefile               \
 496         appl/rcp/Makefile               \
 497         appl/su/Makefile                \
 498         appl/xnlock/Makefile            \
 499         appl/telnet/Makefile            \
 500         appl/telnet/libtelnet/Makefile  \
 501         appl/telnet/telnet/Makefile     \
 502         appl/telnet/telnetd/Makefile    \
 503         appl/test/Makefile              \
 504         appl/kf/Makefile                \
 505         appl/dceutils/Makefile          \
 506         doc/Makefile                    \
 507         tools/Makefile                  \
 508 )
 509
 510 AC_OUTPUT
 511
 512 dnl
 513 dnl This is the release version name-number[beta]
 514 dnl
 515
 516 cat > include/newversion.h.in <<EOF
 517 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 518 const char *heimdal_version = "AC_PACKAGE_STRING";
 519 EOF
 520
 521 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 522         echo "include/version.h is unchanged"
 523         rm -f include/newversion.h.in
 524 else
 525         echo "creating include/version.h"
 526         User=${USER-${LOGNAME}}
 527         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 528         Date=`date`
 529         mv -f include/newversion.h.in include/version.h.in
 530         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 531 fi