configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix], [0.9.0], [bug-guix@gnu.org], [guix],
   6   [http://www.gnu.org/software/guix/])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10  color-tests parallel-tests -Woverride -Wno-portability])
  11
  12 # Enable silent rules by default.
  13 AM_SILENT_RULES([yes])
  14
  15 AC_CONFIG_SRCDIR([guix.scm])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 dnl For the C++ code.  This must be used early.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_GNU_GETTEXT([external])
  22 AM_GNU_GETTEXT_VERSION([0.18.1])
  23
  24 guilemoduledir="${datarootdir}/guile/site/2.0"
  25 AC_SUBST([guilemoduledir])
  26
  27 GUIX_SYSTEM_TYPE
  28 GUIX_ASSERT_SUPPORTED_SYSTEM
  29
  30 AC_ARG_WITH(store-dir,
  31   AC_HELP_STRING([--with-store-dir=PATH],
  32     [file name of the store (defaults to /gnu/store)]),
  33   [storedir="$withval"],
  34   [storedir="/gnu/store"])
  35 AC_SUBST(storedir)
  36
  37 AC_ARG_WITH([bash-completion-dir],
  38   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  39     [name of the Bash completion directory]),
  40   [bashcompletiondir="$withval"],
  41   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  42 AC_SUBST([bashcompletiondir])
  43
  44 dnl Better be verbose.
  45 AC_MSG_CHECKING([for the store directory])
  46 AC_MSG_RESULT([$storedir])
  47
  48 AC_ARG_ENABLE([daemon],
  49   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  50   [guix_build_daemon="$enableval"],
  51   [guix_build_daemon="yes"])
  52
  53 # Prepare a version of $localstatedir & co. that does not contain references
  54 # to shell variables.
  55 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  56 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  57 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  58 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  59 AC_SUBST([guix_localstatedir])
  60 AC_SUBST([guix_sysconfdir])
  61 AC_SUBST([guix_sbindir])
  62
  63 GUIX_CHECK_FILE_NAME_LIMITS
  64
  65 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  66 dnl Make sure they are available.
  67 m4_pattern_forbid([PKG_CHECK_MODULES])
  68 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  69
  70 PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.7])
  71 AC_PATH_PROG([GUILE], [guile])
  72 AC_PATH_PROG([GUILD], [guild])
  73 if test "x$GUILD" = "x"; then
  74    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  75 fi
  76
  77 dnl guile-json is used for the PyPI package importer
  78 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  79 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  80
  81 dnl Make sure we have a full-fledged Guile.
  82 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  83
  84 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
  85 GUIX_CHECK_SRFI_37
  86 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
  87
  88 dnl Check whether (guix build syscalls) can be built.
  89 GUIX_CHECK_LIBC_MOUNT
  90 AM_CONDITIONAL([BUILD_SYSCALLS_MODULE],
  91   [test "x$guix_cv_libc_has_mount" = "xyes"])
  92
  93 AC_ARG_WITH([nix-prefix],
  94   [AS_HELP_STRING([--with-nix-prefix=DIR],
  95     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
  96   [case "$withval" in
  97     yes|no) ;;
  98     *)
  99       NIX_PREFIX="$withval"
 100       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 101       AC_SUBST([NIX_PREFIX])
 102       ;;
 103    esac],
 104   [])
 105
 106 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 107 AC_PATH_PROG([NIX_HASH], [nix-hash])
 108 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 109    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 110 fi
 111
 112 if test "x$NIX_INSTANTIATE" = "x"; then
 113    # This program is an optional dependency, so we just want it to be
 114    # taken from $PATH if it's not available right now.
 115    NIX_INSTANTIATE="nix-instantiate"
 116 fi
 117
 118 AC_ARG_WITH([nixpkgs],
 119   [AS_HELP_STRING([--with-nixpkgs=DIR],
 120     [search for Nixpkgs in DIR (for testing purposes only)])],
 121   [case "$withval" in
 122     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 123     *)      NIXPKGS="$withval";;
 124    esac],
 125   [])
 126
 127 AC_MSG_CHECKING([for Nixpkgs source tree])
 128 if test -f "$NIXPKGS/default.nix"; then
 129    AC_MSG_RESULT([$NIXPKGS])
 130    AC_SUBST([NIXPKGS])
 131 else
 132    AC_MSG_RESULT([not found])
 133 fi
 134
 135 AC_ARG_WITH([libgcrypt-prefix],
 136   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 137   [case "$withval" in
 138     yes|no)
 139       LIBGCRYPT="libgcrypt"
 140       LIBGCRYPT_PREFIX="no"
 141       LIBGCRYPT_LIBDIR="no"
 142       ;;
 143     *)
 144       LIBGCRYPT="$withval/lib/libgcrypt"
 145       LIBGCRYPT_PREFIX="$withval"
 146       LIBGCRYPT_LIBDIR="$withval/lib"
 147       ;;
 148    esac],
 149   [LIBGCRYPT="libgcrypt"
 150    LIBGCRYPT_PREFIX="no"
 151    LIBGCRYPT_LIBDIR="no"])
 152
 153 AC_ARG_WITH([libgcrypt-libdir],
 154   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 155      [search for GNU libgcrypt's shared library in DIR])],
 156   [case "$withval" in
 157     yes|no)
 158       LIBGCRYPT="libgcrypt"
 159       LIBGCRYPT_LIBDIR="no"
 160       ;;
 161     *)
 162       LIBGCRYPT="$withval/libgcrypt"
 163       LIBGCRYPT_LIBDIR="$withval"
 164       ;;
 165    esac],
 166   [if test "x$LIBGCRYPT" = x; then
 167       LIBGCRYPT="libgcrypt"
 168    fi
 169    if test "x$LIBGCRYPT_LIBDIR" = x; then
 170       LIBGCRYPT_LIBDIR="no"
 171    fi])
 172
 173 dnl Library name suitable for `dynamic-link'.
 174 AC_MSG_CHECKING([for libgcrypt shared library name])
 175 AC_MSG_RESULT([$LIBGCRYPT])
 176 AC_SUBST([LIBGCRYPT])
 177 AC_SUBST([LIBGCRYPT_PREFIX])
 178 AC_SUBST([LIBGCRYPT_LIBDIR])
 179
 180 GUIX_ASSERT_LIBGCRYPT_USABLE
 181
 182 AC_CACHE_SAVE
 183
 184 m4_include([config-daemon.ac])
 185
 186 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 187 dnl See `Building from Git' in the manual for more info.
 188 AM_MISSING_PROG([DOT], [dot])
 189
 190 dnl Manual pages.
 191 AM_MISSING_PROG([HELP2MAN], [help2man])
 192
 193 AC_CONFIG_FILES([Makefile
 194                  po/guix/Makefile.in
 195                  po/packages/Makefile.in
 196                  guix/config.scm])
 197
 198 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 199 AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
 200 AC_CONFIG_FILES([test-env],     [chmod +x test-env])
 201
 202 dnl Emacs interface.
 203 AM_PATH_LISPDIR
 204 AM_CONDITIONAL([HAVE_EMACS], [test "x$EMACS" != "xno"])
 205
 206 emacsuidir="${guilemoduledir}/guix/emacs"
 207 AC_SUBST([emacsuidir])
 208 AC_CONFIG_FILES([emacs/guix-config.el
 209                  emacs/guix-helper.scm])
 210
 211 AC_OUTPUT