CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 # PROJECT_VERSION should have the following structure:
   5 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   6 set(PROJECT_VERSION "4.0.99-dev-20100315"
   7     CACHE STRING "Gromacs version string")
   8
   9 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  10 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  11
  12 ########################################################################
  13 # User input options                                                   #
  14 ########################################################################
  15 option(GMX_DOUBLE "Use double precision" OFF)
  16 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  17 option(GMX_THREADS    "Build a parallel (threaded-based) version of GROMACS: (doesn't work yet!)" ON)
  18 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  19 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  20 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  21 set(GMX_ACCELERATION "none"
  22     CACHE STRING "Accelerated kernels. Pick one of: SSE, BlueGene, Power6, ia64, altivec")
  23
  24 set(GMX_FFT_LIBRARY "fftw3"
  25     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  26 option(GMX_DISABLE_FFTW_MEASURE
  27        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  28 set(GMX_QMMM_PROGRAM "none"
  29     CACHE STRING "QM package choices: none,gaussian,mopac,gamess")
  30 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  31 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  32 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  33 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  34 mark_as_advanced(GMX_MPI_IN_PLACE)
  35
  36 enable_language(C)
  37
  38 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  39 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  40 option(USE_VERSION_H "Generate development version string/information" ON)
  41
  42 #######################################################################
  43 # Check for options incompatible with OpenMM build                    #
  44 #######################################################################
  45 if(GMX_OPENMM)
  46     cmake_minimum_required(VERSION 2.6.4)
  47     # we'll use the built-in fft to avoid unnecessary dependencies
  48     set (GMX_FFT_LIBRARY "fftpack")
  49     if(GMX_MPI)
  50         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
  51     endif(GMX_MPI)
  52     if(GMX_THREADS)
  53         message(STATUS "Threads not compatible with OpenMM build, disabled")
  54         set(GMX_THREADS OFF)
  55     endif(GMX_THREADS)
  56     if(GMX_SOFTWARE_INVSQRT)
  57         set(GMX_SOFTWARE_INVSQRT OFF)
  58     endif(GMX_SOFTWARE_INVSQRT)
  59     if(NOT GMX_ACCELERATION MATCHES "none")
  60         message(WARNING "The OpenMM build does not support other acceleration modes!")
  61         set(GMX_ACCELERATION "none")
  62     endif()
  63     if(GMX_FAHCORE)
  64         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
  65     endif(GMX_FAHCORE)
  66 endif(GMX_OPENMM)
  67
  68
  69 ########################################################################
  70 # Fix stupid flags on MSVC
  71 ########################################################################
  72 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  73     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  74     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  75     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  76     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  77 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  78
  79 set(GMX_EXTRA_LIBRARIES)
  80
  81 ########################################################################
  82 #Process MPI settings
  83 ########################################################################
  84 if(GMX_MPI)
  85     if(GMX_THREADS)
  86         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
  87         set(GMX_THREADS OFF CACHE BOOL
  88             "Thread-based parallelization conflicts with MPI." FORCE)
  89     endif(GMX_THREADS)
  90     find_package(MPI)
  91     if(MPI_FOUND)
  92         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
  93         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
  94
  95         include_directories(${MPI_INCLUDE_PATH})
  96         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
  97         add_definitions( -DMPI ) #for FAHCORE
  98         include(gmxTestMPI_IN_PLACE)
  99         if (GMX_MPI_IN_PLACE)
 100             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 101         endif (GMX_MPI_IN_PLACE)
 102     else(MPI_FOUND)
 103         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 104     endif(MPI_FOUND)
 105     include(gmxTestCatamount)
 106     gmx_test_catamount(GMX_CRAY_XT3)
 107     if(GMX_CRAY_XT3)
 108         set(GMX_NO_SYSTEM 1)
 109         set(GMX_NO_NICE 1)
 110     endif(GMX_CRAY_XT3)
 111     set(GMX_LIB_MPI 1)
 112 endif(GMX_MPI)
 113
 114 ########################################################################
 115 # Basic system tests (standard libraries, headers, functions, types)   #
 116 ########################################################################
 117 include(CheckIncludeFiles)
 118 check_include_files(string.h     HAVE_STRING_H)
 119 check_include_files(limits.h     HAVE_LIMITS_H)
 120 check_include_files(memory.h     HAVE_MEMORY_H)
 121 check_include_files(unistd.h     HAVE_UNISTD_H)
 122 check_include_files(pwd.h        HAVE_PWD_H)
 123 check_include_files(stdint.h     HAVE_STDINT_H)
 124 check_include_files(stdlib.h     HAVE_STDLIB_H)
 125 check_include_files(pthread.h    HAVE_PTHREAD_H)
 126 check_include_files(dirent.h     HAVE_DIRENT_H)
 127 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 128 check_include_files(regex.h      HAVE_REGEX_H)
 129 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 130 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 131 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 132 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 133 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 134 # SSE support
 135 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 136 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 137 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 138 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 139
 140 include(CheckFunctionExists)
 141 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 142 check_function_exists(strdup            HAVE_STRDUP)
 143 check_function_exists(vprintf           HAVE_VPRINTF)
 144 check_function_exists(memcmp            HAVE_MEMCMP)
 145 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 146 check_function_exists(isnan             HAVE_ISNAN)
 147 check_function_exists(_isnan            HAVE__ISNAN)
 148 check_function_exists(isfinite          HAVE_ISFINITE)
 149 check_function_exists(_isfinite         HAVE__ISFINITE)
 150 # After large files? check_function_exists(fseeko     HAVE_FSEEKO)
 151
 152 include(CheckLibraryExists)
 153 check_library_exists(m sqrt "" HAVE_LIBM)
 154
 155 include(CheckTypeSize)
 156 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 157 check_type_size("int"           SIZEOF_INT)
 158 check_type_size("long int"      SIZEOF_LONG_INT)
 159 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 160 check_type_size("off_t"         SIZEOF_OFF_T)
 161 check_type_size("void *"        SIZEOF_VOIDP)
 162
 163 # Check for some basic types that we *need*, so set these to int if they are not present
 164 check_type_size(uid_t uid_t)
 165 if(NOT uid_t)
 166   set(uid_t int)
 167 else(NOT uid_t)
 168   set(uid_t 0)
 169 endif(NOT uid_t)
 170
 171 check_type_size(gid_t gid_t)
 172 if(NOT gid_t)
 173   set(gid_t 1)
 174 else(NOT gid_t)
 175   set(gid_t 0)
 176 endif(NOT gid_t)
 177
 178 check_type_size(size_t size_t)
 179 if(NOT size_t)
 180   set(size_t int)
 181 else(NOT size_t)
 182   set(size_t 0)
 183 endif(NOT size_t)
 184
 185 check_type_size(off_t off_t)
 186 if(NOT off_t)
 187   set(off_t int)
 188 else(NOT off_t)
 189   set(off_t 0)
 190 endif(NOT off_t)
 191
 192 include(TestBigEndian)
 193 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 194
 195
 196
 197 ########################################################################
 198 # Find external packages                                               #
 199 ########################################################################
 200
 201 find_package(LibXml2)
 202 if(LIBXML2_FOUND)
 203     include_directories(${LIBXML2_INCLUDE_DIR})
 204     list(APPEND GMX_EXTRA_LIBRARIES ${LIBXML2_LIBRARIES})
 205     set(HAVE_LIBXML2 1)
 206 endif(LIBXML2_FOUND)
 207
 208 find_package(X11)
 209 # X11 includes/libraries are only set in the ngmx subdirectory!
 210 if(X11_FOUND)
 211     set(HAVE_X11 1)
 212 endif(X11_FOUND)
 213
 214 if(GMX_THREADS)
 215     include(ThreadMPI)
 216     set(THREAD_MPI_LIB thread_mpi)
 217     set(GMX_MPI 1)
 218     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 219     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 220         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 221     endif()
 222 endif(GMX_THREADS)
 223
 224 if(GMX_OPENMM)
 225     set(CUDA_BUILD_EMULATION OFF)
 226     find_package(CUDA 2.3 REQUIRED)
 227     add_definitions(-DGMX_OPENMM)
 228     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 229         set(CUDA_VERBOSE_BUILD ON)
 230     endif()
 231     find_package(OpenMM)
 232 endif(GMX_OPENMM)
 233
 234 if(APPLE)
 235    find_library(ACCELERATE_FRAMEWORK Accelerate)
 236    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 237 endif(APPLE)
 238
 239 # only bother with finding git and using version.h if the source is a git repo
 240 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 241     if(USE_VERSION_H)
 242         # We need at least git v1.5.1 be able to parse git's date output. If not
 243         # fund or the version is too small, we can't generate version information.
 244         find_package(Git 1.5.1)
 245         if(NOT Git_FOUND OR Git_VERSION VERSION_LESS "1.5.1")
 246             message("No compatible git version found, won't be able to generate proper development version information.")
 247         endif()
 248     endif()
 249 else()
 250     set(USE_VERSION_H OFF)
 251 endif()
 252
 253 ########################################################################
 254 # Generate development version info for cache
 255 ########################################################################
 256 # set(GEN_VERSION_INFO_INTERNAL "ON")
 257 # include(gmxGenerateVersionString)
 258
 259 ########################################################################
 260 # Our own GROMACS tests
 261 ########################################################################
 262
 263 include(gmxCFlags)
 264 gmx_c_flags()
 265
 266 add_definitions( -DHAVE_CONFIG_H )
 267 include_directories(${CMAKE_BINARY_DIR}/src)
 268 include_directories(${CMAKE_SOURCE_DIR}/include)
 269
 270 include(gmxCheckBuildUserTime)
 271 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 272
 273 include(gmxTestFloatFormat)
 274 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 275                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 276                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 277
 278 include(gmxTestLargeFiles)
 279 gmx_test_large_files(GMX_LARGEFILES)
 280
 281 include(gmxTestSignal)
 282 gmx_test_retsigtype(RETSIGTYPE)
 283
 284 include(gmxTestInline)
 285 gmx_test_inline(INLINE_KEYWORD)
 286
 287 include(gmxTestPipes)
 288 gmx_test_pipes(HAVE_PIPES)
 289
 290 include(gmxTestInlineASM)
 291 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 292 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 293
 294 include(gmxTestXDR)
 295 gmx_test_xdr(GMX_SYSTEM_XDR)
 296 if(NOT GMX_SYSTEM_XDR)
 297     set(GMX_INTERNAL_XDR 1)
 298 endif(NOT GMX_SYSTEM_XDR)
 299
 300 if(GMX_FORTRAN OR GMX_POWER6)
 301     enable_language(Fortran)
 302     include(FortranCInterface)
 303     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 304     if(extra_under_score)
 305         set(extrasuffix "_")
 306     endif(extra_under_score)
 307
 308     if(isupper)
 309         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 310         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 311     else(isupper)
 312         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 313         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 314     endif(isupper)
 315 else(GMX_FORTRAN OR GMX_POWER6)
 316         set(F77_FUNCDEF   "name ## _")
 317         set(F77_FUNCDEF_  "name ## _")
 318 endif(GMX_FORTRAN OR GMX_POWER6)
 319
 320
 321 # Process nonbonded accelerated kernels settings
 322 option(GMX_ASM_USECCOMPILER "Use C compiler for assembly" ON)
 323 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 324 if(${GMX_ACCELERATION} STREQUAL "NONE")
 325   # nothing to do
 326 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 327     if(HAVE_XMMINTRIN_H)
 328         if(GMX_IA32_ASM)
 329           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 330           set(GMX_IA32_SSE 1)
 331         else(GMX_IA32_ASM) #only use intrinsic if not using the ASM loops
 332           set(GMX_SSE 1)
 333         endif(GMX_IA32_ASM)
 334     endif(HAVE_XMMINTRIN_H)
 335     if(HAVE_EMMINTRIN_H)
 336         if(GMX_X86_64_ASM)
 337           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 338           set(GMX_X86_64_SSE 1)
 339         else(GMX_X86_64_ASM)  #only use intrinsic if not using the ASM loops
 340           if(NOT GMX_IA32_ASM)
 341             set(GMX_SSE2 1)
 342           endif(NOT GMX_IA32_ASM)
 343         endif(GMX_X86_64_ASM)
 344     endif(HAVE_EMMINTRIN_H)
 345 #    if(HAVE_PMMINTRIN_H)
 346 #        set(GMX_SSE3 1)
 347 #    endif(HAVE_PMMINTRIN_H)
 348 #    if(HAVE_SMMINTRIN_H)
 349 #        set(GMX_SSE4_1 1)
 350 #    endif(HAVE_SMMINTRIN_H)
 351
 352 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 353     set(GMX_FORTRAN 1)
 354 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 355     set(GMX_BLUEGENE 1)
 356 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 357     set(GMX_POWER6 1)
 358 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 359     set(GMX_IA64_ASM 1)
 360     set(DISABLE_WATERWATER_NLIST 1)
 361     set(DISABLE_WATER_NLIST 1)
 362 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 363     check_include_files(altivec.h HAVE_ALTIVEC_H)
 364     if(HAVE_ALTIVEC_H)
 365         set(GMX_PPC_ALTIVEC 1)
 366     endif(HAVE_ALTIVEC_H)
 367 else(${GMX_ACCELERATION} STREQUAL "NONE")
 368     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 369 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 370
 371
 372
 373
 374
 375
 376
 377 # Process QM/MM Settings
 378 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 379 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 380     set(GMX_QMMM_GAUSSIAN 1)
 381 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 382     set(GMX_QMMM_MOPAC 1)
 383 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 384     set(GMX_QMMM_GAMESS 1)
 385 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 386     # nothing to do
 387 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 388     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, None")
 389 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 390
 391 # Process FFT library settings - if not OpenMM build
 392 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 393 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 394 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 395     if(GMX_DOUBLE)
 396         find_package(FFTW3 REQUIRED)
 397     else(GMX_DOUBLE)
 398         find_package(FFTW3F REQUIRED)
 399     endif(GMX_DOUBLE)
 400
 401     if(NOT FFTW3_FOUND)
 402         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 403     endif(NOT FFTW3_FOUND)
 404
 405     set(GMX_FFT_FFTW3 1)
 406     include_directories(${FFTW3_INCLUDE_DIR})
 407     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW3_LIBRARIES})
 408
 409 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 410 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 411     if(GMX_DOUBLE)
 412         find_package(FFTW2 REQUIRED)
 413     else(GMX_DOUBLE)
 414         find_package(FFTW2F REQUIRED)
 415     endif(GMX_DOUBLE)
 416
 417     if(NOT FFTW2_FOUND)
 418            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 419     endif(NOT FFTW2_FOUND)
 420     include_directories(${FFTW2_INCLUDE_DIR})
 421     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW2_LIBRARIES})
 422
 423     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 424         set(FFTW2_NAME_DFFTW 1)
 425     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 426         set(FFTW2_NAME_SFFTW 1)
 427     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 428         set(FFTW2_NAME_FFTW 1)
 429     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 430
 431     set(GMX_FFT_FFTW2 1)
 432 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 433 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 434     find_package(MKL REQUIRED)
 435     include_directories(${MKL_INCLUDE_DIR})
 436     list(APPEND GMX_EXTRA_LIBRARIES ${MKL_LIBRARIES})
 437
 438     set(GMX_FFT_MKL 1)
 439     set(HAVE_MKL 1)
 440
 441 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 442 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 443 #    set(GMX_FFT_ACML 1)
 444 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 445     MESSAGE(STATUS "Using internal FFT library - fftpack")
 446     set(GMX_FFT_FFTPACK 1)
 447 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 448     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 449 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 450
 451 # MKL has BLAS/LAPACK routines
 452 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 453   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 454   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 455 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 456   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 457   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 458 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 459
 460 # Math and thread libraries must often come after all others when linking...
 461 if(HAVE_LIBM)
 462     list(APPEND GMX_EXTRA_LIBRARIES m)
 463 endif(HAVE_LIBM)
 464
 465
 466
 467 if(GMX_FAHCORE)
 468   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 469       "Path to swindirect.h")
 470   include_directories(${COREWRAP_INCLUDE_DIR})
 471 endif(GMX_FAHCORE)
 472
 473 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 474 set(CMAKE_C_FLAGS ${GROMACS_C_FLAGS} CACHE STRING "Compiler flags")
 475 set(CMAKE_EXE_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} CACHE STRING "Linker flags")
 476
 477 ########################################################################
 478 # Specify install locations and which subdirectories to process        #
 479 ########################################################################
 480 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 481 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 482 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 483 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 484
 485 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 486
 487
 488 add_subdirectory(share)
 489 add_subdirectory(include)
 490 add_subdirectory(man)
 491
 492 add_subdirectory(src)
 493
 494