configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28
  29 AC_ARG_WITH(store-dir,
  30   AC_HELP_STRING([--with-store-dir=PATH],
  31     [file name of the store (defaults to /gnu/store)]),
  32   [storedir="$withval"],
  33   [storedir="/gnu/store"])
  34 AC_SUBST(storedir)
  35
  36 AC_ARG_WITH([bash-completion-dir],
  37   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  38     [name of the Bash completion directory]),
  39   [bashcompletiondir="$withval"],
  40   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  41 AC_SUBST([bashcompletiondir])
  42
  43 AC_ARG_WITH([zsh-completion-dir],
  44   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  45     [name of the Zsh completion directory]),
  46   [zshcompletiondir="$withval"],
  47   [zshcompletiondir='${datadir}/zsh/site-functions'])
  48 AC_SUBST([zshcompletiondir])
  49
  50 AC_ARG_WITH([fish-completion-dir],
  51   AC_HELP_STRING([--with-fish-completion-dir=DIR],
  52     [name of the Fish completion directory]),
  53   [fishcompletiondir="$withval"],
  54   [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  55 AC_SUBST([fishcompletiondir])
  56
  57 AC_ARG_WITH([selinux-policy-dir],
  58   AC_HELP_STRING([--with-selinux-policy-dir=DIR],
  59     [name of the SELinux policy directory]),
  60   [selinux_policydir="$withval"],
  61   [selinux_policydir='${datadir}/selinux/'])
  62 AC_SUBST([selinux_policydir])
  63
  64 dnl Better be verbose.
  65 AC_MSG_CHECKING([for the store directory])
  66 AC_MSG_RESULT([$storedir])
  67
  68 AC_ARG_ENABLE([daemon],
  69   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  70   [guix_build_daemon="$enableval"],
  71   [guix_build_daemon="yes"])
  72
  73 # Prepare a version of $localstatedir & co. that does not contain references
  74 # to shell variables.
  75 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  76 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  77 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  78 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  79 AC_SUBST([guix_localstatedir])
  80 AC_SUBST([guix_sysconfdir])
  81 AC_SUBST([guix_sbindir])
  82
  83 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  84 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  85
  86 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  87 dnl Make sure they are available.
  88 m4_pattern_forbid([PKG_CHECK_MODULES])
  89 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  90 m4_pattern_forbid([^GUILE_P$])
  91
  92 dnl Search for 'guile' and 'guild'.  This macro defines
  93 dnl 'GUILE_EFFECTIVE_VERSION'.
  94 GUILE_PKG([2.2 2.0])
  95 GUILE_PROGS
  96 if test "x$GUILD" = "x"; then
  97    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  98 fi
  99
 100 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
 101   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.13])
 102 fi
 103
 104 dnl Installation directories for .scm and .go files.
 105 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
 106 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
 107 AC_SUBST([guilemoduledir])
 108 AC_SUBST([guileobjectdir])
 109
 110 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
 111 dnl pull', among other things.
 112 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 113 if test "x$have_gnutls" != "xyes"; then
 114   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 115 fi
 116
 117 dnl Check for Guile-Git.
 118 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 119 if test "x$have_guile_git" != "xyes"; then
 120   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 121 fi
 122
 123 dnl Guile-JSON is used in various places.
 124 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
 125 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
 126
 127 dnl Make sure we have a full-fledged Guile.
 128 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 129
 130 dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
 131 dnl found in 2.2.1.  See <https://bugs.gnu.org/29903>.
 132 GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
 133
 134 AC_PROG_SED
 135
 136 dnl Decompressors, for use by the substituter and other modules.
 137 AC_PATH_PROG([GZIP], [gzip])
 138 AC_PATH_PROG([BZIP2], [bzip2])
 139 AC_PATH_PROG([XZ], [xz])
 140 AC_SUBST([GZIP])
 141 AC_SUBST([BZIP2])
 142 AC_SUBST([XZ])
 143
 144 AC_ARG_WITH([nix-prefix],
 145   [AS_HELP_STRING([--with-nix-prefix=DIR],
 146     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 147   [case "$withval" in
 148     yes|no) ;;
 149     *)
 150       NIX_PREFIX="$withval"
 151       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 152       AC_SUBST([NIX_PREFIX])
 153       ;;
 154    esac],
 155   [])
 156
 157 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 158 AC_PATH_PROG([NIX_HASH], [nix-hash])
 159 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 160    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 161 fi
 162
 163 if test "x$NIX_INSTANTIATE" = "x"; then
 164    # This program is an optional dependency, so we just want it to be
 165    # taken from $PATH if it's not available right now.
 166    NIX_INSTANTIATE="nix-instantiate"
 167 fi
 168
 169 AC_ARG_WITH([nixpkgs],
 170   [AS_HELP_STRING([--with-nixpkgs=DIR],
 171     [search for Nixpkgs in DIR (for testing purposes only)])],
 172   [case "$withval" in
 173     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 174     *)      NIXPKGS="$withval";;
 175    esac],
 176   [])
 177
 178 AC_MSG_CHECKING([for Nixpkgs source tree])
 179 if test -f "$NIXPKGS/default.nix"; then
 180    AC_MSG_RESULT([$NIXPKGS])
 181    AC_SUBST([NIXPKGS])
 182 else
 183    AC_MSG_RESULT([not found])
 184 fi
 185
 186 LIBGCRYPT="libgcrypt"
 187 LIBGCRYPT_LIBDIR="no"
 188 LIBGCRYPT_PREFIX="no"
 189
 190 AC_ARG_WITH([libgcrypt-prefix],
 191   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 192   [case "$withval" in
 193     yes|no)
 194       ;;
 195     *)
 196       LIBGCRYPT="$withval/lib/libgcrypt"
 197       LIBGCRYPT_PREFIX="$withval"
 198       LIBGCRYPT_LIBDIR="$withval/lib"
 199       ;;
 200    esac])
 201
 202 AC_ARG_WITH([libgcrypt-libdir],
 203   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 204      [search for GNU libgcrypt's shared library in DIR])],
 205   [case "$withval" in
 206     yes|no)
 207       LIBGCRYPT="libgcrypt"
 208       LIBGCRYPT_LIBDIR="no"
 209       ;;
 210     *)
 211       LIBGCRYPT="$withval/libgcrypt"
 212       LIBGCRYPT_LIBDIR="$withval"
 213       ;;
 214    esac])
 215
 216 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 217 dnl absolute file name of libgcrypt.so.
 218 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 219   xnono)
 220     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 221     if test "x$LIBGCRYPT_LIBDIR" != x; then
 222       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 223     else
 224       dnl 'config-daemon.ac' expects "no" in this case.
 225       LIBGCRYPT_LIBDIR="no"
 226     fi
 227     ;;
 228 esac
 229
 230 dnl Library name suitable for `dynamic-link'.
 231 AC_MSG_CHECKING([for libgcrypt shared library name])
 232 AC_MSG_RESULT([$LIBGCRYPT])
 233 AC_SUBST([LIBGCRYPT])
 234 AC_SUBST([LIBGCRYPT_PREFIX])
 235 AC_SUBST([LIBGCRYPT_LIBDIR])
 236
 237 GUIX_ASSERT_LIBGCRYPT_USABLE
 238
 239 dnl Library name of zlib suitable for 'dynamic-link'.
 240 GUIX_LIBZ_LIBDIR([libz_libdir])
 241 if test "x$libz_libdir" = "x"; then
 242   LIBZ="libz"
 243 else
 244   LIBZ="$libz_libdir/libz"
 245 fi
 246 AC_MSG_CHECKING([for zlib's shared library name])
 247 AC_MSG_RESULT([$LIBZ])
 248 AC_SUBST([LIBZ])
 249
 250 dnl Check for Guile-SSH, for the (guix ssh) module.
 251 GUIX_CHECK_GUILE_SSH
 252 AM_CONDITIONAL([HAVE_GUILE_SSH],
 253   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 254
 255 AC_CACHE_SAVE
 256
 257 m4_include([config-daemon.ac])
 258
 259 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 260 dnl See `Building from Git' in the manual for more info.
 261 AM_MISSING_PROG([DOT], [dot])
 262
 263 dnl Manual pages.
 264 AM_MISSING_PROG([HELP2MAN], [help2man])
 265
 266 dnl Emacs (optional), for 'etc/indent-package.el'.
 267 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
 268 AC_SUBST([EMACS])
 269
 270 case "$storedir" in
 271   /gnu/store)
 272     ;;
 273   *)
 274     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 275     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 276     ;;
 277 esac
 278
 279 AC_CONFIG_FILES([Makefile
 280                  po/guix/Makefile.in
 281                  po/packages/Makefile.in
 282                  etc/guix-daemon.cil
 283                  guix/config.scm])
 284
 285 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 286 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 287   [chmod +x pre-inst-env])
 288 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 289
 290 AC_OUTPUT