configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 2002,2003,2004,2005,2006,2007,2008,2009  Free Software Foundation, Inc.
   4 #
   5 # This configure.ac is free software; the author
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  11 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  12 # PARTICULAR PURPOSE.
  13
  14 dnl This configure script is complicated, because GRUB needs to deal
  15 dnl with three potentially different types:
  16 dnl
  17 dnl   build  -- the environment for building GRUB
  18 dnl   host   -- the environment for running utilities
  19 dnl   target -- the environment for running GRUB
  20 dnl
  21 dnl In addition, GRUB needs to deal with a platform specification
  22 dnl which specifies the system running GRUB, such as firmware.
  23 dnl This is necessary because the target type in autoconf does not
  24 dnl describe such a system very well.
  25 dnl
  26 dnl The current strategy is to use variables with no prefix (such as
  27 dnl CC, CFLAGS, etc.) for the host type as well as the build type,
  28 dnl because GRUB does not need to use those variables for the build
  29 dnl type, so there is no conflict. Variables with the prefix "TARGET_"
  30 dnl (such as TARGET_CC, TARGET_CFLAGS, etc.) are used for the target
  31 dnl type.
  32
  33
  34 AC_INIT([GRUB],[1.96],[bug-grub@gnu.org])
  35 AC_PREREQ(2.59)
  36 AC_CONFIG_SRCDIR([include/grub/dl.h])
  37 AC_CONFIG_HEADER([config.h])
  38
  39 # Checks for host and target systems.
  40 AC_CANONICAL_HOST
  41 AC_CANONICAL_TARGET
  42
  43 # Program name transformations
  44 AC_ARG_PROGRAM
  45
  46 case "$host_cpu" in
  47   powerpc64) host_m32=1 ;;
  48 esac
  49
  50 case "$target_cpu" in
  51   i[[3456]]86) target_cpu=i386 ;;
  52 esac
  53
  54 # Specify the platform (such as firmware).
  55 AC_ARG_WITH([platform],
  56             AS_HELP_STRING([--with-platform=PLATFORM],
  57                            [select the host platform [[guessed]]]))
  58
  59 # Guess the platform if not specified.
  60 if test "x$with_platform" = x; then
  61   case "$target_cpu"-"$target_vendor" in
  62     i386-apple) platform=efi ;;
  63     i386-*) platform=pc ;;
  64     x86_64-apple) platform=efi ;;
  65     x86_64-*) platform=pc ;;
  66     powerpc-*) platform=ieee1275 ;;
  67     powerpc64-*) platform=ieee1275 ;;
  68     sparc64-*) platform=ieee1275 ;;
  69     *) AC_MSG_ERROR([unsupported CPU: "$target_cpu"]) ;;
  70   esac
  71 else
  72   platform="$with_platform"
  73 fi
  74
  75 # Adjust CPU unless target was explicitly specified.
  76 if test -z "$target_alias"; then
  77   case "$target_cpu"-"$platform" in
  78     x86_64-efi) ;;
  79     x86_64-*) target_cpu=i386 ;;
  80     powerpc64-ieee1275) target_cpu=powerpc ;;
  81   esac
  82 fi
  83
  84 # Check if the platform is supported, make final adjustments.
  85 case "$target_cpu"-"$platform" in
  86   i386-efi) ;;
  87   x86_64-efi) ;;
  88   i386-pc) ;;
  89   i386-coreboot) ;;
  90   i386-linuxbios) platform=coreboot ;;
  91   i386-ieee1275) ;;
  92   powerpc-ieee1275) ;;
  93   sparc64-ieee1275) ;;
  94   *) AC_MSG_ERROR([platform "$platform" is not supported for target CPU "$target_cpu"]) ;;
  95 esac
  96
  97 case "$target_cpu" in
  98   i386 | powerpc) target_m32=1 ;;
  99   x86_64 | sparc64) target_m64=1 ;;
 100 esac
 101
 102 case "$host_os" in
 103   mingw32) host_os=cygwin ;;
 104 esac
 105
 106 # This normalizes the names, and creates a new variable ("host_kernel")
 107 # while at it, since the mapping is not always 1:1 (e.g. different OSes
 108 # using the same kernel type).
 109 case "$host_os" in
 110   gnu*)                         host_kernel=hurd ;;
 111   linux*)                       host_kernel=linux ;;
 112   freebsd* | kfreebsd*-gnu)     host_kernel=freebsd ;;
 113   cygwin)                       host_kernel=windows ;;
 114 esac
 115
 116 AC_SUBST(host_cpu)
 117 AC_SUBST(host_os)
 118 AC_SUBST(host_kernel)
 119
 120 AC_SUBST(target_cpu)
 121 AC_SUBST(platform)
 122
 123 #
 124 # Checks for build programs.
 125 #
 126
 127 # Although cmp is listed in the GNU Coding Standards as a command which
 128 # can used directly, OpenBSD lacks cmp in the default installation.
 129 AC_CHECK_PROGS([CMP], [cmp])
 130 if test "x$CMP" = x; then
 131   AC_MSG_ERROR([cmp is not found])
 132 fi
 133
 134 AC_CHECK_PROGS([YACC], [bison])
 135 if test "x$YACC" = x; then
 136   AC_MSG_ERROR([bison is not found])
 137 fi
 138
 139 for file in /usr/src/unifont.bdf ; do
 140   if test -e $file ; then
 141     AC_SUBST([UNIFONT_BDF], [$file])
 142     break
 143   fi
 144 done
 145
 146 AC_PROG_INSTALL
 147 AC_PROG_AWK
 148 AC_PROG_MAKE_SET
 149
 150 # These are not a "must".
 151 AC_PATH_PROG(RUBY, ruby)
 152 AC_PATH_PROG(HELP2MAN, help2man)
 153
 154 #
 155 # Checks for host programs.
 156 #
 157
 158 AC_PROG_CC
 159 # Must be GCC.
 160 test "x$GCC" = xyes || AC_MSG_ERROR([GCC is required])
 161
 162 AC_GNU_SOURCE
 163 AC_SYS_LARGEFILE
 164
 165 # Identify characteristics of the host architecture.
 166 AC_C_BIGENDIAN
 167 AC_CHECK_SIZEOF(void *)
 168 AC_CHECK_SIZEOF(long)
 169
 170 if test "x$host_m32" = x1; then
 171   # Force 32-bit mode.
 172   CFLAGS="$CFLAGS -m32"
 173   LDFLAGS="$LDFLAGS -m32"
 174 fi
 175
 176 # Check LZO when compiling for the i386-pc.
 177 if test "$target_cpu"-"$platform" = i386-pc; then
 178   AC_ARG_ENABLE([lzo],
 179               [AS_HELP_STRING([--enable-lzo],
 180                              [use lzo to compress kernel (default is lzma)])])
 181   [if [ x"$enable_lzo" = xyes ]; then
 182     # There are three possibilities. LZO version 2 installed with the name
 183     # liblzo2, with the name liblzo, and LZO version 1.]
 184     AC_DEFINE([ENABLE_LZO], [1], [Use lzo compression])
 185     AC_CHECK_LIB([lzo2], [__lzo_init_v2], [LIBLZO="-llzo2"],
 186       [AC_CHECK_LIB([lzo], [__lzo_init_v2], [LIBLZO="-llzo"],
 187         [AC_CHECK_LIB([lzo], [__lzo_init2], [LIBLZO="-llzo"],
 188                [AC_MSG_ERROR([LZO library version 1.02 or later is required])])])])
 189     AC_SUBST([LIBLZO])
 190     [LIBS="$LIBS $LIBLZO"]
 191     AC_CHECK_FUNC([lzo1x_999_compress], ,
 192                 [AC_MSG_ERROR([LZO1X-999 must be enabled])])
 193
 194     [# LZO version 2 uses lzo/lzo1x.h, while LZO version 1 uses lzo1x.h.]
 195     AC_CHECK_HEADERS([lzo/lzo1x.h lzo1x.h])
 196   [else]
 197     AC_DEFINE([ENABLE_LZMA], [1], [Use lzma compression])
 198   [fi]
 199   AC_SUBST([enable_lzo])
 200 fi
 201
 202 # Check for functions.
 203 AC_CHECK_FUNCS(posix_memalign memalign asprintf __bswapsi2 __bswapdi2)
 204
 205 #
 206 # Check for target programs.
 207 #
 208
 209
 210 # Use linker script if present, otherwise use builtin -N script.
 211 AC_MSG_CHECKING([for option to link raw image])
 212 if test -f "${srcdir}/conf/${target_cpu}-${platform}-${host_os}-img-ld.sc"; then
 213   TARGET_IMG_LDSCRIPT='$(top_srcdir)'"/conf/${target_cpu}-${platform}-${host_os}-img-ld.sc"
 214   TARGET_IMG_LDFLAGS="-Wl,-T${TARGET_IMG_LDSCRIPT}"
 215   TARGET_IMG_LDFLAGS_AC="-Wl,-T${srcdir}/conf/${target_cpu}-${platform}-${host_os}-img-ld.sc"
 216 else
 217   TARGET_IMG_LDSCRIPT=
 218   TARGET_IMG_LDFLAGS='-Wl,-N'
 219   TARGET_IMG_LDFLAGS_AC='-Wl,-N'
 220 fi
 221 AC_SUBST(TARGET_IMG_LDSCRIPT)
 222 AC_SUBST(TARGET_IMG_LDFLAGS)
 223 AC_MSG_RESULT([$TARGET_IMG_LDFLAGS_AC])
 224
 225 # For platforms where ELF is not the default link format.
 226 AC_MSG_CHECKING([for command to convert module to ELF format])
 227 case "${host_os}" in
 228   cygwin) TARGET_OBJ2ELF='grub-pe2elf' ;;
 229   *) ;;
 230 esac
 231 AC_SUBST(TARGET_OBJ2ELF)
 232 AC_MSG_RESULT([$TARGET_OBJ2ELF])
 233
 234 # For cross-compiling.
 235 if test "x$build" != "x$host"; then
 236   # XXX this depends on the implementation of autoconf!
 237   tmp_ac_tool_prefix="$ac_tool_prefix"
 238   ac_tool_prefix=$target_alias-
 239
 240   AC_CHECK_TOOLS(TARGET_CC, [gcc egcs cc],
 241                  [AC_MSG_ERROR([none of gcc, egcs and cc is found. set TARGET_CC manually.])])
 242   AC_CHECK_TOOL(OBJCOPY, objcopy)
 243   AC_CHECK_TOOL(STRIP, strip)
 244   AC_CHECK_TOOL(NM, nm)
 245
 246   ac_tool_prefix="$tmp_ac_tool_prefix"
 247 else
 248   if test "x$TARGET_CC" = x; then
 249     TARGET_CC=$CC
 250   fi
 251   AC_CHECK_TOOL(OBJCOPY, objcopy)
 252   AC_CHECK_TOOL(STRIP, strip)
 253   AC_CHECK_TOOL(NM, nm)
 254 fi
 255 AC_SUBST(TARGET_CC)
 256
 257
 258 # Test the C compiler for the target environment.
 259 tmp_CC="$CC"
 260 tmp_CFLAGS="$CFLAGS"
 261 tmp_LDFLAGS="$LDFLAGS"
 262 tmp_CPPFLAGS="$CPPFLAGS"
 263 tmp_LIBS="$LIBS"
 264 CC="$TARGET_CC"
 265 CFLAGS="$TARGET_CFLAGS"
 266 CPPFLAGS="$TARGET_CPPFLAGS"
 267 LDFLAGS="$TARGET_LDFLAGS"
 268 LIBS=""
 269
 270 if test "x$TARGET_CFLAGS" = x; then
 271   # debug flags.
 272   TARGET_CFLAGS="-Wall -W -Wshadow -Wpointer-arith -Wmissing-prototypes \
 273                  -Wundef -Wstrict-prototypes -g"
 274
 275   # optimization flags.
 276   AC_CACHE_CHECK([whether optimization for size works], grub_cv_cc_Os, [
 277     CFLAGS=-Os
 278     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 279                       [grub_cv_cc_Os=yes],
 280                       [grub_cv_cc_Os=no])
 281   ])
 282   if test "x$grub_cv_cc_Os" = xyes; then
 283     TARGET_CFLAGS="$TARGET_CFLAGS -Os"
 284   else
 285     TARGET_CFLAGS="$TARGET_CFLAGS -O2 -fno-strength-reduce -fno-unroll-loops"
 286   fi
 287
 288   # Force no alignment to save space on i386.
 289   if test "x$target_cpu" = xi386; then
 290     AC_CACHE_CHECK([whether -falign-loops works], [grub_cv_cc_falign_loop], [
 291       CFLAGS="-falign-loops=1"
 292       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 293                         [grub_cv_cc_falign_loop=yes],
 294                         [grub_cv_cc_falign_loop=no])
 295     ])
 296
 297     if test "x$grub_cv_cc_falign_loop" = xyes; then
 298       TARGET_CFLAGS="$TARGET_CFLAGS -falign-jumps=1 -falign-loops=1 -falign-functions=1"
 299     else
 300       TARGET_CFLAGS="$TARGET_CFLAGS -malign-jumps=1 -malign-loops=1 -malign-functions=1"
 301     fi
 302   fi
 303 fi
 304
 305 if test "x$target_m32" = x1; then
 306   # Force 32-bit mode.
 307   TARGET_CFLAGS="$TARGET_CFLAGS -m32"
 308   TARGET_LDFLAGS="$TARGET_LDFLAGS -m32"
 309 fi
 310
 311 if test "x$target_m64" = x1; then
 312   # Force 64-bit mode.
 313   TARGET_CFLAGS="$TARGET_CFLAGS -m64"
 314   TARGET_LDFLAGS="$TARGET_LDFLAGS -m64"
 315 fi
 316
 317 if test "$target_cpu"-"$platform" = x86_64-efi; then
 318   # Use large model to support 4G memory
 319   AC_CACHE_CHECK([whether option -mcmodel=large works], grub_cv_cc_mcmodel, [
 320     CFLAGS="-m64 -mcmodel=large"
 321     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 322                       [grub_cv_cc_mcmodel=yes],
 323                       [grub_cv_cc_mcmodel=no])
 324   ])
 325   if test "x$grub_cv_cc_no_mcmodel" = xno; then
 326     AC_MSG_ERROR([-mcmodel=large not supported, upgrade your gcc])
 327   fi
 328
 329   # EFI writes to stack below %rsp, we must not use the red zone
 330   AC_CACHE_CHECK([whether option -mno-red-zone works], grub_cv_cc_no_red_zone, [
 331     CFLAGS="-m64 -mno-red-zone"
 332     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 333                       [grub_cv_cc_no_red_zone=yes],
 334                       [grub_cv_cc_no_red_zone=no])
 335   ])
 336   if test "x$grub_cv_cc_no_red_zone" = xno; then
 337     AC_MSG_ERROR([-mno-red-zone not supported, upgrade your gcc])
 338   fi
 339
 340   TARGET_CFLAGS="$TARGET_CFLAGS -mcmodel=large -mno-red-zone"
 341 fi
 342
 343 #
 344 # Compiler features.
 345 #
 346
 347 # Need __enable_execute_stack() for nested function trampolines?
 348 grub_CHECK_ENABLE_EXECUTE_STACK
 349
 350 # Smashing stack protector.
 351 grub_CHECK_STACK_PROTECTOR
 352 # Need that, because some distributions ship compilers that include
 353 # `-fstack-protector' in the default specs.
 354 if test "x$ssp_possible" = xyes; then
 355   TARGET_CFLAGS="$TARGET_CFLAGS -fno-stack-protector"
 356 fi
 357 grub_CHECK_STACK_ARG_PROBE
 358 # Cygwin's GCC uses alloca() to probe the stackframe on static
 359 # stack allocations above some threshold.
 360 if test x"$sap_possible" = xyes; then
 361   TARGET_CFLAGS="$TARGET_CFLAGS -mno-stack-arg-probe"
 362 fi
 363
 364 AC_SUBST(TARGET_CFLAGS)
 365 AC_SUBST(TARGET_CPPFLAGS)
 366 AC_SUBST(TARGET_LDFLAGS)
 367
 368 # Set them to their new values for the tests below.
 369 CC="$TARGET_CC"
 370 CFLAGS="$TARGET_CFLAGS"
 371 CPPFLAGS="$TARGET_CPPFLAGS"
 372 LDFLAGS="$TARGET_LDFLAGS"
 373
 374 # Defined in aclocal.m4.
 375 grub_PROG_TARGET_CC
 376 grub_PROG_OBJCOPY_ABSOLUTE
 377 grub_PROG_LD_BUILD_ID_NONE
 378 grub_ASM_USCORE
 379 if test "x$target_cpu" = xi386; then
 380   if test ! -z "$TARGET_IMG_LDSCRIPT"; then
 381     # Check symbols provided by linker script.
 382     CFLAGS="$TARGET_CFLAGS -nostdlib $TARGET_IMG_LDFLAGS_AC -Wl,-Ttext,8000,--defsym,___main=0x8100"
 383   fi
 384   if test "x$platform" = xpc; then
 385     grub_CHECK_BSS_START_SYMBOL
 386     grub_CHECK_END_SYMBOL
 387   fi
 388   CFLAGS="$TARGET_CFLAGS"
 389   grub_I386_ASM_PREFIX_REQUIREMENT
 390   grub_I386_ASM_ADDR32
 391   grub_I386_ASM_ABSOLUTE_WITHOUT_ASTERISK
 392   grub_I386_CHECK_REGPARM_BUG
 393 else
 394   AC_DEFINE([NESTED_FUNC_ATTR], [], [Catch gcc bug])
 395 fi
 396
 397 # Restore the flags.
 398 CC="$tmp_CC"
 399 CFLAGS="$tmp_CFLAGS"
 400 CPPFLAGS="$tmp_CPPFLAGS"
 401 LDFLAGS="$tmp_LDFLAGS"
 402 LIBS="$tmp_LIBS"
 403
 404 #
 405 # Check for options.
 406 #
 407
 408 # Memory manager debugging.
 409 AC_ARG_ENABLE([mm-debug],
 410               AS_HELP_STRING([--enable-mm-debug],
 411                              [include memory manager debugging]),
 412               [AC_DEFINE([MM_DEBUG], [1],
 413                          [Define to 1 if you enable memory manager debugging.])])
 414
 415 AC_ARG_ENABLE([grub-emu],
 416               [AS_HELP_STRING([--enable-grub-emu],
 417                              [build and install the `grub-emu' debugging utility])])
 418 AC_ARG_ENABLE([grub-emu-usb],
 419               [AS_HELP_STRING([--enable-grub-emu-usb],
 420                              [build and install the `grub-emu' debugging utility with USB support])])
 421 [if [ x"$enable_grub_emu" = xyes ]; then
 422   # Check for curses libraries.]
 423   AC_CHECK_LIB([ncurses], [wgetch], [LIBCURSES="-lncurses"],
 424     [AC_CHECK_LIB([curses], [wgetch], [LIBCURSES="-lcurses"],
 425       [AC_MSG_ERROR([(n)curses libraries are required to build `grub-emu'])])])
 426   AC_SUBST([LIBCURSES])
 427
 428   [# Check for headers.]
 429   AC_CHECK_HEADERS([ncurses/curses.h], [],
 430     [AC_CHECK_HEADERS([ncurses.h], [],
 431       [AC_CHECK_HEADERS([curses.h], [],
 432         [AC_MSG_ERROR([(n)curses header files are required to build `grub-emu'])])])])
 433
 434   [if [ x"$enable_grub_emu_usb" = xyes ]; then
 435     # Check for libusb libraries.]
 436     AC_CHECK_LIB([usb], [usb_claim_interface], [LIBUSB="-lusb"],
 437       [AC_MSG_ERROR([libusb libraries are required to build `grub-emu' with USB support])])
 438     AC_SUBST([LIBUSB])
 439
 440     [# Check for headers.]
 441     AC_CHECK_HEADERS([usb.h], [],
 442       [AC_MSG_ERROR([libusb header file is required to build `grub-emu' with USB support])])
 443   [fi]
 444 [fi]
 445 AC_SUBST([enable_grub_emu])
 446 AC_SUBST([enable_grub_emu_usb])
 447
 448 AC_ARG_ENABLE([grub-fstest],
 449               [AS_HELP_STRING([--enable-grub-fstest],
 450                              [build and install the `grub-fstest' debugging utility])])
 451 AC_SUBST([enable_grub_fstest])
 452
 453 AC_ARG_ENABLE([grub-pe2elf],
 454               [AS_HELP_STRING([--enable-grub-pe2elf],
 455                              [build and install the `grub-pe2elf' conversion utility])])
 456 AC_SUBST([enable_grub_pe2elf])
 457
 458 AC_ARG_ENABLE([grub-mkfont],
 459               [AS_HELP_STRING([--enable-grub-mkfont],
 460                              [build and install the `grub-mkfont' utility])])
 461 if test x"$enable_grub_mkfont" = xyes ; then
 462   # Check for freetype libraries.
 463   AC_CHECK_PROGS([FREETYPE], [freetype-config])
 464   if test "x$FREETYPE" = x ; then
 465     AC_MSG_ERROR([freetype2 libraries are required to build `grub-mkfont'])
 466   fi
 467   freetype_cflags=`freetype-config --cflags`
 468   freetype_libs=`freetype-config --libs`
 469 fi
 470 AC_SUBST([enable_grub_mkfont])
 471 AC_SUBST([freetype_cflags])
 472 AC_SUBST([freetype_libs])
 473
 474 # Output files.
 475 grub_CHECK_LINK_DIR
 476 if test x"$link_dir" = xyes ; then
 477   AC_CONFIG_LINKS([include/grub/cpu:include/grub/$target_cpu
 478         include/grub/machine:include/grub/$target_cpu/$platform])
 479 else
 480   mkdir -p include/grub 2>/dev/null
 481   rm -rf include/grub/cpu
 482   cp -rp $srcdir/include/grub/$target_cpu include/grub/cpu 2>/dev/null
 483   rm -rf include/grub/machine
 484   cp -rp $srcdir/include/grub/$target_cpu/$platform include/grub/machine 2>/dev/null
 485 fi
 486 AC_CONFIG_FILES([Makefile gensymlist.sh genkernsyms.sh])
 487 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 488 AC_OUTPUT