configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix], [0.11.0], [bug-guix@gnu.org], [guix],
   6   [http://www.gnu.org/software/guix/])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10  color-tests parallel-tests -Woverride -Wno-portability])
  11
  12 # Enable silent rules by default.
  13 AM_SILENT_RULES([yes])
  14
  15 AC_CONFIG_SRCDIR([guix.scm])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 dnl For the C++ code.  This must be used early.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_GNU_GETTEXT([external])
  22 AM_GNU_GETTEXT_VERSION([0.18.1])
  23
  24 GUIX_SYSTEM_TYPE
  25 GUIX_ASSERT_SUPPORTED_SYSTEM
  26
  27 AC_ARG_WITH(store-dir,
  28   AC_HELP_STRING([--with-store-dir=PATH],
  29     [file name of the store (defaults to /gnu/store)]),
  30   [storedir="$withval"],
  31   [storedir="/gnu/store"])
  32 AC_SUBST(storedir)
  33
  34 AC_ARG_WITH([bash-completion-dir],
  35   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  36     [name of the Bash completion directory]),
  37   [bashcompletiondir="$withval"],
  38   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  39 AC_SUBST([bashcompletiondir])
  40
  41 AC_ARG_WITH([zsh-completion-dir],
  42   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  43     [name of the Zsh completion directory]),
  44   [zshcompletiondir="$withval"],
  45   [zshcompletiondir='${datadir}/zsh/site-functions'])
  46 AC_SUBST([zshcompletiondir])
  47
  48 dnl Better be verbose.
  49 AC_MSG_CHECKING([for the store directory])
  50 AC_MSG_RESULT([$storedir])
  51
  52 AC_ARG_ENABLE([daemon],
  53   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  54   [guix_build_daemon="$enableval"],
  55   [guix_build_daemon="yes"])
  56
  57 # Prepare a version of $localstatedir & co. that does not contain references
  58 # to shell variables.
  59 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  60 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  61 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  62 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  63 AC_SUBST([guix_localstatedir])
  64 AC_SUBST([guix_sysconfdir])
  65 AC_SUBST([guix_sbindir])
  66
  67 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  68 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  69
  70 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  71 dnl Make sure they are available.
  72 m4_pattern_forbid([PKG_CHECK_MODULES])
  73 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  74 m4_pattern_forbid([^GUILE_P$])
  75
  76 dnl Search for 'guile' and 'guild'.  Prefer 2.0 until the 2.2 upgrade is
  77 dnl complete.  This macro defines 'GUILE_EFFECTIVE_VERSION'.
  78 GUILE_PKG([2.0 2.2])
  79 GUILE_PROGS
  80 if test "x$GUILD" = "x"; then
  81    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  82 fi
  83
  84 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
  85   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.7])
  86 else
  87   AC_MSG_WARN([Guile $GUILE_EFFECTIVE_VERSION is not fully supported!])
  88 fi
  89
  90 dnl Installation directory for .scm and .go files.
  91 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
  92 AC_SUBST([guilemoduledir])
  93
  94 dnl guile-json is used for the PyPI package importer
  95 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  96 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  97
  98 dnl Make sure we have a full-fledged Guile.
  99 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 100
 101 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
 102 GUIX_CHECK_SRFI_37
 103 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
 104
 105 dnl Decompressors, for use by the substituter and other modules.
 106 AC_PATH_PROG([GZIP], [gzip])
 107 AC_PATH_PROG([BZIP2], [bzip2])
 108 AC_PATH_PROG([XZ], [xz])
 109 AC_SUBST([GZIP])
 110 AC_SUBST([BZIP2])
 111 AC_SUBST([XZ])
 112
 113 AC_ARG_WITH([nix-prefix],
 114   [AS_HELP_STRING([--with-nix-prefix=DIR],
 115     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 116   [case "$withval" in
 117     yes|no) ;;
 118     *)
 119       NIX_PREFIX="$withval"
 120       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 121       AC_SUBST([NIX_PREFIX])
 122       ;;
 123    esac],
 124   [])
 125
 126 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 127 AC_PATH_PROG([NIX_HASH], [nix-hash])
 128 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 129    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 130 fi
 131
 132 if test "x$NIX_INSTANTIATE" = "x"; then
 133    # This program is an optional dependency, so we just want it to be
 134    # taken from $PATH if it's not available right now.
 135    NIX_INSTANTIATE="nix-instantiate"
 136 fi
 137
 138 AC_ARG_WITH([nixpkgs],
 139   [AS_HELP_STRING([--with-nixpkgs=DIR],
 140     [search for Nixpkgs in DIR (for testing purposes only)])],
 141   [case "$withval" in
 142     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 143     *)      NIXPKGS="$withval";;
 144    esac],
 145   [])
 146
 147 AC_MSG_CHECKING([for Nixpkgs source tree])
 148 if test -f "$NIXPKGS/default.nix"; then
 149    AC_MSG_RESULT([$NIXPKGS])
 150    AC_SUBST([NIXPKGS])
 151 else
 152    AC_MSG_RESULT([not found])
 153 fi
 154
 155 LIBGCRYPT="libgcrypt"
 156 LIBGCRYPT_LIBDIR="no"
 157 LIBGCRYPT_PREFIX="no"
 158
 159 AC_ARG_WITH([libgcrypt-prefix],
 160   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 161   [case "$withval" in
 162     yes|no)
 163       ;;
 164     *)
 165       LIBGCRYPT="$withval/lib/libgcrypt"
 166       LIBGCRYPT_PREFIX="$withval"
 167       LIBGCRYPT_LIBDIR="$withval/lib"
 168       ;;
 169    esac])
 170
 171 AC_ARG_WITH([libgcrypt-libdir],
 172   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 173      [search for GNU libgcrypt's shared library in DIR])],
 174   [case "$withval" in
 175     yes|no)
 176       LIBGCRYPT="libgcrypt"
 177       LIBGCRYPT_LIBDIR="no"
 178       ;;
 179     *)
 180       LIBGCRYPT="$withval/libgcrypt"
 181       LIBGCRYPT_LIBDIR="$withval"
 182       ;;
 183    esac])
 184
 185 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 186 dnl absolute file name of libgcrypt.so.
 187 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 188   xnono)
 189     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 190     if test "x$LIBGCRYPT_LIBDIR" != x; then
 191       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 192     else
 193       dnl 'config-daemon.ac' expects "no" in this case.
 194       LIBGCRYPT_LIBDIR="no"
 195     fi
 196     ;;
 197 esac
 198
 199 dnl Library name suitable for `dynamic-link'.
 200 AC_MSG_CHECKING([for libgcrypt shared library name])
 201 AC_MSG_RESULT([$LIBGCRYPT])
 202 AC_SUBST([LIBGCRYPT])
 203 AC_SUBST([LIBGCRYPT_PREFIX])
 204 AC_SUBST([LIBGCRYPT_LIBDIR])
 205
 206 GUIX_ASSERT_LIBGCRYPT_USABLE
 207
 208 dnl Library name of zlib suitable for 'dynamic-link'.
 209 GUIX_LIBZ_LIBDIR([libz_libdir])
 210 if test "x$libz_libdir" = "x"; then
 211   LIBZ="libz"
 212 else
 213   LIBZ="$libz_libdir/libz"
 214 fi
 215 AC_MSG_CHECKING([for zlib's shared library name])
 216 AC_MSG_RESULT([$LIBZ])
 217 AC_SUBST([LIBZ])
 218
 219 AC_CACHE_SAVE
 220
 221 m4_include([config-daemon.ac])
 222
 223 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 224 dnl See `Building from Git' in the manual for more info.
 225 AM_MISSING_PROG([DOT], [dot])
 226
 227 dnl Manual pages.
 228 AM_MISSING_PROG([HELP2MAN], [help2man])
 229
 230 AC_CONFIG_FILES([Makefile
 231                  po/guix/Makefile.in
 232                  po/packages/Makefile.in
 233                  guix/config.scm])
 234
 235 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 236 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 237 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 238   [chmod +x pre-inst-env])
 239
 240 dnl Emacs interface.
 241 AC_PATH_PROG([DOT_USER_PROGRAM], [dot], [dot])
 242 AM_PATH_LISPDIR
 243 AM_CONDITIONAL([HAVE_EMACS], [test "x$EMACS" != "xno"])
 244
 245 emacsuidir="${guilemoduledir}/guix/emacs"
 246 AC_SUBST([emacsuidir])
 247 AC_CONFIG_FILES([emacs/guix-config.el
 248                  emacs/guix-helper.scm])
 249
 250 AC_OUTPUT