tests/containers.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2015 David Thompson <davet@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (test-containers)
  20   #:use-module (guix utils)
  21   #:use-module (guix build syscalls)
  22   #:use-module (gnu build linux-container)
  23   #:use-module (srfi srfi-64)
  24   #:use-module (ice-9 match))
  25
  26 (define (assert-exit x)
  27   (primitive-exit (if x 0 1)))
  28
  29 ;; Skip these tests unless user namespaces are available and the setgroups
  30 ;; file (introduced in Linux 3.19 to address a security issue) exists.
  31 (unless (and (file-exists? "/proc/self/ns/user")
  32              (file-exists? "/proc/self/setgroups"))
  33   (exit 77))
  34
  35 (test-begin "containers")
  36
  37 (test-assert "call-with-container, user namespace"
  38   (zero?
  39    (call-with-container '()
  40      (lambda ()
  41        ;; The user is root within the new user namespace.
  42        (assert-exit (and (zero? (getuid)) (zero? (getgid)))))
  43      #:namespaces '(user))))
  44
  45 (test-assert "call-with-container, uts namespace"
  46   (zero?
  47    (call-with-container '()
  48      (lambda ()
  49        ;; The user is root within the container and should be able to change
  50        ;; the hostname of that container.
  51        (sethostname "test-container")
  52        (primitive-exit 0))
  53      #:namespaces '(user uts))))
  54
  55 (test-assert "call-with-container, pid namespace"
  56   (zero?
  57    (call-with-container '()
  58      (lambda ()
  59        (match (primitive-fork)
  60          (0
  61           ;; The first forked process in the new pid namespace is pid 2.
  62           (assert-exit (= 2 (getpid))))
  63          (pid
  64           (primitive-exit
  65            (match (waitpid pid)
  66              ((_ . status)
  67               (status:exit-val status)))))))
  68      #:namespaces '(user pid))))
  69
  70 (test-assert "call-with-container, mnt namespace"
  71   (zero?
  72    (call-with-container '(("none" device "/testing" "tmpfs" () #f #f))
  73      (lambda ()
  74        (assert-exit (file-exists? "/testing")))
  75      #:namespaces '(user mnt))))
  76
  77 (test-assert "call-with-container, all namespaces"
  78   (zero?
  79    (call-with-container '()
  80      (lambda ()
  81        (primitive-exit 0)))))
  82
  83 (test-assert "container-excursion"
  84   (call-with-temporary-directory
  85    (lambda (root)
  86      ;; Two pipes: One for the container to signal that the test can begin,
  87      ;; and one for the parent to signal to the container that the test is
  88      ;; over.
  89      (match (list (pipe) (pipe))
  90        (((start-in . start-out) (end-in . end-out))
  91         (define (container)
  92           (close end-out)
  93           (close start-in)
  94           ;; Signal for the test to start.
  95           (write 'ready start-out)
  96           (close start-out)
  97           ;; Wait for test completion.
  98           (read end-in)
  99           (close end-in))
 100
 101         (define (namespaces pid)
 102           (let ((pid (number->string pid)))
 103             (map (lambda (ns)
 104                    (readlink (string-append "/proc/" pid "/ns/" ns)))
 105                  '("user" "ipc" "uts" "net" "pid" "mnt"))))
 106
 107         (let* ((pid (run-container root '() %namespaces 1 container))
 108                (container-namespaces (namespaces pid))
 109                (result
 110                 (begin
 111                   (close start-out)
 112                   ;; Wait for container to be ready.
 113                   (read start-in)
 114                   (close start-in)
 115                   (container-excursion pid
 116                     (lambda ()
 117                       ;; Fork again so that the pid is within the context of
 118                       ;; the joined pid namespace instead of the original pid
 119                       ;; namespace.
 120                       (match (primitive-fork)
 121                         (0
 122                          ;; Check that all of the namespace identifiers are
 123                          ;; the same as the container process.
 124                          (assert-exit
 125                           (equal? container-namespaces
 126                                   (namespaces (getpid)))))
 127                         (fork-pid
 128                          (match (waitpid fork-pid)
 129                            ((_ . status)
 130                             (primitive-exit
 131                              (status:exit-val status)))))))))))
 132           (close end-in)
 133           ;; Stop the container.
 134           (write 'done end-out)
 135           (close end-out)
 136           (waitpid pid)
 137           (zero? result)))))))
 138
 139 (test-end)
 140
 141 \f
 142 (exit (= (test-runner-fail-count (test-runner-current)) 0))