guix/cvs-download.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2014, 2015, 2016, 2017 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2014 Sree Harsha Totakura <sreeharsha@totakura.in>
   4 ;;; Copyright © 2015 Mark H Weaver <mhw@netris.org>
   5 ;;;
   6 ;;; This file is part of GNU Guix.
   7 ;;;
   8 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   9 ;;; under the terms of the GNU General Public License as published by
  10 ;;; the Free Software Foundation; either version 3 of the License, or (at
  11 ;;; your option) any later version.
  12 ;;;
  13 ;;; GNU Guix is distributed in the hope that it will be useful, but
  14 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;;; GNU General Public License for more details.
  17 ;;;
  18 ;;; You should have received a copy of the GNU General Public License
  19 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 (define-module (guix cvs-download)
  22   #:use-module (guix records)
  23   #:use-module (guix gexp)
  24   #:use-module (guix store)
  25   #:use-module (guix monads)
  26   #:use-module (guix modules)
  27   #:use-module (guix packages)
  28   #:use-module (ice-9 match)
  29   #:export (cvs-reference
  30             cvs-reference?
  31             cvs-reference-url
  32             cvs-reference-revision
  33             cvs-fetch))
  34
  35 ;;; Commentary:
  36 ;;;
  37 ;;; An <origin> method that fetches a specific revision or date from a CVS
  38 ;;; repository.  The CVS-ROOT-DIRECTORY, MODULE and REVISION are specified
  39 ;;; with a <cvs-reference> object.  REVISION should be specified as either a
  40 ;;; date string in ISO-8601 format (e.g. "2012-12-21") or a CVS tag.
  41 ;;;
  42 ;;; Code:
  43
  44 (define-record-type* <cvs-reference>
  45   cvs-reference make-cvs-reference
  46   cvs-reference?
  47   (root-directory cvs-reference-root-directory)         ; string
  48   (module         cvs-reference-module)                 ; string
  49   (revision       cvs-reference-revision))              ; string
  50
  51 (define (cvs-package)
  52   "Return the default CVS package."
  53   (let ((distro (resolve-interface '(gnu packages version-control))))
  54     (module-ref distro 'cvs)))
  55
  56 (define* (cvs-fetch ref hash-algo hash
  57                     #:optional name
  58                     #:key (system (%current-system)) (guile (default-guile))
  59                     (cvs (cvs-package)))
  60   "Return a fixed-output derivation that fetches REF, a <cvs-reference>
  61 object.  The output is expected to have recursive hash HASH of type
  62 HASH-ALGO (a symbol).  Use NAME as the file name, or a generic name if #f."
  63   (define zlib
  64     (module-ref (resolve-interface '(gnu packages compression)) 'zlib))
  65
  66   (define config.scm
  67     (scheme-file "config.scm"
  68                  #~(begin
  69                      (define-module (guix config)
  70                        #:export (%libz))
  71
  72                      (define %libz
  73                        #+(file-append zlib "/lib/libz")))))
  74
  75   (define modules
  76     (cons `((guix config) => ,config.scm)
  77           (delete '(guix config)
  78                   (source-module-closure '((guix build cvs)
  79                                            (guix build download-nar))))))
  80   (define build
  81     (with-imported-modules modules
  82       #~(begin
  83           (use-modules (guix build cvs)
  84                        (guix build download-nar))
  85
  86           (or (cvs-fetch '#$(cvs-reference-root-directory ref)
  87                          '#$(cvs-reference-module ref)
  88                          '#$(cvs-reference-revision ref)
  89                          #$output
  90                          #:cvs-command (string-append #+cvs "/bin/cvs"))
  91               (download-nar #$output)))))
  92
  93   (mlet %store-monad ((guile (package->derivation guile system)))
  94     (gexp->derivation (or name "cvs-checkout") build
  95                       #:system system
  96                       #:hash-algo hash-algo
  97                       #:hash hash
  98                       #:recursive? #t
  99                       #:guile-for-build guile
 100                       #:local-build? #t)))
 101
 102 ;;; cvs-download.scm ends here