gtkdoc-scan.in

   1 #!@PERL@ -w
   2 # -*- cperl -*-
   3 #
   4 # gtk-doc - GTK DocBook documentation generator.
   5 # Copyright (C) 1998  Damon Chaplin
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  20 #
  21
  22 #############################################################################
  23 # Script      : gtkdoc-scan
  24 # Description : Extracts declarations of functions, macros, enums, structs
  25 #               and unions from header files.
  26 #
  27 #               It is called with a module name, an optional source directory,
  28 #               an optional output directory, and the header files to scan.
  29 #
  30 #               It outputs all declarations found to a file named
  31 #               '$MODULE-decl.txt', and the list of decarations to another
  32 #               file '$MODULE-decl-list.txt'.
  33 #
  34 #               This second list file is typically copied to
  35 #               '$MODULE-sections.txt' and organized into sections ready to
  36 #               output the SGML pages.
  37 #############################################################################
  38
  39 use strict;
  40 use Getopt::Long;
  41 use Cwd qw(realpath);
  42
  43 push @INC, '@PACKAGE_DATA_DIR@';
  44 require "gtkdoc-common.pl";
  45
  46 # Options
  47
  48 # name of documentation module
  49 my $MODULE;
  50 my $OUTPUT_DIR;
  51 my @SOURCE_DIRS;
  52 my $IGNORE_HEADERS = "";
  53 my $REBUILD_TYPES;
  54 my $REBUILD_SECTIONS;
  55 my $PRINT_VERSION;
  56 my $PRINT_HELP;
  57 # regexp matching cpp symbols which surround deprecated stuff
  58 # e.g. 'GTK_ENABLE_BROKEN|GTK_DISABLE_DEPRECATED'
  59 # these are detected if they are used as #if FOO, #ifndef FOO, or #ifdef FOO
  60 my $DEPRECATED_GUARDS;
  61 # regexp matching decorators that should be ignored
  62 my $IGNORE_DECORATORS;
  63
  64 my %optctl = (module => \$MODULE,
  65               'source-dir' => \@SOURCE_DIRS,
  66               'ignore-headers' => \$IGNORE_HEADERS,
  67               'output-dir' => \$OUTPUT_DIR,
  68               'rebuild-types' => \$REBUILD_TYPES,
  69               'rebuild-sections' => \$REBUILD_SECTIONS,
  70               'version' => \$PRINT_VERSION,
  71               'help' => \$PRINT_HELP,
  72               'deprecated-guards' => \$DEPRECATED_GUARDS,
  73               'ignore-decorators' => \$IGNORE_DECORATORS);
  74 GetOptions(\%optctl, "module=s", "source-dir:s", "ignore-headers:s",
  75            "output-dir:s", "rebuild-types", "rebuild-sections", "version",
  76            "help", "deprecated-guards:s", "ignore-decorators:s");
  77
  78 if ($PRINT_VERSION) {
  79     print "@VERSION@\n";
  80     exit 0;
  81 }
  82
  83 if (!$MODULE) {
  84     $PRINT_HELP = 1;
  85 }
  86
  87 if ($PRINT_HELP) {
  88     print <<EOF;
  89 gtkdoc-scan version @VERSION@ - scan header files for public symbols
  90
  91 --module=MODULE_NAME       Name of the doc module being parsed
  92 --source-dir=DIRNAME       Directories containing the source files to scan
  93 --ignore-headers=FILES     A space-separated list of header files not to scan
  94 --output-dir=DIRNAME       The directory where the results are stored
  95 --deprecated-guards=GUARDS A |-separated list of symbols used as deprecation
  96                            guards
  97 --ignore-decorators=DECS   A |-separated list of addition decorators in
  98                            declarations that should be ignored
  99 --rebuild-sections         Rebuild (overwrite) the MODULE-sections.txt file
 100 --rebuild-types            Automatically recreate the MODULE.types file using
 101                            all the *_get_type() functions found
 102 --version                  Print the version of this program
 103 --help                     Print this help
 104 EOF
 105     exit 0;
 106 }
 107
 108 $DEPRECATED_GUARDS = $DEPRECATED_GUARDS ? $DEPRECATED_GUARDS : "does_not_match_any_cpp_symbols_at_all_nope";
 109
 110 $IGNORE_DECORATORS = $IGNORE_DECORATORS || "(?=no)match";
 111
 112 $OUTPUT_DIR = $OUTPUT_DIR ? $OUTPUT_DIR : ".";
 113
 114 if (!-d ${OUTPUT_DIR}) {
 115     mkdir($OUTPUT_DIR, 0755) || die "Cannot create $OUTPUT_DIR: $!";
 116 }
 117
 118 my $old_decl_list = "${OUTPUT_DIR}/$MODULE-decl-list.txt";
 119 my $new_decl_list = "${OUTPUT_DIR}/$MODULE-decl-list.new";
 120 my $old_decl = "${OUTPUT_DIR}/$MODULE-decl.txt";
 121 my $new_decl = "${OUTPUT_DIR}/$MODULE-decl.new";
 122 my $old_types = "${OUTPUT_DIR}/$MODULE.types";
 123 my $new_types = "${OUTPUT_DIR}/$MODULE.types.new";
 124 my $sections_file = "${OUTPUT_DIR}/$MODULE-sections.txt";
 125
 126 # If this is the very first run then we create the .types file automatically.
 127 if (! -e $sections_file && ! -e $old_types) {
 128     $REBUILD_TYPES = 1;
 129 }
 130
 131 open (DECLLIST, ">$new_decl_list")
 132     || die "Can't open $new_decl_list";
 133 open (DECL, ">$new_decl")
 134     || die "Can't open $new_decl";
 135 if ($REBUILD_TYPES) {
 136     open (TYPES, ">$new_types")
 137         || die "Can't open $new_types";
 138 }
 139
 140 my $main_list = "";
 141 my $object_list = "";
 142 my $file;
 143
 144 my @get_types = ();
 145
 146
 147 # do not read files twice; checking it here permits to give both srcdir and
 148 # builddir as --source-dir without fear of duplicities
 149 my %seen_headers;
 150
 151 # The header files to scan are passed in as command-line args.
 152 for $file (@ARGV) {
 153     &ScanHeader ($file, \$object_list, \$main_list);
 154 }
 155
 156 for my $dir (@SOURCE_DIRS) {
 157     &ScanHeaders ($dir, \$object_list, \$main_list);
 158 }
 159
 160 print DECLLIST $object_list, $main_list;
 161 close (DECLLIST);
 162 close (DECL);
 163 if ($REBUILD_TYPES) {
 164     my $func;
 165
 166     foreach $func (sort(@get_types)) {
 167        print TYPES "$func\n";
 168     }
 169     close (TYPES);
 170 }
 171
 172 &UpdateFileIfChanged ($old_decl_list, $new_decl_list, 1);
 173 &UpdateFileIfChanged ($old_decl, $new_decl, 1);
 174 &UpdateFileIfChanged ($old_types, $new_types, 1) if ($REBUILD_TYPES);
 175
 176 # If there is no MODULE-sections.txt file yet or we are asked to rebuild it,
 177 # we copy the MODULE-decl-list.txt file into its place. The user can tweak it
 178 # later if they want.
 179 if ($REBUILD_SECTIONS || ! -e $sections_file) {
 180   `cp $old_decl_list $sections_file`;
 181 }
 182
 183 # If there is no MODULE-overrides.txt file we create an empty one.
 184 # FIXME: why?
 185 #my $overrides_file = "${OUTPUT_DIR}/$MODULE-overrides.txt";
 186 #if (! -e $overrides_file) {
 187 #  `touch $overrides_file`;
 188 #}
 189
 190
 191
 192 #############################################################################
 193 # Function    : ScanHeaders
 194 # Description : This scans a directory tree looking for header files.
 195 #
 196 # Arguments   : $source_dir - the directory to scan.
 197 #               $object_list - a reference to the list of object functions &
 198 #                       declarations.
 199 #               $main_list - a reference to the list of other declarations.
 200 #############################################################################
 201
 202 sub ScanHeaders {
 203     my ($source_dir, $object_list, $main_list) = @_;
 204     #print "Scanning source directory: $source_dir\n";
 205
 206     # This array holds any subdirectories found.
 207     my (@subdirs) = ();
 208
 209     opendir (SRCDIR, $source_dir)
 210         || die "Can't open source directory $source_dir: $!";
 211     my $file;
 212     foreach $file (readdir (SRCDIR)) {
 213         if ($file eq '.' || $file eq '..' || $file =~ /^\./) {
 214             next;
 215         } elsif (-d "$source_dir/$file") {
 216             push (@subdirs, $file);
 217         } elsif ($file =~ m/\.h$/) {
 218             &ScanHeader ("$source_dir/$file", $object_list, $main_list);
 219         }
 220     }
 221     closedir (SRCDIR);
 222
 223     # Now recursively scan the subdirectories.
 224     my $dir;
 225     foreach $dir (@subdirs) {
 226         next if ($IGNORE_HEADERS =~ m/(\s|^)\Q${dir}\E(\s|$)/);
 227         &ScanHeaders ("$source_dir/$dir", $object_list, $main_list);
 228     }
 229 }
 230
 231
 232 #############################################################################
 233 # Function    : ScanHeader
 234 # Description : This scans a header file, looking for declarations of
 235 #               functions, macros, typedefs, structs and unions, which it
 236 #               outputs to the DECL file.
 237 # Arguments   : $input_file - the header file to scan.
 238 #               $object_list - a reference to the list of object functions &
 239 #                       declarations.
 240 #               $main_list - a reference to the list of other declarations.
 241 # Returns     : it adds declarations to the appropriate list.
 242 #############################################################################
 243
 244 sub ScanHeader {
 245     my ($input_file, $object_list, $main_list) = @_;
 246
 247     my $list = "";                # Holds the resulting list of declarations.
 248     my ($in_comment) = 0;                 # True if we are in a comment.
 249     my ($in_declaration) = "";    # The type of declaration we are in, e.g.
 250                                   #   'function' or 'macro'.
 251     my ($skip_block) = 0;                 # True if we should skip a block.
 252     my ($symbol);                 # The current symbol being declared.
 253     my ($decl);                   # Holds the declaration of the current symbol.
 254     my ($ret_type);               # For functions and function typedefs this
 255                                   #   holds the function's return type.
 256     my ($pre_previous_line) = "";   # The pre-previous line read in - some Gnome
 257                                   #   functions have the return type on one
 258                                   #   line, the function name on the next,
 259                                   #   and the rest of the declaration after.
 260     my ($previous_line) = "";     # The previous line read in - some Gnome
 261                                   #   functions have the return type on one line
 262                                   #   and the rest of the declaration after.
 263     my ($first_macro) = 1;        # Used to try to skip the standard #ifdef XXX
 264                                   #   #define XXX at the start of headers.
 265     my ($level);                          # Used to handle structs/unions which contain
 266                                   #   nested structs or unions.
 267     my @objects = ();             # Holds declarations that look like GtkObject
 268                                   #   subclasses, which we remove from the list.
 269
 270     my $file_basename;
 271
 272     my $deprecated_conditional_nest = 0;
 273
 274     my $deprecated = "";
 275
 276     # Don't scan headers twice
 277     my $canonical_input_file = realpath $input_file;
 278     return if exists $seen_headers{$canonical_input_file};
 279     $seen_headers{$canonical_input_file} = 1;
 280
 281     if ($input_file =~ m/^.*[\/\\](.*)\.h+$/) {
 282         $file_basename = $1;
 283     } else {
 284         print "WARNING: Can't find basename of file $input_file\n";
 285         $file_basename = $input_file;
 286     }
 287
 288     # Check if the basename is in the list of headers to ignore.
 289     if ($IGNORE_HEADERS =~ m/(\s|^)\Q${file_basename}\E\.h(\s|$)/) {
 290         #print "DEBUG: File ignored: $input_file\n";
 291         return;
 292     }
 293
 294     if (! -f $input_file) {
 295         print "WARNING: File doesn't exist: $input_file\n";
 296         return;
 297     }
 298
 299     #print "DEBUG: Scanning $input_file\n";
 300
 301     open(INPUT, $input_file)
 302         || die "Can't open $input_file: $!";
 303     while(<INPUT>) {
 304         # If this is a private header, skip it.
 305         if (m%^\s*/\*\s*<\s*private_header\s*>\s*\*/%) {
 306             close(INPUT);
 307             return;
 308         }
 309
 310         # Skip to the end of the current comment.
 311         if ($in_comment) {
 312             #print "Comment: $_";
 313             if (m%\*/%) {
 314                 $in_comment = 0;
 315             }
 316             next;
 317         }
 318         # Skip complete blocks, needed fo inline macros
 319         if ($skip_block==1) {
 320             if (m%{%) {
 321                 $skip_block=2;
 322             }
 323             next;
 324         } elsif ($skip_block==2) {
 325             if (m%}%) {
 326                 $skip_block=0;
 327             }
 328             next;
 329         }
 330
 331         # Keep a count of #if, #ifdef, #ifndef nesting,
 332         # and if we enter a deprecation-symbol-bracketed
 333         # zone, take note.
 334         if (m/^\s*#\s*if(?:n?def\b|\s+!?\s*defined\s*\()\s*(\w+)/) {
 335             if ($deprecated_conditional_nest == 0 and $1 =~ /$DEPRECATED_GUARDS/) {
 336                  $deprecated_conditional_nest = 1;
 337             } elsif ($deprecated_conditional_nest > 0) {
 338                  $deprecated_conditional_nest += 1;
 339             }
 340         } elsif (m/^\s*#\sif/) {
 341             if ($deprecated_conditional_nest > 0) {
 342                  $deprecated_conditional_nest += 1;
 343             }
 344         } elsif (m/^\s*#endif/) {
 345             if ($deprecated_conditional_nest > 0) {
 346                 $deprecated_conditional_nest -= 1;
 347             }
 348         }
 349
 350         # set global that affects AddSymbolToList
 351         if ($deprecated_conditional_nest > 0) {
 352             $deprecated = "<DEPRECATED/>\n";
 353         } else {
 354             $deprecated = "";
 355         }
 356
 357         if (!$in_declaration) {
 358             # Skip top-level comments.
 359             if (s%^\s*/\*%%) {
 360                 if (m%\*/%) {
 361                     #print "Found one-line comment: $_";
 362                 } else {
 363                     $in_comment = 1;
 364                     #print "Found start of comment: $_";
 365                 }
 366                 next;
 367             }
 368
 369             #print "0: $_";
 370
 371             # MACROS
 372
 373             if (m/^\s*#\s*define\s+(\w+)/) {
 374                 $symbol = $1;
 375                 # We assume all macros which start with '_' are private, but
 376                 # we accept '_' itself which is the standard gettext macro.
 377                 # We also try to skip the first macro if it looks like the
 378                 # standard #ifndef HEADER_FILE #define HEADER_FILE etc.
 379                 # And we only want TRUE & FALSE defined in GLib (libdefs.h in
 380                 # libgnome also defines them if they are not already defined).
 381                 if (($symbol !~ m/^_/
 382                      && ($previous_line !~ m/#ifndef\s+$symbol/
 383                          || $first_macro == 0)
 384                      && (($symbol ne 'TRUE' && $symbol ne 'FALSE')
 385                          || $MODULE eq 'glib'))
 386                     || $symbol eq "_") {
 387                     $decl = $_;
 388                     $in_declaration = "macro";
 389                 }
 390                 $first_macro = 0;
 391                 #print "DEBUG: Macro: $symbol\n";
 392
 393
 394             # TYPEDEF'D FUNCTIONS (i.e. user functions)
 395
 396             #                        $1                                $3            $4             $5
 397             } elsif (m/^\s*typedef\s+((const\s+|G_CONST_RETURN\s+)?\w+)(\s+const)?\s*(\**)\s*\(\*\s*(\w+)\)\s*\(/) {
 398                 my $p3 = defined($3) ? $3 : "";
 399                 $ret_type = "$1$p3 $4";
 400                 $symbol = $5;
 401                 $decl = $';
 402                 $in_declaration = "user_function";
 403                 #print "DEBUG: user function: $symbol\n";
 404
 405
 406             # ENUMS
 407
 408             } elsif (s/^\s*enum\s+_(\w+)\s+\{/enum $1 {/) {
 409                 # We assume that 'enum _<enum_name> {' is really the
 410                 # declaration of enum <enum_name>.
 411                 $symbol = $1;
 412                 #print "DEBUG: plain enum: $symbol\n";
 413                 $decl = $_;
 414                 $in_declaration = "enum";
 415
 416             } elsif (m/^\s*typedef\s+enum\s+_?(\w+)\s+\1\s*;/) {
 417                 # We skip 'typedef enum <enum_name> _<enum_name>;' as the enum will
 418                 # be declared elsewhere.
 419                 #print "DEBUG: skipping enum typedef: $1\n";
 420
 421             } elsif (m/^\s*typedef\s+enum/) {
 422                 $symbol = "";
 423                 #print "DEBUG: typedef enum: -\n";
 424                 $decl = $_;
 425                 $in_declaration = "enum";
 426
 427
 428             # STRUCTS AND UNIONS
 429
 430             } elsif (m/^\s*typedef\s+(struct|union)\s+_(\w+)\s+\2\s*;/) {
 431                 # We've found a 'typedef struct _<name> <name>;'
 432                 # This could be an opaque data structure, so we output an
 433                 # empty declaration. If the structure is actually found that
 434                 # will override this.
 435                 my $structsym = uc $1;
 436                 #print "DEBUG: $structsym typedef: $2\n";
 437                 &AddSymbolToList (\$list, $2);
 438                 print DECL "<$structsym>\n<NAME>$2</NAME>\n$deprecated</$structsym>\n";
 439
 440             } elsif (m/^\s*(?:struct|union)\s+_(\w+)\s*;/) {
 441                 # Skip private structs/unions.
 442                 #print "DEBUG: private struct/union\n";
 443
 444             } elsif (m/^\s*(struct|union)\s+(\w+)\s*;/) {
 445                 # Do a similar thing for normal structs as for typedefs above.
 446                 # But we output the declaration as well in this case, so we
 447                 # can differentiate it from a typedef.
 448                 my $structsym = uc $1;
 449                 #print "DEBUG: $structsym: $2\n";
 450                 &AddSymbolToList (\$list, $2);
 451                 print DECL "<$structsym>\n<NAME>$2</NAME>\n$_$deprecated</$structsym>\n";
 452
 453             } elsif (m/^\s*typedef\s+(struct|union)\s*\w*\s*{/) {
 454                 $symbol = "";
 455                 $decl = $_;
 456                 $level = 0;
 457                 $in_declaration = $1;
 458                 #print "DEBUG: $1\n";
 459
 460             # OTHER TYPEDEFS
 461
 462             } elsif (m/^\s*typedef\s+(?:struct|union)\s+\w+[\s\*]+(\w+)\s*;/) {
 463                 #print "DEBUG: Found struct/union(*) typedef $1: $_";
 464                 &AddSymbolToList (\$list, $1);
 465                 print DECL "<TYPEDEF>\n<NAME>$1</NAME>\n$deprecated$_</TYPEDEF>\n";
 466
 467             } elsif (m/^\s*(G_GNUC_EXTENSION\s+)?typedef\s+(.+[\s\*])(\w+)(\s*\[[^\]]+\])*\s*;/) {
 468                 if ($2 !~ m/^struct\s/ && $2 !~ m/^union\s/) {
 469                     #print "DEBUG: Found typedef: $_";
 470                     &AddSymbolToList (\$list, $3);
 471                     print DECL "<TYPEDEF>\n<NAME>$3</NAME>\n$deprecated$_</TYPEDEF>\n";
 472                 }
 473             } elsif (m/^\s*typedef\s+/) {
 474                 #print "DEBUG: Skipping typedef: $_";
 475
 476
 477             # VARIABLES (extern'ed variables)
 478
 479             } elsif (m/^\s*(extern|[A-Za-z_]+VAR)\s+((const\s+|unsigned\s+)*\w+)(\s+\*+|\*+|\s)\s*([A-Za-z]\w*)\s*;/) {
 480                 $symbol = $5;
 481                 s/^\s*([A-Za-z_]+VAR)\b/extern/;
 482                 #print "DEBUG: Possible extern: $_";
 483                 &AddSymbolToList (\$list, $symbol);
 484                 print DECL "<VARIABLE>\n<NAME>$symbol</NAME>\n$deprecated$_</VARIABLE>\n";
 485
 486
 487             # FUNCTIONS
 488
 489             # We assume that functions which start with '_' are private, so
 490             # we skip them.
 491             #                                                                        $1                                                                                                                                                           $2
 492             } elsif (m/^\s*(?:\b(?:extern|G_INLINE_FUNC|${IGNORE_DECORATORS})\b\s*)*((?:const\s+|G_CONST_RETURN\s+|unsigned\s+|long\s+|short\s+|struct\s+|union\s+|enum\s+)*\w+(?:\**\s+\**(?:const|G_CONST_RETURN))?(?:\s+|\s*\*+))\s*\(\s*\*+\s*([A-Za-z]\w*)\s*\)\s*\(/o) {
 493                 $ret_type = $1;
 494                 $symbol = $2;
 495                 $decl = $';
 496                 #print "DEBUG: internal Function: $symbol, Returns: $ret_type\n";
 497                 $in_declaration = "function";
 498
 499             #                                                                        $1                                                                                                                                                $2
 500             } elsif (m/^\s*(?:\b(?:extern|G_INLINE_FUNC|${IGNORE_DECORATORS})\b\s*)*((?:const\s+|G_CONST_RETURN\s+|unsigned\s+|long\s+|short\s+|struct\s+|union\s+|enum\s+)*\w+(?:\**\s+\**(?:const|G_CONST_RETURN))?(?:\s+|\s*\*+))\s*([A-Za-z]\w*)\s*\(/o) {
 501                 $ret_type = $1;
 502                 $symbol = $2;
 503                 $decl = $';
 504                 #print "DEBUG: Function: $symbol, Returns: $ret_type\n";
 505                 $in_declaration = "function";
 506
 507             # Try to catch function declarations which have the return type on
 508             # the previous line. But we don't want to catch complete functions
 509             # which have been declared G_INLINE_FUNC, e.g. g_bit_nth_lsf in
 510             # glib, or 'static inline' functions.
 511             } elsif (m/^\s*([A-Za-z]\w*)\s*\(/) {
 512                 $symbol = $1;
 513                 $decl = $';
 514
 515                 if ($previous_line !~ m/^\s*G_INLINE_FUNC/) {
 516                     if ($previous_line !~ m/^\s*static\s+/) {
 517                         #                                                                       $1                                                                         $2
 518                         if ($previous_line =~ m/^\s*(?:\b(?:extern|${IGNORE_DECORATORS})\b\s*)*((?:const\s+|G_CONST_RETURN\s+|unsigned\s+|struct\s+|union\s+|enum\s+)?\w+)((?:\s*(?:\*+|\bconst\b|\bG_CONST_RETURN\b))*)\s*$/o) {
 519                             $ret_type = $1;
 520                             if (defined ($2)) { $ret_type .= " $2"; }
 521                             #print "DEBUG: Function: $symbol, Returns: $ret_type\n";
 522                             $in_declaration = "function";
 523                         }
 524                     }
 525                 }
 526                 else {
 527                     if ($previous_line !~ m/^\s*static\s+/) {
 528                         #print "DEBUG: skip block after inline function\n";
 529                         # now we we need to skip a whole { } block
 530                         $skip_block = 1;
 531                         #                                                                       $1                                                                         $2
 532                         if ($previous_line =~ m/^\s*(?:\b(?:extern|G_INLINE_FUNC|${IGNORE_DECORATORS})\b\s*)*((?:const\s+|G_CONST_RETURN\s+|unsigned\s+|struct\s+|union\s+|enum\s+)?\w+)((?:\s*(?:\*+|\bconst\b|\bG_CONST_RETURN\b))*)\s*$/o) {
 533                             $ret_type = $1;
 534                             if (defined ($2)) { $ret_type .= " $2"; }
 535                             #print "DEBUG: Function: $symbol, Returns: $ret_type\n";
 536                             $in_declaration = "function";
 537                             # this is a hack to detect the end of declaration
 538                             $decl.=";"
 539                         }
 540                     }
 541                 }
 542
 543             # Try to catch function declarations with the return type and name
 544             # on the previous line(s), and the start of the parameters on this.
 545             } elsif (m/^\s*\(/) {
 546                 $decl = $';
 547                 if ($previous_line =~ m/^\s*(?:\b(?:extern|G_INLINE_FUNC|${IGNORE_DECORATORS})\b\s*)*((?:const\s+|G_CONST_RETURN\s+|unsigned\s+|enum\s+)*\w+)(\s+\*+|\*+|\s)\s*([A-Za-z]\w*)\s*$/o) {
 548                     $ret_type = "$1 $2";
 549                     $symbol = $3;
 550                     #print "DEBUG: Function: $symbol, Returns: $ret_type\n";
 551                     $in_declaration = "function";
 552
 553                 } elsif ($previous_line =~ m/^\s*\w+\s*$/
 554                          && $pre_previous_line =~ m/^\s*(?:\b(?:extern|G_INLINE_FUNC|${IGNORE_DECORATORS})\b\s*)*((?:const\s+|G_CONST_RETURN\s+|unsigned\s+|struct\s+|union\s+|enum\s+)*\w+(?:\**\s+\**(?:const|G_CONST_RETURN))?(?:\s+|\s*\*+))\s*$/o) {
 555                     $ret_type = $1;
 556                     $ret_type =~ s/\s*\n//;
 557                     $in_declaration = "function";
 558
 559                     $symbol = $previous_line;
 560                     $symbol =~ s/^\s+//;
 561                     $symbol =~ s/\s*\n//;
 562                     #print "DEBUG: Function: $symbol, Returns: $ret_type\n";
 563                 }
 564
 565             #} elsif (m/^extern\s+/) {
 566                 #print "DEBUG: Skipping extern: $_";
 567
 568
 569             # STRUCTS
 570
 571             } elsif (m/^\s*struct\s+_(\w+)\s*\*/) {
 572                 # Skip 'struct _<struct_name> *', since it could be a
 573                 # return type on its own line.
 574
 575             } elsif (m/^\s*struct\s+_(\w+)/) {
 576                 # We assume that 'struct _<struct_name>' is really the
 577                 # declaration of struct <struct_name>.
 578                 $symbol = $1;
 579                 $decl = $_;
 580                 # we will find the correct level as below we do $level += tr/{//;
 581                 $level = 0;
 582                 $in_declaration = "struct";
 583                 #print "DEBUG: Struct(_): $symbol\n";
 584
 585
 586             # UNIONS
 587
 588             } elsif (m/^\s*union\s+_(\w+)\s*\*/) {
 589                 # Skip 'union _<union_name> *' (see above)
 590             } elsif (m/^\s*union\s+_(\w+)/) {
 591                 $symbol = $1;
 592                 $decl = $_;
 593                 $level = 0;
 594                 $in_declaration = "union";
 595                 #print "DEBUG: Union(_): $symbol\n";
 596             }
 597
 598         } else {
 599             #print "1: $_";
 600             # If we were already in the middle of a declaration, we simply add
 601             # the current line onto the end of it.
 602             $decl .= $_;
 603         }
 604
 605         #if ($in_declaration ne '') {
 606         #    print "$in_declaration = $decl\n";
 607         #}
 608
 609         # Note that sometimes functions end in ') G_GNUC_PRINTF (2, 3);' or
 610         # ') __attribute__ (...);'.
 611         if ($in_declaration eq 'function') {
 612             if ($decl =~ s/\)\s*(G_GNUC_.*|${IGNORE_DECORATORS}\s*|__attribute__\s*\(.*\)\s*)?;.*$//) {
 613                 $decl =~ s%/\*.*?\*/%%gs;       # remove comments.
 614                 #$decl =~ s/^\s+//;             # remove leading whitespace.
 615                 #$decl =~ s/\s+$//;             # remove trailing whitespace.
 616                 $decl =~ s/\s*\n\s*/ /gs;               # consolidate whitespace at start
 617                                                 # and end of lines.
 618                 $ret_type =~ s%/\*.*?\*/%%g;    # remove comments in ret type.
 619                 &AddSymbolToList (\$list, $symbol);
 620                 print DECL "<FUNCTION>\n<NAME>$symbol</NAME>\n$deprecated<RETURNS>$ret_type</RETURNS>\n$decl\n</FUNCTION>\n";
 621                 if ($REBUILD_TYPES) {
 622                     # check if this looks like a get_type function and if so remember
 623                     if (($symbol =~ m/_get_type$/) && ($ret_type =~ m/GType/) && ($decl =~ m/(void|)/)) {
 624                         #print "Adding get-type: [$ret_type] [$symbol] [$decl]\tfrom $input_file\n";
 625                         push (@get_types, $symbol);
 626                     }
 627                 }
 628                 $in_declaration = "";
 629             }
 630         }
 631
 632         if ($in_declaration eq 'user_function') {
 633             if ($decl =~ s/\).*$//) {
 634                 &AddSymbolToList (\$list, $symbol);
 635                 print DECL "<USER_FUNCTION>\n<NAME>$symbol</NAME>\n$deprecated<RETURNS>$ret_type</RETURNS>\n$decl</USER_FUNCTION>\n";
 636                 $in_declaration = "";
 637             }
 638         }
 639
 640         if ($in_declaration eq 'macro') {
 641             if ($decl !~ m/\\\s*$/) {
 642                 &AddSymbolToList (\$list, $symbol);
 643                 print DECL "<MACRO>\n<NAME>$symbol</NAME>\n$deprecated$decl</MACRO>\n";
 644                 $in_declaration = "";
 645             }
 646         }
 647
 648         if ($in_declaration eq 'enum') {
 649             if ($decl =~ m/\}\s*(\w+)?;\s*$/) {
 650                 if ($symbol eq "") {
 651                     $symbol = $1;
 652                 }
 653                 &AddSymbolToList (\$list, $symbol);
 654                 print DECL "<ENUM>\n<NAME>$symbol</NAME>\n$deprecated$decl</ENUM>\n";
 655                 $in_declaration = "";
 656             }
 657         }
 658
 659         # We try to handle nested stucts/unions, but unmatched brackets in
 660         # comments will cause problems.
 661         if ($in_declaration eq 'struct' or $in_declaration eq 'union') {
 662             if ($level <= 1 && $decl =~ m/\}\s*(\w*);\s*$/) {
 663                 if ($symbol eq "") {
 664                     $symbol = $1;
 665                 }
 666
 667                 if ($symbol =~ m/^(\S+)(Class|Iface|Interface)\b/) {
 668                     #print "Found object: $1\n";
 669                     $list .= "<TITLE>$1</TITLE>\n$1\n";
 670                     push (@objects, $1);
 671                 }
 672                 #print "Store struct: $symbol\n";
 673                 &AddSymbolToList (\$list, $symbol);
 674
 675                 my $structsym = uc $in_declaration;
 676                 print DECL "<$structsym>\n<NAME>$symbol</NAME>\n$deprecated$decl</$structsym>\n";
 677                 $in_declaration = "";
 678             } else {
 679                 # We use tr to count the brackets in the line, and adjust
 680                 # $level accordingly.
 681                 $level += tr/{//;
 682                 $level -= tr/}//;
 683                 #print "struct/union level : $level\n";
 684             }
 685         }
 686
 687         $pre_previous_line = $previous_line;
 688         $previous_line = $_;
 689     }
 690     close(INPUT);
 691
 692     #print "DEBUG: Scanning $input_file done\n\n\n";
 693
 694     # Take out any object structs from the list of declarations as we don't
 695     # want them included.
 696     my ($object);
 697     foreach $object (@objects) {
 698         $list =~ s/^$object\n//m;
 699         $list =~ s/^${object}Class\n//m;
 700         $list =~ s/^${object}Iface\n//m;
 701         $list =~ s/^${object}Interface\n//m;
 702     }
 703
 704
 705     # Try to separate the standard macros and functions, placing them at the
 706     # end of the current section, in a subsection named 'Standard'.
 707     my ($class) = "";
 708     my ($standard_decl) = "";
 709     if ($list =~ m/^\S+_IS_(\S*)_CLASS/m) {
 710         $class = $1;
 711     } elsif ($list =~ m/^\S+_IS_(\S*)/m) {
 712         $class = $1;
 713     }
 714
 715     if ($class ne "") {
 716         if ($list =~ s/^\S+_IS_$class\n//m)          { $standard_decl .= $&; }
 717         if ($list =~ s/^\S+_TYPE_$class\n//m)        { $standard_decl .= $&; }
 718         if ($list =~ s/^\S+_.*_get_type\n//m)        { $standard_decl .= $&; }
 719         if ($list =~ s/^\S+_${class}_CLASS\n//m)     { $standard_decl .= $&; }
 720         if ($list =~ s/^\S+_IS_${class}_CLASS\n//m)  { $standard_decl .= $&; }
 721         if ($list =~ s/^\S+_${class}_GET_CLASS\n//m) { $standard_decl .= $&; }
 722         if ($list =~ s/^\S+_${class}_GET_IFACE\n//m) { $standard_decl .= $&; }
 723         if ($list =~ s/^\S+_${class}_GET_INTERFACE\n//m) { $standard_decl .= $&; }
 724
 725         # We do this one last, otherwise it tends to be caught by the IS_$class macro
 726         if ($list =~ s/^\S+_$class\n//m)             { $standard_decl = $& . $standard_decl; }
 727
 728         if ($standard_decl ne "") {
 729             $list .= "<SUBSECTION Standard>\n$standard_decl";
 730         }
 731
 732         $$object_list .= "<SECTION>\n<FILE>$file_basename</FILE>\n$list</SECTION>\n\n";
 733     } else {
 734         $$main_list .= "<SECTION>\n<FILE>$file_basename</FILE>\n$list</SECTION>\n\n";
 735     }
 736 }
 737
 738
 739 #############################################################################
 740 # Function    : AddSymbolToList
 741 # Description : This adds the symbol to the list of declarations, but only if
 742 #               it is not already in the list.
 743 # Arguments   : $list - reference to the list of symbols, one on each line.
 744 #               $symbol - the symbol to add to the list.
 745 #############################################################################
 746
 747 sub AddSymbolToList {
 748     my ($list, $symbol) = @_;
 749
 750     if ($$list =~ m/\b\Q$symbol\E\b/) {
 751 #       print "Symbol $symbol already in list. skipping\n";
 752         return;
 753     }
 754     $$list .= "$symbol\n";
 755 }