gtkdoc-mktmpl.in

   1 #!@PERL@ -w
   2 # -*- cperl -*-
   3 #
   4 # gtk-doc - GTK DocBook documentation generator.
   5 # Copyright (C) 1998  Damon Chaplin
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  20 #
  21
  22 #############################################################################
  23 # Script      : gtkdoc-mktmpl
  24 # Description : This creates or updates the template files which contain the
  25 #               manually-edited documentation. (A 'template' is a simple text
  26 #               form which is filled in with the description of a function,
  27 #               macro, enum, or struct. For functions and macros it also
  28 #               contains fields for describing the parameters.)
  29 #
  30 #               This script reads in the existing templates, found in
  31 #               tmpl/*.sgml, moves these files to tmpl/*.sgml.bak, and then
  32 #               recreates the .sgml files according to the structure given in
  33 #               the file $MODULE-sections.txt.
  34 #
  35 #               Any new templates added, or new function parameters, are
  36 #               marked with 'FIXME' so you can do a grep to see which parts
  37 #               need updating.
  38 #
  39 #               Any templates which are no longer used (i.e. they are remove
  40 #               from $MODULE-sections.txt) are placed in the file
  41 #               tmpl/$MODULE-unused.sgml. If they are included again later
  42 #               they are automatically copied back into position.
  43 #               If you are certain that these templates will never be used
  44 #               again you can delete them from tmpl/$MODULE-unused.sgml.
  45 #
  46 #               Any parameters to functions which are no longer used are
  47 #               separated from the rest of the parameters with the line
  48 #               '<!-- # Unused Parameters # -->'. It may be that the parameter
  49 #               name has just been changed, in which case you can copy the
  50 #               description to the parameter with the new name. You can delete
  51 #               the unused parameter descriptions when no longer needed.
  52 #############################################################################
  53
  54 use strict;
  55 use Getopt::Long;
  56
  57 push @INC, '@PACKAGE_DATA_DIR@';
  58 require "gtkdoc-common.pl";
  59
  60 # Options
  61
  62 # name of documentation module
  63 my $MODULE;
  64 my $TMPL_DIR;
  65 my $FLAG_CHANGES;
  66 my $PRINT_VERSION;
  67 my $PRINT_HELP;
  68 my $ONLY_SECTION_TMPL;
  69
  70 my %optctl = ('module' => \$MODULE,
  71               'flag-changes' => \$FLAG_CHANGES,
  72               'output-dir' => \$TMPL_DIR,
  73               'only-section-tmpl' => \$ONLY_SECTION_TMPL,
  74               'version' => \$PRINT_VERSION,
  75               'help' => \$PRINT_HELP);
  76 GetOptions(\%optctl, "module=s", "flag-changes!", "output-dir:s", "only-section-tmpl!", "version", "help");
  77
  78 if ($PRINT_VERSION) {
  79     print "@VERSION@\n";
  80     exit 0;
  81 }
  82
  83 if (!$MODULE) {
  84     $PRINT_HELP = 1;
  85 }
  86
  87 if ($PRINT_HELP) {
  88     print <<EOF;
  89 gtkdoc-mktmpl version @VERSION@ - generate documentation templates
  90
  91 --module=MODULE_NAME Name of the doc module being parsed
  92 --flag-changes       If specified, changes in templates are flagged
  93 --output-dir=DIRNAME The directory where the results are stored
  94 --only-section-tmpl  Only include section information in templates
  95 --version            Print the version of this program
  96 --help               Print this help
  97 EOF
  98     exit 0;
  99 }
 100
 101 my $ROOT_DIR = ".";
 102
 103 # The directory containing the template files.
 104 $TMPL_DIR = $TMPL_DIR ? $TMPL_DIR : "$ROOT_DIR/tmpl";
 105
 106 # This file contains the object hierarchy.
 107 my $OBJECT_TREE_FILE = "$ROOT_DIR/$MODULE.hierarchy";
 108
 109 # The file containing signal handler prototype information.
 110 my $SIGNALS_FILE = "$ROOT_DIR/$MODULE.signals";
 111
 112 # The file containing Arg information.
 113 my $ARGS_FILE = "$ROOT_DIR/$MODULE.args";
 114
 115 # Set the flag to indicate changes, if requested.
 116 my $CHANGES_FLAG = $FLAG_CHANGES ? "FIXME" : "";
 117
 118 # These global arrays store information on signals. Each signal has an entry
 119 # in each of these arrays at the same index, like a multi-dimensional array.
 120 my @SignalObjects;      # The GtkObject which emits the signal.
 121 my @SignalNames;        # The signal name.
 122 my @SignalReturns;      # The return type.
 123 my @SignalFlags;        # Flags for the signal
 124 my @SignalPrototypes;   # The rest of the prototype of the signal handler.
 125
 126 # These global arrays store information on Args. Each Arg has an entry
 127 # in each of these arrays at the same index, like a multi-dimensional array.
 128 my @ArgObjects;         # The GtkObject which has the Arg.
 129 my @ArgNames;           # The Arg name.
 130 my @ArgTypes;           # The Arg type - gint, GtkArrowType etc.
 131 my @ArgFlags;           # How the Arg can be used - readable/writable etc.
 132
 133 # These global hashes store declaration info keyed on a symbol name.
 134 my %Declarations;
 135 my %DeclarationTypes;
 136 my %DeclarationConditional;
 137 my %DeclarationOutput;
 138
 139 # These global hashes store the existing documentation.
 140 my %SymbolDocs;
 141 my %SymbolTypes;
 142 my %SymbolParams;
 143 my %SymbolSourceFile;
 144 my %SymbolSourceLine;
 145
 146 # These global arrays store GObject and subclasses and the hierarchy.
 147 my @Objects;
 148 my @ObjectLevels;
 149
 150 &ReadSignalsFile ($SIGNALS_FILE);
 151 &ReadArgsFile ($ARGS_FILE);
 152 &ReadObjectHierarchy;
 153
 154 &ReadDeclarationsFile ("$ROOT_DIR/$MODULE-decl.txt", 0);
 155 if (-f "$ROOT_DIR/$MODULE-overrides.txt") {
 156     &ReadDeclarationsFile ("$ROOT_DIR/$MODULE-overrides.txt", 1);
 157 }
 158 &ReadExistingTemplates;
 159
 160 my $changed = 0;
 161
 162 if (&UpdateTemplates ("$ROOT_DIR/$MODULE-sections.txt")) {
 163   $changed = 1;
 164 }
 165 &OutputUnusedTemplates;
 166 if (&CheckAllDeclarationsOutput) {
 167   $changed = 1;
 168 }
 169
 170 if ($changed || ! -e "$ROOT_DIR/tmpl.stamp") {
 171     open (TIMESTAMP, ">$ROOT_DIR/tmpl.stamp")
 172         || die "Can't create $ROOT_DIR/tmpl.stamp";
 173     print (TIMESTAMP "timestamp");
 174     close (TIMESTAMP);
 175 }
 176
 177 #############################################################################
 178 # Function    : ReadExistingTemplates
 179 # Description : This reads in all the existing documentation, into the global
 180 #               variables %SymbolDocs, %SymbolTypes, and %SymbolParams (a
 181 #               hash of arrays).
 182 # Arguments   : none
 183 #############################################################################
 184
 185 sub ReadExistingTemplates {
 186     %SymbolDocs = ();
 187     %SymbolTypes = ();
 188     %SymbolParams = ();
 189
 190     # Read the unused docs first, so they get overridden by any real docs.
 191     # (though this shouldn't happen often).
 192     my $unused_doc = "$TMPL_DIR/$MODULE-unused.sgml";
 193     if (-e $unused_doc) {
 194         &ReadTemplateFile ($unused_doc, 0);
 195     }
 196
 197     while (<$TMPL_DIR/*.sgml>) {
 198 #       print "Reading $_\n";
 199         if ($_ eq $unused_doc) {
 200 #           print "skipping $unused_doc\n";
 201         } else {
 202             &ReadTemplateFile ($_, 0);
 203         }
 204     }
 205 }
 206
 207
 208 #############################################################################
 209 # Function    : UpdateTemplates
 210 # Description : This collects the output for each section of the docs, and
 211 #               outputs each file when the end of the section is found.
 212 # Arguments   : $file - the file containing the sections of the docs.
 213 #############################################################################
 214
 215 sub UpdateTemplates {
 216     my ($file) = @_;
 217 #    print "Reading: $file\n";
 218
 219     open (INPUT, $file)
 220         || die "Can't open $file";
 221
 222     # Create the top output directory if it doesn't exist.
 223     if (! -e $TMPL_DIR) {
 224         mkdir ("$TMPL_DIR", 0777)
 225             || die "Can't create directory: $TMPL_DIR";
 226     }
 227
 228     my $filename = "";
 229     my $title = "";
 230     my $subsection = "";
 231     my $output;
 232     my $changed = 0;
 233     while (<INPUT>) {
 234         if (m/^#/) {
 235             next;
 236
 237         } elsif (m/^<SECTION>/) {
 238             $output = "";
 239
 240         } elsif (m/^<SUBSECTION\s*(.*)>/i) {
 241             $subsection = $1;
 242             next;
 243
 244         } elsif (m/^<TITLE>(.*)<\/TITLE>/) {
 245             $title = $1;
 246 #           print "Section: $title\n";
 247
 248         } elsif (m/^<FILE>(.*)<\/FILE>/) {
 249             $filename = $1;
 250
 251         } elsif (m/^<INCLUDE>(.*)<\/INCLUDE>/) {
 252             next;
 253
 254         } elsif (m/^<\/SECTION>/) {
 255             if ($title eq "") {
 256                 $title = $filename;
 257             }
 258 #           print "End of section: $title\n";
 259
 260             $filename =~ s/\s/_/g;
 261             $filename .= ".sgml";
 262
 263             if (&OutputTemplateFile ($filename, $title, \$output)) {
 264               $changed = 1;
 265             }
 266
 267             $title = "";
 268             $subsection = "";
 269
 270         } elsif (m/^(\S+)/) {
 271             my $symbol = $1;
 272 #           print "  Symbol: $symbol\n";
 273
 274             my $declaration = $Declarations{$1};
 275             if (defined ($declaration)) {
 276                 # We don't want templates for standard macros/functions of
 277                 # GObjects or private declarations.
 278                 if ($subsection ne "Standard" && $subsection ne "Private") {
 279                     $output .= &OutputDeclaration ($DeclarationTypes {$symbol},
 280                                                    $symbol, $declaration);
 281
 282                     $output .= &OutputSignalTemplates ($symbol);
 283                     $output .= &OutputArgTemplates ($symbol);
 284                 }
 285
 286                 # Note that the declaration has been output.
 287                 $DeclarationOutput{$symbol} = 1;
 288
 289                 if ($declaration eq '##conditional##') {
 290 #                   print "Conditional $DeclarationTypes{$symbol}\n";
 291                 }
 292
 293             } else {
 294                 &LogWarning ($file, $., "No declaration found for: $1");
 295             }
 296         }
 297     }
 298     close (INPUT);
 299
 300     return $changed;
 301 }
 302
 303
 304 #############################################################################
 305 # Function    : CheckAllDeclarationsOutput
 306 # Description : This steps through all the declarations that were loaded, and
 307 #               makes sure that each one has been output, by checking the
 308 #               corresponding flag in the %DeclarationOutput hash. It is
 309 #               intended to check that any new declarations in new versions
 310 #               of the module get added to the $MODULE-sections.txt file.
 311 # Arguments   : none
 312 #############################################################################
 313
 314 sub CheckAllDeclarationsOutput {
 315     my $num_unused = 0;
 316
 317     my $old_unused_file = "$ROOT_DIR/$MODULE-unused.txt";
 318     my $new_unused_file = "$ROOT_DIR/$MODULE-unused.new";
 319
 320     open (UNUSED, ">$new_unused_file")
 321         || die "Can't open $new_unused_file";
 322     my ($symbol);
 323     foreach $symbol (sort keys (%Declarations)) {
 324         if (!defined ($DeclarationOutput{$symbol})) {
 325             print (UNUSED "$symbol\n");
 326             $num_unused++;
 327         }
 328     }
 329     close (UNUSED);
 330     if ($num_unused != 0) {
 331         &LogWarning ($old_unused_file, 1, "$num_unused unused declarations.".
 332             "They should be added to $MODULE-sections.txt in the appropriate place.");
 333     }
 334
 335     return &UpdateFileIfChanged ($old_unused_file, $new_unused_file, 0);
 336 }
 337
 338
 339 #############################################################################
 340 # Function    : OutputDeclaration
 341 # Description : This returns the template for one symbol & declaration.
 342 #               Note that it uses the global %SymbolDocs and %SymbolParams to
 343 #               lookup any existing documentation.
 344 # Arguments   : $type - the type of the symbol ('FUNCTION'/'MACRO' etc.)
 345 #               $symbol - the symbol name.
 346 #               $declaration - the declaration of the symbol.
 347 #############################################################################
 348
 349 sub OutputDeclaration {
 350     my ($type, $symbol, $declaration) = @_;
 351     my ($output) = "";
 352
 353     #print "Outputting $type: $symbol\n";
 354
 355     # See if symbol already has a description.
 356     my ($symbol_desc) = $SymbolDocs{$symbol};
 357     my ($template_exists);
 358     if (defined ($symbol_desc)) {
 359         $template_exists = 1;
 360         $symbol_desc =~ s/\s+$//;
 361     } else {
 362         $template_exists = 0;
 363         $symbol_desc = "<para>\n$CHANGES_FLAG\n</para>";
 364     }
 365
 366     $output .= <<EOF;
 367 <!-- ##### $type $symbol ##### -->
 368 $symbol_desc
 369
 370 EOF
 371
 372     # For functions, function typedefs and macros, we output the arguments.
 373     # For functions and function typedefs we also output the return value.
 374     if ($type eq "FUNCTION" || $type eq "USER_FUNCTION") {
 375         # Take out the return type
 376         $declaration =~ s/<RETURNS>\s*((const\s+|G_CONST_RETURN\s+|unsigned\s+|struct\s+|enum\s+)*)(\w+)\s*(\**\s*(const|G_CONST_RETURN)?\s*\**\s*(restrict)?\s*)<\/RETURNS>\n//;
 377         my $ret_type_modifier = defined($1) ? $1 : "";
 378         my $ret_type = $3;
 379         my $ret_type_pointer = $4;
 380
 381         my @fields = ParseFunctionDeclaration($declaration);
 382
 383         for (my $i = 0; $i <= $#fields; $i += 2) {
 384             my $field_name = $fields[$i];
 385             $output .= &OutputParam ($symbol, $field_name, $template_exists, 1, "");
 386         }
 387
 388         if ($ret_type ne "void" || $ret_type_modifier || $ret_type_pointer) {
 389             $output .= &OutputParam ($symbol, "Returns", $template_exists, 1, "");
 390         }
 391
 392         $output .= &OutputParam ($symbol, "Deprecated", $template_exists, 0, "");
 393         $output .= &OutputParam ($symbol, "Since", $template_exists, 0, "");
 394         $output .= &OutputParam ($symbol, "Stability", $template_exists, 0, "");
 395         $output .= &OutputOldParams ($symbol);
 396         $output .= "\n";
 397     }
 398
 399     if ($type eq "MACRO") {
 400         my @fields = ParseMacroDeclaration($declaration);
 401
 402         for (my $i = 0; $i <= $#fields; $i +=2) {
 403             my $field_name = $fields[$i];
 404
 405             $output .= &OutputParam ($symbol, $field_name, $template_exists,
 406                                      1, "");
 407         }
 408         $output .= &OutputParam ($symbol, "Returns", $template_exists, 0, "");
 409         $output .= &OutputParam ($symbol, "Deprecated", $template_exists, 0, "");
 410         $output .= &OutputParam ($symbol, "Since", $template_exists, 0, "");
 411         $output .= &OutputParam ($symbol, "Stability", $template_exists, 0, "");
 412         $output .= &OutputOldParams ($symbol);
 413         $output .= "\n";
 414     }
 415
 416     if ($type eq "STRUCT") {
 417         my $is_object_struct = CheckIsObject ($symbol);
 418         my @fields = ParseStructDeclaration($declaration, $is_object_struct, 1);
 419
 420         for (my $i = 0; $i <= $#fields; $i += 2) {
 421             my $field_name = $fields[$i];
 422             $output .= &OutputParam ($symbol, $field_name, $template_exists, 1, "");
 423         }
 424         $output .= &OutputParam ($symbol, "Deprecated", $template_exists, 0, "");
 425         $output .= &OutputParam ($symbol, "Since", $template_exists, 0, "");
 426         $output .= &OutputParam ($symbol, "Stability", $template_exists, 0, "");
 427     }
 428
 429     if ($type eq "ENUM") {
 430         my @members = ParseEnumDeclaration($declaration);
 431
 432         for my $member (@members) {
 433             $output .= &OutputParam ($symbol, $member, $template_exists, 1, "");
 434         }
 435         $output .= &OutputParam ($symbol, "Deprecated", $template_exists, 0, "");
 436         $output .= &OutputParam ($symbol, "Since", $template_exists, 0, "");
 437         $output .= &OutputParam ($symbol, "Stability", $template_exists, 0, "");
 438     }
 439
 440     $output .= "\n";
 441
 442     # Remove the used docs from the hashes.
 443     if ($template_exists) {
 444         delete $SymbolDocs{$symbol};
 445         delete $SymbolParams{$symbol};
 446     }
 447
 448     return $output;
 449 }
 450
 451
 452 #############################################################################
 453 # Function    : OutputParam
 454 # Description : This outputs the part of a template for one parameter.
 455 #               It first checks if the parameter is already described, and if
 456 #               so it uses that description, and clears it so it isn't output
 457 #               as an old param.
 458 # Arguments   : $symbol - the symbol (function or macro) name.
 459 #               $param_to_output - the parameter to add.
 460 #               $template_exists - TRUE if the template already existed in
 461 #                 template files. If it did, then we will flag any changes
 462 #                 with 'FIXME'.
 463 #               $force_output - TRUE if the parameter should be output even
 464 #                 if it didn't already exist in the template. (The return
 465 #                 values of macros are added manually if required, and so we
 466 #                 never add it here - we only copy it if it already exists.)
 467 #               $default_description - the default description of the
 468 #                 parameter to be used if it doesn't already exist. (Signal
 469 #                 handlers have a few common parameters.)
 470 #############################################################################
 471
 472 sub OutputParam {
 473     my ($symbol, $param_to_output, $template_exists,
 474         $force_output, $default_description) = @_;
 475     my ($j);
 476
 477     my ($params) = $SymbolParams{$symbol};
 478     if (defined ($params)) {
 479         for ($j = 0; $j <= $#$params; $j += 2) {
 480             my $param_name = $$params[$j];
 481             my $param_desc = $$params[$j + 1];
 482
 483             if ($param_name eq $param_to_output) {
 484                 $param_desc =~ s/\s+$//;
 485                 $$params[$j] = "";
 486                 $$params[$j + 1] = "";
 487                 return "\@$param_name: $param_desc\n";
 488             }
 489         }
 490     }
 491
 492     # If the template was already in a file, flag the new parameter.
 493     # If not, the template itself will be flagged, so we don't need to flag
 494     # all the new parameters as well.
 495     if ($force_output) {
 496         if ($default_description ne "") {
 497             $default_description =~ s/\s+$//;
 498             return "\@$param_to_output: $default_description\n";
 499         } else {
 500             if ($template_exists) {
 501                 return "\@$param_to_output: $CHANGES_FLAG\n";
 502             } else {
 503                 return "\@$param_to_output: \n";
 504             }
 505         }
 506     }
 507     return "";
 508 }
 509
 510
 511 #############################################################################
 512 # Function    : OutputOldParams
 513 # Description : This returns all the existing documentation for parameters of
 514 #               the given function/macro/signal symbol which are unused, with
 515 #               a comment before them.
 516 # Arguments   : $symbol - the symbol (function/macro/signal) name.
 517 #############################################################################
 518
 519 sub OutputOldParams {
 520     my ($symbol) = @_;
 521     my $output = "";
 522
 523     my ($params) = $SymbolParams{$symbol};
 524     if (defined ($params)) {
 525         my $j;
 526         for ($j = 0; $j <= $#$params; $j += 2) {
 527             my $param_name = $$params[$j];
 528             my $param_desc = $$params[$j + 1];
 529
 530             if ($param_name ne "") {
 531                 $param_desc =~ s/\s+$//;
 532
 533                 # There's no point keeping it if it has no docs.
 534                 if ($param_desc ne "") {
 535                   $output .= "\@$param_name: $param_desc\n";
 536                 }
 537             }
 538         }
 539     }
 540     if ($output) {
 541         $output = "<!-- # Unused Parameters # -->\n" . $output;
 542     }
 543     return $output;
 544 }
 545
 546
 547 #############################################################################
 548 # Function    : OutputTemplateFile
 549 # Description : This outputs one template file.
 550 # Arguments   : $file - the basename of the file to output.
 551 #               $title - the title from the $MODULE-sections.txt file. This
 552 #                 will be overridden by any title given in the template file.
 553 #               $output - reference to the templates to output.
 554 #############################################################################
 555
 556 sub OutputTemplateFile {
 557     my ($file, $title, $output) = @_;
 558
 559     my ($short_desc, $long_desc, $see_also, $stability, $image);
 560
 561     if (defined ($SymbolDocs{"$TMPL_DIR/$file:Title"})) {
 562         $title = $SymbolDocs{"$TMPL_DIR/$file:Title"};
 563         delete $SymbolDocs{"$TMPL_DIR/$file:Title"};
 564     }
 565     if (defined ($SymbolDocs{"$TMPL_DIR/$file:Short_Description"})) {
 566         $short_desc = $SymbolDocs{"$TMPL_DIR/$file:Short_Description"};
 567         delete $SymbolDocs{"$TMPL_DIR/$file:Short_Description"};
 568     } else {
 569         $short_desc = "";
 570     }
 571     if (defined ($SymbolDocs{"$TMPL_DIR/$file:Long_Description"})) {
 572         $long_desc = $SymbolDocs{"$TMPL_DIR/$file:Long_Description"};
 573         delete $SymbolDocs{"$TMPL_DIR/$file:Long_Description"};
 574     } else {
 575         $long_desc = "<para>\n\n</para>\n";
 576     }
 577     if (defined ($SymbolDocs{"$TMPL_DIR/$file:See_Also"})) {
 578         $see_also = $SymbolDocs{"$TMPL_DIR/$file:See_Also"};
 579         delete $SymbolDocs{"$TMPL_DIR/$file:See_Also"};
 580     } else {
 581         $see_also = "<para>\n\n</para>\n";
 582     }
 583     if (defined ($SymbolDocs{"$TMPL_DIR/$file:Stability_Level"})) {
 584         $stability = $SymbolDocs{"$TMPL_DIR/$file:Stability_Level"};
 585         delete $SymbolDocs{"$TMPL_DIR/$file:Stability_Level"};
 586     } else {
 587         $stability = "";
 588     }
 589     if (defined ($SymbolDocs{"$TMPL_DIR/$file:Image"})) {
 590         $image = $SymbolDocs{"$TMPL_DIR/$file:Image"};
 591         delete $SymbolDocs{"$TMPL_DIR/$file:Image"};
 592     } else {
 593         $image = "";
 594     }
 595
 596
 597     my $old_tmpl_file = "$TMPL_DIR/$file";
 598     my $new_tmpl_file = "$TMPL_DIR/$file.new";
 599
 600     open (OUTPUT, ">$new_tmpl_file")
 601         || die "Can't create $new_tmpl_file";
 602
 603     print (OUTPUT <<EOF);
 604 <!-- ##### SECTION Title ##### -->
 605 $title
 606
 607 <!-- ##### SECTION Short_Description ##### -->
 608 $short_desc
 609
 610 <!-- ##### SECTION Long_Description ##### -->
 611 $long_desc
 612
 613 <!-- ##### SECTION See_Also ##### -->
 614 $see_also
 615
 616 <!-- ##### SECTION Stability_Level ##### -->
 617 $stability
 618
 619 <!-- ##### SECTION Image ##### -->
 620 $image
 621
 622 EOF
 623
 624     print (OUTPUT $$output) unless $ONLY_SECTION_TMPL;
 625     close (OUTPUT);
 626
 627     return &UpdateFileIfChanged ($old_tmpl_file, $new_tmpl_file, 1);
 628 }
 629
 630
 631 #############################################################################
 632 # Function    : OutputSignalTemplates
 633 # Description : Outputs templates for signal handlers.
 634 # Arguments   : $title - the title from the $MODULE-sections.txt file. If the
 635 #                 file is describing a GtkObject subclass, the title should
 636 #                 be the name of the class, e.g. 'GtkButton'.
 637 #############################################################################
 638
 639 sub OutputSignalTemplates {
 640     my ($title) = @_;
 641
 642     my $output = "";
 643     my ($i, $template_exists);
 644     for ($i = 0; $i <= $#SignalObjects; $i++) {
 645         if ($SignalObjects[$i] eq $title) {
 646 #           print "Found signal: $SignalObjects[$i]\n";
 647             my ($symbol) = "$SignalObjects[$i]::$SignalNames[$i]";
 648
 649             # See if symbol already has a description.
 650             my ($symbol_desc) = $SymbolDocs{$symbol};
 651             if (defined ($symbol_desc)) {
 652                 $template_exists = 1;
 653                 $symbol_desc =~ s/\s+$//;
 654                 delete $SymbolDocs{$symbol};
 655             } else {
 656                 $template_exists = 0;
 657                 $symbol_desc = "<para>\n$CHANGES_FLAG\n</para>";
 658             }
 659
 660             $output .= <<EOF;
 661 <!-- ##### SIGNAL $symbol ##### -->
 662 $symbol_desc
 663
 664 EOF
 665             my $sourceparams = $SymbolParams{$symbol};
 666             my @params = split ("[,\n]", $SignalPrototypes[$i]);
 667             my ($j, $name);
 668             for ($j = 0; $j <= $#params; $j++) {
 669                 my $param = $params[$j];
 670                 $param =~ s/^\s+//;
 671                 $param =~ s/\s*$//;
 672                 if ($param =~ m/^\s*$/) { next; }
 673                 if ($param =~ m/^void$/) { next; }
 674
 675                 if ($param =~ m/^\s*(\w+)\s*(\**)\s*([\w\[\]]+)?\s*$/) {
 676                     if (defined ($sourceparams)) {
 677                         $name = $$sourceparams[2 * $j];
 678                     } else {
 679                         $name = $3;
 680                     }
 681
 682                     if (!defined ($name)) {
 683                         $name = "Param" . ($j + 1);
 684                     }
 685
 686                     if ($j == 0) {
 687                         $output .= &OutputParam ($symbol, $name,
 688                                                  $template_exists, 1,
 689                                                  "the object which received the signal.");
 690                     } else {
 691                         $output .= &OutputParam ($symbol, $name,
 692                                                  $template_exists, 1, "");
 693                     }
 694                 }
 695             }
 696
 697             if ($SignalReturns[$i] ne "void") {
 698                 $output .= &OutputParam ($symbol, "Returns", $template_exists,
 699                                          1, "");
 700             }
 701             $output .= &OutputOldParams ($symbol);
 702             $output .= "\n";
 703         }
 704     }
 705     return $output;
 706 }
 707
 708
 709 #############################################################################
 710 # Function    : OutputArgTemplates
 711 # Description : Outputs templates for Args.
 712 # Arguments   : $title - the title from the $MODULE-sections.txt file. If the
 713 #                 file is describing a GtkObject subclass, the title should
 714 #                 be the name of the class, e.g. 'GtkButton'.
 715 #############################################################################
 716
 717 sub OutputArgTemplates {
 718     my ($title) = @_;
 719
 720     my $output = "";
 721     my $i;
 722     for ($i = 0; $i <= $#ArgObjects; $i++) {
 723         if ($ArgObjects[$i] eq $title) {
 724 #           print "Found arg: $ArgObjects[$i]\n";
 725             # I've only used one colon so we don't clash with signals.
 726             my ($symbol) = "$ArgObjects[$i]:$ArgNames[$i]";
 727
 728             # See if symbol already has a description.
 729             my ($symbol_desc) = $SymbolDocs{$symbol};
 730             if (defined ($symbol_desc)) {
 731                 delete $SymbolDocs{$symbol};
 732                 $symbol_desc =~ s/\s+$//;
 733             } else {
 734                 $symbol_desc = "<para>\n$CHANGES_FLAG\n</para>";
 735             }
 736
 737             $output .= <<EOF;
 738 <!-- ##### ARG $symbol ##### -->
 739 $symbol_desc
 740
 741 EOF
 742         }
 743     }
 744     return $output;
 745 }
 746
 747
 748 #############################################################################
 749 # Function    : OutputUnusedTemplates
 750 # Description : This saves any unused documentation into $MODULE-unused.sgml.
 751 # Arguments   : none
 752 #############################################################################
 753
 754 sub OutputUnusedTemplates {
 755     my ($old_unused_file) = "$TMPL_DIR/$MODULE-unused.sgml";
 756     my ($new_unused_file) = "$TMPL_DIR/$MODULE-unused.new";
 757
 758     open (UNUSED, ">$new_unused_file")
 759         || die "Can't open file: $new_unused_file";
 760
 761     my $output = "";
 762     my ($symbol, $symbol_desc);
 763     for $symbol (sort keys %SymbolDocs) {
 764         $symbol_desc = $SymbolDocs{$symbol};
 765
 766 #       print "Unused: $symbol\n";
 767
 768         my $type = $SymbolTypes{$symbol};
 769         if (!defined ($type)) {
 770             $type = "UNKNOWN";
 771             &LogWarning ($SymbolSourceFile{$symbol},$SymbolSourceLine{$symbol}, "Unused symbol $symbol has unknown type.");
 772         }
 773
 774     $output .= <<EOF;
 775 <!-- ##### $type $symbol ##### -->
 776 $symbol_desc
 777
 778 EOF
 779
 780         my ($params) = $SymbolParams{$symbol};
 781         if (defined ($params)) {
 782             my $j;
 783             for ($j = 0; $j <= $#$params; $j += 2) {
 784                 my $param_name = $$params[$j];
 785                 my $param_desc = $$params[$j + 1];
 786                 $param_desc =~ s/\s+$//;
 787                 $output .= "\@$param_name: $param_desc\n";
 788             }
 789         }
 790         $output .= "\n";
 791     }
 792
 793     print UNUSED $output;
 794     close (UNUSED);
 795
 796     &UpdateFileIfChanged ($old_unused_file, $new_unused_file, 1);
 797 }
 798
 799
 800 #############################################################################
 801 # LIBRARY FUNCTIONS -   These functions are used in both gtkdoc-mkdb and
 802 #                       gtkdoc-mktmpl and should eventually be moved to a
 803 #                       separate library.
 804 #############################################################################
 805
 806 #############################################################################
 807 # Function    : ReadDeclarationsFile
 808 # Description : This reads in a file containing the function/macro/enum etc.
 809 #               declarations.
 810 #
 811 #               Note that in some cases there are several declarations with
 812 #               the same name, e.g. for conditional macros. In this case we
 813 #               set a flag in the %DeclarationConditional hash so the
 814 #               declaration is not shown in the docs.
 815 #
 816 #               If a macro and a function have the same name, e.g. for
 817 #               gtk_object_ref, the function declaration takes precedence.
 818 #
 819 #               Some opaque structs are just declared with 'typedef struct
 820 #               _name name;' in which case the declaration may be empty.
 821 #               The structure may have been found later in the header, so
 822 #               that overrides the empty declaration.
 823 #
 824 # Arguments   : $file - the declarations file to read
 825 #               $override - if declarations in this file should override
 826 #                       any current declaration.
 827 #############################################################################
 828
 829 sub ReadDeclarationsFile {
 830     my ($file, $override) = @_;
 831
 832     if ($override == 0) {
 833         %Declarations = ();
 834         %DeclarationTypes = ();
 835         %DeclarationConditional = ();
 836         %DeclarationOutput = ();
 837     }
 838
 839     open (INPUT, $file)
 840         || die "Can't open $file";
 841     my $declaration_type = "";
 842     my $declaration_name;
 843     my $declaration;
 844     while (<INPUT>) {
 845         if (!$declaration_type) {
 846             if (m/^<([^>]+)>/) {
 847                 $declaration_type = $1;
 848                 $declaration_name = "";
 849 #               print "Found declaration: $declaration_type\n";
 850                 $declaration = "";
 851             }
 852         } else {
 853             if (m%^<NAME>(.*)</NAME>%) {
 854                 $declaration_name = $1;
 855             } elsif (m%<DEPRECATED/>%) {
 856                 # do nothing, just skip the line; we handle this
 857                 # in mkdb
 858             } elsif (m%^</$declaration_type>%) {
 859 #               print "Found end of declaration: $declaration_name\n";
 860                 # Check that the declaration has a name
 861                 if ($declaration_name eq "") {
 862                     print "ERROR: $declaration_type has no name $file:$.\n";
 863                 }
 864
 865                 # Check if the symbol is already defined.
 866                 if (defined ($Declarations{$declaration_name})
 867                     && $override == 0) {
 868                     # Function declarations take precedence.
 869                     if ($DeclarationTypes{$declaration_name} eq 'FUNCTION') {
 870                         # Ignore it.
 871                     } elsif ($declaration_type eq 'FUNCTION') {
 872                         $Declarations{$declaration_name} = $declaration;
 873                         $DeclarationTypes{$declaration_name} = $declaration_type;
 874                     } elsif ($DeclarationTypes{$declaration_name}
 875                               eq $declaration_type) {
 876                         # If the existing declaration is empty, or is just a
 877                         # forward declaration of a struct, override it.
 878                         if ($declaration_type eq 'STRUCT') {
 879                             if ($Declarations{$declaration_name} =~ m/^\s*(struct\s+\w+\s*;)?\s*$/) {
 880                                 $Declarations{$declaration_name} = $declaration;
 881                             } elsif ($declaration =~ m/^\s*(struct\s+\w+\s*;)?\s*$/) {
 882                                 # Ignore an empty or forward declaration.
 883                             } else {
 884                                 &LogWarning ($file, $., "Structure $declaration_name has multiple definitions.");
 885                             }
 886
 887                         } else {
 888                             # set flag in %DeclarationConditional hash for
 889                             # multiply defined macros/typedefs.
 890                             $DeclarationConditional{$declaration_name} = 1;
 891                         }
 892                     } else {
 893                         &LogWarning ($file, $., "$declaration_name has multiple definitions.");
 894                     }
 895                 } else {
 896                     $Declarations{$declaration_name} = $declaration;
 897                     $DeclarationTypes{$declaration_name} = $declaration_type;
 898                 }
 899                 $declaration_type = "";
 900             } else {
 901                 $declaration .= $_;
 902             }
 903         }
 904     }
 905     close (INPUT);
 906 }
 907
 908
 909 #############################################################################
 910 # Function    : ReadSignalsFile
 911 # Description : This reads in an existing file which contains information on
 912 #               all GObject signals. It creates the arrays @SignalNames and
 913 #               @SignalPrototypes containing info on the signals. The first
 914 #               line of the SignalPrototype is the return type of the signal
 915 #               handler. The remaining lines are the parameters passed to it.
 916 #               The last parameter, "gpointer user_data" is always the same
 917 #               so is not included.
 918 # Arguments   : $file - the file containing the signal handler prototype
 919 #                       information.
 920 #############################################################################
 921
 922 sub ReadSignalsFile {
 923     my ($file) = @_;
 924
 925     my $in_signal = 0;
 926     my $signal_object;
 927     my $signal_name;
 928     my $signal_returns;
 929     my $signal_flags;
 930     my $signal_prototype;
 931
 932     # Reset the signal info.
 933     @SignalObjects = ();
 934     @SignalNames = ();
 935     @SignalReturns = ();
 936     @SignalFlags = ();
 937     @SignalPrototypes = ();
 938
 939     if (! -f $file) {
 940         return;
 941     }
 942     if (!open (INPUT, $file)) {
 943         warn "Can't open $file - skipping signals\n";
 944         return;
 945     }
 946     while (<INPUT>) {
 947         if (!$in_signal) {
 948             if (m/^<SIGNAL>/) {
 949                 $in_signal = 1;
 950                 $signal_object = "";
 951                 $signal_name = "";
 952                 $signal_returns = "";
 953                 $signal_prototype = "";
 954             }
 955         } else {
 956             if (m/^<NAME>(.*)<\/NAME>/) {
 957                 $signal_name = $1;
 958                 if ($signal_name =~ m/^(.*)::(.*)$/) {
 959                     $signal_object = $1;
 960                     ($signal_name = $2) =~ s/_/-/g;
 961 #                   print "Found signal: $signal_name\n";
 962                 } else {
 963                     print "Invalid signal name: $signal_name\n";
 964                 }
 965             } elsif (m/^<RETURNS>(.*)<\/RETURNS>/) {
 966                 $signal_returns = $1;
 967             } elsif (m/^<FLAGS>(.*)<\/FLAGS>/) {
 968                 $signal_flags = $1;
 969             } elsif (m%^</SIGNAL>%) {
 970 #               print "Found end of signal: ${signal_object}::${signal_name}\nReturns: ${signal_returns}\n${signal_prototype}";
 971                 push (@SignalObjects, $signal_object);
 972                 push (@SignalNames, $signal_name);
 973                 push (@SignalReturns, $signal_returns);
 974                 push (@SignalFlags, $signal_flags);
 975                 push (@SignalPrototypes, $signal_prototype);
 976                 $in_signal = 0;
 977             } else {
 978                 $signal_prototype .= $_;
 979             }
 980         }
 981     }
 982     close (INPUT);
 983 }
 984
 985
 986 #############################################################################
 987 # Function    : ReadTemplateFile
 988 # Description : This reads in the manually-edited documentation file
 989 #               corresponding to the file currently being created, so we can
 990 #               insert the documentation at the appropriate places.
 991 #               It outputs %SymbolTypes, %SymbolDocs and %SymbolParams, which
 992 #               is a hash of arrays.
 993 #               NOTE: This function is duplicated in gtkdoc-mkdb (but
 994 #               slightly different).
 995 # Arguments   : $docsfile - the template file to read in.
 996 #               $skip_unused_params - 1 if the unused parameters should be
 997 #                       skipped.
 998 #############################################################################
 999
1000 sub ReadTemplateFile {
1001     my ($docsfile, $skip_unused_params) = @_;
1002
1003 #    print "Reading $docsfile\n";
1004     if (! -f $docsfile) {
1005         print "File doesn't exist: $docsfile\n";
1006         return 0;
1007     }
1008
1009     my $CurrentType = "";       # Type of symbol being read.
1010     my $CurrentSymbol = "";     # Name of symbol being read.
1011     my $SymbolDoc = "";         # Description of symbol being read.
1012     my @Params;                 # Parameter names and descriptions of current
1013                                 #   function/macro/function typedef.
1014     my $CurrentParam = -1;      # Index of parameter currently being read.
1015                                 #   Note that the param array contains pairs
1016                                 #   of param name & description.
1017     my $InUnusedParameters = 0; # True if we are reading in the unused params.
1018
1019     open (DOCS, $docsfile)
1020         || die "Can't open file $docsfile: $!";
1021     while (<DOCS>) {
1022         if (m/^<!-- ##### ([A-Z_]+) (\S+) ##### -->/) {
1023             my $type = $1;
1024             my $symbol = $2;
1025             if ($symbol eq "Title"
1026                 || $symbol eq "Short_Description"
1027                 || $symbol eq "Long_Description"
1028                 || $symbol eq "See_Also"
1029                 || $symbol eq "Stability_Level"
1030                 || $symbol eq "Image") {
1031                 $symbol = $docsfile . ":" . $symbol;
1032             }
1033
1034             #print "Found symbol: $symbol\n";
1035             # Remember file and line for the symbol
1036             $SymbolSourceFile{$symbol} = $docsfile;
1037             $SymbolSourceLine{$symbol} = $.;
1038
1039             # Canonicalize signal and argument names to have -, not _
1040             if ($type eq "ARG" || $type eq "SIGNAL") {
1041               $symbol =~ s/_/-/g;
1042             }
1043
1044             # Store previous symbol, but remove any trailing blank lines.
1045             if ($CurrentSymbol ne "") {
1046                 $SymbolDoc =~ s/\s+$//;
1047                 $SymbolTypes{$CurrentSymbol} = $CurrentType;
1048                 $SymbolDocs{$CurrentSymbol} = $SymbolDoc;
1049
1050                 if ($CurrentParam >= 0) {
1051                     $SymbolParams{$CurrentSymbol} = [ @Params ];
1052                 } else {
1053                     # Delete any existing params in case we are overriding a
1054                     # previously read template.
1055                     delete $SymbolParams{$CurrentSymbol};
1056                 }
1057             }
1058             $CurrentType = $type;
1059             $CurrentSymbol = $symbol;
1060             $CurrentParam = -1;
1061             $InUnusedParameters = 0;
1062             $SymbolDoc = "";
1063             @Params = ();
1064
1065         } elsif (m/^<!-- # Unused Parameters # -->/) {
1066             $InUnusedParameters = 1;
1067             next;
1068
1069         } else {
1070             # Workaround for an old bug that left a mess in the templates.
1071             # This happened with macros with args spread over several lines.
1072             if (m/^\@\\$/) {
1073               # Skip the next line.
1074               $_ = <DOCS>;
1075               next;
1076             }
1077
1078             # Workaround for an old bug that left '@:' at start of lines.
1079             if (m/^\@:$/) {
1080               next;
1081             }
1082
1083
1084             # Check if param found. Need to handle "..." and "format...".
1085             if (s/^\@([\w\.]+):\040?//) {
1086                 my $param_name = $1;
1087                 # Allow variations of 'Returns'
1088                 if ($param_name =~ m/^[Rr]eturns?$/) {
1089                     $param_name = "Returns";
1090                 }
1091 #               print "Found param: $param_name\n";
1092                 push (@Params, $param_name);
1093                 push (@Params, $_);
1094                 $CurrentParam += 2;
1095                 next;
1096             }
1097
1098             # When outputting the DocBook we skip unused parameters.
1099             if (!$InUnusedParameters || !$skip_unused_params) {
1100                 if ($CurrentParam >= 0) {
1101                     $Params[$CurrentParam] .= $_;
1102                 } else {
1103                     $SymbolDoc .= $_;
1104                 }
1105             }
1106         }
1107     }
1108
1109     # Remember to finish the current symbol doccs.
1110     if ($CurrentSymbol ne "") {
1111
1112         $SymbolDoc =~ s/\s+$//;
1113         $SymbolTypes{$CurrentSymbol} = $CurrentType;
1114         $SymbolDocs{$CurrentSymbol} = $SymbolDoc;
1115
1116         if ($CurrentParam >= 0) {
1117             $SymbolParams{$CurrentSymbol} = [ @Params ];
1118         } else {
1119             delete $SymbolParams{$CurrentSymbol};
1120         }
1121     }
1122
1123     close (DOCS);
1124     return 1;
1125 }
1126
1127
1128 #############################################################################
1129 # Function    : ReadObjectHierarchy
1130 # Description : This reads in the $MODULE-hierarchy.txt file containing all
1131 #               the GtkObject subclasses described in this module (and their
1132 #               ancestors).
1133 #               It places them in the @Objects array, and places their level
1134 #               in the widget hierarchy in the @ObjectLevels array, at the
1135 #               same index. GtkObject, the root object, has a level of 1.
1136 #
1137 #               FIXME: the version in gtkdoc-mkdb also generates tree_index.sgml
1138 #               as it goes along, this should be split out into a separate
1139 #               function.
1140 #
1141 # Arguments   : none
1142 #############################################################################
1143
1144 sub ReadObjectHierarchy {
1145     @Objects = ();
1146     @ObjectLevels = ();
1147
1148     if (! -f $OBJECT_TREE_FILE) {
1149         return;
1150     }
1151     if (!open (INPUT, $OBJECT_TREE_FILE)) {
1152         warn "Can't open $OBJECT_TREE_FILE - skipping object tree\n";
1153         return;
1154     }
1155     while (<INPUT>) {
1156         if (m/\S+/) {
1157             my $object = $&;
1158             my $level = (length($`)) / 2 + 1;
1159 #            print ("Level: $level  Object: $object\n");
1160
1161             push (@Objects, $object);
1162             push (@ObjectLevels, $level);
1163         }
1164     }
1165
1166     close (INPUT);
1167 }
1168
1169
1170 #############################################################################
1171 # Function    : ReadArgsFile
1172 # Description : This reads in an existing file which contains information on
1173 #               all GObject args. It creates the arrays @ArgObjects, @ArgNames,
1174 #               @ArgTypes and @ArgFlags containing info on the args.
1175 # Arguments   : $file - the file containing the arg information.
1176 #############################################################################
1177
1178 sub ReadArgsFile {
1179     my ($file) = @_;
1180
1181     my $in_arg = 0;
1182     my $arg_object;
1183     my $arg_name;
1184     my $arg_type;
1185     my $arg_flags;
1186
1187     # Reset the signal info.
1188     @ArgObjects = ();
1189     @ArgNames = ();
1190     @ArgTypes = ();
1191     @ArgFlags = ();
1192
1193     if (! -f $file) {
1194         return;
1195     }
1196     if (!open (INPUT, $file)) {
1197         warn "Can't open $file - skipping args\n";
1198         return;
1199     }
1200     while (<INPUT>) {
1201         if (!$in_arg) {
1202             if (m/^<ARG>/) {
1203                 $in_arg = 1;
1204                 $arg_object = "";
1205                 $arg_name = "";
1206                 $arg_type = "";
1207                 $arg_flags = "";
1208             }
1209         } else {
1210             if (m/^<NAME>(.*)<\/NAME>/) {
1211                 $arg_name = $1;
1212                 if ($arg_name =~ m/^(.*)::(.*)$/) {
1213                     $arg_object = $1;
1214                     ($arg_name = $2) =~ s/_/-/g;
1215 #                   print "Found arg: $arg_name\n";
1216                 } else {
1217                     print "Invalid arg name: $arg_name\n";
1218                 }
1219             } elsif (m/^<TYPE>(.*)<\/TYPE>/) {
1220                 $arg_type = $1;
1221             } elsif (m/^<FLAGS>(.*)<\/FLAGS>/) {
1222                 $arg_flags = $1;
1223             } elsif (m%^</ARG>%) {
1224 #               print "Found end of arg: ${arg_object}::${arg_name}\n${arg_type} : ${arg_flags}\n";
1225                 push (@ArgObjects, $arg_object);
1226                 push (@ArgNames, $arg_name);
1227                 push (@ArgTypes, $arg_type);
1228                 push (@ArgFlags, $arg_flags);
1229                 $in_arg = 0;
1230             }
1231         }
1232     }
1233     close (INPUT);
1234 }
1235
1236
1237 #############################################################################
1238 # Function    : CheckIsObject
1239 # Description : Returns 1 if the given name is a GObject or a subclass.
1240 #               It uses the global @Objects array.
1241 #               Note that the @Objects array only contains classes in the
1242 #               current module and their ancestors - not all GObject classes.
1243 # Arguments   : $name - the name to check.
1244 #############################################################################
1245
1246 sub CheckIsObject {
1247     my ($name) = @_;
1248
1249     my $object;
1250     foreach $object (@Objects) {
1251         if ($object eq $name) {
1252             return 1;
1253         }
1254     }
1255     return 0;
1256 }
1257