Gruta/Data.pm

   1 package Gruta::Data;
   2
   3 use strict;
   4 use warnings;
   5
   6 package Gruta::Data::BASE;
   7
   8 use Carp;
   9
  10 sub fields { return (); }
  11 sub vfields { return (); }
  12 sub afields { return ($_[0]->fields(), $_[0]->vfields()); }
  13
  14 sub source {
  15         my $self        = shift;
  16
  17         if (@_) {
  18                 $self->{_source} = shift;
  19         }
  20
  21         return $self->{_source};
  22 }
  23
  24
  25 sub _assert {
  26         my $self        = shift;
  27
  28         my $id = $self->get('id') || '';
  29         $id =~ /^[\d\w_-]+$/ or croak "Bad id [$id]";
  30
  31         return $self;
  32 }
  33
  34 sub new {
  35         my $class       = shift;
  36         my %args        = @_;
  37
  38         my $self = bless({ }, $class);
  39
  40         foreach my $k ($self->afields()) {
  41                 $self->{$k} = $args{$k};
  42         }
  43
  44         return $self;
  45 }
  46
  47 sub get {
  48         my $self        = shift;
  49         my $field       = shift;
  50
  51         croak 'get ' . ref($self) . " field '$field'?" unless exists $self->{$field};
  52
  53         return $self->{$field};
  54 }
  55
  56 sub set {
  57         my $self        = shift;
  58         my $field       = shift;
  59
  60         croak 'set ' . ref($self) . " field '$field'?" unless exists $self->{$field};
  61
  62         $self->{$field} = shift;
  63
  64         return $self->{$field};
  65 }
  66
  67
  68 package Gruta::Data::Topic;
  69
  70 use base 'Gruta::Data::BASE';
  71
  72 sub fields { return qw(id name editors max_stories internal); }
  73
  74 package Gruta::Data::Story;
  75
  76 use base 'Gruta::Data::BASE';
  77
  78 use Carp;
  79
  80 sub fields { return qw(id topic_id title date userid format hits ctime content); }
  81 sub vfields { return qw(tags abstract body); }
  82
  83 sub _assert {
  84         my $self        = shift;
  85
  86         $self->SUPER::_assert();
  87
  88         my $topic_id = $self->get('topic_id') || '';
  89         $topic_id =~ /^[\d\w_-]+$/ or croak "Bad topic_id";
  90
  91         return $self;
  92 }
  93
  94 sub date { return Gruta::Data::format_date($_[0]->get('date'), $_[1]); }
  95
  96 sub touch { return $_[0]; }
  97
  98 sub tags {
  99         my $self        = shift;
 100         my @ret         = undef;
 101
 102         if (scalar(@_)) {
 103                 $self->set('tags', [ @_ ]);
 104         }
 105         else {
 106                 @ret = @{ $self->get('tags') };
 107         }
 108
 109         return @ret;
 110 }
 111
 112 sub new_id {
 113         my $self        = shift;
 114
 115         return sprintf ('%08x', int(rand(0xffffffff)));
 116 }
 117
 118 package Gruta::Data::User;
 119
 120 use base 'Gruta::Data::BASE';
 121
 122 sub fields { return qw(id username email password can_upload is_admin xdate); }
 123 sub vfields { return qw(sid); }
 124
 125 sub xdate { return Gruta::Data::format_date($_[0]->get('xdate'), $_[1]); }
 126
 127 package Gruta::Data::Session;
 128
 129 use base 'Gruta::Data::BASE';
 130
 131 sub fields { return qw(id time user_id ip); }
 132
 133 package Gruta::Data;
 134
 135 sub format_date {
 136         my $date        = shift;
 137         my $format      = shift;
 138
 139         if ($format) {
 140                 my ($y, $m, $d, $H, $M, $S) = ($date =~
 141                         /^(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})$/);
 142
 143                 $format =~ s/%Y/$y/g;
 144                 $format =~ s/%y/$y/g;
 145                 $format =~ s/%m/$m/g;
 146                 $format =~ s/%d/$d/g;
 147                 $format =~ s/%H/$H/g;
 148                 $format =~ s/%M/$M/g;
 149                 $format =~ s/%S/$S/g;
 150         }
 151         else {
 152                 $format = $date;
 153         }
 154
 155         return $format;
 156 }
 157
 158
 159 sub today {
 160         my $format      = shift;
 161
 162         my ($S,$M,$H,$d,$m,$y) = (localtime)[0..5];
 163
 164         my $date = sprintf('%04d%02d%02d%02d%02d%02d',
 165                 1900 + $y, $m + 1, $d, $H, $M, $S);
 166
 167         return Gruta::Data::format_date($date, $format);
 168 }
 169
 170
 171 1;