gtk-doc.m4

   1 dnl -*- mode: autoconf -*-
   2
   3 # serial 1
   4
   5 dnl Usage:
   6 dnl   GTK_DOC_CHECK([minimum-gtk-doc-version])
   7 AC_DEFUN([GTK_DOC_CHECK],
   8 [
   9   AC_BEFORE([AC_PROG_LIBTOOL],[$0])dnl setup libtool first
  10   AC_BEFORE([AM_PROG_LIBTOOL],[$0])dnl setup libtool first
  11
  12   dnl for overriding the documentation installation directory
  13   AC_ARG_WITH([html-dir],
  14     AS_HELP_STRING([--with-html-dir=PATH], [path to installed docs]),,
  15     [with_html_dir='${datadir}/gtk-doc/html'])
  16   HTML_DIR="$with_html_dir"
  17   AC_SUBST([HTML_DIR])
  18
  19   dnl enable/disable documentation building
  20   AC_ARG_ENABLE([gtk-doc],
  21     AS_HELP_STRING([--enable-gtk-doc],
  22                    [use gtk-doc to build documentation [[default=no]]]),,
  23     [enable_gtk_doc=no])
  24
  25   if test x$enable_gtk_doc = xyes; then
  26     ifelse([$1],[],
  27       [PKG_CHECK_EXISTS([gtk-doc],,
  28                         AC_MSG_ERROR([gtk-doc not installed and --enable-gtk-doc requested]))],
  29       [PKG_CHECK_EXISTS([gtk-doc >= $1],,
  30                         AC_MSG_ERROR([You need to have gtk-doc >= $1 installed to build gtk-doc]))])
  31   fi
  32
  33   AC_MSG_CHECKING([whether to build gtk-doc documentation])
  34   AC_MSG_RESULT($enable_gtk_doc)
  35
  36   dnl check for tools we added during development
  37   AC_PATH_PROG([GTKDOC_CHECK],[gtkdoc-check])
  38   AC_PATH_PROGS([GTKDOC_REBASE],[gtkdoc-rebase],[true])
  39
  40   AM_CONDITIONAL([ENABLE_GTK_DOC], [test x$enable_gtk_doc = xyes])
  41   AM_CONDITIONAL([GTK_DOC_USE_LIBTOOL], [test -n "$LIBTOOL"])
  42   AM_CONDITIONAL([GTK_DOC_USE_REBASE], [test -n "$GTKDOC_REBASE"])
  43 ])