CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 # PROJECT_VERSION should have the following structure:
   6 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   7 set(PROJECT_VERSION "4.0.99-dev-20100315"
   8     CACHE STRING "Gromacs version string")
   9
  10 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  11 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  12
  13 if(NOT CMAKE_BUILD_TYPE)
  14     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  15 endif(NOT CMAKE_BUILD_TYPE)
  16
  17
  18 ########################################################################
  19 # User input options                                                   #
  20 ########################################################################
  21 option(GMX_DOUBLE "Use double precision" OFF)
  22 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  23 option(GMX_THREADS    "Build a parallel (threaded-based) version of GROMACS: (doesn't work yet!)" ON)
  24 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  25 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  26 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  27 set(GMX_ACCELERATION "none"
  28     CACHE STRING "Accelerated kernels. Pick one of: SSE, BlueGene, Power6, ia64, altivec")
  29
  30 set(GMX_FFT_LIBRARY "fftw3"
  31     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  32 option(GMX_DISABLE_FFTW_MEASURE
  33        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  34 set(GMX_QMMM_PROGRAM "none"
  35     CACHE STRING "QM package choices: none,gaussian,mopac,gamess")
  36 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  37 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  38 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  39 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  40 mark_as_advanced(GMX_MPI_IN_PLACE)
  41
  42 enable_language(C)
  43
  44 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  45 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  46 option(USE_VERSION_H "Generate development version string/information" ON)
  47 option(GMX_DISABLE_GCC41_CHECK "Disable check for (buggy) gcc 4.1.x" OFF)
  48
  49 #######################################################################
  50 # Check for options incompatible with OpenMM build                    #
  51 #######################################################################
  52 if(GMX_OPENMM)
  53     cmake_minimum_required(VERSION 2.6.4)
  54     # we'll use the built-in fft to avoid unnecessary dependencies
  55     set (GMX_FFT_LIBRARY "fftpack")
  56     if(GMX_MPI)
  57         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
  58     endif(GMX_MPI)
  59     if(GMX_THREADS)
  60         message(STATUS "Threads not compatible with OpenMM build, disabled")
  61         set(GMX_THREADS OFF)
  62     endif(GMX_THREADS)
  63     if(GMX_SOFTWARE_INVSQRT)
  64         set(GMX_SOFTWARE_INVSQRT OFF)
  65     endif(GMX_SOFTWARE_INVSQRT)
  66     if(NOT GMX_ACCELERATION MATCHES "none")
  67         message(WARNING "The OpenMM build does not support other acceleration modes!")
  68         set(GMX_ACCELERATION "none")
  69     endif()
  70     if(GMX_FAHCORE)
  71         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
  72     endif(GMX_FAHCORE)
  73 endif(GMX_OPENMM)
  74
  75
  76 ########################################################################
  77 # Fix stupid flags on MSVC
  78 ########################################################################
  79 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  80     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  81     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  82     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  83     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  84 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  85
  86 set(GMX_EXTRA_LIBRARIES)
  87
  88 ########################################################################
  89 #Process MPI settings
  90 ########################################################################
  91 if(GMX_MPI)
  92     if(GMX_THREADS)
  93         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
  94         set(GMX_THREADS OFF CACHE BOOL
  95             "Thread-based parallelization conflicts with MPI." FORCE)
  96     endif(GMX_THREADS)
  97     find_package(MPI)
  98     if(MPI_FOUND)
  99         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 100         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 101
 102         include_directories(${MPI_INCLUDE_PATH})
 103         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 104         add_definitions( -DMPI ) #for FAHCORE
 105         include(gmxTestMPI_IN_PLACE)
 106         if (GMX_MPI_IN_PLACE)
 107             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 108         endif (GMX_MPI_IN_PLACE)
 109     else(MPI_FOUND)
 110         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 111     endif(MPI_FOUND)
 112     include(gmxTestCatamount)
 113     gmx_test_catamount(GMX_CRAY_XT3)
 114     if(GMX_CRAY_XT3)
 115         set(GMX_NO_SYSTEM 1)
 116         set(GMX_NO_NICE 1)
 117     endif(GMX_CRAY_XT3)
 118     set(GMX_LIB_MPI 1)
 119 endif(GMX_MPI)
 120
 121 ########################################################################
 122 # Basic system tests (standard libraries, headers, functions, types)   #
 123 ########################################################################
 124 include(CheckIncludeFiles)
 125 check_include_files(string.h     HAVE_STRING_H)
 126 check_include_files(math.h       HAVE_MATH_H)
 127 check_include_files(limits.h     HAVE_LIMITS_H)
 128 check_include_files(memory.h     HAVE_MEMORY_H)
 129 check_include_files(unistd.h     HAVE_UNISTD_H)
 130 check_include_files(pwd.h        HAVE_PWD_H)
 131 check_include_files(stdint.h     HAVE_STDINT_H)
 132 check_include_files(stdlib.h     HAVE_STDLIB_H)
 133 check_include_files(pthread.h    HAVE_PTHREAD_H)
 134 check_include_files(dirent.h     HAVE_DIRENT_H)
 135 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 136 check_include_files(regex.h      HAVE_REGEX_H)
 137 check_include_files(copyfile.h   HAVE_COPYFILE_H)
 138 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 139 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 140 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 141 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 142 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 143 # SSE support
 144 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 145 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 146 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 147 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 148 check_include_files(io.h                 HAVE_IO_H)
 149
 150
 151 include(CheckFunctionExists)
 152 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 153 check_function_exists(strdup            HAVE_STRDUP)
 154 check_function_exists(vprintf           HAVE_VPRINTF)
 155 check_function_exists(memcmp            HAVE_MEMCMP)
 156 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 157 check_function_exists(isnan             HAVE_ISNAN)
 158 check_function_exists(_isnan            HAVE__ISNAN)
 159 check_function_exists(isfinite          HAVE_ISFINITE)
 160 check_function_exists(_isfinite         HAVE__ISFINITE)
 161 check_function_exists(fsync             HAVE_FSYNC)
 162 check_function_exists(_fileno           HAVE__FILENO)
 163 check_function_exists(fileno            HAVE_FILENO)
 164 check_function_exists(_commit           HAVE__COMMIT)
 165 check_function_exists(copyfile          HAVE_COPYFILE)
 166 # check_function_exists(CopyFile          HAVE_WIN_COPYFILE)
 167 # After large files? check_function_exists(fseeko     HAVE_FSEEKO)
 168
 169 include(CheckLibraryExists)
 170 check_library_exists(m sqrt "" HAVE_LIBM)
 171 check_library_exists(m cbrt "" HAVE_CBRT)
 172
 173 include(CheckTypeSize)
 174 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 175 check_type_size("int"           SIZEOF_INT)
 176 check_type_size("long int"      SIZEOF_LONG_INT)
 177 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 178 check_type_size("off_t"         SIZEOF_OFF_T)
 179 check_type_size("void *"        SIZEOF_VOIDP)
 180
 181 if (SIZEOF_VOIDP LESS 8)
 182     set(GMX_64_BIT FALSE)
 183 else (SIZEOF_VOIDP LESS 8)
 184     set(GMX_64_BIT TRUE)
 185 endif (SIZEOF_VOIDP LESS 8)
 186
 187 # Check for some basic types that we *need*, so set these to int if they are not present
 188 check_type_size(uid_t uid_t)
 189 if(NOT uid_t)
 190   set(uid_t int)
 191 else(NOT uid_t)
 192   set(uid_t 0)
 193 endif(NOT uid_t)
 194
 195 check_type_size(gid_t gid_t)
 196 if(NOT gid_t)
 197   set(gid_t 1)
 198 else(NOT gid_t)
 199   set(gid_t 0)
 200 endif(NOT gid_t)
 201
 202 check_type_size(size_t size_t)
 203 if(NOT size_t)
 204   set(size_t int)
 205 else(NOT size_t)
 206   set(size_t 0)
 207 endif(NOT size_t)
 208
 209 check_type_size(off_t off_t)
 210 if(NOT off_t)
 211   set(off_t int)
 212 else(NOT off_t)
 213   set(off_t 0)
 214 endif(NOT off_t)
 215
 216 include(TestBigEndian)
 217 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 218
 219
 220
 221
 222 ########################################################################
 223 # Find external packages                                               #
 224 ########################################################################
 225
 226 find_package(LibXml2)
 227 if(LIBXML2_FOUND)
 228     include_directories(${LIBXML2_INCLUDE_DIR})
 229     list(APPEND GMX_EXTRA_LIBRARIES ${LIBXML2_LIBRARIES})
 230     set(HAVE_LIBXML2 1)
 231 endif(LIBXML2_FOUND)
 232
 233 find_package(X11)
 234 # X11 includes/libraries are only set in the ngmx subdirectory!
 235 if(X11_FOUND)
 236     set(HAVE_X11 1)
 237 endif(X11_FOUND)
 238
 239 if(GMX_THREADS)
 240     include(ThreadMPI)
 241     set(THREAD_MPI_LIB thread_mpi)
 242     set(GMX_MPI 1)
 243     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 244     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 245         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 246     endif()
 247 endif(GMX_THREADS)
 248
 249 if(GMX_OPENMM)
 250     set(CUDA_BUILD_EMULATION OFF)
 251     find_package(CUDA 2.3 REQUIRED)
 252     add_definitions(-DGMX_OPENMM)
 253     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 254         set(CUDA_VERBOSE_BUILD ON)
 255     endif()
 256     find_package(OpenMM)
 257 endif(GMX_OPENMM)
 258
 259 if(APPLE)
 260    find_library(ACCELERATE_FRAMEWORK Accelerate)
 261    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 262 endif(APPLE)
 263
 264 # only bother with finding git and using version.h if the source is a git repo
 265 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 266     if(USE_VERSION_H)
 267         # We need at least git v1.5.1 be able to parse git's date output. If not
 268         # fund or the version is too small, we can't generate version information.
 269         find_package(Git 1.5.1)
 270         # this should at some point become VERSION_LESS
 271         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 272             message("No compatible git version found, won't be able to generate proper development version information.")
 273         endif()
 274     endif()
 275 else()
 276     set(USE_VERSION_H OFF)
 277 endif()
 278
 279 if (GMX_DLOPEN)
 280     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 281 endif (GMX_DLOPEN)
 282
 283 ########################################################################
 284 # Generate development version info for cache
 285 ########################################################################
 286 # set(GEN_VERSION_INFO_INTERNAL "ON")
 287 # include(gmxGenerateVersionString)
 288
 289 ########################################################################
 290 # Our own GROMACS tests
 291 ########################################################################
 292
 293 include(CheckCCompilerFlag)
 294 include(CheckCXXCompilerFlag)
 295
 296 # check for buggy GCC 4.1.x
 297 include(gmxCheckGCCVersion)
 298
 299 include(gmxCFlags)
 300 gmx_c_flags()
 301
 302 add_definitions( -DHAVE_CONFIG_H )
 303 include_directories(${CMAKE_BINARY_DIR}/src)
 304 include_directories(${CMAKE_SOURCE_DIR}/include)
 305
 306 include(gmxCheckBuildUserTime)
 307 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 308
 309 include(gmxTestFloatFormat)
 310 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 311                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 312                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 313
 314 include(gmxTestLargeFiles)
 315 gmx_test_large_files(GMX_LARGEFILES)
 316
 317 include(gmxTestSignal)
 318 gmx_test_retsigtype(RETSIGTYPE)
 319
 320 include(gmxTestInline)
 321 gmx_test_inline(INLINE_KEYWORD)
 322
 323 include(gmxTestPipes)
 324 gmx_test_pipes(HAVE_PIPES)
 325
 326 include(gmxTestInlineASM)
 327 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 328 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 329
 330 # reasonable defaults for fast binaries.
 331 if (NOT DEFINED GMX_SSE_SET)
 332     if (GMX_X86_GCC_INLINE_ASM)
 333         set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: SSE, BlueGene, Power6, ia64, altivec" FORCE)
 334         if (GMX_64_BIT)
 335             set(GMX_X86_64_ASM ON CACHE BOOL
 336                 "Add SSE assembly files for x86_64" FORCE)
 337         else (GMX_64_BIT)
 338             set(GMX_IA32_ASM ON CACHE BOOL
 339                 "Add SSE assembly files for IA32" FORCE)
 340         endif (GMX_64_BIT)
 341     endif (GMX_X86_GCC_INLINE_ASM)
 342     set (GMX_SSE_SET true CACHE INTERNAL "SSE is set" FORCE)
 343 endif (NOT DEFINED GMX_SSE_SET)
 344
 345
 346
 347
 348 include(gmxTestXDR)
 349 gmx_test_xdr(GMX_SYSTEM_XDR)
 350 if(NOT GMX_SYSTEM_XDR)
 351     set(GMX_INTERNAL_XDR 1)
 352 endif(NOT GMX_SYSTEM_XDR)
 353
 354 if(GMX_FORTRAN OR GMX_POWER6)
 355     enable_language(Fortran)
 356     include(FortranCInterface)
 357     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 358     if(extra_under_score)
 359         set(extrasuffix "_")
 360     endif(extra_under_score)
 361
 362     if(isupper)
 363         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 364         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 365     else(isupper)
 366         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 367         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 368     endif(isupper)
 369 else(GMX_FORTRAN OR GMX_POWER6)
 370         set(F77_FUNCDEF   "name ## _")
 371         set(F77_FUNCDEF_  "name ## _")
 372 endif(GMX_FORTRAN OR GMX_POWER6)
 373
 374
 375 # Process nonbonded accelerated kernels settings
 376 option(GMX_ASM_USECCOMPILER "Use C compiler for assembly" ON)
 377 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 378 if(${GMX_ACCELERATION} STREQUAL "NONE")
 379   # nothing to do
 380 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 381     if (NOT GMX_64_BIT)
 382         # for 32-bit compiles, we might need to turn on sse
 383         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 384         if (XFLAGS_SSE)
 385             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 386         endif (XFLAGS_SSE)
 387         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 388         if (XXFLAGS_SSE)
 389             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 390         endif (XXFLAGS_SSE)
 391     endif (NOT GMX_64_BIT)
 392     if(HAVE_XMMINTRIN_H)
 393         if(GMX_IA32_ASM)
 394           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 395           set(GMX_IA32_SSE 1)
 396         else(GMX_IA32_ASM) #only use intrinsic if not using the ASM loops
 397           set(GMX_SSE 1)
 398         endif(GMX_IA32_ASM)
 399     endif(HAVE_XMMINTRIN_H)
 400     if(HAVE_EMMINTRIN_H)
 401         if(GMX_X86_64_ASM)
 402           option(GMX_ASM_USEASM-ATT "Use ATT-style assembly" ON)
 403           set(GMX_X86_64_SSE 1)
 404         else(GMX_X86_64_ASM)  #only use intrinsic if not using the ASM loops
 405           if(NOT GMX_IA32_ASM)
 406             set(GMX_SSE2 1)
 407           endif(NOT GMX_IA32_ASM)
 408         endif(GMX_X86_64_ASM)
 409     endif(HAVE_EMMINTRIN_H)
 410 #    if(HAVE_PMMINTRIN_H)
 411 #        set(GMX_SSE3 1)
 412 #    endif(HAVE_PMMINTRIN_H)
 413 #    if(HAVE_SMMINTRIN_H)
 414 #        set(GMX_SSE4_1 1)
 415 #    endif(HAVE_SMMINTRIN_H)
 416
 417 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 418     set(GMX_FORTRAN 1)
 419 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 420     set(GMX_BLUEGENE 1)
 421 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 422     set(GMX_POWER6 1)
 423 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 424     set(GMX_IA64_ASM 1)
 425     set(DISABLE_WATERWATER_NLIST 1)
 426     set(DISABLE_WATER_NLIST 1)
 427 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 428     check_include_files(altivec.h HAVE_ALTIVEC_H)
 429     if(HAVE_ALTIVEC_H)
 430         set(GMX_PPC_ALTIVEC 1)
 431     endif(HAVE_ALTIVEC_H)
 432 else(${GMX_ACCELERATION} STREQUAL "NONE")
 433     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 434 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 435
 436
 437
 438
 439
 440
 441
 442 # Process QM/MM Settings
 443 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 444 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 445     set(GMX_QMMM_GAUSSIAN 1)
 446 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 447     set(GMX_QMMM_MOPAC 1)
 448 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 449     set(GMX_QMMM_GAMESS 1)
 450 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 451     # nothing to do
 452 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 453     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, None")
 454 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 455
 456 # Process FFT library settings - if not OpenMM build
 457 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 458 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 459 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 460     if(GMX_DOUBLE)
 461         find_package(FFTW3 REQUIRED)
 462     else(GMX_DOUBLE)
 463         find_package(FFTW3F REQUIRED)
 464     endif(GMX_DOUBLE)
 465
 466     if(NOT FFTW3_FOUND)
 467         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 468     endif(NOT FFTW3_FOUND)
 469
 470     set(GMX_FFT_FFTW3 1)
 471     include_directories(${FFTW3_INCLUDE_DIR})
 472     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW3_LIBRARIES})
 473
 474 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 475 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 476     if(GMX_DOUBLE)
 477         find_package(FFTW2 REQUIRED)
 478     else(GMX_DOUBLE)
 479         find_package(FFTW2F REQUIRED)
 480     endif(GMX_DOUBLE)
 481
 482     if(NOT FFTW2_FOUND)
 483            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 484     endif(NOT FFTW2_FOUND)
 485     include_directories(${FFTW2_INCLUDE_DIR})
 486     list(APPEND GMX_EXTRA_LIBRARIES ${FFTW2_LIBRARIES})
 487
 488     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 489         set(FFTW2_NAME_DFFTW 1)
 490     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 491         set(FFTW2_NAME_SFFTW 1)
 492     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 493         set(FFTW2_NAME_FFTW 1)
 494     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 495
 496     set(GMX_FFT_FFTW2 1)
 497 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 498 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 499     find_package(MKL REQUIRED)
 500     include_directories(${MKL_INCLUDE_DIR})
 501     list(APPEND GMX_EXTRA_LIBRARIES ${MKL_LIBRARIES})
 502
 503     set(GMX_FFT_MKL 1)
 504     set(HAVE_MKL 1)
 505
 506 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 507 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 508 #    set(GMX_FFT_ACML 1)
 509 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 510     MESSAGE(STATUS "Using internal FFT library - fftpack")
 511     set(GMX_FFT_FFTPACK 1)
 512 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 513     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 514 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 515
 516 # MKL has BLAS/LAPACK routines
 517 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 518   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 519   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 520 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 521   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 522   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 523 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 524
 525 # Math and thread libraries must often come after all others when linking...
 526 if(HAVE_LIBM)
 527     list(APPEND GMX_EXTRA_LIBRARIES m)
 528 endif(HAVE_LIBM)
 529
 530
 531
 532 if(GMX_FAHCORE)
 533   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 534       "Path to swindirect.h")
 535   include_directories(${COREWRAP_INCLUDE_DIR})
 536 endif(GMX_FAHCORE)
 537
 538 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 539 # these are set after everything else
 540 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 541     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 542         FORCE)
 543     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 544         "Flags used by the compiler during all build types" FORCE)
 545     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 546         "Flags used by the compiler during all build types" FORCE)
 547     set(CMAKE_EXE_LINKER_FLAGS
 548         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 549         CACHE STRING "Linker flags" FORCE)
 550 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 551
 552 ########################################################################
 553 # Specify install locations and which subdirectories to process        #
 554 ########################################################################
 555 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 556 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 557 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 558 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 559
 560 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 561
 562
 563 add_subdirectory(share)
 564 add_subdirectory(include)
 565 add_subdirectory(man)
 566
 567 add_subdirectory(src)
 568
 569