aclocal.m4

   1 dnl Check whether target compiler is working
   2 AC_DEFUN(grub_PROG_TARGET_CC,
   3 [AC_MSG_CHECKING([whether target compiler is working])
   4 AC_CACHE_VAL(grub_cv_prog_target_cc,
   5 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
   6                 [grub_cv_prog_target_cc=yes],
   7                 [grub_cv_prog_target_cc=no])
   8 ])
   9 AC_MSG_RESULT([$grub_cv_prog_target_cc])
  10
  11 if test "x$grub_cv_prog_target_cc" = xno; then
  12   AC_MSG_ERROR([cannot compile for the target])
  13 fi
  14 ])
  15
  16
  17 dnl grub_ASM_USCORE checks if C symbols get an underscore after
  18 dnl compiling to assembler.
  19 dnl Written by Pavel Roskin. Based on grub_ASM_EXT_C written by
  20 dnl Erich Boleyn and modified by Yoshinori K. Okuji.
  21 AC_DEFUN(grub_ASM_USCORE,
  22 [AC_REQUIRE([AC_PROG_CC])
  23 AC_MSG_CHECKING([if C symbols get an underscore after compilation])
  24 AC_CACHE_VAL(grub_cv_asm_uscore,
  25 [cat > conftest.c <<\EOF
  26 int
  27 func (int *list)
  28 {
  29   *list = 0;
  30   return *list;
  31 }
  32 EOF
  33
  34 if AC_TRY_COMMAND([${CC-cc} ${CFLAGS} -S conftest.c]) && test -s conftest.s; then
  35   true
  36 else
  37   AC_MSG_ERROR([${CC-cc} failed to produce assembly code])
  38 fi
  39
  40 if grep _func conftest.s >/dev/null 2>&1; then
  41   grub_cv_asm_uscore=yes
  42 else
  43   grub_cv_asm_uscore=no
  44 fi
  45
  46 rm -f conftest*])
  47
  48 if test "x$grub_cv_asm_uscore" = xyes; then
  49   AC_DEFINE_UNQUOTED([HAVE_ASM_USCORE], $grub_cv_asm_uscore,
  50     [Define if C symbols get an underscore after compilation])
  51 fi
  52
  53 AC_MSG_RESULT([$grub_cv_asm_uscore])
  54 ])
  55
  56
  57 dnl Some versions of `objcopy -O binary' vary their output depending
  58 dnl on the link address.
  59 AC_DEFUN(grub_PROG_OBJCOPY_ABSOLUTE,
  60 [AC_MSG_CHECKING([whether ${OBJCOPY} works for absolute addresses])
  61 AC_CACHE_VAL(grub_cv_prog_objcopy_absolute,
  62 [cat > conftest.c <<\EOF
  63 void
  64 cmain (void)
  65 {
  66    *((int *) 0x1000) = 2;
  67 }
  68 EOF
  69
  70 if AC_TRY_EVAL(ac_compile) && test -s conftest.o; then :
  71 else
  72   AC_MSG_ERROR([${CC-cc} cannot compile C source code])
  73 fi
  74 grub_cv_prog_objcopy_absolute=yes
  75 for link_addr in 2000 8000 7C00; do
  76   if AC_TRY_COMMAND([${CC-cc} ${CFLAGS} -nostdlib ${TARGET_IMG_LDFLAGS_AC} -Wl,-Ttext -Wl,$link_addr conftest.o -o conftest.exec]); then :
  77   else
  78     AC_MSG_ERROR([${CC-cc} cannot link at address $link_addr])
  79   fi
  80   if AC_TRY_COMMAND([${OBJCOPY-objcopy} --only-section=.text -O binary conftest.exec conftest]); then :
  81   else
  82     AC_MSG_ERROR([${OBJCOPY-objcopy} cannot create binary files])
  83   fi
  84   if test ! -f conftest.old || AC_TRY_COMMAND([cmp -s conftest.old conftest]); then
  85     mv -f conftest conftest.old
  86   else
  87     grub_cv_prog_objcopy_absolute=no
  88     break
  89   fi
  90 done
  91 rm -f conftest*])
  92 AC_MSG_RESULT([$grub_cv_prog_objcopy_absolute])
  93
  94 if test "x$grub_cv_prog_objcopy_absolute" = xno; then
  95   AC_MSG_ERROR([GRUB requires a working absolute objcopy; upgrade your binutils])
  96 fi
  97 ])
  98
  99
 100 dnl Supply --build-id=none to ld if building modules.
 101 dnl This suppresses warnings from ld on some systems
 102 AC_DEFUN(grub_PROG_LD_BUILD_ID_NONE,
 103 [AC_MSG_CHECKING([whether linker accepts --build-id=none])
 104 AC_CACHE_VAL(grub_cv_prog_ld_build_id_none,
 105 [save_LDFLAGS="$LDFLAGS"
 106 LDFLAGS="$LDFLAGS -Wl,--build-id=none"
 107 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 108                [grub_cv_prog_ld_build_id_none=yes],
 109                [grub_cv_prog_ld_build_id_none=no])
 110 LDFLAGS="$save_LDFLAGS"
 111 ])
 112 AC_MSG_RESULT([$grub_cv_prog_ld_build_id_none])
 113
 114 if test "x$grub_cv_prog_ld_build_id_none" = xyes; then
 115   TARGET_LDFLAGS="$TARGET_LDFLAGS -Wl,--build-id=none"
 116 fi
 117 ])
 118
 119
 120 dnl Mass confusion!
 121 dnl Older versions of GAS interpret `.code16' to mean ``generate 32-bit
 122 dnl instructions, but implicitly insert addr32 and data32 bytes so
 123 dnl that the code works in real mode''.
 124 dnl
 125 dnl Newer versions of GAS interpret `.code16' to mean ``generate 16-bit
 126 dnl instructions,'' which seems right.  This requires the programmer
 127 dnl to explicitly insert addr32 and data32 instructions when they want
 128 dnl them.
 129 dnl
 130 dnl We only support the newer versions, because the old versions cause
 131 dnl major pain, by requiring manual assembly to get 16-bit instructions into
 132 dnl asm files.
 133 AC_DEFUN(grub_I386_ASM_ADDR32,
 134 [AC_REQUIRE([AC_PROG_CC])
 135 AC_REQUIRE([grub_I386_ASM_PREFIX_REQUIREMENT])
 136 AC_MSG_CHECKING([for .code16 addr32 assembler support])
 137 AC_CACHE_VAL(grub_cv_i386_asm_addr32,
 138 [cat > conftest.s.in <<\EOF
 139         .code16
 140 l1:     @ADDR32@        movb    %al, l1
 141 EOF
 142
 143 if test "x$grub_cv_i386_asm_prefix_requirement" = xyes; then
 144   sed -e s/@ADDR32@/addr32/ < conftest.s.in > conftest.s
 145 else
 146   sed -e s/@ADDR32@/addr32\;/ < conftest.s.in > conftest.s
 147 fi
 148
 149 if AC_TRY_COMMAND([${CC-cc} ${CFLAGS} -c conftest.s]) && test -s conftest.o; then
 150   grub_cv_i386_asm_addr32=yes
 151 else
 152   grub_cv_i386_asm_addr32=no
 153 fi
 154
 155 rm -f conftest*])
 156
 157 AC_MSG_RESULT([$grub_cv_i386_asm_addr32])])
 158
 159
 160 dnl Later versions of GAS requires that addr32 and data32 prefixes
 161 dnl appear in the same lines as the instructions they modify, while
 162 dnl earlier versions requires that they appear in separate lines.
 163 AC_DEFUN(grub_I386_ASM_PREFIX_REQUIREMENT,
 164 [AC_REQUIRE([AC_PROG_CC])
 165 AC_MSG_CHECKING(dnl
 166 [whether addr32 must be in the same line as the instruction])
 167 AC_CACHE_VAL(grub_cv_i386_asm_prefix_requirement,
 168 [cat > conftest.s <<\EOF
 169         .code16
 170 l1:     addr32  movb    %al, l1
 171 EOF
 172
 173 if AC_TRY_COMMAND([${CC-cc} ${CFLAGS} -c conftest.s]) && test -s conftest.o; then
 174   grub_cv_i386_asm_prefix_requirement=yes
 175 else
 176   grub_cv_i386_asm_prefix_requirement=no
 177 fi
 178
 179 rm -f conftest*])
 180
 181 if test "x$grub_cv_i386_asm_prefix_requirement" = xyes; then
 182   grub_tmp_addr32="addr32"
 183   grub_tmp_data32="data32"
 184 else
 185   grub_tmp_addr32="addr32;"
 186   grub_tmp_data32="data32;"
 187 fi
 188
 189 AC_DEFINE_UNQUOTED([ADDR32], $grub_tmp_addr32,
 190   [Define it to \"addr32\" or \"addr32;\" to make GAS happy])
 191 AC_DEFINE_UNQUOTED([DATA32], $grub_tmp_data32,
 192   [Define it to \"data32\" or \"data32;\" to make GAS happy])
 193
 194 AC_MSG_RESULT([$grub_cv_i386_asm_prefix_requirement])])
 195
 196
 197 dnl Older versions of GAS require that absolute indirect calls/jumps are
 198 dnl not prefixed with `*', while later versions warn if not prefixed.
 199 AC_DEFUN(grub_I386_ASM_ABSOLUTE_WITHOUT_ASTERISK,
 200 [AC_REQUIRE([AC_PROG_CC])
 201 AC_MSG_CHECKING(dnl
 202 [whether an absolute indirect call/jump must not be prefixed with an asterisk])
 203 AC_CACHE_VAL(grub_cv_i386_asm_absolute_without_asterisk,
 204 [cat > conftest.s <<\EOF
 205         lcall   *(offset)
 206 offset:
 207         .long   0
 208         .word   0
 209 EOF
 210
 211 if AC_TRY_COMMAND([${CC-cc} ${CFLAGS} -c conftest.s]) && test -s conftest.o; then
 212   grub_cv_i386_asm_absolute_without_asterisk=no
 213 else
 214   grub_cv_i386_asm_absolute_without_asterisk=yes
 215 fi
 216
 217 rm -f conftest*])
 218
 219 if test "x$grub_cv_i386_asm_absolute_without_asterisk" = xyes; then
 220   AC_DEFINE([ABSOLUTE_WITHOUT_ASTERISK], 1,
 221             [Define it if GAS requires that absolute indirect calls/jumps are not prefixed with an asterisk])
 222 fi
 223
 224 AC_MSG_RESULT([$grub_cv_i386_asm_absolute_without_asterisk])])
 225
 226
 227 dnl Check what symbol is defined as a bss start symbol.
 228 dnl Written by Michael Hohmoth and Yoshinori K. Okuji.
 229 AC_DEFUN(grub_CHECK_BSS_START_SYMBOL,
 230 [AC_REQUIRE([AC_PROG_CC])
 231 AC_MSG_CHECKING([if __bss_start is defined by the compiler])
 232 AC_CACHE_VAL(grub_cv_check_uscore_uscore_bss_start_symbol,
 233 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 234                 [[asm ("incl __bss_start")]])],
 235                 [grub_cv_check_uscore_uscore_bss_start_symbol=yes],
 236                 [grub_cv_check_uscore_uscore_bss_start_symbol=no])])
 237
 238 AC_MSG_RESULT([$grub_cv_check_uscore_uscore_bss_start_symbol])
 239
 240 AC_MSG_CHECKING([if edata is defined by the compiler])
 241 AC_CACHE_VAL(grub_cv_check_edata_symbol,
 242 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 243                 [[asm ("incl edata")]])],
 244                 [grub_cv_check_edata_symbol=yes],
 245                 [grub_cv_check_edata_symbol=no])])
 246
 247 AC_MSG_RESULT([$grub_cv_check_edata_symbol])
 248
 249 AC_MSG_CHECKING([if _edata is defined by the compiler])
 250 AC_CACHE_VAL(grub_cv_check_uscore_edata_symbol,
 251 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 252                 [[asm ("incl _edata")]])],
 253                 [grub_cv_check_uscore_edata_symbol=yes],
 254                 [grub_cv_check_uscore_edata_symbol=no])])
 255
 256 AC_MSG_RESULT([$grub_cv_check_uscore_edata_symbol])
 257
 258 AH_TEMPLATE([BSS_START_SYMBOL], [Define it to one of __bss_start, edata and _edata])
 259
 260 if test "x$grub_cv_check_uscore_uscore_bss_start_symbol" = xyes; then
 261   AC_DEFINE([BSS_START_SYMBOL], [__bss_start])
 262 elif test "x$grub_cv_check_edata_symbol" = xyes; then
 263   AC_DEFINE([BSS_START_SYMBOL], [edata])
 264 elif test "x$grub_cv_check_uscore_edata_symbol" = xyes; then
 265   AC_DEFINE([BSS_START_SYMBOL], [_edata])
 266 else
 267   AC_MSG_ERROR([none of __bss_start, edata or _edata is defined])
 268 fi
 269 ])
 270
 271 dnl Check what symbol is defined as an end symbol.
 272 dnl Written by Yoshinori K. Okuji.
 273 AC_DEFUN(grub_CHECK_END_SYMBOL,
 274 [AC_REQUIRE([AC_PROG_CC])
 275 AC_MSG_CHECKING([if end is defined by the compiler])
 276 AC_CACHE_VAL(grub_cv_check_end_symbol,
 277 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 278                 [[asm ("incl end")]])],
 279                 [grub_cv_check_end_symbol=yes],
 280                 [grub_cv_check_end_symbol=no])])
 281
 282 AC_MSG_RESULT([$grub_cv_check_end_symbol])
 283
 284 AC_MSG_CHECKING([if _end is defined by the compiler])
 285 AC_CACHE_VAL(grub_cv_check_uscore_end_symbol,
 286 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 287                 [[asm ("incl _end")]])],
 288                 [grub_cv_check_uscore_end_symbol=yes],
 289                 [grub_cv_check_uscore_end_symbol=no])])
 290
 291 AC_MSG_RESULT([$grub_cv_check_uscore_end_symbol])
 292
 293 AH_TEMPLATE([END_SYMBOL], [Define it to either end or _end])
 294
 295 if test "x$grub_cv_check_end_symbol" = xyes; then
 296   AC_DEFINE([END_SYMBOL], [end])
 297 elif test "x$grub_cv_check_uscore_end_symbol" = xyes; then
 298   AC_DEFINE([END_SYMBOL], [_end])
 299 else
 300   AC_MSG_ERROR([neither end nor _end is defined])
 301 fi
 302 ])
 303
 304 dnl Check if the C compiler has a bug while using nested functions when
 305 dnl mregparm is used on the i386.  Some gcc versions do not pass the third
 306 dnl parameter correctly to the nested function.
 307 dnl Written by Marco Gerards.
 308 AC_DEFUN(grub_I386_CHECK_REGPARM_BUG,
 309 [AC_REQUIRE([AC_PROG_CC])
 310 AC_MSG_CHECKING([if GCC has the regparm=3 bug])
 311 AC_CACHE_VAL(grub_cv_i386_check_nested_functions,
 312 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 313 [[
 314 static int
 315 test (int *n)
 316 {
 317   return *n == -1;
 318 }
 319
 320 static int
 321 testfunc (int __attribute__ ((__regparm__ (3))) (*hook) (int a, int b, int *c))
 322 {
 323   int a = 0;
 324   int b = 0;
 325   int c = -1;
 326   return hook (a, b, &c);
 327 }
 328
 329 int
 330 main (void)
 331 {
 332   int __attribute__ ((__regparm__ (3))) nestedfunc (int a, int b, int *c)
 333     {
 334       return a == b && test (c);
 335     }
 336   return testfunc (nestedfunc) ? 0 : 1;
 337 }
 338 ]])],
 339         [grub_cv_i386_check_nested_functions=no],
 340         [grub_cv_i386_check_nested_functions=yes],
 341         [grub_cv_i386_check_nested_functions=yes])])
 342
 343 AC_MSG_RESULT([$grub_cv_i386_check_nested_functions])
 344
 345 if test "x$grub_cv_i386_check_nested_functions" = xyes; then
 346   AC_DEFINE([NESTED_FUNC_ATTR],
 347         [__attribute__ ((__regparm__ (1)))],
 348         [Catch gcc bug])
 349 else
 350 dnl Unfortunately, the above test does not detect a bug in gcc-4.0.
 351 dnl So use regparm 2 until a better test is found.
 352   AC_DEFINE([NESTED_FUNC_ATTR],
 353         [__attribute__ ((__regparm__ (1)))],
 354         [Catch gcc bug])
 355 fi
 356 ])
 357
 358 dnl Check if the C compiler generates calls to `__enable_execute_stack()'.
 359 AC_DEFUN(grub_CHECK_ENABLE_EXECUTE_STACK,[
 360 AC_MSG_CHECKING([whether `$CC' generates calls to `__enable_execute_stack()'])
 361 AC_LANG_CONFTEST([[
 362 void f (int (*p) (void));
 363 void g (int i)
 364 {
 365   int nestedfunc (void) { return i; }
 366   f (nestedfunc);
 367 }
 368 ]])
 369 if AC_TRY_COMMAND([${CC-cc} ${CFLAGS} -S conftest.c]) && test -s conftest.s; then
 370   true
 371 else
 372   AC_MSG_ERROR([${CC-cc} failed to produce assembly code])
 373 fi
 374 if grep __enable_execute_stack conftest.s >/dev/null 2>&1; then
 375   AC_DEFINE([NEED_ENABLE_EXECUTE_STACK], 1,
 376             [Define to 1 if GCC generates calls to __enable_execute_stack()])
 377   AC_MSG_RESULT([yes])
 378 else
 379   AC_MSG_RESULT([no])
 380 fi
 381 rm -f conftest*
 382 ])
 383
 384 \f
 385 dnl Check if the C compiler supports `-fstack-protector'.
 386 AC_DEFUN(grub_CHECK_STACK_PROTECTOR,[
 387 [# Smashing stack protector.
 388 ssp_possible=yes]
 389 AC_MSG_CHECKING([whether `$CC' accepts `-fstack-protector'])
 390 # Is this a reliable test case?
 391 AC_LANG_CONFTEST([[void foo (void) { volatile char a[8]; a[3]; }]])
 392 [# `$CC -c -o ...' might not be portable.  But, oh, well...  Is calling
 393 # `ac_compile' like this correct, after all?
 394 if eval "$ac_compile -S -fstack-protector -o conftest.s" 2> /dev/null; then]
 395   AC_MSG_RESULT([yes])
 396   [# Should we clear up other files as well, having called `AC_LANG_CONFTEST'?
 397   rm -f conftest.s
 398 else
 399   ssp_possible=no]
 400   AC_MSG_RESULT([no])
 401 [fi]
 402 ])
 403
 404 dnl Check if the C compiler supports `-mstack-arg-probe' (Cygwin).
 405 AC_DEFUN(grub_CHECK_STACK_ARG_PROBE,[
 406 [# Smashing stack arg probe.
 407 sap_possible=yes]
 408 AC_MSG_CHECKING([whether `$CC' accepts `-mstack-arg-probe'])
 409 AC_LANG_CONFTEST([[void foo (void) { volatile char a[8]; a[3]; }]])
 410 [if eval "$ac_compile -S -mstack-arg-probe -o conftest.s" 2> /dev/null; then]
 411   AC_MSG_RESULT([yes])
 412   [# Should we clear up other files as well, having called `AC_LANG_CONFTEST'?
 413   rm -f conftest.s
 414 else
 415   sap_possible=no]
 416   AC_MSG_RESULT([no])
 417 [fi]
 418 ])
 419
 420 dnl Check if ln can handle directories properly (mingw).
 421 AC_DEFUN(grub_CHECK_LINK_DIR,[
 422 AC_MSG_CHECKING([whether ln can handle directories properly])
 423 [mkdir testdir 2>/dev/null
 424 case $srcdir in
 425 [\\/$]* | ?:[\\/]* ) reldir=$srcdir/include/grub/util ;;
 426     *) reldir=../$srcdir/include/grub/util ;;
 427 esac
 428 if ln -s $reldir testdir/util 2>/dev/null ; then]
 429   AC_MSG_RESULT([yes])
 430   [link_dir=yes
 431 else
 432   link_dir=no]
 433   AC_MSG_RESULT([no])
 434 [fi
 435 rm -rf testdir]
 436 ])