gtkdoc-common.pl.in

   1 #!@PERL@ -w
   2 # -*- cperl -*-
   3 #
   4 # gtk-doc - GTK DocBook documentation generator.
   5 # Copyright (C) 2001  Damon Chaplin
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  20 #
  21
  22 #
  23 # These are functions used by several of the gtk-doc Perl scripts.
  24 # We'll move more of the common routines here eventually, though they need to
  25 # stop using global variables first.
  26 #
  27
  28 1;
  29
  30
  31 #############################################################################
  32 # Function    : UpdateFileIfChanged
  33 # Description : Compares the old version of the file with the new version and
  34 #                if the file has changed it moves the new version into the old
  35 #                versions place. This is used so we only change files if
  36 #                needed, so we can do proper dependency tracking and we don't
  37 #                needlessly check files into version control systems that haven't
  38 #               changed.
  39 #                It returns 0 if the file hasn't changed, and 1 if it has.
  40 # Arguments   : $old_file - the pathname of the old file.
  41 #                $new_file - the pathname of the new version of the file.
  42 #                $make_backup - 1 if a backup of the old file should be kept.
  43 #                        It will have the .bak suffix added to the file name.
  44 #############################################################################
  45
  46 sub UpdateFileIfChanged {
  47     my ($old_file, $new_file, $make_backup) = @_;
  48
  49     #@TRACE@("Comparing $old_file with $new_file...");
  50
  51     # If the old file doesn't exist we want this to default to 1.
  52     my $exit_code = 1;
  53
  54     if (-e $old_file) {
  55         `cmp -s "$old_file" "$new_file"`;
  56         $exit_code = $? >> 8;
  57         #@TRACE@("   cmp exit code: $exit_code ($?)";
  58     }
  59
  60     if ($exit_code > 1) {
  61         die "Error running 'cmp $old_file $new_file'";
  62     }
  63
  64     if ($exit_code == 1) {
  65         #@TRACE@("   files changed - replacing old version with new version.");
  66         if ($make_backup && -e $old_file) {
  67             rename ($old_file, "$old_file.bak")
  68                 || die "Can't move $old_file to $old_file.bak: $!";
  69         }
  70         rename ($new_file, $old_file)
  71             || die "Can't move $new_file to $old_file: $!";
  72
  73         return 1;
  74     } else {
  75         #@TRACE@("   files the same - deleting new version.");
  76         unlink ("$new_file")
  77             || die "Can't delete file: $new_file: $!";
  78
  79         return 0;
  80     }
  81 }
  82
  83
  84 #############################################################################
  85 # Function    : ParseStructDeclaration
  86 # Description : This function takes a structure declaration and
  87 #               breaks it into individual type declarations.
  88 # Arguments   : $declaration - the declaration to parse
  89 #               $is_object - true if this is an object structure
  90 #               $output_function_params - true if full type is wanted for
  91 #                                         function pointer members
  92 #               $typefunc - function reference to apply to type
  93 #               $namefunc - function reference to apply to name
  94 #############################################################################
  95
  96 sub ParseStructDeclaration {
  97     my ($declaration, $is_object, $output_function_params, $typefunc, $namefunc) = @_;
  98
  99     # For forward struct declarations just return an empty array.
 100     if ($declaration =~ m/(?:struct|union)\s+\S+\s*;/msg) {
 101       return ();
 102     }
 103
 104     # Remove all private parts of the declaration
 105
 106     # For objects, assume private
 107     if ($is_object) {
 108         $declaration =~ s!((?:struct|union)\s+\w*\s*\{)
 109                           .*?
 110                           (?:/\*\s*<\s*public\s*>\s*\*/|(?=\}))!$1!msgx;
 111     }
 112
 113     # Remove private symbols
 114     # Assume end of declaration if line begins with '}'
 115     $declaration =~ s!\n?[ \t]*/\*\s*<\s*(private|protected)\s*>\s*\*/.*?(?:/\*\s*<\s*public\s*>\s*\*/|(?=^\}))!!msgx;
 116
 117     # Remove all other comments
 118     $declaration =~ s@\n\s*/\*([^*]+|\*(?!/))*\*/\s*\n@\n@msg;
 119     $declaration =~ s@/\*([^*]+|\*(?!/))*\*/@ @g;
 120     $declaration =~ s@\n\s*//.*?\n@\n@msg;
 121     $declaration =~ s@//.*@@g;
 122
 123     my @result = ();
 124
 125     if ($declaration =~ /^\s*$/) {
 126         return @result;
 127     }
 128
 129     # Prime match after "struct/union {" declaration
 130     if (!scalar($declaration =~ m/(?:struct|union)\s+\w*\s*\{/msg)) {
 131         die "Declaration '$declaration' does not begin with struct/union [NAME] {\n";
 132     }
 133
 134     #@TRACE@("public fields in struct/union: $declaration");
 135
 136     # Treat lines in sequence, allowing singly nested anonymous structs
 137     # and unions.
 138     while ($declaration =~ m/\s*([^{;]+(\{[^\}]*\}[^{;]+)?);/msg) {
 139         my $line = $1;
 140
 141         last if $line =~ /^\s*\}\s*\w*\s*$/;
 142
 143         # FIXME: Just ignore nested structs and unions for now
 144         next if $line =~ /{/;
 145
 146         # ignore preprocessor directives
 147         while ($line =~ /^#.*?\n\s*(.*)/msg) {
 148             $line=$1;
 149         }
 150
 151         last if $line =~ /^\s*\}\s*\w*\s*$/;
 152
 153         # Try to match structure members which are functions
 154         if ($line =~ m/^
 155                  (const\s+|G_CONST_RETURN\s+|unsigned\s+|signed\s+|long\s+|short\s+)*(struct\s+|enum\s+)?  # mod1
 156                  (\w+)\s*                             # type
 157                  (\**(?:\s*restrict)?)\s*             # ptr1
 158                  (const\s+)?                          # mod2
 159                  (\**\s*)                              # ptr2
 160                  (const\s+)?                          # mod3
 161                  \(\s*\*\s*(\w+)\s*\)\s*              # name
 162                  \(([^)]*)\)\s*                       # func_params
 163                             $/x) {
 164
 165             my $mod1 = defined($1) ? $1 : "";
 166             if (defined($2)) { $mod1 .= $2; }
 167             my $type = $3;
 168             my $ptr1 = $4;
 169             my $mod2 = defined($5) ? $5 : "";
 170             my $ptr2 = $6;
 171             my $mod3 = defined($7) ? $7 : "";
 172             my $name = $8;
 173             my $func_params = $9;
 174             my $ptype = defined $typefunc ? $typefunc->($type, "<type>$type</type>") : $type;
 175             my $pname = defined $namefunc ? $namefunc->($name) : $name;
 176
 177             push @result, $name;
 178
 179             if ($output_function_params) {
 180               push @result, "$mod1$ptype$ptr1$mod2$ptr2$mod3 (*$pname) ($func_params)";
 181             } else {
 182               push @result, "$pname&#160;()";
 183             }
 184
 185
 186         # Try to match normal struct fields of comma-separated variables/
 187         } elsif ($line =~ m/^
 188             ((?:const\s+|volatile\s+|unsigned\s+|signed\s+|short\s+|long\s+)?)(struct\s+|enum\s+)? # mod1
 189             (\w+)\s*                            # type
 190             (\** \s* const\s+)?                 # mod2
 191             (.*)                                # variables
 192             $/x) {
 193
 194             my $mod1 = defined($1) ? $1 : "";
 195             if (defined($2)) { $mod1 .= $2; }
 196             my $type = $3;
 197             my $ptype = defined $typefunc ? $typefunc->($type, "<type>$type</type>") : $type;
 198             my $mod2 = defined($4) ? " " . $4 : "";
 199             my $list = $5;
 200
 201             #@TRACE@("'$mod1' '$type' '$mod2' '$list'");
 202
 203             $mod1 =~ s/ /&#160;/g;
 204             $mod2 =~ s/ /&#160;/g;
 205
 206             my @names = split /,/, $list;
 207             for my $n (@names) {
 208                 # Each variable can have any number of '*' before the
 209                 # identifier, and be followed by any number of pairs of
 210                 # brackets or a bit field specifier.
 211                 # e.g. *foo, ***bar, *baz[12][23], foo : 25.
 212                 if ($n =~ m/^\s* (\**(?:\s*restrict\b)?) \s* (\w+) \s* (?: ((?:\[[^\]]*\]\s*)+) | (:\s*\d+)?) \s* $/x) {
 213                     my $ptrs = $1;
 214                     my $name = $2;
 215                     my $array = defined($3) ? $3 : "";
 216                     my $bits =  defined($4) ? " $4" : "";
 217
 218                     if ($ptrs && $ptrs !~ m/\*$/) { $ptrs .= " "; }
 219                     $array =~ s/ /&#160;/g;
 220                     $bits =~ s/ /&#160;/g;
 221
 222                     push @result, $name;
 223                     if (defined $namefunc) {
 224                         $name = $namefunc->($name);
 225                     }
 226                     push @result, "$mod1$ptype$mod2&#160;$ptrs$name$array$bits;";
 227
 228                     #@TRACE@("Matched line: $mod1$ptype$mod2 $ptrs$name$array$bits");
 229                 } else {
 230                     print "WARNING: Couldn't parse struct field: $n\n";
 231                 }
 232             }
 233
 234         } else {
 235             print "WARNING: Cannot parse structure field: \"$line\"\n";
 236         }
 237     }
 238
 239     return @result;
 240 }
 241
 242
 243 #############################################################################
 244 # Function    : ParseEnumDeclaration
 245 # Description : This function takes a enumeration declaration and
 246 #               breaks it into individual enum member declarations.
 247 # Arguments   : $declaration - the declaration to parse
 248 #############################################################################
 249
 250 sub ParseEnumDeclaration {
 251     my ($declaration, $is_object) = @_;
 252
 253     # For forward enum declarations just return an empty array.
 254     if ($declaration =~ m/enum\s+\S+\s*;/msg) {
 255         return ();
 256     }
 257
 258     # Remove private symbols
 259     # Assume end of declaration if line begins with '}'
 260     $declaration =~ s!\n?[ \t]*/\*\s*<\s*(private|protected)\s*>\s*\*/.*?(?:/\*\s*<\s*public\s*>\s*\*/|(?=^\}))!!msgx;
 261
 262     # Remove all other comments
 263     $declaration =~ s@\n\s*/\*([^*]+|\*(?!/))*\*/\s*\n@\n@msg;
 264     $declaration =~ s@/\*([^*]+|\*(?!/))*\*/@ @g;
 265     $declaration =~ s@\n\s*//.*?\n@\n@msg;
 266     $declaration =~ s@//.*@@g;
 267
 268     my @result = ();
 269
 270     if ($declaration =~ /^\s*$/) {
 271         return @result;
 272     }
 273
 274     # Remove parenthesized expressions (in macros like GTK_BLAH = BLAH(1,3))
 275     # to avoid getting confused by commas they might contain. This
 276     # doesn't handle nested parentheses correctly.
 277
 278     $declaration =~ s/\([^)\n]+\)//g;
 279
 280     # Remove comma from comma - possible whitespace - closing brace sequence
 281     # since it is legal in GNU C and C99 to have a trailing comma but doesn't
 282     # result in an actual enum member
 283
 284     $declaration =~ s/,(\s*})/$1/g;
 285
 286     # Prime match after "typedef enum {" declaration
 287     if (!scalar($declaration =~ m/(typedef\s+)?enum\s*(\S+\s*)?\{/msg)) {
 288         die "Enum declaration '$declaration' does not begin with 'typedef enum {' or 'enum XXX {'\n";
 289     }
 290
 291     #@TRACE@("public fields in enum: $declaration");
 292
 293     # Treat lines in sequence.
 294     while ($declaration =~ m/\s*([^,\}]+)([,\}])/msg) {
 295         my $line = $1;
 296         my $terminator = $2;
 297
 298         # ignore preprocessor directives
 299         while ($line =~ /^#.*?\n\s*(.*)/msg) {
 300             $line=$1;
 301         }
 302
 303         if ($line =~ m/^(\w+)\s*(=.*)?$/msg) {
 304             push @result, $1;
 305
 306         # Special case for GIOCondition, where the values are specified by
 307         # macros which expand to include the equal sign like '=1'.
 308         } elsif ($line =~ m/^(\w+)\s*GLIB_SYSDEF_POLL/msg) {
 309             push @result, $1;
 310
 311         # Special case include of <gdk/gdkcursors.h>, just ignore it
 312         } elsif ($line =~ m/^#include/) {
 313             last;
 314
 315         # Special case for #ifdef/#else/#endif, just ignore it
 316         } elsif ($line =~ m/^#(?:if|else|endif)/) {
 317             last;
 318
 319         } else {
 320             warn "Cannot parse enumeration member \"$line\"";
 321         }
 322
 323         last if $terminator eq '}';
 324     }
 325
 326     return @result;
 327 }
 328
 329
 330 #############################################################################
 331 # Function    : ParseFunctionDeclaration
 332 # Description : This function takes a function declaration and
 333 #               breaks it into individual parameter declarations.
 334 # Arguments   : $declaration - the declaration to parse
 335 #               $typefunc - function reference to apply to type
 336 #               $namefunc - function reference to apply to name
 337 #############################################################################
 338
 339 sub ParseFunctionDeclaration {
 340     my ($declaration, $typefunc, $namefunc) = @_;
 341
 342     my @result = ();
 343
 344     my ($param_num) = 0;
 345     while ($declaration ne "") {
 346         #@TRACE@("[$declaration]");
 347
 348         if ($declaration =~ s/^[\s,]+//) {
 349             # skip whitespace and commas
 350             next;
 351
 352         } elsif ($declaration =~ s/^void\s*[,\n]//) {
 353             if ($param_num != 0) {
 354                 # FIXME: whats the problem here?
 355                 warn "void used as parameter in function $declaration";
 356             }
 357             push @result, "void";
 358             my $xref = "<type>void</type>";
 359             my $label = defined $namefunc ? $namefunc->($xref) : $xref;
 360             push @result, $label;
 361
 362         } elsif ($declaration =~ s/^\s*[_a-zA-Z0-9]*\.\.\.\s*[,\n]//) {
 363             push @result, "...";
 364             my $label = defined $namefunc ? $namefunc->("...") : "...";
 365             push @result, $label;
 366
 367         # allow alphanumerics, '_', '[' & ']' in param names
 368         # Try to match a standard parameter
 369         #                               $1                                                                                                                                            $2                             $3                                                                                                $4       $5
 370         } elsif ($declaration =~ s/^\s*((?:(?:G_CONST_RETURN|G_GNUC_[A-Z_]+\s+|unsigned long|unsigned short|signed long|signed short|unsigned|signed|long|short|volatile|const)\s+)*)((?:struct\b|enum\b)?\s*\w+)\s*((?:(?:const\b|restrict\b|G_GNUC_[A-Z_]+\b)?\s*\*?\s*(?:const\b|restrict\b|G_GNUC_[A-Z_]+\b)?\s*)*)(\w+)?\s*((?:\[\S*\])*)\s*(?:G_GNUC_[A-Z_]+)?\s*[,\n]//) {
 371             my $pre        = defined($1) ? $1 : "";
 372             my $type        = $2;
 373             my $ptr        = defined($3) ? $3 : "";
 374             my $name        = defined($4) ? $4 : "";
 375             my $array        = defined($5) ? $5 : "";
 376
 377             $pre  =~ s/\s+/ /g;
 378             $type =~ s/\s+/ /g;
 379             $ptr  =~ s/\s+/ /g;
 380             $ptr  =~ s/\s+$//;
 381             if ($ptr && $ptr !~ m/\*$/) { $ptr .= " "; }
 382
 383             #@TRACE@("$symbol: '$pre' '$type' '$ptr' '$name' '$array'");
 384
 385             if (($name eq "") && $pre =~ m/^((un)?signed .*)\s?/ ) {
 386                 $name = $type;
 387                 $type = "$1";
 388                 $pre = "";
 389             }
 390
 391             if ($name eq "") {
 392                 $name = "Param" . ($param_num + 1);
 393             }
 394
 395             #@TRACE@("$symbol: '$pre' '$type' '$ptr' '$name' '$array'");
 396
 397             push @result, $name;
 398             my $xref = defined $typefunc ? $typefunc->($type, "<type>$type</type>") : $type;
 399             my $label        = "$pre$xref $ptr$name$array";
 400             if (defined $namefunc) {
 401                 $label = $namefunc->($label)
 402             }
 403             push @result, $label;
 404
 405         # Try to match parameters which are functions
 406         #                            $1                                                                  $2          $3      $4                        $5              $6            $7             $8
 407         } elsif ($declaration =~ s/^(const\s+|G_CONST_RETURN\s+|G_GNUC_[A-Z_]+\s+|signed\s+|unsigned\s+)*(struct\s+)?(\w+)\s*(\**)\s*(?:restrict\b)?\s*(const\s+)?\(\s*(\*[\s\*]*)\s*(\w+)\s*\)\s*\(([^)]*)\)\s*[,\n]//) {
 408              my $mod1 = defined($1) ? $1 : "";
 409             if (defined($2)) { $mod1 .= $2; }
 410             my $type = $3;
 411             my $ptr1 = $4;
 412             my $mod2 = defined($5) ? $5 : "";
 413             my $func_ptr = $6;
 414             my $name = $7;
 415             my $func_params = defined($8) ? $8 : "";
 416
 417             #if (!defined($type)) { print "## no type\n"; };
 418             #if (!defined($ptr1)) { print "## no ptr1\n"; };
 419             #if (!defined($func_ptr)) { print "## no func_ptr\n"; };
 420             #if (!defined($name)) { print "## no name\n"; };
 421
 422             if ($ptr1 && $ptr1 !~ m/\*$/) { $ptr1 .= " "; }
 423             $func_ptr  =~ s/\s+//g;
 424
 425             push @result, $name;
 426             my $xref = defined $typefunc ? $typefunc->($type, "<type>$type</type>") : $type;
 427             #@TRACE@("Type: [$mod1][$xref][$ptr1][$mod2] ([$func_ptr][$name]) ($func_params)");
 428             my $label = "$mod1$xref$ptr1$mod2 ($func_ptr$name) ($func_params)";
 429             if (defined $namefunc) {
 430                 $label = $namefunc->($label)
 431             }
 432             push @result, $label;
 433         } else {
 434             warn "Can't parse args for function in \"$declaration\"";
 435             last;
 436         }
 437         $param_num++;
 438     }
 439
 440     return @result;
 441 }
 442
 443
 444 #############################################################################
 445 # Function    : ParseMacroDeclaration
 446 # Description : This function takes a macro declaration and
 447 #               breaks it into individual parameter declarations.
 448 # Arguments   : $declaration - the declaration to parse
 449 #               $namefunc - function reference to apply to name
 450 #############################################################################
 451
 452 sub ParseMacroDeclaration {
 453     my ($declaration, $namefunc) = @_;
 454
 455     my @result = ();
 456
 457     if ($declaration =~ m/^\s*#\s*define\s+\w+\(([^\)]*)\)/) {
 458         my $params = $1;
 459
 460         $params =~ s/\\\n//g;
 461         foreach $param (split (/,/, $params)) {
 462             $param =~ s/^\s+//;
 463             $param =~ s/\s*$//;
 464             # Allow varargs variations
 465             if ($param =~ m/^.*\.\.\.$/) {
 466                 $param = "...";
 467             }
 468             if ($param =~ m/\S/) {
 469                 push @result, $param;
 470                 push @result, defined $namefunc ? $namefunc->($param) : $param;
 471             }
 472         }
 473     }
 474
 475     return @result;
 476 }
 477
 478
 479 #############################################################################
 480 # Function    : LogWarning
 481 # Description : Log a warning in gcc style format
 482 # Arguments   : $file - the file the error comes from
 483 #                $line - line number for the wrong entry
 484 #                $message - description of the issue
 485 #############################################################################
 486
 487 sub LogWarning {
 488     my ($file, $line, $message) = @_;
 489
 490     $file="unknown" if !defined($file);
 491     $line="0" if !defined($line);
 492
 493     print "$file:$line: warning: $message\n"
 494 }
 495
 496 sub LogTrace {
 497     my ($message) = @_;
 498
 499     if (defined($ENV{"GTKDOC_TRACE"})) {
 500         my (undef, $file, $line) = caller;
 501
 502         chomp($message);
 503         print "$file:$line: trace: $message\n"
 504     }
 505 }
 506
 507
 508 #############################################################################
 509 # Function    : CreateValidSGMLID
 510 # Description : Creates a valid SGML 'id' from the given string.
 511 #               According to http://www.w3.org/TR/html4/types.html#type-id
 512 #                 "ID and NAME tokens must begin with a letter ([A-Za-z]) and
 513 #                  may be followed by any number of letters, digits ([0-9]),
 514 #                  hyphens ("-"), underscores ("_"), colons (":"), and
 515 #                  periods (".")."
 516 #
 517 #                NOTE: When creating SGML IDS, we append ":CAPS" to all
 518 #                     all-caps identifiers to prevent name clashes (SGML ids are
 519 #                     case-insensitive). (It basically never is the case that
 520 #                     mixed-case identifiers would collide.)
 521 # Arguments   : $id - the string to be converted into a valid SGML id.
 522 #############################################################################
 523
 524 sub CreateValidSGMLID {
 525     my ($id) = $_[0];
 526
 527     # Special case, '_' would end up as '' so we use 'gettext-macro' instead.
 528     if ($id eq "_") { return "gettext-macro"; }
 529
 530     $id =~ s/[_ ]/-/g;
 531     $id =~ s/[,;]//g;
 532     $id =~ s/^-*//;
 533     $id =~ s/::/-/g;
 534     $id =~ s/:/--/g;
 535
 536     # Append ":CAPS" to all all-caps identifiers
 537     # FIXME: there are some inconsistencies here, we have sgml.index files
 538     # containing e.g. TRUE--CAPS
 539     if ($id !~ /[a-z]/ && $id !~ /-CAPS$/) { $id .= ":CAPS" };
 540
 541     return $id;
 542 }
 543