config-daemon.ac

   1 dnl -*- Autoconf -*- fragment for the C++ daemon.
   2
   3 AC_MSG_CHECKING([whether to build daemon])
   4 AC_MSG_RESULT([$guix_build_daemon])
   5
   6 dnl C++ environment.  This macro must be used unconditionnaly.
   7 AC_PROG_CXX
   8 AC_LANG([C++])
   9
  10 if test "x$guix_build_daemon" = "xyes"; then
  11
  12   GUIX_ASSERT_CXX11
  13
  14   AC_PROG_RANLIB
  15   AC_CONFIG_HEADER([nix/config.h])
  16
  17   dnl Use 64-bit file system calls so that we can support files > 2 GiB.
  18   AC_SYS_LARGEFILE
  19
  20   dnl Look for libbz2, a required dependency.
  21   AC_CHECK_LIB([bz2], [BZ2_bzWriteOpen], [true],
  22     [AC_MSG_ERROR([Guix requires libbz2, which is part of bzip2.  See http://www.bzip.org/.])])
  23   AC_CHECK_HEADERS([bzlib.h], [true],
  24     [AC_MSG_ERROR([Guix requires libbz2, which is part of bzip2.  See http://www.bzip.org/.])])
  25
  26   dnl Look for SQLite, a required dependency.
  27   PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= 3.6.19])
  28
  29   AC_DEFINE([NIX_VERSION], ["0.0.0"], [Fake Nix version number.])
  30   AC_DEFINE_UNQUOTED([SYSTEM], ["$guix_system"],
  31     [Guix host system type--i.e., platform and OS kernel tuple.])
  32
  33   case "$LIBGCRYPT_PREFIX" in
  34     no)
  35       LIBGCRYPT_CFLAGS=""
  36       ;;
  37     *)
  38       LIBGCRYPT_CFLAGS="-I$LIBGCRYPT_PREFIX/include"
  39       ;;
  40   esac
  41
  42   case "$LIBGCRYPT_LIBDIR" in
  43     no)
  44       LIBGCRYPT_LIBS="-lgcrypt"
  45       ;;
  46     *)
  47       LIBGCRYPT_LIBS="-L$LIBGCRYPT_LIBDIR -lgcrypt"
  48       ;;
  49   esac
  50
  51   AC_SUBST([LIBGCRYPT_CFLAGS])
  52   AC_SUBST([LIBGCRYPT_LIBS])
  53
  54   save_CFLAGS="$CFLAGS"
  55   save_LDFLAGS="$LDFLAGS"
  56   CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
  57   LDFLAGS="$LDFLAGS $LIBGCRYPT_LDFLAGS"
  58
  59   have_gcrypt=yes
  60   AC_CHECK_LIB([gcrypt], [gcry_md_open], [:], [have_gcrypt=no])
  61   AC_CHECK_HEADER([gcrypt.h], [:], [have_gcrypt=no])
  62   if test "x$have_gcrypt" != "xyes"; then
  63     AC_MSG_ERROR([GNU libgcrypt not found; please install it.])
  64   fi
  65
  66   CFLAGS="$save_CFLAGS"
  67   LDFLAGS="$save_LDFLAGS"
  68
  69   dnl Chroot support.
  70   AC_CHECK_FUNCS([chroot unshare])
  71   AC_CHECK_HEADERS([sched.h sys/param.h sys/mount.h sys/syscall.h])
  72
  73   if test "x$ac_cv_func_chroot" != "xyes"; then
  74     AC_MSG_ERROR(['chroot' function missing, bailing out])
  75   fi
  76
  77   dnl lutimes and lchown: used when canonicalizing store items.
  78   dnl posix_fallocate: used when extracting archives.
  79   dnl vfork: to speed up spawning of helper programs.
  80   dnl   `--> now disabled because of unpredictable behavior:
  81   dnl        see <http://lists.gnu.org/archive/html/guix-devel/2014-05/msg00036.html>
  82   dnl        and Nix commit f794465c (Nov. 2012).
  83   dnl sched_setaffinity: to improve RPC locality.
  84   dnl statvfs: to detect disk-full conditions.
  85   dnl strsignal: for error reporting.
  86   AC_CHECK_FUNCS([lutimes lchown posix_fallocate sched_setaffinity \
  87      statvfs nanosleep strsignal])
  88
  89   dnl Check whether the store optimiser can optimise symlinks.
  90   AC_MSG_CHECKING([whether it is possible to create a link to a symlink])
  91   ln -s bla tmp_link
  92   if ln tmp_link tmp_link2 2> /dev/null; then
  93       AC_MSG_RESULT(yes)
  94       AC_DEFINE(CAN_LINK_SYMLINK, 1, [Whether link() works on symlinks.])
  95   else
  96       AC_MSG_RESULT(no)
  97   fi
  98   rm -f tmp_link tmp_link2
  99
 100   dnl Check for <locale>.
 101   AC_LANG_PUSH(C++)
 102   AC_CHECK_HEADERS([locale])
 103   AC_LANG_POP(C++)
 104
 105
 106   dnl Check whether we have the `personality' syscall, which allows us
 107   dnl to do i686-linux builds on x86_64-linux machines.
 108   AC_CHECK_HEADERS([sys/personality.h])
 109
 110   dnl Check for <linux/fs.h> (for immutable file support).
 111   AC_CHECK_HEADERS([linux/fs.h])
 112
 113   dnl Determine the appropriate default list of substitute URLs.
 114   GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 115   if test "x$have_gnutls" = "xyes"; then
 116     guix_substitute_urls="https://mirror.hydra.gnu.org"
 117   else
 118     AC_MSG_WARN([GnuTLS is missing, substitutes will be downloaded in the clear])
 119     guix_substitute_urls="http://mirror.hydra.gnu.org"
 120   fi
 121   AC_MSG_CHECKING([for default substitute URLs])
 122   AC_MSG_RESULT([$guix_substitute_urls])
 123
 124   AC_DEFINE_UNQUOTED([GUIX_SUBSTITUTE_URLS], ["$guix_substitute_urls"],
 125     [Default list of substitute URLs used by 'guix-daemon'.])
 126
 127   dnl Check whether the 'offload' build hook can be built (uses
 128   dnl 'restore-file-set', which requires unbuffered custom binary input
 129   dnl ports from Guile >= 2.0.10.)
 130   GUIX_CHECK_UNBUFFERED_CBIP
 131
 132   dnl Check for Guile-SSH, which is required by 'guix offload'.
 133   GUIX_CHECK_GUILE_SSH
 134
 135   case "x$ac_cv_guix_cbips_support_setvbuf$guix_cv_have_recent_guile_ssh" in
 136     xyesyes)
 137       guix_build_daemon_offload="yes"
 138       AC_DEFINE([HAVE_DAEMON_OFFLOAD_HOOK], [1],
 139         [Define if the daemon's 'offload' build hook is being built (requires Guile-SSH).])
 140       ;;
 141     *)
 142       guix_build_daemon_offload="no"
 143       ;;
 144   esac
 145
 146   dnl Temporary directory used to store the daemon's data.
 147   GUIX_TEST_ROOT_DIRECTORY
 148   GUIX_TEST_ROOT="$ac_cv_guix_test_root"
 149   AC_SUBST([GUIX_TEST_ROOT])
 150
 151   GUIX_CHECK_LOCALSTATEDIR
 152
 153   AC_CONFIG_FILES([nix/scripts/list-runtime-roots],
 154     [chmod +x nix/scripts/list-runtime-roots])
 155   AC_CONFIG_FILES([nix/scripts/download],
 156     [chmod +x nix/scripts/download])
 157   AC_CONFIG_FILES([nix/scripts/substitute],
 158     [chmod +x nix/scripts/substitute])
 159   AC_CONFIG_FILES([nix/scripts/guix-authenticate],
 160     [chmod +x nix/scripts/guix-authenticate])
 161   AC_CONFIG_FILES([nix/scripts/offload],
 162     [chmod +x nix/scripts/offload])
 163 fi
 164
 165 AM_CONDITIONAL([BUILD_DAEMON], [test "x$guix_build_daemon" = "xyes"])
 166 AM_CONDITIONAL([BUILD_DAEMON_OFFLOAD],                  \
 167   [test "x$guix_build_daemon" = "xyes"                  \
 168    && test "x$guix_build_daemon_offload" = "xyes"])