gnu/system.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2015 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2015, 2016 Alex Kost <alezost@gmail.com>
   5 ;;; Copyright © 2016 Chris Marusich <cmmarusich@gmail.com>
   6 ;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
   7 ;;; Copyright © 2019 Meiyo Peng <meiyo.peng@gmail.com>
   8 ;;;
   9 ;;; This file is part of GNU Guix.
  10 ;;;
  11 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  12 ;;; under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation; either version 3 of the License, or (at
  14 ;;; your option) any later version.
  15 ;;;
  16 ;;; GNU Guix is distributed in the hope that it will be useful, but
  17 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20 ;;;
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 (define-module (gnu system)
  25   #:use-module (guix inferior)
  26   #:use-module (guix store)
  27   #:use-module (guix monads)
  28   #:use-module (guix gexp)
  29   #:use-module (guix records)
  30   #:use-module (guix packages)
  31   #:use-module (guix derivations)
  32   #:use-module (guix profiles)
  33   #:use-module (guix ui)
  34   #:use-module (gnu packages base)
  35   #:use-module (gnu packages bash)
  36   #:use-module (gnu packages guile)
  37   #:use-module (gnu packages admin)
  38   #:use-module (gnu packages linux)
  39   #:use-module (gnu packages pciutils)
  40   #:use-module (gnu packages package-management)
  41   #:use-module (gnu packages less)
  42   #:use-module (gnu packages zile)
  43   #:use-module (gnu packages nano)
  44   #:use-module (gnu packages gawk)
  45   #:use-module (gnu packages man)
  46   #:use-module (gnu packages texinfo)
  47   #:use-module (gnu packages compression)
  48   #:use-module (gnu packages firmware)
  49   #:use-module (gnu services)
  50   #:use-module (gnu services shepherd)
  51   #:use-module (gnu services base)
  52   #:use-module (gnu bootloader)
  53   #:use-module (gnu system shadow)
  54   #:use-module (gnu system nss)
  55   #:use-module (gnu system locale)
  56   #:use-module (gnu system pam)
  57   #:use-module (gnu system linux-initrd)
  58   #:use-module (gnu system uuid)
  59   #:use-module (gnu system file-systems)
  60   #:use-module (gnu system mapped-devices)
  61   #:use-module (ice-9 match)
  62   #:use-module (srfi srfi-1)
  63   #:use-module (srfi srfi-26)
  64   #:use-module (srfi srfi-34)
  65   #:use-module (srfi srfi-35)
  66   #:use-module (rnrs bytevectors)
  67   #:export (operating-system
  68             operating-system?
  69
  70             operating-system-bootloader
  71             operating-system-services
  72             operating-system-essential-services
  73             operating-system-user-services
  74             operating-system-packages
  75             operating-system-host-name
  76             operating-system-hosts-file
  77             operating-system-kernel
  78             operating-system-kernel-file
  79             operating-system-kernel-arguments
  80             operating-system-initrd-modules
  81             operating-system-initrd
  82             operating-system-users
  83             operating-system-groups
  84             operating-system-issue
  85             operating-system-timezone
  86             operating-system-locale
  87             operating-system-locale-definitions
  88             operating-system-locale-libcs
  89             operating-system-mapped-devices
  90             operating-system-file-systems
  91             operating-system-store-file-system
  92             operating-system-user-mapped-devices
  93             operating-system-boot-mapped-devices
  94             operating-system-activation-script
  95             operating-system-user-accounts
  96             operating-system-shepherd-service-names
  97             operating-system-user-kernel-arguments
  98
  99             operating-system-derivation
 100             operating-system-profile
 101             operating-system-bootcfg
 102             operating-system-etc-directory
 103             operating-system-locale-directory
 104             operating-system-boot-script
 105
 106             system-linux-image-file-name
 107
 108             boot-parameters
 109             boot-parameters?
 110             boot-parameters-label
 111             boot-parameters-root-device
 112             boot-parameters-bootloader-name
 113             boot-parameters-store-device
 114             boot-parameters-store-mount-point
 115             boot-parameters-kernel
 116             boot-parameters-kernel-arguments
 117             boot-parameters-initrd
 118             read-boot-parameters
 119             read-boot-parameters-file
 120             boot-parameters->menu-entry
 121
 122             local-host-aliases
 123             %root-account
 124             %setuid-programs
 125             %base-packages
 126             %base-firmware))
 127
 128 ;;; Commentary:
 129 ;;;
 130 ;;; This module supports whole-system configuration.
 131 ;;;
 132 ;;; Code:
 133
 134 (define (bootable-kernel-arguments system root-device)
 135   "Return a list of kernel arguments (gexps) to boot SYSTEM from ROOT-DEVICE."
 136   (list (string-append "--root="
 137                        (cond ((uuid? root-device)
 138
 139                               ;; Note: Always use the DCE format because that's
 140                               ;; what (gnu build linux-boot) expects for the
 141                               ;; '--root' kernel command-line option.
 142                               (uuid->string (uuid-bytevector root-device)
 143                                             'dce))
 144                              ((file-system-label? root-device)
 145                               (file-system-label->string root-device))
 146                              (else root-device)))
 147         #~(string-append "--system=" #$system)
 148         #~(string-append "--load=" #$system "/boot")))
 149
 150 ;; System-wide configuration.
 151 ;; TODO: Add per-field docstrings/stexi.
 152 (define-record-type* <operating-system> operating-system
 153   make-operating-system
 154   operating-system?
 155   (kernel operating-system-kernel                 ; package
 156           (default linux-libre))
 157   (kernel-arguments operating-system-user-kernel-arguments
 158                     (default '()))                ; list of gexps/strings
 159   (bootloader operating-system-bootloader)        ; <bootloader-configuration>
 160
 161   (keyboard-layout operating-system-keyboard-layout ;#f | <keyboard-layout>
 162                    (default #f))
 163   (initrd operating-system-initrd                 ; (list fs) -> file-like
 164           (default base-initrd))
 165   (initrd-modules operating-system-initrd-modules ; list of strings
 166                   (thunked)                       ; it's system-dependent
 167                   (default %base-initrd-modules))
 168
 169   (firmware operating-system-firmware             ; list of packages
 170             (default %base-firmware))
 171
 172   (host-name operating-system-host-name)          ; string
 173   (hosts-file operating-system-hosts-file         ; file-like | #f
 174               (default #f))
 175
 176   (mapped-devices operating-system-mapped-devices ; list of <mapped-device>
 177                   (default '()))
 178   (file-systems operating-system-file-systems)    ; list of fs
 179   (swap-devices operating-system-swap-devices     ; list of strings
 180                 (default '()))
 181
 182   (users operating-system-users                   ; list of user accounts
 183          (default %base-user-accounts))
 184   (groups operating-system-groups                 ; list of user groups
 185           (default %base-groups))
 186
 187   (skeletons operating-system-skeletons           ; list of name/file-like value
 188              (default (default-skeletons)))
 189   (issue operating-system-issue                   ; string
 190          (default %default-issue))
 191
 192   (packages operating-system-packages             ; list of (PACKAGE OUTPUT...)
 193             (default %base-packages))             ; or just PACKAGE
 194
 195   (timezone operating-system-timezone)            ; string
 196   (locale   operating-system-locale               ; string
 197             (default "en_US.utf8"))
 198   (locale-definitions operating-system-locale-definitions ; list of <locale-definition>
 199                       (default %default-locale-definitions))
 200   (locale-libcs operating-system-locale-libcs     ; list of <packages>
 201                 (default %default-locale-libcs))
 202   (name-service-switch operating-system-name-service-switch ; <name-service-switch>
 203                        (default %default-nss))
 204
 205   (essential-services operating-system-essential-services ; list of services
 206                       (thunked)
 207                       (default (essential-services this-record)))
 208   (services operating-system-user-services        ; list of services
 209             (default %base-services))
 210
 211   (pam-services operating-system-pam-services     ; list of PAM services
 212                 (default (base-pam-services)))
 213   (setuid-programs operating-system-setuid-programs
 214                    (default %setuid-programs))    ; list of string-valued gexps
 215
 216   (sudoers-file operating-system-sudoers-file     ; file-like
 217                 (default %sudoers-specification)))
 218
 219 (define (operating-system-kernel-arguments os root-device)
 220   "Return all the kernel arguments, including the ones not specified
 221 directly by the user."
 222   (append (bootable-kernel-arguments os root-device)
 223           (operating-system-user-kernel-arguments os)))
 224
 225 \f
 226 ;;;
 227 ;;; Boot parameters
 228 ;;;
 229
 230 (define-record-type* <boot-parameters>
 231   boot-parameters make-boot-parameters boot-parameters?
 232   (label            boot-parameters-label)
 233   ;; Because we will use the 'store-device' to create the GRUB search command,
 234   ;; the 'store-device' has slightly different semantics than 'root-device'.
 235   ;; The 'store-device' can be a file system uuid, a file system label, or #f,
 236   ;; but it cannot be a device path such as "/dev/sda3", since GRUB would not
 237   ;; understand that.  The 'root-device', on the other hand, corresponds
 238   ;; exactly to the device field of the <file-system> object representing the
 239   ;; OS's root file system, so it might be a device path like "/dev/sda3".
 240   (root-device      boot-parameters-root-device)
 241   (bootloader-name  boot-parameters-bootloader-name)
 242   (store-device     boot-parameters-store-device)
 243   (store-mount-point boot-parameters-store-mount-point)
 244   (kernel           boot-parameters-kernel)
 245   (kernel-arguments boot-parameters-kernel-arguments)
 246   (initrd           boot-parameters-initrd))
 247
 248 (define (ensure-not-/dev device)
 249   "If DEVICE starts with a slash, return #f.  This is meant to filter out
 250 Linux device names such as /dev/sda, and to preserve GRUB device names and
 251 file system labels."
 252   (if (and (string? device) (string-prefix? "/" device))
 253       #f
 254       device))
 255
 256 (define (read-boot-parameters port)
 257   "Read boot parameters from PORT and return the corresponding
 258 <boot-parameters> object or #f if the format is unrecognized."
 259   (define device-sexp->device
 260     (match-lambda
 261       (('uuid (? symbol? type) (? bytevector? bv))
 262        (bytevector->uuid bv type))
 263       (('file-system-label (? string? label))
 264        (file-system-label label))
 265       ((? bytevector? bv)                         ;old format
 266        (bytevector->uuid bv 'dce))
 267       ((? string? device)
 268        ;; It used to be that we would not distinguish between labels and
 269        ;; device names.  Try to infer the right thing here.
 270        (if (string-prefix? "/dev/" device)
 271            device
 272            (file-system-label device)))))
 273
 274   (match (read port)
 275     (('boot-parameters ('version 0)
 276                        ('label label) ('root-device root)
 277                        ('kernel linux)
 278                        rest ...)
 279      (boot-parameters
 280       (label label)
 281       (root-device (device-sexp->device root))
 282
 283       (bootloader-name
 284        (match (assq 'bootloader-name rest)
 285          ((_ args) args)
 286          (#f       'grub))) ; for compatibility reasons.
 287
 288       ;; In the past, we would store the directory name of the kernel instead
 289       ;; of the absolute file name of its image.  Detect that and correct it.
 290       (kernel (if (string=? linux (direct-store-path linux))
 291                   (string-append linux "/"
 292                                  (system-linux-image-file-name))
 293                   linux))
 294
 295       (kernel-arguments
 296        (match (assq 'kernel-arguments rest)
 297          ((_ args) args)
 298          (#f       '())))                         ;the old format
 299
 300       (initrd
 301        (match (assq 'initrd rest)
 302          (('initrd ('string-append directory file)) ;the old format
 303           (string-append directory file))
 304          (('initrd (? string? file))
 305           file)))
 306
 307       (store-device
 308        ;; Linux device names like "/dev/sda1" are not suitable GRUB device
 309        ;; identifiers, so we just filter them out.
 310        (ensure-not-/dev
 311         (match (assq 'store rest)
 312           (('store ('device #f) _ ...)
 313            root-device)
 314           (('store ('device device) _ ...)
 315            (device-sexp->device device))
 316           (_                                      ;the old format
 317            root-device))))
 318
 319       (store-mount-point
 320        (match (assq 'store rest)
 321          (('store ('device _) ('mount-point mount-point) _ ...)
 322           mount-point)
 323          (_                                       ;the old format
 324           "/")))))
 325     (x                                            ;unsupported format
 326      (warning (G_ "unrecognized boot parameters at '~a'~%")
 327               (port-filename port))
 328      #f)))
 329
 330 (define (read-boot-parameters-file system)
 331   "Read boot parameters from SYSTEM's (system or generation) \"parameters\"
 332 file and returns the corresponding <boot-parameters> object or #f if the
 333 format is unrecognized.
 334 The object has its kernel-arguments extended in order to make it bootable."
 335   (let* ((file (string-append system "/parameters"))
 336          (params (call-with-input-file file read-boot-parameters))
 337          (root (boot-parameters-root-device params)))
 338     (boot-parameters
 339      (inherit params)
 340      (kernel-arguments (append (bootable-kernel-arguments system root)
 341                                (boot-parameters-kernel-arguments params))))))
 342
 343 (define (boot-parameters->menu-entry conf)
 344   (menu-entry
 345    (label (boot-parameters-label conf))
 346    (device (boot-parameters-store-device conf))
 347    (device-mount-point (boot-parameters-store-mount-point conf))
 348    (linux (boot-parameters-kernel conf))
 349    (linux-arguments (boot-parameters-kernel-arguments conf))
 350    (initrd (boot-parameters-initrd conf))))
 351
 352
 353 \f
 354 ;;;
 355 ;;; Services.
 356 ;;;
 357
 358 (define (non-boot-file-system-service os)
 359   "Return the file system service for the file systems of OS that are not
 360 marked as 'needed-for-boot'."
 361   (define file-systems
 362     (remove file-system-needed-for-boot?
 363             (operating-system-file-systems os)))
 364
 365   (define mapped-devices-for-boot
 366     (operating-system-boot-mapped-devices os))
 367
 368   (define (device-mappings fs)
 369     (let ((device (file-system-device fs)))
 370       (if (string? device)                        ;title is 'device
 371           (filter (lambda (md)
 372                     (string=? (string-append "/dev/mapper/"
 373                                              (mapped-device-target md))
 374                               device))
 375                   (operating-system-mapped-devices os))
 376           '())))
 377
 378   (define (add-dependencies fs)
 379     ;; Add the dependencies due to device mappings to FS.
 380     (file-system
 381       (inherit fs)
 382       (dependencies
 383        (delete-duplicates
 384         (remove (cut member <> mapped-devices-for-boot)
 385                 (append (device-mappings fs)
 386                         (file-system-dependencies fs)))
 387         eq?))))
 388
 389   (service file-system-service-type
 390            (map add-dependencies file-systems)))
 391
 392 (define (mapped-device-users device file-systems)
 393   "Return the subset of FILE-SYSTEMS that use DEVICE."
 394   (let ((target (string-append "/dev/mapper/" (mapped-device-target device))))
 395     (filter (lambda (fs)
 396               (or (member device (file-system-dependencies fs))
 397                   (and (string? (file-system-device fs))
 398                        (string=? (file-system-device fs) target))))
 399             file-systems)))
 400
 401 (define (operating-system-user-mapped-devices os)
 402   "Return the subset of mapped devices that can be installed in
 403 user-land--i.e., those not needed during boot."
 404   (let ((devices      (operating-system-mapped-devices os))
 405         (file-systems (operating-system-file-systems os)))
 406    (filter (lambda (md)
 407              (let ((users (mapped-device-users md file-systems)))
 408                (not (any file-system-needed-for-boot? users))))
 409            devices)))
 410
 411 (define (operating-system-boot-mapped-devices os)
 412   "Return the subset of mapped devices that must be installed during boot,
 413 from the initrd."
 414   (let ((devices      (operating-system-mapped-devices os))
 415         (file-systems (operating-system-file-systems os)))
 416    (filter (lambda (md)
 417              (let ((users (mapped-device-users md file-systems)))
 418                (any file-system-needed-for-boot? users)))
 419            devices)))
 420
 421 (define (device-mapping-services os)
 422   "Return the list of device-mapping services for OS as a list."
 423   (map device-mapping-service
 424        (operating-system-user-mapped-devices os)))
 425
 426 (define (swap-services os)
 427   "Return the list of swap services for OS."
 428   (map swap-service (operating-system-swap-devices os)))
 429
 430 (define* (system-linux-image-file-name #:optional (system (%current-system)))
 431   "Return the basename of the kernel image file for SYSTEM."
 432   ;; FIXME: Evaluate the conditional based on the actual current system.
 433   (cond
 434    ((string-prefix? "arm" (%current-system)) "zImage")
 435    ((string-prefix? "mips" (%current-system)) "vmlinuz")
 436    ((string-prefix? "aarch64" (%current-system)) "Image")
 437    (else "bzImage")))
 438
 439 (define (operating-system-kernel-file os)
 440   "Return an object representing the absolute file name of the kernel image of
 441 OS."
 442   (file-append (operating-system-kernel os)
 443                "/" (system-linux-image-file-name os)))
 444
 445 (define* (operating-system-directory-base-entries os)
 446   "Return the basic entries of the 'system' directory of OS for use as the
 447 value of the SYSTEM-SERVICE-TYPE service."
 448   (let ((locale (operating-system-locale-directory os)))
 449     (mlet %store-monad ((kernel -> (operating-system-kernel os))
 450                         (initrd -> (operating-system-initrd-file os))
 451                         (params    (operating-system-boot-parameters-file os)))
 452       (return `(("kernel" ,kernel)
 453                 ("parameters" ,params)
 454                 ("initrd" ,initrd)
 455                 ("locale" ,locale))))))   ;used by libc
 456
 457 (define* (essential-services os)
 458   "Return the list of essential services for OS.  These are special services
 459 that implement part of what's declared in OS are responsible for low-level
 460 bookkeeping."
 461   (define known-fs
 462     (map file-system-mount-point (operating-system-file-systems os)))
 463
 464   (let* ((mappings  (device-mapping-services os))
 465          (root-fs   (root-file-system-service))
 466          (other-fs  (non-boot-file-system-service os))
 467          (swaps     (swap-services os))
 468          (procs     (service user-processes-service-type))
 469          (host-name (host-name-service (operating-system-host-name os)))
 470          (entries   (operating-system-directory-base-entries os)))
 471     (cons* (service system-service-type entries)
 472            %boot-service
 473
 474            ;; %SHEPHERD-ROOT-SERVICE must come last so that the gexp that
 475            ;; execs shepherd comes last in the boot script (XXX).  Likewise,
 476            ;; the cleanup service must come first so that its gexp runs before
 477            ;; activation code.
 478            (service cleanup-service-type #f)
 479            %activation-service
 480            %shepherd-root-service
 481
 482            (pam-root-service (operating-system-pam-services os))
 483            (account-service (append (operating-system-accounts os)
 484                                     (operating-system-groups os))
 485                             (operating-system-skeletons os))
 486            (operating-system-etc-service os)
 487            (service fstab-service-type '())
 488            (session-environment-service
 489             (operating-system-environment-variables os))
 490            host-name procs root-fs
 491            (service setuid-program-service-type
 492                     (operating-system-setuid-programs os))
 493            (service profile-service-type
 494                     (operating-system-packages os))
 495            other-fs
 496            (append mappings swaps
 497
 498                    ;; Add the firmware service.
 499                    (list %linux-bare-metal-service
 500                          (service firmware-service-type
 501                                   (operating-system-firmware os)))))))
 502
 503 (define* (operating-system-services os)
 504   "Return all the services of OS, including \"essential\" services."
 505   (instantiate-missing-services
 506    (append (operating-system-user-services os)
 507            (operating-system-essential-services os))))
 508
 509 \f
 510 ;;;
 511 ;;; /etc.
 512 ;;;
 513
 514 (define %base-firmware
 515   ;; Firmware usable by default.
 516   (list ath9k-htc-firmware
 517         openfwwf-firmware))
 518
 519 (define %base-packages
 520   ;; Default set of packages globally visible.  It should include anything
 521   ;; required for basic administrator tasks.
 522   (cons* procps psmisc which less zile nano
 523          pciutils usbutils
 524          util-linux
 525          inetutils isc-dhcp
 526          (@ (gnu packages admin) shadow)          ;for 'passwd'
 527
 528          ;; wireless-tools is deprecated in favor of iw, but it's still what
 529          ;; many people are familiar with, so keep it around.
 530          iw wireless-tools
 531
 532          iproute
 533          net-tools                        ; XXX: remove when Inetutils suffices
 534          man-db
 535          info-reader                     ;the standalone Info reader (no Perl)
 536
 537          ;; The 'sudo' command is already in %SETUID-PROGRAMS, but we also
 538          ;; want the other commands and the man pages (notably because
 539          ;; auto-completion in Emacs shell relies on man pages.)
 540          sudo
 541
 542          ;; Get 'insmod' & co. from kmod, not module-init-tools, since udev
 543          ;; already depends on it anyway.
 544          kmod eudev
 545
 546          e2fsprogs kbd
 547
 548          bash-completion
 549
 550          ;; XXX: We don't use (canonical-package guile-2.2) here because that
 551          ;; would create a collision in the global profile between the GMP
 552          ;; variant propagated by 'guile-final' and the GMP variant propagated
 553          ;; by 'gnutls', itself propagated by 'guix'.
 554          guile-2.2
 555
 556          ;; The packages below are also in %FINAL-INPUTS, so take them from
 557          ;; there to avoid duplication.
 558          (map canonical-package
 559               (list bash coreutils findutils grep sed
 560                     diffutils patch gawk tar gzip bzip2 xz lzip))))
 561
 562 (define %default-issue
 563   ;; Default contents for /etc/issue.
 564   "
 565 This is the GNU system.  Welcome.\n")
 566
 567 (define (local-host-aliases host-name)
 568   "Return aliases for HOST-NAME, to be used in /etc/hosts."
 569   (string-append "127.0.0.1 localhost " host-name "\n"
 570                  "::1       localhost " host-name "\n"))
 571
 572 (define (default-/etc/hosts host-name)
 573   "Return the default /etc/hosts file."
 574   (plain-file "hosts" (local-host-aliases host-name)))
 575
 576 (define* (operating-system-etc-service os)
 577   "Return a <service> that builds containing the static part of the /etc
 578 directory."
 579   (let ((login.defs
 580           (plain-file "login.defs"
 581                       (string-append
 582                         "# Default paths for non-login shells started by su(1).\n"
 583                         "ENV_PATH    /run/setuid-programs:"
 584                         "/run/current-system/profile/bin:"
 585                         "/run/current-system/profile/sbin\n"
 586                         "ENV_SUPATH  /run/setuid-programs:"
 587                         "/run/current-system/profile/bin:"
 588                         "/run/current-system/profile/sbin\n")))
 589
 590         (issue      (plain-file "issue" (operating-system-issue os)))
 591         (nsswitch   (plain-file "nsswitch.conf"
 592                                 (name-service-switch->string
 593                                  (operating-system-name-service-switch os))))
 594
 595         ;; Startup file for POSIX-compliant login shells, which set system-wide
 596         ;; environment variables.
 597         (profile    (mixed-text-file "profile"  "\
 598 # Crucial variables that could be missing in the profiles' 'etc/profile'
 599 # because they would require combining both profiles.
 600 # FIXME: See <http://bugs.gnu.org/20255>.
 601 export MANPATH=$HOME/.guix-profile/share/man:/run/current-system/profile/share/man
 602 export INFOPATH=$HOME/.guix-profile/share/info:/run/current-system/profile/share/info
 603 export XDG_DATA_DIRS=$HOME/.guix-profile/share:/run/current-system/profile/share
 604 export XDG_CONFIG_DIRS=$HOME/.guix-profile/etc/xdg:/run/current-system/profile/etc/xdg
 605
 606 # Make sure libXcursor finds cursors installed into user or system profiles.  See <http://bugs.gnu.org/24445>
 607 export XCURSOR_PATH=$HOME/.icons:$HOME/.guix-profile/share/icons:/run/current-system/profile/share/icons
 608
 609 # Ignore the default value of 'PATH'.
 610 unset PATH
 611
 612 # Load the system profile's settings.
 613 GUIX_PROFILE=/run/current-system/profile ; \\
 614 . /run/current-system/profile/etc/profile
 615
 616 # Since 'lshd' does not use pam_env, /etc/environment must be explicitly
 617 # loaded when someone logs in via SSH.  See <http://bugs.gnu.org/22175>.
 618 # We need 'PATH' to be defined here, for 'cat' and 'cut'.  Do this before
 619 # reading the user's 'etc/profile' to allow variables to be overridden.
 620 if [ -f /etc/environment -a -n \"$SSH_CLIENT\" \\
 621      -a -z \"$LINUX_MODULE_DIRECTORY\" ]
 622 then
 623   . /etc/environment
 624   export `cat /etc/environment | cut -d= -f1`
 625 fi
 626
 627 # Arrange so that ~/.config/guix/current comes first.
 628 for profile in \"$HOME/.guix-profile\" \"$HOME/.config/guix/current\"
 629 do
 630   if [ -f \"$profile/etc/profile\" ]
 631   then
 632     # Load the user profile's settings.
 633     GUIX_PROFILE=\"$profile\" ; \\
 634     . \"$profile/etc/profile\"
 635   else
 636     # At least define this one so that basic things just work
 637     # when the user installs their first package.
 638     export PATH=\"$profile/bin:$PATH\"
 639   fi
 640 done
 641
 642 # Prepend setuid programs.
 643 export PATH=/run/setuid-programs:$PATH
 644
 645 # Arrange so that ~/.config/guix/current/share/info comes first.
 646 export INFOPATH=\"$HOME/.config/guix/current/share/info:$INFOPATH\"
 647
 648 # Set the umask, notably for users logging in via 'lsh'.
 649 # See <http://bugs.gnu.org/22650>.
 650 umask 022
 651
 652 # Allow Hunspell-based applications (IceCat, LibreOffice, etc.) to
 653 # find dictionaries.
 654 export DICPATH=\"$HOME/.guix-profile/share/hunspell:/run/current-system/profile/share/hunspell\"
 655
 656 # Allow GStreamer-based applications to find plugins.
 657 export GST_PLUGIN_PATH=\"$HOME/.guix-profile/lib/gstreamer-1.0\"
 658
 659 if [ -n \"$BASH_VERSION\" -a -f /etc/bashrc ]
 660 then
 661   # Load Bash-specific initialization code.
 662   . /etc/bashrc
 663 fi
 664 "))
 665
 666         (bashrc    (plain-file "bashrc" "\
 667 # Bash-specific initialization.
 668
 669 # The 'bash-completion' package.
 670 if [ -f /run/current-system/profile/etc/profile.d/bash_completion.sh ]
 671 then
 672   # Bash-completion sources ~/.bash_completion.  It installs a dynamic
 673   # completion loader that searches its own completion files as well
 674   # as those in ~/.guix-profile and /run/current-system/profile.
 675   source /run/current-system/profile/etc/profile.d/bash_completion.sh
 676 fi\n")))
 677     (etc-service
 678      `(("services" ,(file-append net-base "/etc/services"))
 679        ("protocols" ,(file-append net-base "/etc/protocols"))
 680        ("rpc" ,(file-append net-base "/etc/rpc"))
 681        ("login.defs" ,#~#$login.defs)
 682        ("issue" ,#~#$issue)
 683        ("nsswitch.conf" ,#~#$nsswitch)
 684        ("profile" ,#~#$profile)
 685        ("bashrc" ,#~#$bashrc)
 686        ("hosts" ,#~#$(or (operating-system-hosts-file os)
 687                          (default-/etc/hosts (operating-system-host-name os))))
 688        ;; Write the operating-system-host-name to /etc/hostname to prevent
 689        ;; NetworkManager from changing the system's hostname when connecting
 690        ;; to certain networks.  Some discussion at
 691        ;; https://lists.gnu.org/archive/html/help-guix/2017-09/msg00037.html
 692        ("hostname" ,(plain-file "hostname" (operating-system-host-name os)))
 693        ("localtime" ,(file-append tzdata "/share/zoneinfo/"
 694                                   (operating-system-timezone os)))
 695        ("sudoers" ,(operating-system-sudoers-file os))))))
 696
 697 (define %root-account
 698   ;; Default root account.
 699   (user-account
 700    (name "root")
 701    (password "")
 702    (uid 0) (group "root")
 703    (comment "System administrator")
 704    (home-directory "/root")))
 705
 706 (define (operating-system-accounts os)
 707   "Return the user accounts for OS, including an obligatory 'root' account,
 708 and excluding accounts requested by services."
 709   ;; Make sure there's a root account.
 710   (if (find (lambda (user)
 711               (and=> (user-account-uid user) zero?))
 712             (operating-system-users os))
 713       (operating-system-users os)
 714       (cons %root-account (operating-system-users os))))
 715
 716 (define (maybe-string->file file-name thing)
 717   "If THING is a string, return a <plain-file> with THING as its content.
 718 Otherwise just return THING.
 719
 720 This is for backward-compatibility of fields that used to be strings and are
 721 now file-like objects.."
 722   (match thing
 723     ((? string?)
 724      (warning (G_ "using a string for file '~a' is deprecated; \
 725 use 'plain-file' instead~%")
 726               file-name)
 727      (plain-file file-name thing))
 728     (x
 729      x)))
 730
 731 (define (maybe-file->monadic file-name thing)
 732   "If THING is a value in %STORE-MONAD, return it as is; otherwise return
 733 THING in the %STORE-MONAD.
 734
 735 This is for backward-compatibility of fields that used to be monadic values
 736 and are now file-like objects."
 737   (with-monad %store-monad
 738     (match thing
 739       ((? procedure?)
 740        (warning (G_ "using a monadic value for '~a' is deprecated; \
 741 use 'plain-file' instead~%")
 742                 file-name)
 743        thing)
 744       (x
 745        (return x)))))
 746
 747 (define (operating-system-etc-directory os)
 748   "Return that static part of the /etc directory of OS."
 749   (etc-directory
 750    (fold-services (operating-system-services os)
 751                   #:target-type etc-service-type)))
 752
 753 (define (operating-system-environment-variables os)
 754   "Return the environment variables of OS for
 755 @var{session-environment-service-type}, to be used in @file{/etc/environment}."
 756   `(("LANG" . ,(operating-system-locale os))
 757     ;; Note: No need to set 'TZ' since (1) we provide /etc/localtime, and (2)
 758     ;; it doesn't work for setuid binaries.  See <https://bugs.gnu.org/29212>.
 759     ("TZDIR" . ,(file-append tzdata "/share/zoneinfo"))
 760     ;; Tell 'modprobe' & co. where to look for modules.
 761     ("LINUX_MODULE_DIRECTORY" . "/run/booted-system/kernel/lib/modules")
 762     ;; These variables are honored by OpenSSL (libssl) and Git.
 763     ("SSL_CERT_DIR" . "/etc/ssl/certs")
 764     ("SSL_CERT_FILE" . "/etc/ssl/certs/ca-certificates.crt")
 765     ("GIT_SSL_CAINFO" . "/etc/ssl/certs/ca-certificates.crt")
 766
 767     ;; 'GTK_DATA_PREFIX' must name one directory where GTK+ themes are
 768     ;; searched for.
 769     ("GTK_DATA_PREFIX" . "/run/current-system/profile")
 770
 771     ;; By default, applications that use D-Bus, such as Emacs, abort at startup
 772     ;; when /etc/machine-id is missing.  Make sure these warnings are non-fatal.
 773     ("DBUS_FATAL_WARNINGS" . "0")
 774
 775     ;; XXX: Normally we wouldn't need to do this, but our glibc@2.23 package
 776     ;; used to look things up in 'PREFIX/lib/locale' instead of
 777     ;; '/run/current-system/locale' as was intended.  Keep this hack around so
 778     ;; that people who still have glibc@2.23-using packages in their profiles
 779     ;; can use them correctly.
 780     ;; TODO: Remove when glibc@2.23 is long gone.
 781     ("GUIX_LOCPATH" . "/run/current-system/locale")))
 782
 783 (define %setuid-programs
 784   ;; Default set of setuid-root programs.
 785   (let ((shadow (@ (gnu packages admin) shadow)))
 786     (list (file-append shadow "/bin/passwd")
 787           (file-append shadow "/bin/su")
 788           (file-append shadow "/bin/newuidmap")
 789           (file-append shadow "/bin/newgidmap")
 790           (file-append inetutils "/bin/ping")
 791           (file-append inetutils "/bin/ping6")
 792           (file-append sudo "/bin/sudo")
 793           (file-append sudo "/bin/sudoedit")
 794           (file-append fuse "/bin/fusermount"))))
 795
 796 (define %sudoers-specification
 797   ;; Default /etc/sudoers contents: 'root' and all members of the 'wheel'
 798   ;; group can do anything.  See
 799   ;; <http://www.sudo.ws/sudo/man/1.8.10/sudoers.man.html>.
 800   ;; TODO: Add a declarative API.
 801   (plain-file "sudoers" "\
 802 root ALL=(ALL) ALL
 803 %wheel ALL=(ALL) ALL\n"))
 804
 805 (define* (operating-system-activation-script os)
 806   "Return the activation script for OS---i.e., the code that \"activates\" the
 807 stateful part of OS, including user accounts and groups, special directories,
 808 etc."
 809   (let* ((services   (operating-system-services os))
 810          (activation (fold-services services
 811                                     #:target-type activation-service-type)))
 812     (activation-service->script activation)))
 813
 814 (define* (operating-system-boot-script os)
 815   "Return the boot script for OS---i.e., the code started by the initrd once
 816 we're running in the final root."
 817   (let* ((services (operating-system-services os))
 818          (boot     (fold-services services #:target-type boot-service-type)))
 819     (service-value boot)))
 820
 821 (define (operating-system-user-accounts os)
 822   "Return the list of user accounts of OS."
 823   (let* ((services (operating-system-services os))
 824          (account  (fold-services services
 825                                   #:target-type account-service-type)))
 826     (filter user-account?
 827             (service-value account))))
 828
 829 (define (operating-system-shepherd-service-names os)
 830   "Return the list of Shepherd service names for OS."
 831   (append-map shepherd-service-provision
 832               (service-value
 833                (fold-services (operating-system-services os)
 834                               #:target-type
 835                               shepherd-root-service-type))))
 836
 837 (define* (operating-system-derivation os)
 838   "Return a derivation that builds OS."
 839   (let* ((services (operating-system-services os))
 840          (system   (fold-services services)))
 841     ;; SYSTEM contains the derivation as a monadic value.
 842     (service-value system)))
 843
 844 (define* (operating-system-profile os)
 845   "Return a derivation that builds the system profile of OS."
 846   (mlet* %store-monad
 847       ((services -> (operating-system-services os))
 848        (profile (fold-services services
 849                                #:target-type profile-service-type)))
 850     (match profile
 851       (("profile" profile)
 852        (return profile)))))
 853
 854 (define (operating-system-root-file-system os)
 855   "Return the root file system of OS."
 856   (find (lambda (fs)
 857           (string=? "/" (file-system-mount-point fs)))
 858         (operating-system-file-systems os)))
 859
 860 (define (operating-system-initrd-file os)
 861   "Return a gexp denoting the initrd file of OS."
 862   (define boot-file-systems
 863     (filter file-system-needed-for-boot?
 864             (operating-system-file-systems os)))
 865
 866   (define mapped-devices
 867     (operating-system-boot-mapped-devices os))
 868
 869   (define make-initrd
 870     (operating-system-initrd os))
 871
 872   (make-initrd boot-file-systems
 873                #:linux (operating-system-kernel os)
 874                #:linux-modules
 875                (operating-system-initrd-modules os)
 876                #:mapped-devices mapped-devices
 877                #:keyboard-layout (operating-system-keyboard-layout os)))
 878
 879 (define (locale-name->definition* name)
 880   "Variant of 'locale-name->definition' that raises an error upon failure."
 881   (match (locale-name->definition name)
 882     (#f
 883      (raise (condition
 884              (&message
 885               (message (format #f (G_ "~a: invalid locale name") name))))))
 886     (def def)))
 887
 888 (define (operating-system-locale-directory os)
 889   "Return the directory containing the locales compiled for the definitions
 890 listed in OS.  The C library expects to find it under
 891 /run/current-system/locale."
 892   (define name
 893     (operating-system-locale os))
 894
 895   (define definitions
 896     ;; While we're at it, check whether NAME is defined and add it if needed.
 897     (if (member name (map locale-definition-name
 898                           (operating-system-locale-definitions os)))
 899         (operating-system-locale-definitions os)
 900         (cons (locale-name->definition* name)
 901               (operating-system-locale-definitions os))))
 902
 903   (locale-directory definitions
 904                     #:libcs (operating-system-locale-libcs os)))
 905
 906 (define (kernel->boot-label kernel)
 907   "Return a label for the bootloader menu entry that boots KERNEL."
 908   (cond ((package? kernel)
 909          (string-append "GNU with "
 910                         (string-titlecase (package-name kernel)) " "
 911                         (package-version kernel)
 912                         " (beta)"))
 913         ((inferior-package? kernel)
 914          (string-append "GNU with "
 915                         (string-titlecase (inferior-package-name kernel)) " "
 916                         (inferior-package-version kernel)
 917                         " (beta)"))
 918         (else "GNU")))
 919
 920 (define (store-file-system file-systems)
 921   "Return the file system object among FILE-SYSTEMS that contains the store."
 922   (match (filter (lambda (fs)
 923                    (and (file-system-mount? fs)
 924                         (not (memq 'bind-mount (file-system-flags fs)))
 925                         (string-prefix? (file-system-mount-point fs)
 926                                         (%store-prefix))))
 927                  file-systems)
 928     ((and candidates (head . tail))
 929      (reduce (lambda (fs1 fs2)
 930                (if (> (string-length (file-system-mount-point fs1))
 931                       (string-length (file-system-mount-point fs2)))
 932                    fs1
 933                    fs2))
 934              head
 935              candidates))))
 936
 937 (define (operating-system-store-file-system os)
 938   "Return the file system that contains the store of OS."
 939   (store-file-system (operating-system-file-systems os)))
 940
 941 (define* (operating-system-bootcfg os #:optional (old-entries '()))
 942   "Return the bootloader configuration file for OS.  Use OLD-ENTRIES,
 943 a list of <menu-entry>, to populate the \"old entries\" menu."
 944   (let* ((root-fs         (operating-system-root-file-system os))
 945          (root-device     (file-system-device root-fs))
 946          (params          (operating-system-boot-parameters
 947                            os root-device
 948                            #:system-kernel-arguments? #t))
 949          (entry           (boot-parameters->menu-entry params))
 950          (bootloader-conf (operating-system-bootloader os)))
 951     (define generate-config-file
 952       (bootloader-configuration-file-generator
 953        (bootloader-configuration-bootloader bootloader-conf)))
 954
 955     (generate-config-file bootloader-conf (list entry)
 956                           #:old-entries old-entries)))
 957
 958 (define* (operating-system-boot-parameters os root-device
 959                                            #:key system-kernel-arguments?)
 960   "Return a monadic <boot-parameters> record that describes the boot
 961 parameters of OS.  When SYSTEM-KERNEL-ARGUMENTS? is true, add kernel arguments
 962 such as '--root' and '--load' to <boot-parameters>."
 963   (let* ((initrd          (operating-system-initrd-file os))
 964          (store           (operating-system-store-file-system os))
 965          (bootloader      (bootloader-configuration-bootloader
 966                            (operating-system-bootloader os)))
 967          (bootloader-name (bootloader-name bootloader))
 968          (label           (kernel->boot-label (operating-system-kernel os))))
 969     (boot-parameters
 970      (label label)
 971      (root-device root-device)
 972      (kernel (operating-system-kernel-file os))
 973      (kernel-arguments
 974       (if system-kernel-arguments?
 975           (operating-system-kernel-arguments os root-device)
 976           (operating-system-user-kernel-arguments os)))
 977      (initrd initrd)
 978      (bootloader-name bootloader-name)
 979      (store-device (ensure-not-/dev (file-system-device store)))
 980      (store-mount-point (file-system-mount-point store)))))
 981
 982 (define (device->sexp device)
 983   "Serialize DEVICE as an sexp (really, as an object with a read syntax.)"
 984   (match device
 985     ((? uuid? uuid)
 986      `(uuid ,(uuid-type uuid) ,(uuid-bytevector uuid)))
 987     ((? file-system-label? label)
 988      `(file-system-label ,(file-system-label->string label)))
 989     (_
 990      device)))
 991
 992 (define* (operating-system-boot-parameters-file os
 993                                                 #:key system-kernel-arguments?)
 994    "Return a file that describes the boot parameters of OS.  The primary use of
 995 this file is the reconstruction of GRUB menu entries for old configurations.
 996
 997 When SYSTEM-KERNEL-ARGUMENTS? is true, add kernel arguments such as '--root'
 998 and '--load' to the returned file (since the returned file is then usually
 999 stored into the content-addressed \"system\" directory, it's usually not a
1000 good idea to give it because the content hash would change by the content hash
1001 being stored into the \"parameters\" file)."
1002    (let* ((root   (operating-system-root-file-system os))
1003           (device (file-system-device root))
1004           (params (operating-system-boot-parameters
1005                    os device
1006                    #:system-kernel-arguments?
1007                    system-kernel-arguments?)))
1008      (gexp->file "parameters"
1009                  #~(boot-parameters
1010                     (version 0)
1011                     (label #$(boot-parameters-label params))
1012                     (root-device
1013                      #$(device->sexp
1014                         (boot-parameters-root-device params)))
1015                     (kernel #$(boot-parameters-kernel params))
1016                     (kernel-arguments
1017                      #$(boot-parameters-kernel-arguments params))
1018                     (initrd #$(boot-parameters-initrd params))
1019                     (bootloader-name #$(boot-parameters-bootloader-name params))
1020                     (store
1021                      (device
1022                       #$(device->sexp (boot-parameters-store-device params)))
1023                      (mount-point #$(boot-parameters-store-mount-point params))))
1024                  #:set-load-path? #f)))
1025
1026 (define-gexp-compiler (operating-system-compiler (os <operating-system>)
1027                                                  system target)
1028   ((store-lift
1029     (lambda (store)
1030       ;; XXX: This is not super elegant but we can't pass SYSTEM and TARGET to
1031       ;; 'operating-system-derivation'.
1032       (run-with-store store (operating-system-derivation os)
1033                       #:system system
1034                       #:target target)))))
1035
1036 ;;; system.scm ends here