guix/scripts/edit.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2015, 2016 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2015 Mathieu Lirzin <mthl@gnu.org>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (guix scripts edit)
  21   #:use-module (guix ui)
  22   #:use-module (guix scripts)
  23   #:use-module (guix utils)
  24   #:use-module (guix packages)
  25   #:use-module (gnu packages)
  26   #:use-module (srfi srfi-1)
  27   #:use-module (srfi srfi-37)
  28   #:export (%editor
  29             guix-edit))
  30
  31 (define %options
  32   (list (option '(#\h "help") #f #f
  33                 (lambda args
  34                   (show-help)
  35                   (exit 0)))
  36         (option '(#\V "version") #f #f
  37                 (lambda args
  38                   (show-version-and-exit "guix edit")))))
  39
  40 (define (show-help)
  41   (display (G_ "Usage: guix edit PACKAGE...
  42 Start $VISUAL or $EDITOR to edit the definitions of PACKAGE...\n"))
  43   (newline)
  44   (display (G_ "
  45   -h, --help             display this help and exit"))
  46   (display (G_ "
  47   -V, --version          display version information and exit"))
  48   (newline)
  49   (show-bug-report-information))
  50
  51 (define %editor
  52   ;; XXX: It would be better to default to something more likely to be
  53   ;; pre-installed on an average GNU system.  Since Nano is not suited for
  54   ;; editing Scheme, Emacs is used instead.
  55   (make-parameter (or (getenv "VISUAL") (getenv "EDITOR") "emacs")))
  56
  57 (define (search-path* path file)
  58   "Like 'search-path' but exit if FILE is not found."
  59   (let ((absolute-file-name (search-path path file)))
  60     (unless absolute-file-name
  61       ;; Shouldn't happen unless somebody fiddled with the 'location' field.
  62       (leave (G_ "file '~a' not found in search path ~s~%")
  63              file path))
  64     absolute-file-name))
  65
  66 (define (package->location-specification package)
  67   "Return the location specification for PACKAGE for a typical editor command
  68 line."
  69   (let ((loc (package-location package)))
  70     (list (string-append "+"
  71                          (number->string
  72                           (location-line loc)))
  73           (search-path* %load-path (location-file loc)))))
  74
  75 \f
  76 (define (guix-edit . args)
  77   (define (parse-arguments)
  78     ;; Return the list of package names.
  79     (args-fold* args %options
  80                 (lambda (opt name arg result)
  81                   (leave (G_ "~A: unrecognized option~%") name))
  82                 cons
  83                 '()))
  84
  85   (with-error-handling
  86     (let* ((specs    (reverse (parse-arguments)))
  87            (packages (map specification->package specs)))
  88       (for-each (lambda (package)
  89                   (unless (package-location package)
  90                     (leave (G_ "source location of package '~a' is unknown~%")
  91                            (package-full-name package))))
  92                 packages)
  93
  94       (catch 'system-error
  95         (lambda ()
  96           (let ((file-names (append-map package->location-specification
  97                                         packages)))
  98             ;; Use `system' instead of `exec' in order to sanely handle
  99             ;; possible command line arguments in %EDITOR.
 100             (exit (system (string-join (cons (%editor) file-names))))))
 101         (lambda args
 102           (let ((errno (system-error-errno args)))
 103             (leave (G_ "failed to launch '~a': ~a~%")
 104                    (%editor) (strerror errno))))))))